gcc/ada/a-coormu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --     A D A . C O N T A I N E R S . O R D E R E D _ M U L T I S E T S      --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Red_Black_Trees;
  37 with Ada.Finalization;
  38 with Ada.Streams;
  39
  40 generic
  41    type Element_Type is private;
  42
  43    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  44    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  45
  46 package Ada.Containers.Ordered_Multisets is
  47    pragma Preelaborate;
  48
  49    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  50
  51    type Set is tagged private;
  52
  53    type Cursor is private;
  54
  55    Empty_Set : constant Set;
  56
  57    No_Element : constant Cursor;
  58
  59    function "=" (Left, Right : Set) return Boolean;
  60
  61    function Equivalent_Sets (Left, Right : Set) return Boolean;
  62
  63    function To_Set (New_Item : Element_Type) return Set;
  64
  65    function Length (Container : Set) return Count_Type;
  66
  67    function Is_Empty (Container : Set) return Boolean;
  68
  69    procedure Clear (Container : in out Set);
  70
  71    function Element (Position : Cursor) return Element_Type;
  72
  73    procedure Replace_Element
  74      (Container : in out Set;
  75       Position  : Cursor;
  76       New_Item  : Element_Type);
  77
  78    procedure Query_Element
  79      (Position : Cursor;
  80       Process  : not null access procedure (Element : Element_Type));
  81
  82    procedure Move (Target : in out Set; Source : in out Set);
  83
  84    procedure Insert
  85      (Container : in out Set;
  86       New_Item  : Element_Type;
  87       Position  : out Cursor);
  88
  89    procedure Insert
  90      (Container : in out Set;
  91       New_Item  : Element_Type);
  92
  93 --  TODO: include Replace too???
  94 --
  95 --     procedure Replace
  96 --       (Container : in out Set;
  97 --        New_Item  : Element_Type);
  98
  99    procedure Exclude
 100      (Container : in out Set;
 101       Item      : Element_Type);
 102
 103    procedure Delete
 104      (Container : in out Set;
 105       Item      : Element_Type);
 106
 107    procedure Delete
 108      (Container : in out Set;
 109       Position  : in out Cursor);
 110
 111    procedure Delete_First (Container : in out Set);
 112
 113    procedure Delete_Last (Container : in out Set);
 114
 115    procedure Union (Target : in out Set; Source : Set);
 116
 117    function Union (Left, Right : Set) return Set;
 118
 119    function "or" (Left, Right : Set) return Set renames Union;
 120
 121    procedure Intersection (Target : in out Set; Source : Set);
 122
 123    function Intersection (Left, Right : Set) return Set;
 124
 125    function "and" (Left, Right : Set) return Set renames Intersection;
 126
 127    procedure Difference (Target : in out Set; Source : Set);
 128
 129    function Difference (Left, Right : Set) return Set;
 130
 131    function "-" (Left, Right : Set) return Set renames Difference;
 132
 133    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 134
 135    function Symmetric_Difference (Left, Right : Set) return Set;
 136
 137    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 138
 139    function Overlap (Left, Right : Set) return Boolean;
 140
 141    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 142
 143    function First (Container : Set) return Cursor;
 144
 145    function First_Element (Container : Set) return Element_Type;
 146
 147    function Last (Container : Set) return Cursor;
 148
 149    function Last_Element (Container : Set) return Element_Type;
 150
 151    function Next (Position : Cursor) return Cursor;
 152
 153    procedure Next (Position : in out Cursor);
 154
 155    function Previous (Position : Cursor) return Cursor;
 156
 157    procedure Previous (Position : in out Cursor);
 158
 159    function Find (Container : Set; Item : Element_Type) return Cursor;
 160
 161    function Floor (Container : Set; Item : Element_Type) return Cursor;
 162
 163    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 164
 165    function Contains (Container : Set; Item : Element_Type) return Boolean;
 166
 167    function Has_Element (Position : Cursor) return Boolean;
 168
 169    function "<" (Left, Right : Cursor) return Boolean;
 170
 171    function ">" (Left, Right : Cursor) return Boolean;
 172
 173    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 174
 175    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 176
 177    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 178
 179    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 180
 181    procedure Iterate
 182      (Container : Set;
 183       Process   : not null access procedure (Position : Cursor));
 184
 185    procedure Reverse_Iterate
 186      (Container : Set;
 187       Process   : not null access procedure (Position : Cursor));
 188
 189    procedure Iterate
 190      (Container : Set;
 191       Item      : Element_Type;
 192       Process   : not null access procedure (Position : Cursor));
 193
 194    procedure Reverse_Iterate
 195      (Container : Set;
 196       Item      : Element_Type;
 197       Process   : not null access procedure (Position : Cursor));
 198
 199    generic
 200       type Key_Type (<>) is private;
 201
 202       with function Key (Element : Element_Type) return Key_Type;
 203
 204       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 205
 206    package Generic_Keys is
 207
 208       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 209
 210       function Key (Position : Cursor) return Key_Type;
 211
 212       function Element (Container : Set; Key : Key_Type) return Element_Type;
 213
 214       procedure Exclude (Container : in out Set; Key : Key_Type);
 215
 216       procedure Delete (Container : in out Set; Key : Key_Type);
 217
 218       function Find (Container : Set; Key : Key_Type) return Cursor;
 219
 220       function Floor (Container : Set; Key : Key_Type) return Cursor;
 221
 222       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 223
 224       function Contains (Container : Set; Key : Key_Type) return Boolean;
 225
 226       procedure Update_Element_Preserving_Key
 227         (Container : in out Set;
 228          Position  : Cursor;
 229          Process   : not null access
 230                        procedure (Element : in out Element_Type));
 231
 232       procedure Iterate
 233         (Container : Set;
 234          Key       : Key_Type;
 235          Process   : not null access procedure (Position : Cursor));
 236
 237       procedure Reverse_Iterate
 238         (Container : Set;
 239          Key       : Key_Type;
 240          Process   : not null access procedure (Position : Cursor));
 241
 242    end Generic_Keys;
 243
 244 private
 245
 246    type Node_Type;
 247    type Node_Access is access Node_Type;
 248
 249    type Node_Type is limited record
 250       Parent  : Node_Access;
 251       Left    : Node_Access;
 252       Right   : Node_Access;
 253       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 254       Element : Element_Type;
 255    end record;
 256
 257    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 258      (Node_Type,
 259       Node_Access);
 260
 261    type Set is new Ada.Finalization.Controlled with record
 262       Tree : Tree_Types.Tree_Type;
 263    end record;
 264
 265    procedure Adjust (Container : in out Set);
 266
 267    procedure Finalize (Container : in out Set) renames Clear;
 268
 269    use Red_Black_Trees;
 270    use Tree_Types;
 271    use Ada.Finalization;
 272    use Ada.Streams;
 273
 274    type Set_Access is access all Set;
 275    for Set_Access'Storage_Size use 0;
 276
 277    type Cursor is record
 278       Container : Set_Access;
 279       Node      : Node_Access;
 280    end record;
 281
 282    procedure Write
 283      (Stream : access Root_Stream_Type'Class;
 284       Item   : Cursor);
 285
 286    for Cursor'Write use Write;
 287
 288    procedure Read
 289      (Stream : access Root_Stream_Type'Class;
 290       Item   : out Cursor);
 291
 292    for Cursor'Read use Read;
 293
 294    No_Element : constant Cursor := Cursor'(null, null);
 295
 296    procedure Write
 297      (Stream    : access Root_Stream_Type'Class;
 298       Container : Set);
 299
 300    for Set'Write use Write;
 301
 302    procedure Read
 303      (Stream    : access Root_Stream_Type'Class;
 304       Container : out Set);
 305
 306    for Set'Read use Read;
 307
 308    Empty_Set : constant Set :=
 309                  (Controlled with Tree => (First  => null,
 310                                            Last   => null,
 311                                            Root   => null,
 312                                            Length => 0,
 313                                            Busy   => 0,
 314                                            Lock   => 0));
 315
 316 end Ada.Containers.Ordered_Multisets;