libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 if test "$enable_vtable_verify" = yes; then
 101   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 102   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 103 fi
 104
 105
 106 # libtool variables for C++ shared and position-independent compiles.
 107 #
 108 # Use glibcxx_lt_pic_flag to designate the automake variable
 109 # used to encapsulate the default libtool approach to creating objects
 110 # with position-independent code. Default: -prefer-pic.
 111 #
 112 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 113 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 114 #
 115 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 116 # creating position-independent objects. This varies with the target
 117 # hardware and operating system, but is often: -DPIC -fPIC.
 118 if test "$enable_shared" = yes; then
 119   glibcxx_lt_pic_flag="-prefer-pic"
 120   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 121   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 122
 123 else
 124   glibcxx_lt_pic_flag=
 125   glibcxx_compiler_pic_flag=
 126   glibcxx_compiler_shared_flag=
 127 fi
 128 AC_SUBST(glibcxx_lt_pic_flag)
 129 AC_SUBST(glibcxx_compiler_pic_flag)
 130 AC_SUBST(glibcxx_compiler_shared_flag)
 131
 132 # Override the libtool's pic_flag and pic_mode.
 133 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 134 # NB: this impacts --with-pic and --without-pic.
 135 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 136 pic_mode='default'
 137
 138 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 139 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 140
 141 # Possibly disable most of the library.
 142 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 143 ## than just ignoring the results.  Faster /and/ more correct, win win.
 144 GLIBCXX_ENABLE_HOSTED
 145
 146 # Enable descriptive messages to standard output on termination.
 147 GLIBCXX_ENABLE_VERBOSE
 148
 149 # Enable compiler support that doesn't require linking.
 150 GLIBCXX_ENABLE_PCH($is_hosted)
 151 GLIBCXX_ENABLE_THREADS
 152 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 153 GLIBCXX_ENABLE_DECIMAL_FLOAT
 154 GLIBCXX_ENABLE_INT128_FLOAT128
 155 if test "$enable_float128" = yes; then
 156   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 157 fi
 158
 159 # Checks for compiler support that doesn't require linking.
 160 GLIBCXX_CHECK_COMPILER_FEATURES
 161
 162 # Enable all the variable C++ runtime options that don't require linking.
 163 GLIBCXX_ENABLE_CSTDIO
 164 GLIBCXX_ENABLE_CLOCALE
 165 GLIBCXX_ENABLE_ALLOCATOR
 166 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 167 GLIBCXX_ENABLE_LONG_LONG([yes])
 168 GLIBCXX_ENABLE_WCHAR_T([yes])
 169 GLIBCXX_ENABLE_C99([yes])
 170 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 171 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 172 GLIBCXX_ENABLE_DEBUG([no])
 173 GLIBCXX_ENABLE_PARALLEL([yes])
 174 GLIBCXX_ENABLE_CXX_FLAGS
 175 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 176 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 177 GLIBCXX_ENABLE_PYTHON
 178 GLIBCXX_ENABLE_WERROR([no])
 179 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 180
 181 # Checks for operating systems support that doesn't require linking.
 182 GLIBCXX_CHECK_STDIO_PROTO
 183 GLIBCXX_CHECK_MATH11_PROTO
 184 GLIBCXX_CHECK_SYSTEM_ERROR
 185 GLIBCXX_CHECK_UCHAR_H
 186
 187 # For the streamoff typedef.
 188 GLIBCXX_CHECK_INT64_T
 189
 190 # For LFS support.
 191 GLIBCXX_CHECK_LFS
 192
 193 # For showmanyc_helper().
 194 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 195 GLIBCXX_CHECK_POLL
 196 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 197
 198 # For xsputn_2().
 199 AC_CHECK_HEADERS(sys/uio.h)
 200 GLIBCXX_CHECK_WRITEV
 201
 202 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 203 # so that the check is done with the C compiler (not C++).
 204 # Checking with C++ can break a canadian cross build if either
 205 # file does not exist in C but does in C++.
 206 AC_CHECK_HEADERS(fenv.h complex.h)
 207
 208 # For C99 support to TR1.
 209 GLIBCXX_CHECK_C99_TR1
 210
 211 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 212 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 213
 214 # For gettimeofday support.
 215 GLIBCXX_CHECK_GETTIMEOFDAY
 216
 217 # For clock_gettime, nanosleep and sched_yield support.
 218 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 219
 220 # Check for tmpnam which is obsolescent in POSIX.1-2008
 221 GLIBCXX_CHECK_TMPNAM
 222
 223 AC_LC_MESSAGES
 224
 225 # For hardware_concurrency
 226 AC_CHECK_HEADERS(sys/sysinfo.h)
 227 GLIBCXX_CHECK_GET_NPROCS
 228 AC_CHECK_HEADERS(unistd.h)
 229 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 230 GLIBCXX_CHECK_SC_NPROC_ONLN
 231 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 232 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 233 GLIBCXX_CHECK_SDT_H
 234
 235 # Check for available headers.
 236 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 237 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 238 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 239 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 240 wchar.h wctype.h linux/types.h])
 241
 242 AC_CHECK_HEADERS([linux/random.h], [], [],
 243 [[#ifdef HAVE_LINUX_TYPES_H
 244 # include <linux/types.h>
 245 #endif
 246 ]])
 247
 248 # Only do link tests if native. Else, hardcode.
 249 if $GLIBCXX_IS_NATIVE; then
 250
 251   # We can do more elaborate tests that assume a working linker.
 252   CANADIAN=no
 253
 254   GLIBCXX_CHECK_LINKER_FEATURES
 255   GLIBCXX_CHECK_MATH_SUPPORT
 256   GLIBCXX_CHECK_STDLIB_SUPPORT
 257
 258   # For /dev/random and /dev/urandom for TR1.
 259   GLIBCXX_CHECK_RANDOM_TR1
 260
 261   # For TLS support.
 262   GCC_CHECK_TLS
 263
 264   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 265   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 266   AC_CHECK_FUNCS(_wfopen)
 267
 268   # For iconv support.
 269   AM_ICONV
 270
 271 else
 272
 273   # This lets us hard-code the functionality we know we'll have in the cross
 274   # target environment.  "Let" is a sugar-coated word placed on an especially
 275   # dull and tedious hack, actually.
 276   #
 277   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 278   # that involve linking, can't be used:
 279   #    "cannot open sim-crt0.o"
 280   #    "cannot open crt0.o"
 281   # etc.  All this is because there currently exists no unified, consistent
 282   # way for top level CC information to be passed down to target directories:
 283   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 284   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 285   # crosses can be removed.
 286
 287   # If Canadian cross, then don't pick up tools from the build directory.
 288   # Used only in GLIBCXX_EXPORT_INCLUDES.
 289   if test -n "$with_cross_host" &&
 290      test x"$build_alias" != x"$with_cross_host" &&
 291      test x"$build" != x"$target";
 292   then
 293     CANADIAN=yes
 294   else
 295     CANADIAN=no
 296   fi
 297
 298   # Construct crosses by hand, eliminating bits that need ld...
 299   # GLIBCXX_CHECK_MATH_SUPPORT
 300
 301   # First, test for "known" system libraries.  We may be using newlib even
 302   # on a hosted environment.
 303   if test "x${with_newlib}" = "xyes"; then
 304     os_include_dir="os/newlib"
 305     AC_DEFINE(HAVE_HYPOT)
 306
 307     # GLIBCXX_CHECK_STDLIB_SUPPORT
 308     AC_DEFINE(HAVE_STRTOF)
 309
 310     AC_DEFINE(HAVE_ACOSF)
 311     AC_DEFINE(HAVE_ASINF)
 312     AC_DEFINE(HAVE_ATAN2F)
 313     AC_DEFINE(HAVE_ATANF)
 314     AC_DEFINE(HAVE_CEILF)
 315     AC_DEFINE(HAVE_COSF)
 316     AC_DEFINE(HAVE_COSHF)
 317     AC_DEFINE(HAVE_EXPF)
 318     AC_DEFINE(HAVE_FABSF)
 319     AC_DEFINE(HAVE_FLOORF)
 320     AC_DEFINE(HAVE_FMODF)
 321     AC_DEFINE(HAVE_FREXPF)
 322     AC_DEFINE(HAVE_LDEXPF)
 323     AC_DEFINE(HAVE_LOG10F)
 324     AC_DEFINE(HAVE_LOGF)
 325     AC_DEFINE(HAVE_MODFF)
 326     AC_DEFINE(HAVE_POWF)
 327     AC_DEFINE(HAVE_SINF)
 328     AC_DEFINE(HAVE_SINHF)
 329     AC_DEFINE(HAVE_SQRTF)
 330     AC_DEFINE(HAVE_TANF)
 331     AC_DEFINE(HAVE_TANHF)
 332
 333     AC_DEFINE(HAVE_ICONV)
 334     AC_DEFINE(HAVE_MEMALIGN)
 335   else
 336     GLIBCXX_CROSSCONFIG
 337   fi
 338
 339   # At some point, we should differentiate between architectures
 340   # like x86, which have long double versions, and alpha/powerpc/etc.,
 341   # which don't. For the time being, punt.
 342   if test x"long_double_math_on_this_cpu" = x"yes"; then
 343     AC_DEFINE(HAVE_ACOSL)
 344     AC_DEFINE(HAVE_ASINL)
 345     AC_DEFINE(HAVE_ATAN2L)
 346     AC_DEFINE(HAVE_ATANL)
 347     AC_DEFINE(HAVE_CEILL)
 348     AC_DEFINE(HAVE_COSL)
 349     AC_DEFINE(HAVE_COSHL)
 350     AC_DEFINE(HAVE_EXPL)
 351     AC_DEFINE(HAVE_FABSL)
 352     AC_DEFINE(HAVE_FLOORL)
 353     AC_DEFINE(HAVE_FMODL)
 354     AC_DEFINE(HAVE_FREXPL)
 355     AC_DEFINE(HAVE_LDEXPL)
 356     AC_DEFINE(HAVE_LOG10L)
 357     AC_DEFINE(HAVE_LOGL)
 358     AC_DEFINE(HAVE_MODFL)
 359     AC_DEFINE(HAVE_POWL)
 360     AC_DEFINE(HAVE_SINCOSL)
 361     AC_DEFINE(HAVE_SINL)
 362     AC_DEFINE(HAVE_SINHL)
 363     AC_DEFINE(HAVE_SQRTL)
 364     AC_DEFINE(HAVE_TANL)
 365     AC_DEFINE(HAVE_TANHL)
 366   fi
 367 fi
 368
 369 # Check for _Unwind_GetIPInfo.
 370 GCC_CHECK_UNWIND_GETIPINFO
 371
 372 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 373
 374 GCC_HEADER_STDINT(include/gstdint.h)
 375
 376 GLIBCXX_ENABLE_SYMVERS([yes])
 377 AC_SUBST(libtool_VERSION)
 378
 379 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 380
 381 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 382 GLIBCXX_DEFAULT_ABI
 383
 384 ac_ldbl_compat=no
 385 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 386 case "$target" in
 387   powerpc*-*-linux* | \
 388   sparc*-*-linux* | \
 389   s390*-*-linux* | \
 390   alpha*-*-linux*)
 391   AC_TRY_COMPILE(, [
 392 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 393 #error no need for long double compatibility
 394 #endif
 395   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 396   if test "$ac_ldbl_compat" = yes; then
 397     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 398               [Define if compatibility should be provided for -mlong-double-64.])
 399     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 400     case "$target" in
 401       powerpc*-*-linux*)
 402         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
 403     esac
 404   fi
 405 esac
 406 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 407 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 408
 409 # Check if assembler supports disabling hardware capability support.
 410 GCC_CHECK_ASSEMBLER_HWCAP
 411
 412 # Check if assembler supports rdrand opcode.
 413 GLIBCXX_CHECK_X86_RDRAND
 414
 415 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 416 GLIBCXX_CONFIGURE_TESTSUITE
 417
 418 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 419 GLIBCXX_CHECK_GTHREADS
 420
 421 # For Filesystem TS.
 422 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 423 GLIBCXX_ENABLE_FILESYSTEM_TS
 424 GLIBCXX_CHECK_FILESYSTEM_DEPS
 425
 426 # For Transactional Memory TS
 427 GLIBCXX_CHECK_SIZE_T_MANGLING
 428
 429 # Check which release added std::exception_ptr for the target
 430 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 431
 432 # Define documentation rules conditionally.
 433
 434 # See if makeinfo has been installed and is modern enough
 435 # that we can use it.
 436 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 437                    [GNU texinfo.* \([0-9][0-9.]*\)],
 438                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 439 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 440
 441 # Check for doxygen
 442 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 443 AC_CHECK_PROG([DOT], dot, yes, no)
 444
 445 # Check for docbook
 446 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 447 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 448 GLIBCXX_CONFIGURE_DOCBOOK
 449
 450 # Check for xml/html dependencies.
 451 AM_CONDITIONAL(BUILD_XML,
 452                test $ac_cv_prog_DOXYGEN = "yes" &&
 453                test $ac_cv_prog_DOT = "yes" &&
 454                test $ac_cv_prog_XSLTPROC = "yes" &&
 455                test $ac_cv_prog_XMLLINT = "yes" &&
 456                test $glibcxx_stylesheets = "yes")
 457
 458 AM_CONDITIONAL(BUILD_HTML,
 459                test $ac_cv_prog_DOXYGEN = "yes" &&
 460                test $ac_cv_prog_DOT = "yes" &&
 461                test $ac_cv_prog_XSLTPROC = "yes" &&
 462                test $ac_cv_prog_XMLLINT = "yes" &&
 463                test $glibcxx_stylesheets = "yes")
 464
 465 # Check for man dependencies.
 466 AM_CONDITIONAL(BUILD_MAN,
 467                test $ac_cv_prog_DOXYGEN = "yes" &&
 468                test $ac_cv_prog_DOT = "yes")
 469
 470 # Check for pdf dependencies.
 471 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 472 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 473 AM_CONDITIONAL(BUILD_PDF,
 474                test $ac_cv_prog_DBLATEX = "yes" &&
 475                test $ac_cv_prog_PDFLATEX = "yes")
 476
 477 case "$build" in
 478  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 479  * ) glibcxx_include_dir_notparallel=no ;;
 480 esac
 481 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 482                test $glibcxx_include_dir_notparallel = "yes")
 483
 484 # Propagate the target-specific source directories through the build chain.
 485 ATOMICITY_SRCDIR=config/${atomicity_dir}
 486 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 487 ATOMIC_FLAGS=${atomic_flags}
 488 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 489 OS_INC_SRCDIR=config/${os_include_dir}
 490 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 491 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 492 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 493 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 494 AC_SUBST(ATOMICITY_SRCDIR)
 495 AC_SUBST(ATOMIC_WORD_SRCDIR)
 496 AC_SUBST(ATOMIC_FLAGS)
 497 AC_SUBST(CPU_DEFINES_SRCDIR)
 498 AC_SUBST(ABI_TWEAKS_SRCDIR)
 499 AC_SUBST(OS_INC_SRCDIR)
 500 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 501 AC_SUBST(CPU_OPT_EXT_RANDOM)
 502 AC_SUBST(CPU_OPT_BITS_RANDOM)
 503
 504
 505 # Add CET specific flags if Intel CET is enabled.
 506 GCC_CET_FLAGS(CET_FLAGS)
 507 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 508 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 509 AC_SUBST(EXTRA_CFLAGS)
 510 AC_SUBST(EXTRA_CXX_FLAGS)
 511
 512 # Determine cross-compile flags and AM_CONDITIONALs.
 513 #AC_SUBST(GLIBCXX_IS_NATIVE)
 514 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 515 GLIBCXX_EVALUATE_CONDITIONALS
 516
 517 AC_CACHE_SAVE
 518
 519 if test ${multilib} = yes; then
 520   multilib_arg="--enable-multilib"
 521 else
 522   multilib_arg=
 523 fi
 524
 525 # Export all the install information.
 526 GLIBCXX_EXPORT_INSTALL_INFO
 527
 528 # Export all the include and flag information to Makefiles.
 529 GLIBCXX_EXPORT_INCLUDES
 530 GLIBCXX_EXPORT_FLAGS
 531
 532 # Determine what GCC version number to use in filesystem paths.
 533 GCC_BASE_VER
 534
 535 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 536 dnl which can all be called multiple times as needed, plus one (different)
 537 dnl AC_OUTPUT macro.  This one lists the files to be created:
 538 AC_CONFIG_FILES(Makefile)
 539 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 540 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 541 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 542
 543 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 544 # that multilib installs will end up installed in the correct place.
 545 # The testsuite needs it for multilib-aware ABI baseline files.
 546 # To work around this not being passed down from config-ml.in ->
 547 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 548 # append it here.  Only modify Makefiles that have just been created.
 549 #
 550 # Also, get rid of this simulated-VPATH thing that automake does.
 551 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 552   [cat > vpsed$$ << \_EOF
 553 s!`test -f '$<' || echo '$(srcdir)/'`!!
 554 _EOF
 555    sed -f vpsed$$ $ac_file > tmp$$
 556    mv tmp$$ $ac_file
 557    rm vpsed$$
 558    echo 'MULTISUBDIR =' >> $ac_file
 559    ml_norecursion=yes
 560    . ${multi_basedir}/config-ml.in
 561    AS_UNSET([ml_norecursion])
 562 ])
 563
 564 AC_CONFIG_COMMANDS([generate-headers],
 565   [(cd include && ${MAKE-make} pch_build= )])
 566
 567 dnl And this actually makes things happen:
 568 AC_OUTPUT