gcc/ada/s-imgllw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ L L W                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System.Unsigned_Types; use System.Unsigned_Types;
  36
  37 package body System.Img_LLW is
  38
  39    ---------------------------------------
  40    -- Set_Image_Width_Long_Long_Integer --
  41    ---------------------------------------
  42
  43    procedure Set_Image_Width_Long_Long_Integer
  44      (V : Long_Long_Integer;
  45       W : Integer;
  46       S : out String;
  47       P : in out Natural)
  48    is
  49       Start : Natural;
  50
  51    begin
  52       --  Positive case can just use the unsigned circuit directly
  53
  54       if V >= 0 then
  55          Set_Image_Width_Long_Long_Unsigned
  56            (Long_Long_Unsigned (V), W, S, P);
  57
  58       --  Negative case has to set a minus sign. Note also that we have to be
  59       --  careful not to generate overflow with the largest negative number.
  60
  61       else
  62          P := P + 1;
  63          S (P) := ' ';
  64          Start := P;
  65
  66          declare
  67             pragma Suppress (Overflow_Check);
  68             pragma Suppress (Range_Check);
  69          begin
  70             Set_Image_Width_Long_Long_Unsigned
  71               (Long_Long_Unsigned (-V), W - 1, S, P);
  72          end;
  73
  74          --  Set minus sign in last leading blank location. Because of the
  75          --  code above, there must be at least one such location.
  76
  77          while S (Start + 1) = ' ' loop
  78             Start := Start + 1;
  79          end loop;
  80
  81          S (Start) := '-';
  82       end if;
  83
  84    end Set_Image_Width_Long_Long_Integer;
  85
  86    ----------------------------------------
  87    -- Set_Image_Width_Long_Long_Unsigned --
  88    ----------------------------------------
  89
  90    procedure Set_Image_Width_Long_Long_Unsigned
  91      (V : Long_Long_Unsigned;
  92       W : Integer;
  93       S : out String;
  94       P : in out Natural)
  95    is
  96       Start : constant Natural := P;
  97       F, T  : Natural;
  98
  99       procedure Set_Digits (T : Long_Long_Unsigned);
 100       --  Set digits of absolute value of T
 101
 102       procedure Set_Digits (T : Long_Long_Unsigned) is
 103       begin
 104          if T >= 10 then
 105             Set_Digits (T / 10);
 106             P := P + 1;
 107             S (P) := Character'Val (T mod 10 + Character'Pos ('0'));
 108          else
 109             P := P + 1;
 110             S (P) := Character'Val (T + Character'Pos ('0'));
 111          end if;
 112       end Set_Digits;
 113
 114    --  Start of processing for Set_Image_Width_Long_Long_Unsigned
 115
 116    begin
 117       Set_Digits (V);
 118
 119       --  Add leading spaces if required by width parameter
 120
 121       if P - Start < W then
 122          F := P;
 123          P := P + (W - (P - Start));
 124          T := P;
 125
 126          while F > Start loop
 127             S (T) := S (F);
 128             T := T - 1;
 129             F := F - 1;
 130          end loop;
 131
 132          for J in Start + 1 .. T loop
 133             S (J) := ' ';
 134          end loop;
 135       end if;
 136
 137    end Set_Image_Width_Long_Long_Unsigned;
 138
 139 end System.Img_LLW;