gcc/optc-gen.awk

   1 #  Copyright (C) 2003-2018 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23
  24 # This program uses functions from opt-functions.awk and code from
  25 # opt-read.awk.
  26 #
  27 # Usage: awk -f opt-functions.awk -f opt-read.awk -f optc-gen.awk \
  28 #            [-v header_name=header.h] < inputfile > options.c
  29
  30 # Dump that array of options into a C file.
  31 END {
  32
  33
  34 # Combine the flags of identical switches.  Switches
  35 # appear many times if they are handled by many front
  36 # ends, for example.
  37 for (i = 0; i < n_opts; i++) {
  38     merged_flags[i] = flags[i]
  39 }
  40 for (i = 0; i < n_opts; i++) {
  41     while(i + 1 != n_opts && opts[i] == opts[i + 1] ) {
  42         merged_flags[i + 1] = merged_flags[i] " " merged_flags[i + 1];
  43         i++;
  44     }
  45 }
  46
  47 # Record EnabledBy and LangEnabledBy uses.
  48 n_enabledby = 0;
  49 for (i = 0; i < n_langs; i++) {
  50     n_enabledby_lang[i] = 0;
  51 }
  52 for (i = 0; i < n_opts; i++) {
  53     enabledby_arg = opt_args("EnabledBy", flags[i]);
  54     if (enabledby_arg != "") {
  55         logical_and = index(enabledby_arg, " && ");
  56         if (logical_and != 0) {
  57             # EnabledBy(arg1 && arg2)
  58             split_sep = " && ";
  59         } else {
  60             # EnabledBy(arg) or EnabledBy(arg1 || arg2 || arg3)
  61             split_sep = " \\|\\| ";
  62         }
  63         n_enabledby_names = split(enabledby_arg, enabledby_names, split_sep);
  64         if (logical_and != 0 && n_enabledby_names > 2) {
  65             print "#error " opts[i] " EnabledBy(Wfoo && Wbar && Wbaz) currently not supported"
  66         }
  67         for (j = 1; j <= n_enabledby_names; j++) {
  68             enabledby_name = enabledby_names[j];
  69             enabledby_index = opt_numbers[enabledby_name];
  70             if (enabledby_index == "") {
  71                 print "#error " opts[i] " Enabledby(" enabledby_name "), unknown option '" enabledby_name "'"
  72             } else if (!flag_set_p("Common", merged_flags[enabledby_index])) {
  73                 print "#error " opts[i] " Enabledby(" enabledby_name "), '" \
  74                     enabledby_name "' must have flag 'Common'"          \
  75                     " to use Enabledby(), otherwise use LangEnabledBy()"
  76             } else {
  77                 condition = "";
  78                 if (logical_and != 0) {
  79                     opt_var_name_1 = search_var_name(enabledby_names[1], opt_numbers, opts, flags, n_opts);
  80                     opt_var_name_2 = search_var_name(enabledby_names[2], opt_numbers, opts, flags, n_opts);
  81                     if (opt_var_name_1 == "") {
  82                         print "#error " enabledby_names[1] " does not have a Var() flag"
  83                     }
  84                     if (opt_var_name_2 == "") {
  85                         print "#error " enabledby_names[2] " does not have a Var() flag"
  86                     }
  87                     condition = "opts->x_" opt_var_name_1 " && opts->x_" opt_var_name_2;
  88                 }
  89                 if (enables[enabledby_name] == "") {
  90                     enabledby[n_enabledby] = enabledby_name;
  91                     n_enabledby++;
  92                 }
  93                 enables[enabledby_name] = enables[enabledby_name] opts[i] ";";
  94                 enablesif[enabledby_name] = enablesif[enabledby_name] condition ";";
  95             }
  96         }
  97     }
  98
  99     enabledby_arg = opt_args("LangEnabledBy", flags[i]);
 100     if (enabledby_arg != "") {
 101         enabledby_langs = nth_arg(0, enabledby_arg);
 102         enabledby_name = nth_arg(1, enabledby_arg);
 103         enabledby_posarg = nth_arg(2, enabledby_arg);
 104         enabledby_negarg = nth_arg(3, enabledby_arg);
 105         lang_enabled_by(enabledby_langs, enabledby_name, enabledby_posarg, enabledby_negarg);
 106     }
 107 }
 108
 109
 110 print "/* This file is auto-generated by optc-gen.awk.  */"
 111 print ""
 112 n_headers = split(header_name, headers, " ")
 113 for (i = 1; i <= n_headers; i++)
 114         print "#include " quote headers[i] quote
 115 print "#include " quote "opts.h" quote
 116 print "#include " quote "intl.h" quote
 117 print "#include " quote "insn-attr-common.h" quote
 118 print ""
 119
 120 if (n_extra_c_includes > 0) {
 121         for (i = 0; i < n_extra_c_includes; i++) {
 122                 print "#include " quote extra_c_includes[i] quote
 123         }
 124         print ""
 125 }
 126
 127 for (i = 0; i < n_enums; i++) {
 128         name = enum_names[i]
 129         type = enum_type[name]
 130         print "static const struct cl_enum_arg cl_enum_" name \
 131             "_data[] = "
 132         print "{"
 133         print enum_data[name] "  { NULL, 0, 0 }"
 134         print "};"
 135         print ""
 136         print "static void"
 137         print "cl_enum_" name "_set (void *var, int value)"
 138         print "{"
 139         print "  *((" type " *) var) = (" type ") value;"
 140         print "}"
 141         print ""
 142         print "static int"
 143         print "cl_enum_" name "_get (const void *var)"
 144         print "{"
 145         print "  return (int) *((const " type " *) var);"
 146         print "}"
 147         print ""
 148 }
 149
 150 print "const struct cl_enum cl_enums[] ="
 151 print "{"
 152 for (i = 0; i < n_enums; i++) {
 153         name = enum_names[i]
 154         ehelp = enum_help[name]
 155         if (ehelp == "")
 156                 ehelp = "NULL"
 157         else
 158                 ehelp = quote ehelp quote
 159         unknown_error = enum_unknown_error[name]
 160         if (unknown_error == "")
 161                 unknown_error = "NULL"
 162         else
 163                 unknown_error = quote unknown_error quote
 164         print "  {"
 165         print "    " ehelp ","
 166         print "    " unknown_error ","
 167         print "    cl_enum_" name "_data,"
 168         print "    sizeof (" enum_type[name] "),"
 169         print "    cl_enum_" name "_set,"
 170         print "    cl_enum_" name "_get"
 171         print "  },"
 172 }
 173 print "};"
 174 print "const unsigned int cl_enums_count = " n_enums ";"
 175 print ""
 176
 177 print "const struct gcc_options global_options_init =\n{"
 178 for (i = 0; i < n_extra_vars; i++) {
 179         var = extra_vars[i]
 180         init = extra_vars[i]
 181         if (var ~ "=" ) {
 182                 sub(".*= *", "", init)
 183         } else {
 184                 init = "0"
 185         }
 186         sub(" *=.*", "", var)
 187         name = var
 188         sub("^.*[ *]", "", name)
 189         sub("\\[.*\\]$", "", name)
 190         var_seen[name] = 1
 191         print "  " init ", /* " name " */"
 192 }
 193 for (i = 0; i < n_opts; i++) {
 194         name = var_name(flags[i]);
 195         if (name == "")
 196                 continue;
 197
 198         init = opt_args("Init", flags[i])
 199         if (init != "") {
 200                 if (name in var_init && var_init[name] != init)
 201                         print "#error multiple initializers for " name
 202                 var_init[name] = init
 203         }
 204 }
 205 for (i = 0; i < n_opts; i++) {
 206         name = var_name(flags[i]);
 207         if (name == "")
 208                 continue;
 209
 210         if (name in var_seen)
 211                 continue;
 212
 213         if (name in var_init)
 214                 init = var_init[name]
 215         else
 216                 init = "0"
 217
 218         print "  " init ", /* " name " */"
 219
 220         var_seen[name] = 1;
 221 }
 222 for (i = 0; i < n_opts; i++) {
 223         name = static_var(opts[i], flags[i]);
 224         if (name != "") {
 225                 print "  0, /* " name " (private state) */"
 226                 print "#undef x_" name
 227         }
 228 }
 229 for (i = 0; i < n_opts; i++) {
 230         if (flag_set_p("SetByCombined", flags[i]))
 231                 print "  false, /* frontend_set_" var_name(flags[i]) " */"
 232 }
 233 print "};"
 234 print ""
 235 print "struct gcc_options global_options;"
 236 print "struct gcc_options global_options_set;"
 237 print ""
 238
 239 print "const char * const lang_names[] =\n{"
 240 for (i = 0; i < n_langs; i++) {
 241         macros[i] = "CL_" lang_sanitized_name(langs[i])
 242         s = substr("         ", length (macros[i]))
 243         print "  " quote langs[i] quote ","
 244     }
 245
 246 print "  0\n};\n"
 247 print "const unsigned int cl_options_count = N_OPTS;\n"
 248 print "#if (1U << " n_langs ") > CL_MIN_OPTION_CLASS"
 249 print "  #error the number of languages exceeds the implementation limit"
 250 print "#endif"
 251 print "const unsigned int cl_lang_count = " n_langs ";\n"
 252
 253 print "const struct cl_option cl_options[] =\n{"
 254
 255 j = 0
 256 for (i = 0; i < n_opts; i++) {
 257         back_chain[i] = "N_OPTS";
 258         indices[opts[i]] = j;
 259         # Combine the flags of identical switches.  Switches
 260         # appear many times if they are handled by many front
 261         # ends, for example.
 262         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 263                 flags[i + 1] = flags[i] " " flags[i + 1];
 264                 if (help[i + 1] == "")
 265                         help[i + 1] = help[i]
 266                 else if (help[i] != "" && help[i + 1] != help[i])
 267                         print "#error Multiple different help strings for " \
 268                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1]
 269
 270                 i++;
 271                 back_chain[i] = "N_OPTS";
 272                 indices[opts[i]] = j;
 273         }
 274         j++;
 275 }
 276
 277 optindex = 0
 278 for (i = 0; i < n_opts; i++) {
 279         # With identical flags, pick only the last one.  The
 280         # earlier loop ensured that it has all flags merged,
 281         # and a nonempty help text if one of the texts was nonempty.
 282         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 283                 i++;
 284         }
 285
 286         len = length (opts[i]);
 287         enum = opt_enum(opts[i])
 288
 289         # If this switch takes joined arguments, back-chain all
 290         # subsequent switches to it for which it is a prefix.  If
 291         # a later switch S is a longer prefix of a switch T, T
 292         # will be back-chained to S in a later iteration of this
 293         # for() loop, which is what we want.
 294         if (flag_set_p("Joined.*", flags[i])) {
 295                 for (j = i + 1; j < n_opts; j++) {
 296                         if (substr (opts[j], 1, len) != opts[i])
 297                                 break;
 298                         back_chain[j] = enum;
 299                 }
 300         }
 301
 302         s = substr("                                  ", length (opts[i]))
 303         if (i + 1 == n_opts)
 304                 comma = ""
 305
 306         if (help[i] == "")
 307                 hlp = "NULL"
 308         else
 309                 hlp = quote help[i] quote;
 310
 311         missing_arg_error = opt_args("MissingArgError", flags[i])
 312         if (missing_arg_error == "")
 313                 missing_arg_error = "NULL"
 314         else
 315                 missing_arg_error = quote missing_arg_error quote
 316
 317
 318         warn_message = opt_args("Warn", flags[i])
 319         if (warn_message == "")
 320                 warn_message = "NULL"
 321         else
 322                 warn_message = quote warn_message quote
 323
 324         alias_arg = opt_args("Alias", flags[i])
 325         if (alias_arg == "") {
 326                 if (flag_set_p("Ignore", flags[i]))
 327                         alias_data = "NULL, NULL, OPT_SPECIAL_ignore"
 328                 else
 329                         alias_data = "NULL, NULL, N_OPTS"
 330                 if (flag_set_p("Enum.*", flags[i])) {
 331                         if (!flag_set_p("RejectNegative", flags[i]) \
 332                             && opts[i] ~ "^[Wfgm]")
 333                                 print "#error Enum allowing negative form"
 334                 }
 335         } else {
 336                 alias_opt = nth_arg(0, alias_arg)
 337                 alias_posarg = nth_arg(1, alias_arg)
 338                 alias_negarg = nth_arg(2, alias_arg)
 339
 340                 if (var_ref(opts[i], flags[i]) != "(unsigned short) -1")
 341                         print "#error Alias setting variable"
 342
 343                 if (alias_posarg != "" && alias_negarg == "") {
 344                         if (!flag_set_p("RejectNegative", flags[i]) \
 345                             && opts[i] ~ "^[Wfm]")
 346                                 print "#error Alias with single argument " \
 347                                         "allowing negative form"
 348                 }
 349                 if (alias_posarg != "" \
 350                     && flag_set_p("NegativeAlias", flags[i])) {
 351                         print "#error Alias with multiple arguments " \
 352                                 "used with NegativeAlias"
 353                 }
 354
 355                 alias_opt = opt_enum(alias_opt)
 356                 if (alias_posarg == "")
 357                         alias_posarg = "NULL"
 358                 else
 359                         alias_posarg = quote alias_posarg quote
 360                 if (alias_negarg == "")
 361                         alias_negarg = "NULL"
 362                 else
 363                         alias_negarg = quote alias_negarg quote
 364                 alias_data = alias_posarg ", " alias_negarg ", " alias_opt
 365         }
 366
 367         neg = opt_args("Negative", flags[i]);
 368         if (neg != "")
 369                 idx = indices[neg]
 370         else {
 371                 if (flag_set_p("RejectNegative", flags[i]))
 372                         idx = -1;
 373                 else {
 374                         if (opts[i] ~ "^[Wfgm]")
 375                                 idx = indices[opts[i]];
 376                         else
 377                                 idx = -1;
 378                 }
 379         }
 380         # Split the printf after %u to work around an ia64-hp-hpux11.23
 381         # awk bug.
 382         printf(" /* [%i] = */ {\n", optindex)
 383         printf("    %c-%s%c,\n    %s,\n    %s,\n    %s,\n    %s, %s, %u,",
 384                quote, opts[i], quote, hlp, missing_arg_error, warn_message,
 385                alias_data, back_chain[i], len)
 386         printf(" /* .neg_idx = */ %d,\n", idx)
 387         condition = opt_args("Condition", flags[i])
 388         cl_flags = switch_flags(flags[i])
 389         cl_bit_fields = switch_bit_fields(flags[i])
 390         cl_zero_bit_fields = switch_bit_fields("")
 391         if (condition != "")
 392                 printf("#if %s\n" \
 393                        "    %s,\n" \
 394                        "    0, %s,\n" \
 395                        "#else\n" \
 396                        "    0,\n" \
 397                        "    1 /* Disabled.  */, %s,\n" \
 398                        "#endif\n",
 399                        condition, cl_flags, cl_bit_fields, cl_zero_bit_fields)
 400         else
 401                 printf("    %s,\n" \
 402                        "    0, %s,\n",
 403                        cl_flags, cl_bit_fields)
 404         printf("    %s, %s, %s }%s\n", var_ref(opts[i], flags[i]),
 405                var_set(flags[i]), integer_range_info(opt_args("IntegerRange", flags[i]),
 406                     opt_args("Init", flags[i]), opts[i]), comma)
 407
 408         # Bump up the informational option index.
 409         ++optindex
 410  }
 411
 412 print "};"
 413
 414 print "\n\n"
 415 print "bool                                                                  "
 416 print "common_handle_option_auto (struct gcc_options *opts,                  "
 417 print "                           struct gcc_options *opts_set,              "
 418 print "                           const struct cl_decoded_option *decoded,   "
 419 print "                           unsigned int lang_mask, int kind,          "
 420 print "                           location_t loc,                            "
 421 print "                           const struct cl_option_handlers *handlers, "
 422 print "                           diagnostic_context *dc)                    "
 423 print "{                                                                     "
 424 print "  size_t scode = decoded->opt_index;                                  "
 425 print "  HOST_WIDE_INT value = decoded->value;                               "
 426 print "  enum opt_code code = (enum opt_code) scode;                         "
 427 print "                                                                      "
 428 print "  gcc_assert (decoded->canonical_option_num_elements <= 2);           "
 429 print "                                                                      "
 430 print "  switch (code)                                                       "
 431 print "    {                                                                 "
 432 # Handle EnabledBy
 433 for (i = 0; i < n_enabledby; i++) {
 434     enabledby_name = enabledby[i];
 435     print "    case " opt_enum(enabledby_name) ":"
 436     n_enables = split(enables[enabledby_name], thisenable, ";");
 437     n_enablesif = split(enablesif[enabledby_name], thisenableif, ";");
 438     if (n_enables != n_enablesif) {
 439         print "#error n_enables != n_enablesif: Something went wrong!"
 440     }
 441     for (j = 1; j < n_enables; j++) {
 442         opt_var_name = var_name(flags[opt_numbers[thisenable[j]]]);
 443         if (opt_var_name != "") {
 444             condition = "!opts_set->x_" opt_var_name
 445             if (thisenableif[j] != "") {
 446                 value = "(" thisenableif[j] ")"
 447             } else {
 448                 value = "value"
 449             }
 450             print "      if (" condition ")"
 451             print "        handle_generated_option (opts, opts_set,"
 452             print "                                 " opt_enum(thisenable[j]) ", NULL, " value ","
 453             print "                                 lang_mask, kind, loc, handlers, true, dc);"
 454         } else {
 455             print "#error " thisenable[j] " does not have a Var() flag"
 456         }
 457     }
 458     print "      break;\n"
 459 }
 460 print "    default:    "
 461 print "      break;    "
 462 print "    }           "
 463 print "  return true;  "
 464 print "}               "
 465
 466 # Handle LangEnabledBy
 467 for (i = 0; i < n_langs; i++) {
 468     lang_name = lang_sanitized_name(langs[i]);
 469     mark_unused = " ATTRIBUTE_UNUSED";
 470
 471     print "\n\n"
 472     print "bool                                                                  "
 473     print lang_name "_handle_option_auto (struct gcc_options *opts" mark_unused ",              "
 474     print "                           struct gcc_options *opts_set" mark_unused ",              "
 475     print "                           size_t scode" mark_unused ", const char *arg" mark_unused ", HOST_WIDE_INT value" mark_unused ",  "
 476     print "                           unsigned int lang_mask" mark_unused ", int kind" mark_unused ",          "
 477     print "                           location_t loc" mark_unused ",                            "
 478     print "                           const struct cl_option_handlers *handlers" mark_unused ", "
 479     print "                           diagnostic_context *dc" mark_unused ")                    "
 480     print "{                                                                     "
 481     print "  enum opt_code code = (enum opt_code) scode;                         "
 482     print "                                                                      "
 483     print "  switch (code)                                                       "
 484     print "    {                                                                 "
 485
 486     for (k = 0; k < n_enabledby_lang[i]; k++) {
 487         enabledby_name = enabledby[lang_name,k];
 488         print "    case " opt_enum(enabledby_name) ":"
 489         n_thisenable = split(enables[lang_name,enabledby_name], thisenable, ";");
 490         for (j = 1; j < n_thisenable; j++) {
 491             n_thisenable_args = split(thisenable[j], thisenable_args, ",");
 492             if (n_thisenable_args == 1) {
 493                 thisenable_opt = thisenable[j];
 494                 value = "value";
 495             } else {
 496                 thisenable_opt = thisenable_args[1];
 497                 with_posarg = thisenable_args[2];
 498                 with_negarg = thisenable_args[3];
 499                 value = "value ? " with_posarg " : " with_negarg;
 500             }
 501             opt_var_name = var_name(flags[opt_numbers[thisenable_opt]]);
 502             if (opt_var_name != "") {
 503                 print "      if (!opts_set->x_" opt_var_name ")"
 504                 print "        handle_generated_option (opts, opts_set,"
 505                 print "                                 " opt_enum(thisenable_opt) ", NULL, " value ","
 506                 print "                                 lang_mask, kind, loc, handlers, true, dc);"
 507             } else {
 508                 print "#error " thisenable_opt " does not have a Var() flag"
 509             }
 510         }
 511         print "      break;\n"
 512     }
 513     print "    default:    "
 514     print "      break;    "
 515     print "    }           "
 516     print "  return true;  "
 517     print "}               "
 518 }
 519
 520 #Handle CPP()
 521 print "\n"
 522 print "#include " quote "cpplib.h" quote;
 523 print "void"
 524 print "cpp_handle_option_auto (const struct gcc_options * opts,                   "
 525 print "                        size_t scode, struct cpp_options * cpp_opts)"
 526 print "{                                                                     "
 527 print "  enum opt_code code = (enum opt_code) scode;                         "
 528 print "                                                                      "
 529 print "  switch (code)                                                       "
 530 print "    {                                                                 "
 531 for (i = 0; i < n_opts; i++) {
 532     # With identical flags, pick only the last one.  The
 533     # earlier loop ensured that it has all flags merged,
 534     # and a nonempty help text if one of the texts was nonempty.
 535     while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 536         i++;
 537     }
 538
 539     cpp_option = nth_arg(0, opt_args("CPP", flags[i]));
 540     if (cpp_option != "") {
 541         opt_var_name = var_name(flags[i]);
 542         init = opt_args("Init", flags[i])
 543         if (opt_var_name != "" && init != "") {
 544             print "    case " opt_enum(opts[i]) ":"
 545             print "      cpp_opts->" cpp_option " = opts->x_" opt_var_name ";"
 546             print "      break;"
 547         } else if (opt_var_name == "" && init == "") {
 548             print "#error CPP() requires setting Init() and Var() for " opts[i]
 549         } else if (opt_var_name != "") {
 550             print "#error CPP() requires setting Init() for " opts[i]
 551         } else {
 552             print "#error CPP() requires setting Var() for " opts[i]
 553         }
 554     }
 555 }
 556 print "    default:    "
 557 print "      break;    "
 558 print "    }           "
 559 print "}\n"
 560 print "void"
 561 print "init_global_opts_from_cpp(struct gcc_options * opts,                   "
 562 print "                         const struct cpp_options * cpp_opts)"
 563 print "{                                                                     "
 564 for (i = 0; i < n_opts; i++) {
 565     # With identical flags, pick only the last one.  The
 566     # earlier loop ensured that it has all flags merged,
 567     # and a nonempty help text if one of the texts was nonempty.
 568     while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 569         i++;
 570     }
 571     cpp_option = nth_arg(0, opt_args("CPP", flags[i]));
 572     opt_var_name = var_name(flags[i]);
 573     if (cpp_option != "" && opt_var_name != "") {
 574         print "  opts->x_" opt_var_name " = cpp_opts->" cpp_option ";"
 575     }
 576 }
 577 print "}               "
 578
 579 }
 580