libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Check for uClibc since Linux platforms use different configuration
 129   # directories depending on the C library in use.
 130   AC_EGREP_CPP([_using_uclibc], [
 131   #include <stdio.h>
 132   #if __UCLIBC__
 133     _using_uclibc
 134   #endif
 135   ], uclibc=yes, uclibc=no)
 136
 137   # Find platform-specific directories containing configuration info.
 138   # Also possibly modify flags used elsewhere, as needed by the platform.
 139   GLIBCXX_CHECK_HOST
 140 ])
 141
 142
 143 dnl
 144 dnl Tests for newer compiler features, or features that are present in newer
 145 dnl compiler versions but not older compiler versions still in use, should
 146 dnl be placed here.
 147 dnl
 148 dnl Defines:
 149 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 150 dnl   new inlining code or the new system_header pragma will die on -Werror.
 151 dnl   Leave it out by default and use maint-mode to use it.
 152 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 153 dnl   compiler supports it and the user has not requested debug mode.
 154 dnl
 155 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 156   # All these tests are for C++; save the language and the compiler flags.
 157   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 158   # found in GLIBCXX_CONFIGURE.
 159   AC_LANG_SAVE
 160   AC_LANG_CPLUSPLUS
 161   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 162   ac_save_CXXFLAGS="$CXXFLAGS"
 163
 164   # Check for maintainer-mode bits.
 165   if test x"$USE_MAINTAINER_MODE" = xno; then
 166     WERROR=''
 167   else
 168     WERROR='-Werror'
 169   fi
 170
 171   # Check for -ffunction-sections -fdata-sections
 172   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 173   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 174   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 175   if test "$ac_test_CXXFLAGS" = set; then
 176     CXXFLAGS="$ac_save_CXXFLAGS"
 177   else
 178     # this is the suspicious part
 179     CXXFLAGS=''
 180   fi
 181   if test x"$ac_fdsections" = x"yes"; then
 182     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 183   fi
 184   AC_MSG_RESULT($ac_fdsections)
 185
 186   AC_LANG_RESTORE
 187   AC_SUBST(WERROR)
 188   AC_SUBST(SECTION_FLAGS)
 189 ])
 190
 191
 192 dnl
 193 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 194 dnl the native linker is in use, all variables will be defined to something
 195 dnl safe (like an empty string).
 196 dnl
 197 dnl Defines:
 198 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 199 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 200 dnl  LD (as a side effect of testing)
 201 dnl Sets:
 202 dnl  with_gnu_ld
 203 dnl  glibcxx_gnu_ld_version (possibly)
 204 dnl
 205 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 206 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 207 dnl
 208 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 209   # If we're not using GNU ld, then there's no point in even trying these
 210   # tests.  Check for that first.  We should have already tested for gld
 211   # by now (in libtool), but require it now just to be safe...
 212   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 213   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 214   AC_REQUIRE([AC_PROG_LD])
 215   AC_REQUIRE([AC_PROG_AWK])
 216
 217   # The name set by libtool depends on the version of libtool.  Shame on us
 218   # for depending on an impl detail, but c'est la vie.  Older versions used
 219   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 220   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 221   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 222   # set (hence we're using an older libtool), then set it.
 223   if test x${with_gnu_ld+set} != xset; then
 224     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 225       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 226       with_gnu_ld=no
 227     else
 228       with_gnu_ld=$ac_cv_prog_gnu_ld
 229     fi
 230   fi
 231
 232   # Start by getting the version number.  I think the libtool test already
 233   # does some of this, but throws away the result.
 234   if test x"$with_gnu_ld" = x"yes"; then
 235     AC_MSG_CHECKING([for ld version])
 236     changequote(,)
 237     ldver=`$LD --version 2>/dev/null | head -1 | \
 238            sed -e 's/GNU ld \(version \)\{0,1\}\(([^)]*) \)\{0,1\}\([0-9.][0-9.]*\).*/\3/'`
 239     changequote([,])
 240     glibcxx_gnu_ld_version=`echo $ldver | \
 241            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 242     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 243   fi
 244
 245   # Set --gc-sections.
 246   glibcxx_gcsections_min_ld=21602
 247   if test x"$with_gnu_ld" = x"yes" &&
 248         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 249
 250     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 251     # NB: This flag only works reliably after 2.16.1. Configure tests
 252     # for this are difficult, so hard wire a value that should work.
 253
 254     ac_test_CFLAGS="${CFLAGS+set}"
 255     ac_save_CFLAGS="$CFLAGS"
 256     CFLAGS='-Wl,--gc-sections'
 257
 258     # Check for -Wl,--gc-sections
 259     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 260     AC_TRY_LINK([ int one(void) { return 1; }
 261      int two(void) { return 2; }
 262         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 263     if test "$ac_gcsections" = "yes"; then
 264       rm -f conftest.c
 265       touch conftest.c
 266       if $CC -c conftest.c; then
 267         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 268            grep "Warning: gc-sections option ignored" > /dev/null; then
 269           ac_gcsections=no
 270         fi
 271       fi
 272       rm -f conftest.c conftest.o conftest
 273     fi
 274     if test "$ac_gcsections" = "yes"; then
 275       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 276     fi
 277     AC_MSG_RESULT($ac_gcsections)
 278
 279     if test "$ac_test_CFLAGS" = set; then
 280       CFLAGS="$ac_save_CFLAGS"
 281     else
 282       # this is the suspicious part
 283       CFLAGS=''
 284     fi
 285   fi
 286
 287   # Set -z,relro.
 288   # Note this is only for shared objects.
 289   ac_ld_relro=no
 290   if test x"$with_gnu_ld" = x"yes"; then
 291     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 292     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 293     if test -n "$cxx_z_relo"; then
 294       OPT_LDFLAGS="-Wl,-z,relro"
 295       ac_ld_relro=yes
 296     fi
 297     AC_MSG_RESULT($ac_ld_relro)
 298   fi
 299
 300   # Set linker optimization flags.
 301   if test x"$with_gnu_ld" = x"yes"; then
 302     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 303   fi
 304
 305   AC_SUBST(SECTION_LDFLAGS)
 306   AC_SUBST(OPT_LDFLAGS)
 307 ])
 308
 309
 310 dnl
 311 dnl Check for headers for, and arguments to, the setrlimit() function.
 312 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 313 dnl
 314 dnl Defines:
 315 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 316 dnl  various HAVE_LIMIT_* for individual limit names
 317 dnl
 318 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 319   AC_MSG_CHECKING([for RLIMIT_$1])
 320   AC_TRY_COMPILE(
 321     [#include <unistd.h>
 322      #include <sys/time.h>
 323      #include <sys/resource.h>
 324     ],
 325     [ int f = RLIMIT_$1 ; ],
 326     [glibcxx_mresult=1], [glibcxx_mresult=0])
 327   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 328                      [Only used in build directory testsuite_hooks.h.])
 329   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 330   AC_MSG_RESULT($res)
 331 ])
 332
 333 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 334   setrlimit_have_headers=yes
 335   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 336                    [],
 337                    [setrlimit_have_headers=no])
 338   # If don't have the headers, then we can't run the tests now, and we
 339   # won't be seeing any of these during testsuite compilation.
 340   if test $setrlimit_have_headers = yes; then
 341     # Can't do these in a loop, else the resulting syntax is wrong.
 342     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 343     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 344     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 345     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 346     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 347
 348     # Check for rlimit, setrlimit.
 349     AC_CACHE_VAL(ac_setrlimit, [
 350       AC_TRY_COMPILE(
 351         [#include <unistd.h>
 352          #include <sys/time.h>
 353          #include <sys/resource.h>
 354         ],
 355         [struct rlimit r;
 356          setrlimit(0, &r);],
 357         [ac_setrlimit=yes], [ac_setrlimit=no])
 358     ])
 359   fi
 360
 361   AC_MSG_CHECKING([for testsuite resource limits support])
 362   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 363     ac_res_limits=yes
 364     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 365               [Define if using setrlimit to set resource limits during
 366               "make check"])
 367   else
 368     ac_res_limits=no
 369   fi
 370   AC_MSG_RESULT($ac_res_limits)
 371 ])
 372
 373
 374 dnl
 375 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 376 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 377 dnl
 378 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 379   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 380   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 381     AC_TRY_LINK(
 382       [#include <sys/stat.h>],
 383       [struct stat buffer;
 384        fstat(0, &buffer);
 385        S_ISREG(buffer.st_mode);],
 386       [glibcxx_cv_S_ISREG=yes],
 387       [glibcxx_cv_S_ISREG=no])
 388   ])
 389   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 390     AC_TRY_LINK(
 391       [#include <sys/stat.h>],
 392       [struct stat buffer;
 393        fstat(0, &buffer);
 394        S_IFREG & buffer.st_mode;],
 395       [glibcxx_cv_S_IFREG=yes],
 396       [glibcxx_cv_S_IFREG=no])
 397   ])
 398   res=no
 399   if test $glibcxx_cv_S_ISREG = yes; then
 400     AC_DEFINE(HAVE_S_ISREG, 1,
 401               [Define if S_IFREG is available in <sys/stat.h>.])
 402     res=S_ISREG
 403   elif test $glibcxx_cv_S_IFREG = yes; then
 404     AC_DEFINE(HAVE_S_IFREG, 1,
 405               [Define if S_IFREG is available in <sys/stat.h>.])
 406     res=S_IFREG
 407   fi
 408   AC_MSG_RESULT($res)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 414 dnl
 415 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 416   AC_MSG_CHECKING([for poll])
 417   AC_CACHE_VAL(glibcxx_cv_POLL, [
 418     AC_TRY_LINK(
 419       [#include <poll.h>],
 420       [struct pollfd pfd[1];
 421        pfd[0].events = POLLIN;
 422        poll(pfd, 1, 0);],
 423       [glibcxx_cv_POLL=yes],
 424       [glibcxx_cv_POLL=no])
 425   ])
 426   if test $glibcxx_cv_POLL = yes; then
 427     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 428   fi
 429   AC_MSG_RESULT($glibcxx_cv_POLL)
 430 ])
 431
 432
 433 dnl
 434 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 435 dnl
 436 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 437   AC_MSG_CHECKING([for writev])
 438   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 439     AC_TRY_LINK(
 440       [#include <sys/uio.h>],
 441       [struct iovec iov[2];
 442        writev(0, iov, 0);],
 443       [glibcxx_cv_WRITEV=yes],
 444       [glibcxx_cv_WRITEV=no])
 445   ])
 446   if test $glibcxx_cv_WRITEV = yes; then
 447     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 448   fi
 449   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 450 ])
 451
 452
 453 dnl
 454 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 455 dnl
 456 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 457   AC_MSG_CHECKING([for int64_t])
 458   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 459     AC_TRY_COMPILE(
 460       [#include <stdint.h>],
 461       [int64_t var;],
 462       [glibcxx_cv_INT64_T=yes],
 463       [glibcxx_cv_INT64_T=no])
 464   ])
 465   if test $glibcxx_cv_INT64_T = yes; then
 466     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 467   fi
 468   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 469 ])
 470
 471
 472 dnl
 473 dnl Check whether LFS support is available.
 474 dnl
 475 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 476   AC_LANG_SAVE
 477   AC_LANG_CPLUSPLUS
 478   ac_save_CXXFLAGS="$CXXFLAGS"
 479   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 480   AC_MSG_CHECKING([for LFS support])
 481   AC_CACHE_VAL(glibcxx_cv_LFS, [
 482     AC_TRY_LINK(
 483       [#include <unistd.h>
 484        #include <stdio.h>
 485        #include <sys/stat.h>
 486       ],
 487       [FILE* fp;
 488        fopen64("t", "w");
 489        fseeko64(fp, 0, SEEK_CUR);
 490        ftello64(fp);
 491        lseek64(1, 0, SEEK_CUR);
 492        struct stat64 buf;
 493        fstat64(1, &buf);],
 494       [glibcxx_cv_LFS=yes],
 495       [glibcxx_cv_LFS=no])
 496   ])
 497   if test $glibcxx_cv_LFS = yes; then
 498     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 499   fi
 500   AC_MSG_RESULT($glibcxx_cv_LFS)
 501   CXXFLAGS="$ac_save_CXXFLAGS"
 502   AC_LANG_RESTORE
 503 ])
 504
 505
 506 dnl
 507 dnl Check for whether a fully dynamic basic_string implementation should
 508 dnl be turned on, that does not put empty objects in per-process static
 509 dnl memory (mostly useful together with shared memory allocators, see PR
 510 dnl libstdc++/16612 for details).
 511 dnl
 512 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 513 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 514 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 515 dnl       Where DEFAULT is either `yes' or `no'.
 516 dnl
 517 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 518   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 519   if test $enable_fully_dynamic_string = yes; then
 520     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 521               [Define if a fully dynamic basic_string is wanted.])
 522   fi
 523 ])
 524
 525
 526 dnl
 527 dnl Does any necessary configuration of the testsuite directory.  Generates
 528 dnl the testsuite_hooks.h header.
 529 dnl
 530 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 531 dnl
 532 dnl Sets:
 533 dnl  enable_abi_check
 534 dnl  GLIBCXX_TEST_WCHAR_T
 535 dnl  GLIBCXX_TEST_THREAD
 536 dnl Substs:
 537 dnl  baseline_dir
 538 dnl
 539 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 540   if $GLIBCXX_IS_NATIVE ; then
 541     # Do checks for resource limit functions.
 542     GLIBCXX_CHECK_SETRLIMIT
 543
 544     # Look for setenv, so that extended locale tests can be performed.
 545     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 546   fi
 547
 548   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 549      test $enable_symvers != no; then
 550     case "$host" in
 551       *-*-cygwin*)
 552         enable_abi_check=no ;;
 553       *)
 554         enable_abi_check=yes ;;
 555     esac
 556   else
 557     # Only build this as native, since automake does not understand
 558     # CXX_FOR_BUILD.
 559     enable_abi_check=no
 560   fi
 561
 562   # Export file names for ABI checking.
 563   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 564   AC_SUBST(baseline_dir)
 565 ])
 566
 567
 568 dnl
 569 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 570 dnl
 571 dnl Substs:
 572 dnl  GLIBCXX_INCLUDES
 573 dnl  TOPLEVEL_INCLUDES
 574 dnl
 575 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 576   # Used for every C++ compile we perform.
 577   GLIBCXX_INCLUDES="\
 578 -I$glibcxx_builddir/include/$host_alias \
 579 -I$glibcxx_builddir/include \
 580 -I$glibcxx_srcdir/libsupc++"
 581
 582   # For Canadian crosses, pick this up too.
 583   if test $CANADIAN = yes; then
 584     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 585   fi
 586
 587   # Stuff in the actual top level.  Currently only used by libsupc++ to
 588   # get unwind* headers from the gcc dir.
 589   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 590   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 591
 592   # Now, export this to all the little Makefiles....
 593   AC_SUBST(GLIBCXX_INCLUDES)
 594   AC_SUBST(TOPLEVEL_INCLUDES)
 595 ])
 596
 597
 598 dnl
 599 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 600 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 601 dnl
 602 dnl Substs:
 603 dnl  OPTIMIZE_CXXFLAGS
 604 dnl  WARN_FLAGS
 605 dnl
 606 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 607   # Optimization flags that are probably a good idea for thrill-seekers. Just
 608   # uncomment the lines below and make, everything else is ready to go...
 609   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 610   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 611   AC_SUBST(OPTIMIZE_CXXFLAGS)
 612
 613   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 614   AC_SUBST(WARN_FLAGS)
 615 ])
 616
 617
 618 dnl
 619 dnl All installation directory information is determined here.
 620 dnl
 621 dnl Substs:
 622 dnl  gxx_install_dir
 623 dnl  glibcxx_prefixdir
 624 dnl  glibcxx_toolexecdir
 625 dnl  glibcxx_toolexeclibdir
 626 dnl
 627 dnl Assumes cross_compiling bits already done, and with_cross_host in
 628 dnl particular.
 629 dnl
 630 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 631 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 632 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 633   glibcxx_toolexecdir=no
 634   glibcxx_toolexeclibdir=no
 635   glibcxx_prefixdir=$prefix
 636
 637   AC_MSG_CHECKING([for gxx-include-dir])
 638   AC_ARG_WITH([gxx-include-dir],
 639     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 640                    [installation directory for include files]),
 641     [case "$withval" in
 642       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 643       no)  gxx_include_dir=no ;;
 644       *)   gxx_include_dir=$withval ;;
 645      esac],
 646     [gxx_include_dir=no])
 647   AC_MSG_RESULT($gxx_include_dir)
 648
 649   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 650   AC_ARG_ENABLE([version-specific-runtime-libs],
 651     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 652                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 653     [case "$enableval" in
 654       yes) version_specific_libs=yes ;;
 655       no)  version_specific_libs=no ;;
 656       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 657      esac],
 658     [version_specific_libs=no])
 659   AC_MSG_RESULT($version_specific_libs)
 660
 661   # Default case for install directory for include files.
 662   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 663     gxx_include_dir='include/c++/${gcc_version}'
 664     if test -n "$with_cross_host" &&
 665        test x"$with_cross_host" != x"no"; then
 666       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 667     else
 668       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 669     fi
 670   fi
 671
 672   # Version-specific runtime libs processing.
 673   if test $version_specific_libs = yes; then
 674     # Need the gcc compiler version to know where to install libraries
 675     # and header files if --enable-version-specific-runtime-libs option
 676     # is selected.  FIXME: these variables are misnamed, there are
 677     # no executables installed in _toolexecdir or _toolexeclibdir.
 678     if test x"$gxx_include_dir" = x"no"; then
 679       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 680     fi
 681     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 682     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 683   fi
 684
 685   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 686   # Install a library built with a cross compiler in tooldir, not libdir.
 687   if test x"$glibcxx_toolexecdir" = x"no"; then
 688     if test -n "$with_cross_host" &&
 689        test x"$with_cross_host" != x"no"; then
 690       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 691       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 692     else
 693       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 694       glibcxx_toolexeclibdir='${libdir}'
 695     fi
 696     multi_os_directory=`$CXX -print-multi-os-directory`
 697     case $multi_os_directory in
 698       .) ;; # Avoid trailing /.
 699       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 700     esac
 701   fi
 702
 703   AC_MSG_CHECKING([for install location])
 704   AC_MSG_RESULT($gxx_include_dir)
 705
 706   AC_SUBST(glibcxx_prefixdir)
 707   AC_SUBST(gxx_include_dir)
 708   AC_SUBST(glibcxx_toolexecdir)
 709   AC_SUBST(glibcxx_toolexeclibdir)
 710 ])
 711
 712
 713 dnl
 714 dnl GLIBCXX_ENABLE
 715 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 716 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 717 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 718 dnl
 719 dnl See docs/html/17_intro/configury.html#enable for documentation.
 720 dnl
 721 m4_define([GLIBCXX_ENABLE],[dnl
 722 m4_define([_g_switch],[--enable-$1])dnl
 723 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 724  AC_ARG_ENABLE($1,_g_help,
 725   m4_bmatch([$5],
 726    [^permit ],
 727      [[
 728       case "$enableval" in
 729        m4_bpatsubst([$5],[permit ])) ;;
 730        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 731           dnl Idea for future:  generate a URL pointing to
 732           dnl "onlinedocs/configopts.html#whatever"
 733       esac
 734      ]],
 735    [^$],
 736      [[
 737       case "$enableval" in
 738        yes|no) ;;
 739        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 740       esac
 741      ]],
 742    [[$5]]),
 743   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 744 m4_undefine([_g_switch])dnl
 745 m4_undefine([_g_help])dnl
 746 ])
 747
 748
 749 dnl
 750 dnl Check for ISO/IEC 9899:1999 "C99" support.
 751 dnl
 752 dnl --enable-c99 defines _GLIBCXX_USE_C99
 753 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 754 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 755 dnl       Where DEFAULT is either `yes' or `no'.
 756 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 757 dnl
 758 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 759   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 760
 761   if test x"$enable_c99" = x"yes"; then
 762
 763   AC_LANG_SAVE
 764   AC_LANG_CPLUSPLUS
 765
 766   # Use -fno-exceptions so that the C driver can link these tests without
 767   # hitting undefined references to personality routines.
 768   ac_save_CXXFLAGS="$CXXFLAGS"
 769   ac_save_LIBS="$LIBS"
 770   ac_save_gcc_no_link="$gcc_no_link"
 771
 772   if test x$gcc_no_link != xyes; then
 773     # Use -fno-exceptions to that the C driver can link these tests without
 774     # hitting undefined references to personality routines.
 775     CXXFLAGS="$CXXFLAGS -fno-exceptions"
 776     AC_CHECK_LIB(m, sin, [
 777       LIBS="$LIBS -lm"
 778     ], [
 779       # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
 780       gcc_no_link=yes
 781     ])
 782   fi
 783
 784   # Check for the existence of <math.h> functions used if C99 is enabled.
 785   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 786   AC_CACHE_VAL(ac_c99_math, [
 787   GCC_TRY_COMPILE_OR_LINK(
 788      [#include <math.h>
 789       volatile double d1, d2;
 790       volatile int i;],
 791      [i = fpclassify(d1);
 792       i = isfinite(d1);
 793       i = isinf(d1);
 794       i = isnan(d1);
 795       i = isnormal(d1);
 796       i = signbit(d1);
 797       i = isgreater(d1, d2);
 798       i = isgreaterequal(d1, d2);
 799       i = isless(d1, d2);
 800       i = islessequal(d1, d2);
 801       i = islessgreater(d1, d2);
 802       i = islessgreater(d1, d2);
 803       i = isunordered(d1, d2);
 804      ],[ac_c99_math=yes], [ac_c99_math=no])
 805   ])
 806   AC_MSG_RESULT($ac_c99_math)
 807   if test x"$ac_c99_math" = x"yes"; then
 808     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 809               [Define if C99 functions or macros in <math.h> should be imported
 810               in <cmath> in namespace std.])
 811   fi
 812
 813   # Check for the existence of <complex.h> complex math functions.
 814   # This is necessary even though libstdc++ uses the builtin versions
 815   # of these functions, because if the builtin cannot be used, a reference
 816   # to the library function is emitted.
 817   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 818   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 819   ac_c99_complex=no;
 820   if test x"$ac_has_complex_h" = x"yes"; then
 821     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 822     GCC_TRY_COMPILE_OR_LINK(
 823        [#include <complex.h>
 824         typedef __complex__ float float_type;
 825         typedef __complex__ double double_type;
 826         typedef __complex__ long double ld_type;
 827         volatile float_type tmpf;
 828         volatile double_type tmpd;
 829         volatile ld_type tmpld;
 830         volatile float f;
 831         volatile double d;
 832         volatile long double ld;],
 833        [f = cabsf(tmpf);
 834         f = cargf(tmpf);
 835         tmpf = ccosf(tmpf);
 836         tmpf = ccoshf(tmpf);
 837         tmpf = cexpf(tmpf);
 838         tmpf = clogf(tmpf);
 839         tmpf = csinf(tmpf);
 840         tmpf = csinhf(tmpf);
 841         tmpf = csqrtf(tmpf);
 842         tmpf = ctanf(tmpf);
 843         tmpf = ctanhf(tmpf);
 844         tmpf = cpowf(tmpf, tmpf);
 845         d = cabs(tmpd);
 846         d = carg(tmpd);
 847         tmpd = ccos(tmpd);
 848         tmpd = ccosh(tmpd);
 849         tmpd = cexp(tmpd);
 850         tmpd = clog(tmpd);
 851         tmpd = csin(tmpd);
 852         tmpd = csinh(tmpd);
 853         tmpd = csqrt(tmpd);
 854         tmpd = ctan(tmpd);
 855         tmpd = ctanh(tmpd);
 856         tmpd = cpow(tmpd, tmpd);
 857         ld = cabsl(tmpld);
 858         ld = cargl(tmpld);
 859         tmpld = ccosl(tmpld);
 860         tmpld = ccoshl(tmpld);
 861         tmpld = cexpl(tmpld);
 862         tmpld = clogl(tmpld);
 863         tmpld = csinl(tmpld);
 864         tmpld = csinhl(tmpld);
 865         tmpld = csqrtl(tmpld);
 866         tmpld = ctanl(tmpld);
 867         tmpld = ctanhl(tmpld);
 868         tmpld = cpowl(tmpld, tmpld);
 869        ],[ac_c99_complex=yes], [ac_c99_complex=no])
 870   fi
 871   AC_MSG_RESULT($ac_c99_complex)
 872   if test x"$ac_c99_complex" = x"yes"; then
 873     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 874               [Define if C99 functions in <complex.h> should be used in
 875               <complex>. Using compiler builtins for these functions requires
 876               corresponding C99 library functions to be present.])
 877   fi
 878
 879   # Check for the existence in <stdio.h> of vscanf, et. al.
 880   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 881   AC_CACHE_VAL(ac_c99_stdio, [
 882   GCC_TRY_COMPILE_OR_LINK(
 883      [#include <stdio.h>
 884       #include <stdarg.h>
 885       void foo(char* fmt, ...)
 886       {
 887         va_list args; va_start(args, fmt);
 888         vfscanf(stderr, "%i", args);
 889         vscanf("%i", args);
 890         vsnprintf(fmt, 0, "%i", args);
 891         vsscanf(fmt, "%i", args);
 892       }],
 893      [snprintf("12", 0, "%i");],
 894      [ac_c99_stdio=yes], [ac_c99_stdio=no])
 895   ])
 896   AC_MSG_RESULT($ac_c99_stdio)
 897
 898   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 899   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 900   AC_CACHE_VAL(ac_c99_stdlib, [
 901   GCC_TRY_COMPILE_OR_LINK(
 902      [#include <stdlib.h>
 903       volatile float f;
 904       volatile long double ld;
 905       volatile unsigned long long ll;
 906       lldiv_t mydivt;],
 907      [char* tmp;
 908       f = strtof("gnu", &tmp);
 909       ld = strtold("gnu", &tmp);
 910       ll = strtoll("gnu", &tmp, 10);
 911       ll = strtoull("gnu", &tmp, 10);
 912       ll = llabs(10);
 913       mydivt = lldiv(10,1);
 914       ll = mydivt.quot;
 915       ll = mydivt.rem;
 916       ll = atoll("10");
 917       _Exit(0);
 918       ],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 919   ])
 920   AC_MSG_RESULT($ac_c99_stdlib)
 921
 922   # Check for the existence in <wchar.h> of wcstold, etc.
 923   ac_c99_wchar=no;
 924   if test x"$ac_has_wchar_h" = xyes &&
 925      test x"$ac_has_wctype_h" = xyes; then
 926     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
 927     AC_TRY_COMPILE([#include <wchar.h>
 928                     namespace test
 929                     {
 930                       using ::wcstold;
 931                       using ::wcstoll;
 932                       using ::wcstoull;
 933                     }
 934                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 935
 936     # Checks for wide character functions that may not be present.
 937     # Injection of these is wrapped with guard macros.
 938     # NB: only put functions here, instead of immediately above, if
 939     # absolutely necessary.
 940     AC_TRY_COMPILE([#include <wchar.h>
 941                     namespace test { using ::vfwscanf; } ], [],
 942                    [AC_DEFINE(HAVE_VFWSCANF,1,
 943                         [Defined if vfwscanf exists.])],[])
 944
 945     AC_TRY_COMPILE([#include <wchar.h>
 946                     namespace test { using ::vswscanf; } ], [],
 947                    [AC_DEFINE(HAVE_VSWSCANF,1,
 948                         [Defined if vswscanf exists.])],[])
 949
 950     AC_TRY_COMPILE([#include <wchar.h>
 951                     namespace test { using ::vwscanf; } ], [],
 952                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
 953
 954     AC_TRY_COMPILE([#include <wchar.h>
 955                     namespace test { using ::wcstof; } ], [],
 956                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
 957
 958     AC_TRY_COMPILE([#include <wctype.h>],
 959                    [ wint_t t; int i = iswblank(t);],
 960                    [AC_DEFINE(HAVE_ISWBLANK,1,
 961                         [Defined if iswblank exists.])],[])
 962
 963     AC_MSG_RESULT($ac_c99_wchar)
 964   fi
 965
 966   # Option parsed, now set things appropriately.
 967   if test x"$ac_c99_math" = x"no" ||
 968      test x"$ac_c99_complex" = x"no" ||
 969      test x"$ac_c99_stdio" = x"no" ||
 970      test x"$ac_c99_stdlib" = x"no" ||
 971      test x"$ac_c99_wchar" = x"no"; then
 972     enable_c99=no;
 973   else
 974     AC_DEFINE(_GLIBCXX_USE_C99, 1,
 975     [Define if C99 functions or macros from <wchar.h>, <math.h>,
 976     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
 977   fi
 978
 979   gcc_no_link="$ac_save_gcc_no_link"
 980   LIBS="$ac_save_LIBS"
 981   CXXFLAGS="$ac_save_CXXFLAGS"
 982   AC_LANG_RESTORE
 983   fi
 984
 985   AC_MSG_CHECKING([for fully enabled ISO C99 support])
 986   AC_MSG_RESULT($enable_c99)
 987 ])
 988
 989
 990 dnl
 991 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
 992 dnl facilities in Chapter 8, "C compatibility".
 993 dnl
 994 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
 995
 996   AC_LANG_SAVE
 997   AC_LANG_CPLUSPLUS
 998
 999   # Check for the existence of <complex.h> complex math functions used
1000   # by tr1/complex.
1001   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1002   ac_c99_complex_tr1=no;
1003   if test x"$ac_has_complex_h" = x"yes"; then
1004     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1005     AC_TRY_COMPILE([#include <complex.h>],
1006                    [typedef __complex__ float float_type; float_type tmpf;
1007                     cacosf(tmpf);
1008                     casinf(tmpf);
1009                     catanf(tmpf);
1010                     cacoshf(tmpf);
1011                     casinhf(tmpf);
1012                     catanhf(tmpf);
1013                     typedef __complex__ double double_type; double_type tmpd;
1014                     cacos(tmpd);
1015                     casin(tmpd);
1016                     catan(tmpd);
1017                     cacosh(tmpd);
1018                     casinh(tmpd);
1019                     catanh(tmpd);
1020                     typedef __complex__ long double ld_type; ld_type tmpld;
1021                     cacosl(tmpld);
1022                     casinl(tmpld);
1023                     catanl(tmpld);
1024                     cacoshl(tmpld);
1025                     casinhl(tmpld);
1026                     catanhl(tmpld);
1027                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1028   fi
1029   AC_MSG_RESULT($ac_c99_complex_tr1)
1030   if test x"$ac_c99_complex_tr1" = x"yes"; then
1031     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1032               [Define if C99 functions in <complex.h> should be used in
1033               <tr1/complex>. Using compiler builtins for these functions
1034               requires corresponding C99 library functions to be present.])
1035   fi
1036
1037   # Check for the existence of <ctype.h> functions.
1038   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1039   AC_CACHE_VAL(ac_c99_ctype_tr1, [
1040   AC_TRY_COMPILE([#include <ctype.h>],
1041                  [int ch;
1042                   int ret;
1043                   ret = isblank(ch);
1044                  ],[ac_c99_ctype_tr1=yes], [ac_c99_ctype_tr1=no])
1045   ])
1046   AC_MSG_RESULT($ac_c99_ctype_tr1)
1047   if test x"$ac_c99_ctype_tr1" = x"yes"; then
1048     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1049               [Define if C99 functions in <ctype.h> should be imported in
1050               <tr1/cctype> in namespace std::tr1.])
1051   fi
1052
1053   # Check for the existence of <fenv.h> functions.
1054   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1055   ac_c99_fenv_tr1=no;
1056   if test x"$ac_has_fenv_h" = x"yes"; then
1057     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1058     AC_TRY_COMPILE([#include <fenv.h>],
1059                    [int except, mode;
1060                     fexcept_t* pflag;
1061                     fenv_t* penv;
1062                     int ret;
1063                     ret = feclearexcept(except);
1064                     ret = fegetexceptflag(pflag, except);
1065                     ret = feraiseexcept(except);
1066                     ret = fesetexceptflag(pflag, except);
1067                     ret = fetestexcept(except);
1068                     ret = fegetround();
1069                     ret = fesetround(mode);
1070                     ret = fegetenv(penv);
1071                     ret = feholdexcept(penv);
1072                     ret = fesetenv(penv);
1073                     ret = feupdateenv(penv);
1074                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1075   fi
1076   AC_MSG_RESULT($ac_c99_fenv_tr1)
1077   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1078     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1079               [Define if C99 functions in <fenv.h> should be imported in
1080               <tr1/cfenv> in namespace std::tr1.])
1081   fi
1082
1083   # Check for the existence of <stdint.h> types.
1084   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1085   AC_CACHE_VAL(ac_c99_stdint_tr1, [
1086   AC_TRY_COMPILE([#include <stdint.h>],
1087                  [typedef int8_t          my_int8_t;
1088                   typedef int16_t         my_int16_t;
1089                   typedef int32_t         my_int32_t;
1090                   typedef int64_t         my_int64_t;
1091                   typedef int_fast8_t     my_int_fast8_t;
1092                   typedef int_fast16_t    my_int_fast16_t;
1093                   typedef int_fast32_t    my_int_fast32_t;
1094                   typedef int_fast64_t    my_int_fast64_t;
1095                   typedef int_least8_t    my_int_least8_t;
1096                   typedef int_least16_t   my_int_least16_t;
1097                   typedef int_least32_t   my_int_least32_t;
1098                   typedef int_least64_t   my_int_least64_t;
1099                   typedef intmax_t        my_intmax_t;
1100                   typedef intptr_t        my_intptr_t;
1101                   typedef uint8_t         my_uint8_t;
1102                   typedef uint16_t        my_uint16_t;
1103                   typedef uint32_t        my_uint32_t;
1104                   typedef uint64_t        my_uint64_t;
1105                   typedef uint_fast8_t    my_uint_fast8_t;
1106                   typedef uint_fast16_t   my_uint_fast16_t;
1107                   typedef uint_fast32_t   my_uint_fast32_t;
1108                   typedef uint_fast64_t   my_uint_fast64_t;
1109                   typedef uint_least8_t   my_uint_least8_t;
1110                   typedef uint_least16_t  my_uint_least16_t;
1111                   typedef uint_least32_t  my_uint_least32_t;
1112                   typedef uint_least64_t  my_uint_least64_t;
1113                   typedef uintmax_t       my_uintmax_t;
1114                   typedef uintptr_t       my_uintptr_t;
1115                  ],[ac_c99_stdint_tr1=yes], [ac_c99_stdint_tr1=no])
1116   ])
1117   AC_MSG_RESULT($ac_c99_stdint_tr1)
1118   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1119     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1120               [Define if C99 types in <stdint.h> should be imported in
1121               <tr1/cstdint> in namespace std::tr1.])
1122   fi
1123
1124   # Check for the existence of <math.h> functions.
1125   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1126   AC_CACHE_VAL(ac_c99_math_tr1, [
1127   AC_TRY_COMPILE([#include <math.h>],
1128                  [typedef double_t  my_double_t;
1129                   typedef float_t   my_float_t;
1130                   acosh(0.0);
1131                   acoshf(0.0f);
1132                   acoshl(0.0l);
1133                   asinh(0.0);
1134                   asinhf(0.0f);
1135                   asinhl(0.0l);
1136                   atanh(0.0);
1137                   atanhf(0.0f);
1138                   atanhl(0.0l);
1139                   cbrt(0.0);
1140                   cbrtf(0.0f);
1141                   cbrtl(0.0l);
1142                   copysign(0.0, 0.0);
1143                   copysignf(0.0f, 0.0f);
1144                   copysignl(0.0l, 0.0l);
1145                   erf(0.0);
1146                   erff(0.0f);
1147                   erfl(0.0l);
1148                   erfc(0.0);
1149                   erfcf(0.0f);
1150                   erfcl(0.0l);
1151                   exp2(0.0);
1152                   exp2f(0.0f);
1153                   exp2l(0.0l);
1154                   expm1(0.0);
1155                   expm1f(0.0f);
1156                   expm1l(0.0l);
1157                   fdim(0.0, 0.0);
1158                   fdimf(0.0f, 0.0f);
1159                   fdiml(0.0l, 0.0l);
1160                   fma(0.0, 0.0, 0.0);
1161                   fmaf(0.0f, 0.0f, 0.0f);
1162                   fmal(0.0l, 0.0l, 0.0l);
1163                   fmax(0.0, 0.0);
1164                   fmaxf(0.0f, 0.0f);
1165                   fmaxl(0.0l, 0.0l);
1166                   fmin(0.0, 0.0);
1167                   fminf(0.0f, 0.0f);
1168                   fminl(0.0l, 0.0l);
1169                   hypot(0.0, 0.0);
1170                   hypotf(0.0f, 0.0f);
1171                   hypotl(0.0l, 0.0l);
1172                   ilogb(0.0);
1173                   ilogbf(0.0f);
1174                   ilogbl(0.0l);
1175                   lgamma(0.0);
1176                   lgammaf(0.0f);
1177                   lgammal(0.0l);
1178                   llrint(0.0);
1179                   llrintf(0.0f);
1180                   llrintl(0.0l);
1181                   llround(0.0);
1182                   llroundf(0.0f);
1183                   llroundl(0.0l);
1184                   log1p(0.0);
1185                   log1pf(0.0f);
1186                   log1pl(0.0l);
1187                   log2(0.0);
1188                   log2f(0.0f);
1189                   log2l(0.0l);
1190                   logb(0.0);
1191                   logbf(0.0f);
1192                   logbl(0.0l);
1193                   lrint(0.0);
1194                   lrintf(0.0f);
1195                   lrintl(0.0l);
1196                   lround(0.0);
1197                   lroundf(0.0f);
1198                   lroundl(0.0l);
1199                   nan(0);
1200                   nanf(0);
1201                   nanl(0);
1202                   nearbyint(0.0);
1203                   nearbyintf(0.0f);
1204                   nearbyintl(0.0l);
1205                   nextafter(0.0, 0.0);
1206                   nextafterf(0.0f, 0.0f);
1207                   nextafterl(0.0l, 0.0l);
1208                   nexttoward(0.0, 0.0);
1209                   nexttowardf(0.0f, 0.0f);
1210                   nexttowardl(0.0l, 0.0l);
1211                   remainder(0.0, 0.0);
1212                   remainderf(0.0f, 0.0f);
1213                   remainderl(0.0l, 0.0l);
1214                   remquo(0.0, 0.0, 0);
1215                   remquo(0.0f, 0.0f, 0);
1216                   remquo(0.0l, 0.0l, 0);
1217                   rint(0.0);
1218                   rintf(0.0f);
1219                   rintl(0.0l);
1220                   round(0.0);
1221                   roundf(0.0f);
1222                   roundl(0.0l);
1223                   scalbln(0.0, 0l);
1224                   scalblnf(0.0f, 0l);
1225                   scalblnl(0.0l, 0l);
1226                   scalbn(0.0, 0);
1227                   scalbnf(0.0f, 0);
1228                   scalbnl(0.0l, 0);
1229                   tgamma(0.0);
1230                   tgammaf(0.0f);
1231                   tgammal(0.0l);
1232                   trunc(0.0);
1233                   truncf(0.0f);
1234                   truncl(0.0l);
1235                  ],[ac_c99_math_tr1=yes], [ac_c99_math_tr1=no])
1236   ])
1237   AC_MSG_RESULT($ac_c99_math_tr1)
1238   if test x"$ac_c99_math_tr1" = x"yes"; then
1239     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1240               [Define if C99 functions or macros in <math.h> should be imported
1241               in <tr1/cmath> in namespace std::tr1.])
1242   fi
1243
1244   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1245   # sense if the previous check fails, per C99, 7.8/1).
1246   ac_c99_inttypes_tr1=no;
1247   if test x"$ac_c99_stdint_tr1" = x"yes"; then
1248     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1249     AC_TRY_COMPILE([#include <inttypes.h>],
1250                    [intmax_t i, numer, denom, base;
1251                     const char* s;
1252                     char** endptr;
1253                     intmax_t ret = imaxabs(i);
1254                     imaxdiv_t dret = imaxdiv(numer, denom);
1255                     ret = strtoimax(s, endptr, base);
1256                     uintmax_t uret = strtoumax(s, endptr, base);
1257                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1258   fi
1259   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1260   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1261     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1262               [Define if C99 functions in <inttypes.h> should be imported in
1263               <tr1/cinttypes> in namespace std::tr1.])
1264   fi
1265
1266   # Check for the existence of the <stdbool.h> header.
1267   AC_CHECK_HEADERS(stdbool.h)
1268
1269   AC_LANG_RESTORE
1270 ])
1271
1272 dnl
1273 dnl Check whether "dev/random" and "dev/urandom" are available for the
1274 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1275 dnl
1276 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1277
1278   AC_MSG_CHECKING([for "dev/random" and "dev/urandom" for TR1 random_device])
1279   AC_CACHE_VAL(ac_random_tr1, [
1280   AC_TRY_RUN([#include <stdio.h>
1281               int main()
1282               {
1283                 return !(fopen("/dev/random", "r")
1284                          && fopen("/dev/urandom", "r"));
1285               }
1286              ],
1287              [ac_random_tr1=yes], [ac_random_tr1=no],
1288              [ac_random_tr1=no])
1289   ])
1290   AC_MSG_RESULT($ac_random_tr1)
1291   if test x"$ac_random_tr1" = x"yes"; then
1292     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1293               [Define if dev/random and dev/urandom are available for
1294                the random_device of TR1 (Chapter 5.1).])
1295   fi
1296
1297 ])
1298
1299 dnl
1300 dnl Check whether macros, etc are present for <system_error>
1301 dnl
1302 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1303
1304   AC_MSG_CHECKING([for EOWNERDEAD])
1305   AC_CACHE_VAL(ac_system_error1, [
1306   AC_TRY_COMPILE([#include <errno.h>], [ int i = EOWNERDEAD; ],
1307              [ac_system_error1=yes], [ac_system_error1=no])
1308   ])
1309   AC_MSG_RESULT($ac_system_error1)
1310   if test x"$ac_system_error1" = x"yes"; then
1311     AC_DEFINE(HAVE_EOWNERDEAD, 1, [Define if EOWNERDEAD exists.])
1312   fi
1313
1314   AC_MSG_CHECKING([for ENOTRECOVERABLE])
1315   AC_CACHE_VAL(ac_system_error2, [
1316   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOTRECOVERABLE; ],
1317              [ac_system_error2=yes], [ac_system_error2=no])
1318   ])
1319   AC_MSG_RESULT($ac_system_error2)
1320   if test x"$ac_system_error2" = x"yes"; then
1321     AC_DEFINE(HAVE_ENOTRECOVERABLE, 1, [Define if ENOTRECOVERABLE exists.])
1322   fi
1323
1324   AC_MSG_CHECKING([for ENOLINK])
1325   AC_CACHE_VAL(ac_system_error3, [
1326   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOLINK; ],
1327              [ac_system_error3=yes], [ac_system_error3=no])
1328   ])
1329   AC_MSG_RESULT($ac_system_error3)
1330   if test x"$ac_system_error3" = x"yes"; then
1331     AC_DEFINE(HAVE_ENOLINK, 1, [Define if ENOLINK exists.])
1332   fi
1333
1334   AC_MSG_CHECKING([for EPROTO])
1335   AC_CACHE_VAL(ac_system_error_4, [
1336   AC_TRY_COMPILE([#include <errno.h>], [ int i = EPROTO; ],
1337              [ac_system_error_4=yes], [ac_system_error_4=no])
1338   ])
1339   AC_MSG_RESULT($ac_system_error_4)
1340   if test x"$ac_system_error_4" = x"yes"; then
1341     AC_DEFINE(HAVE_EPROTO, 1, [Define if EPROTO exists.])
1342   fi
1343
1344   AC_MSG_CHECKING([for ENODATA])
1345   AC_CACHE_VAL(ac_system_error_5, [
1346   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENODATA; ],
1347              [ac_system_error_5=yes], [ac_system_error_5=no])
1348   ])
1349   AC_MSG_RESULT($ac_system_error_5)
1350   if test x"$ac_system_error_5" = x"yes"; then
1351     AC_DEFINE(HAVE_ENODATA, 1, [Define if ENODATA exists.])
1352   fi
1353
1354   AC_MSG_CHECKING([for ENOSR])
1355   AC_CACHE_VAL(ac_system_error_6, [
1356   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOSR; ],
1357              [ac_system_error_6=yes], [ac_system_error_6=no])
1358   ])
1359   AC_MSG_RESULT($ac_system_error_6)
1360   if test x"$ac_system_error_6" = x"yes"; then
1361     AC_DEFINE(HAVE_ENOSR, 1, [Define if ENOSR exists.])
1362   fi
1363
1364   AC_MSG_CHECKING([for ENOSTR])
1365   AC_CACHE_VAL(ac_system_error_7, [
1366   AC_TRY_COMPILE([#include <errno.h>], [ int i = ENOSTR; ],
1367              [ac_system_error_7=yes], [ac_system_error_7=no])
1368   ])
1369   AC_MSG_RESULT($ac_system_error_7)
1370   if test x"$ac_system_error_7" = x"yes"; then
1371     AC_DEFINE(HAVE_ENOSTR, 1, [Define if ENOSTR exists.])
1372   fi
1373
1374   AC_MSG_CHECKING([for ETIME])
1375   AC_CACHE_VAL(ac_system_error_8, [
1376   AC_TRY_COMPILE([#include <errno.h>], [ int i = ETIME; ],
1377              [ac_system_error_8=yes], [ac_system_error_8=no])
1378   ])
1379   AC_MSG_RESULT($ac_system_error_8)
1380   if test x"$ac_system_error_8" = x"yes"; then
1381     AC_DEFINE(HAVE_ETIME, 1, [Define if ETIME exists.])
1382   fi
1383
1384   AC_MSG_CHECKING([for sys_nerr])
1385   AC_CACHE_VAL(ac_system_error9, [
1386   AC_TRY_COMPILE([#include <errno.h> ], [ int i = sys_nerr; ],
1387              [ac_system_error9=yes], [ac_system_error9=no])
1388   ])
1389   AC_MSG_RESULT($ac_system_error9)
1390   if test x"$ac_system_error9" = x"yes"; then
1391     AC_DEFINE(HAVE_SYS_NERR, 1, [Define if sys_nerr exists.])
1392   fi
1393
1394   AC_MSG_CHECKING([for EBADMSG])
1395   AC_CACHE_VAL(ac_system_error_10, [
1396   AC_TRY_COMPILE([#include <errno.h>], [ int i = EBADMSG; ],
1397              [ac_system_error_10=yes], [ac_system_error_10=no])
1398   ])
1399   AC_MSG_RESULT($ac_system_error_10)
1400   if test x"$ac_system_error_10" = x"yes"; then
1401     AC_DEFINE(HAVE_EBADMSG, 1, [Define if EBADMSG exists.])
1402   fi
1403
1404   AC_MSG_CHECKING([for ECANCELED])
1405   AC_CACHE_VAL(ac_system_error_11, [
1406   AC_TRY_COMPILE([#include <errno.h>], [ int i = ECANCELED; ],
1407              [ac_system_error_11=yes], [ac_system_error_11=no])
1408   ])
1409   AC_MSG_RESULT($ac_system_error_11)
1410   if test x"$ac_system_error_11" = x"yes"; then
1411     AC_DEFINE(HAVE_ECANCELED, 1, [Define if ECANCELED exists.])
1412   fi
1413
1414   AC_MSG_CHECKING([for EOVERFLOW])
1415   AC_CACHE_VAL(ac_system_error_12, [
1416   AC_TRY_COMPILE([#include <errno.h>], [ int i = EOVERFLOW; ],
1417              [ac_system_error_12=yes], [ac_system_error_12=no])
1418   ])
1419   AC_MSG_RESULT($ac_system_error_12)
1420   if test x"$ac_system_error_12" = x"yes"; then
1421     AC_DEFINE(HAVE_EOVERFLOW, 1, [Define if EOVERFLOW exists.])
1422   fi
1423 ])
1424
1425 dnl
1426 dnl Check for what type of C headers to use.
1427 dnl
1428 dnl --enable-cheaders= [does stuff].
1429 dnl --disable-cheaders [does not do anything, really].
1430 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1431 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1432 dnl
1433 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1434   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1435     [construct "C" headers for g++], [permit c|c_std|c_global])
1436   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1437
1438   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1439
1440   # Allow overrides to configure.host here.
1441   if test $enable_cheaders = c_global; then
1442      c_compatibility=yes
1443   fi
1444
1445   if test $enable_cheaders = c_global || test $enable_cheaders = c_std; then
1446      c_extra=yes
1447   fi
1448
1449   AC_SUBST(C_INCLUDE_DIR)
1450   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1451   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1452   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1453   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1454   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_EXTRA, test $c_extra = yes)
1455 ])
1456
1457
1458 dnl
1459 dnl Check for which locale library to use.  The choice is mapped to
1460 dnl a subdirectory of config/locale.
1461 dnl
1462 dnl Default is generic.
1463 dnl
1464 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1465   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1466     [use MODEL for target locale package],
1467     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1468
1469   # Deal with gettext issues.  Default to not using it (=no) until we detect
1470   # support for it later.  Let the user turn it off via --e/d, but let that
1471   # default to on for easier handling.
1472   USE_NLS=no
1473   AC_ARG_ENABLE(nls,
1474     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1475     [],
1476     [enable_nls=yes])
1477
1478   # Either a known packaage, or "auto"
1479   if test $enable_clocale = no || test $enable_clocale = yes; then
1480      enable_clocale=auto
1481   fi
1482   enable_clocale_flag=$enable_clocale
1483
1484   # Probe for locale model to use if none specified.
1485   # Default to "generic".
1486   if test $enable_clocale_flag = auto; then
1487     case ${target_os} in
1488       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1489         enable_clocale_flag=gnu
1490         ;;
1491       darwin* | freebsd*)
1492         enable_clocale_flag=darwin
1493         ;;
1494       *)
1495         enable_clocale_flag=generic
1496         ;;
1497     esac
1498   fi
1499
1500   # Sanity check model, and test for special functionality.
1501   if test $enable_clocale_flag = gnu; then
1502     AC_EGREP_CPP([_GLIBCXX_ok], [
1503     #include <features.h>
1504     #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1505       _GLIBCXX_ok
1506     #endif
1507     ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1508
1509     if test $enable_clocale = auto; then
1510       # Test for bugs early in glibc-2.2.x series
1511       AC_TRY_RUN([
1512       #define _GNU_SOURCE 1
1513       #include <locale.h>
1514       #include <string.h>
1515       #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1516       extern __typeof(newlocale) __newlocale;
1517       extern __typeof(duplocale) __duplocale;
1518       extern __typeof(strcoll_l) __strcoll_l;
1519       #endif
1520       int main()
1521       {
1522         const char __one[] = "Äuglein Augmen";
1523         const char __two[] = "Äuglein";
1524         int i;
1525         int j;
1526         __locale_t        loc;
1527         __locale_t        loc_dup;
1528         loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1529         loc_dup = __duplocale(loc);
1530         i = __strcoll_l(__one, __two, loc);
1531         j = __strcoll_l(__one, __two, loc_dup);
1532         return 0;
1533       }
1534       ],
1535       [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1536       [enable_clocale_flag=generic])
1537     fi
1538
1539     # Set it to scream when it hurts.
1540     ac_save_CFLAGS="$CFLAGS"
1541     CFLAGS="-Wimplicit-function-declaration -Werror"
1542
1543     # Use strxfrm_l if available.
1544     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1545                     #include <string.h>
1546                     #include <locale.h>],
1547                     [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1548                     AC_DEFINE(HAVE_STRXFRM_L, 1,
1549                     [Define if strxfrm_l is available in <string.h>.]),)
1550
1551     # Use strerror_l if available.
1552     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1553                     #include <string.h>
1554                     #include <locale.h>],
1555                     [__locale_t loc; strerror_l(5, loc);],
1556                     AC_DEFINE(HAVE_STRERROR_L, 1,
1557                     [Define if strerror_l is available in <string.h>.]),)
1558
1559     CFLAGS="$ac_save_CFLAGS"
1560   fi
1561
1562   # Perhaps use strerror_r if available, and strerror_l isn't.
1563   ac_save_CFLAGS="$CFLAGS"
1564   CFLAGS="-Wimplicit-function-declaration -Werror"
1565   AC_TRY_COMPILE([#define _GNU_SOURCE 1
1566                   #include <string.h>
1567                   #include <locale.h>],
1568                   [char s[128]; strerror_r(5, s, 128);],
1569                   AC_DEFINE(HAVE_STRERROR_R, 1,
1570                   [Define if strerror_r is available in <string.h>.]),)
1571   CFLAGS="$ac_save_CFLAGS"
1572
1573   # Set configure bits for specified locale package
1574   AC_MSG_CHECKING([for C locale to use])
1575   case ${enable_clocale_flag} in
1576     generic)
1577       AC_MSG_RESULT(generic)
1578
1579       CLOCALE_H=config/locale/generic/c_locale.h
1580       CLOCALE_CC=config/locale/generic/c_locale.cc
1581       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1582       CCOLLATE_CC=config/locale/generic/collate_members.cc
1583       CCTYPE_CC=config/locale/generic/ctype_members.cc
1584       CMESSAGES_H=config/locale/generic/messages_members.h
1585       CMESSAGES_CC=config/locale/generic/messages_members.cc
1586       CMONEY_CC=config/locale/generic/monetary_members.cc
1587       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1588       CTIME_H=config/locale/generic/time_members.h
1589       CTIME_CC=config/locale/generic/time_members.cc
1590       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1591       ;;
1592     darwin)
1593       AC_MSG_RESULT(darwin or freebsd)
1594
1595       CLOCALE_H=config/locale/generic/c_locale.h
1596       CLOCALE_CC=config/locale/generic/c_locale.cc
1597       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1598       CCOLLATE_CC=config/locale/generic/collate_members.cc
1599       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1600       CMESSAGES_H=config/locale/generic/messages_members.h
1601       CMESSAGES_CC=config/locale/generic/messages_members.cc
1602       CMONEY_CC=config/locale/generic/monetary_members.cc
1603       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1604       CTIME_H=config/locale/generic/time_members.h
1605       CTIME_CC=config/locale/generic/time_members.cc
1606       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1607       ;;
1608
1609     gnu)
1610       AC_MSG_RESULT(gnu)
1611
1612       # Declare intention to use gettext, and add support for specific
1613       # languages.
1614       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1615       ALL_LINGUAS="de fr"
1616
1617       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1618       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1619       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1620         USE_NLS=yes
1621       fi
1622       # Export the build objects.
1623       for ling in $ALL_LINGUAS; do \
1624         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1625         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1626       done
1627       AC_SUBST(glibcxx_MOFILES)
1628       AC_SUBST(glibcxx_POFILES)
1629
1630       CLOCALE_H=config/locale/gnu/c_locale.h
1631       CLOCALE_CC=config/locale/gnu/c_locale.cc
1632       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1633       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1634       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1635       CMESSAGES_H=config/locale/gnu/messages_members.h
1636       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1637       CMONEY_CC=config/locale/gnu/monetary_members.cc
1638       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1639       CTIME_H=config/locale/gnu/time_members.h
1640       CTIME_CC=config/locale/gnu/time_members.cc
1641       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1642       ;;
1643     ieee_1003.1-2001)
1644       AC_MSG_RESULT(IEEE 1003.1)
1645
1646       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1647       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1648       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1649       CCOLLATE_CC=config/locale/generic/collate_members.cc
1650       CCTYPE_CC=config/locale/generic/ctype_members.cc
1651       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1652       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1653       CMONEY_CC=config/locale/generic/monetary_members.cc
1654       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1655       CTIME_H=config/locale/generic/time_members.h
1656       CTIME_CC=config/locale/generic/time_members.cc
1657       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1658       ;;
1659   esac
1660
1661   # This is where the testsuite looks for locale catalogs, using the
1662   # -DLOCALEDIR define during testsuite compilation.
1663   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1664   AC_SUBST(glibcxx_localedir)
1665
1666   # A standalone libintl (e.g., GNU libintl) may be in use.
1667   if test $USE_NLS = yes; then
1668     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1669     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1670   fi
1671   if test $USE_NLS = yes; then
1672     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1673               [Define if NLS translations are to be used.])
1674   fi
1675
1676   AC_SUBST(USE_NLS)
1677   AC_SUBST(CLOCALE_H)
1678   AC_SUBST(CMESSAGES_H)
1679   AC_SUBST(CCODECVT_CC)
1680   AC_SUBST(CCOLLATE_CC)
1681   AC_SUBST(CCTYPE_CC)
1682   AC_SUBST(CMESSAGES_CC)
1683   AC_SUBST(CMONEY_CC)
1684   AC_SUBST(CNUMERIC_CC)
1685   AC_SUBST(CTIME_H)
1686   AC_SUBST(CTIME_CC)
1687   AC_SUBST(CLOCALE_CC)
1688   AC_SUBST(CLOCALE_INTERNAL_H)
1689 ])
1690
1691
1692 dnl
1693 dnl Check for which std::allocator base class to use.  The choice is
1694 dnl mapped from a subdirectory of include/ext.
1695 dnl
1696 dnl Default is new.
1697 dnl
1698 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1699   AC_MSG_CHECKING([for std::allocator base class])
1700   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1701     [use KIND for target std::allocator base],
1702     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1703
1704   # If they didn't use this option switch, or if they specified --enable
1705   # with no specific model, we'll have to look for one.  If they
1706   # specified --disable (???), do likewise.
1707   if test $enable_libstdcxx_allocator = no ||
1708      test $enable_libstdcxx_allocator = yes;
1709   then
1710      enable_libstdcxx_allocator=auto
1711   fi
1712
1713   # Either a known package, or "auto". Auto implies the default choice
1714   # for a particular platform.
1715   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1716
1717   # Probe for host-specific support if no specific model is specified.
1718   # Default to "new".
1719   if test $enable_libstdcxx_allocator_flag = auto; then
1720     case ${target_os} in
1721       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1722         enable_libstdcxx_allocator_flag=new
1723         ;;
1724       *)
1725         enable_libstdcxx_allocator_flag=new
1726         ;;
1727     esac
1728   fi
1729   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1730
1731
1732   # Set configure bits for specified locale package
1733   case ${enable_libstdcxx_allocator_flag} in
1734     bitmap)
1735       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1736       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1737       ;;
1738     malloc)
1739       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1740       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1741       ;;
1742     mt)
1743       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1744       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1745       ;;
1746     new)
1747       ALLOCATOR_H=config/allocator/new_allocator_base.h
1748       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1749       ;;
1750     pool)
1751       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1752       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1753       ;;
1754   esac
1755
1756   AC_SUBST(ALLOCATOR_H)
1757   AC_SUBST(ALLOCATOR_NAME)
1758 ])
1759
1760
1761 dnl
1762 dnl Check for whether the Boost-derived checks should be turned on.
1763 dnl
1764 dnl --enable-concept-checks turns them on.
1765 dnl --disable-concept-checks leaves them off.
1766 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1767 dnl       Where DEFAULT is either `yes' or `no'.
1768 dnl
1769 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1770   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1771   if test $enable_concept_checks = yes; then
1772     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1773               [Define to use concept checking code from the boost libraries.])
1774   fi
1775 ])
1776
1777 dnl
1778 dnl Check for parallel mode pre-requisites, including OpenMP support.
1779 dnl
1780 dnl  +  Usage:  GLIBCXX_ENABLE_PARALLEL
1781 dnl
1782 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
1783
1784   # NB: libstdc++ may be configured before libgomp: can't check for the actual
1785   # dependencies (omp.h and libgomp).
1786   enable_parallel=no;
1787   if test -f $glibcxx_builddir/../libgomp/omp.h; then
1788     enable_parallel=yes;
1789   else
1790     AC_MSG_NOTICE([$glibcxx_builddir/../libgomp/omp.h not found])
1791   fi
1792
1793   # Check to see if it's explicitly disabled.
1794 #  GLIBCXX_ENABLE(libgomp,$1,,[enable code depending on libgomp],
1795 #       [permit yes|no])
1796
1797 #  if test x$enable_libgomp = xno; then
1798 #    enable_parallel=no
1799 #  fi
1800
1801   AC_MSG_CHECKING([for parallel mode support])
1802   AC_MSG_RESULT([$enable_parallel])
1803   GLIBCXX_CONDITIONAL(ENABLE_PARALLEL, test $enable_parallel = yes)
1804 ])
1805
1806
1807 dnl
1808 dnl Check for which I/O library to use:  stdio, or something specific.
1809 dnl
1810 dnl Default is stdio.
1811 dnl
1812 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1813   AC_MSG_CHECKING([for underlying I/O to use])
1814   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1815     [use target-specific I/O package], [permit stdio])
1816
1817   # Now that libio has been removed, you can have any color you want as long
1818   # as it's black.  This is one big no-op until other packages are added, but
1819   # showing the framework never hurts.
1820   case ${enable_cstdio} in
1821     stdio)
1822       CSTDIO_H=config/io/c_io_stdio.h
1823       BASIC_FILE_H=config/io/basic_file_stdio.h
1824       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1825       AC_MSG_RESULT(stdio)
1826       ;;
1827   esac
1828
1829   AC_SUBST(CSTDIO_H)
1830   AC_SUBST(BASIC_FILE_H)
1831   AC_SUBST(BASIC_FILE_CC)
1832 ])
1833
1834
1835 dnl
1836 dnl Check for "unusual" flags to pass to the compiler while building.
1837 dnl
1838 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1839 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1840 dnl --disable-cxx-flags passes nothing.
1841 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1842 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1843 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1844 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1845 dnl       If "default flags" is an empty string, the effect is the same
1846 dnl       as --disable or --enable=no.
1847 dnl
1848 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1849   AC_MSG_CHECKING([for extra compiler flags for building])
1850   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1851     [pass compiler FLAGS when building library],
1852     [case "x$enable_cxx_flags" in
1853       xno | x)   enable_cxx_flags= ;;
1854       x-*)       ;;
1855       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1856      esac])
1857
1858   # Run through flags (either default or command-line) and set anything
1859   # extra (e.g., #defines) that must accompany particular g++ options.
1860   if test -n "$enable_cxx_flags"; then
1861     for f in $enable_cxx_flags; do
1862       case "$f" in
1863         -fhonor-std)  ;;
1864         -*)  ;;
1865         *)   # and we're trying to pass /what/ exactly?
1866              AC_MSG_ERROR([compiler flags start with a -]) ;;
1867       esac
1868     done
1869   fi
1870
1871   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1872   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1873   AC_SUBST(EXTRA_CXX_FLAGS)
1874 ])
1875
1876
1877 dnl
1878 dnl Check to see if debugging libraries are to be built.
1879 dnl
1880 dnl --enable-libstdcxx-debug
1881 dnl builds a separate set of debugging libraries in addition to the
1882 dnl normal (shared, static) libstdc++ binaries.
1883 dnl
1884 dnl --disable-libstdcxx-debug
1885 dnl builds only one (non-debug) version of libstdc++.
1886 dnl
1887 dnl --enable-libstdcxx-debug-flags=FLAGS
1888 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1889 dnl
1890 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1891 dnl       Where DEFAULT is either `yes' or `no'.
1892 dnl
1893 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1894   AC_MSG_CHECKING([for additional debug build])
1895   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1896   AC_MSG_RESULT($enable_libstdcxx_debug)
1897   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1898 ])
1899
1900
1901 dnl
1902 dnl Check for explicit debug flags.
1903 dnl
1904 dnl --enable-libstdcxx-debug-flags='-O1'
1905 dnl is a general method for passing flags to be used when
1906 dnl building debug libraries with --enable-debug.
1907 dnl
1908 dnl --disable-libstdcxx-debug-flags does nothing.
1909 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1910 dnl       If "default flags" is an empty string, the effect is the same
1911 dnl       as --disable or --enable=no.
1912 dnl
1913 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1914   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1915     [pass compiler FLAGS when building debug library],
1916     [case "x$enable_libstdcxx_debug_flags" in
1917       xno | x)    enable_libstdcxx_debug_flags= ;;
1918       x-*)        ;;
1919       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1920      esac])
1921
1922   # Option parsed, now set things appropriately
1923   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1924   AC_SUBST(DEBUG_FLAGS)
1925
1926   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1927 ])
1928
1929
1930 dnl
1931 dnl Check if the user only wants a freestanding library implementation.
1932 dnl
1933 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1934 dnl installing only the headers required by [17.4.1.3] and the language
1935 dnl support library.  More than that will be built (to keep the Makefiles
1936 dnl conveniently clean), but not installed.
1937 dnl
1938 dnl Sets:
1939 dnl  is_hosted  (yes/no)
1940 dnl
1941 dnl Defines:
1942 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1943 dnl
1944 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1945   AC_ARG_ENABLE([hosted-libstdcxx],
1946     AC_HELP_STRING([--disable-hosted-libstdcxx],
1947                    [only build freestanding C++ runtime support]),,
1948     [case "$host" in
1949         arm*-*-symbianelf*)
1950             enable_hosted_libstdcxx=no
1951             ;;
1952         *)
1953             enable_hosted_libstdcxx=yes
1954             ;;
1955      esac])
1956   if test "$enable_hosted_libstdcxx" = no; then
1957     AC_MSG_NOTICE([Only freestanding libraries will be built])
1958     is_hosted=no
1959     hosted_define=0
1960     enable_abi_check=no
1961     enable_libstdcxx_pch=no
1962   else
1963     is_hosted=yes
1964     hosted_define=1
1965   fi
1966   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1967   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1968     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1969 ])
1970
1971
1972 dnl
1973 dnl Check for template specializations for the 'long long' type.
1974 dnl The result determines only whether 'long long' I/O is enabled; things
1975 dnl like numeric_limits<> specializations are always available.
1976 dnl
1977 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1978 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1979 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1980 dnl       Where DEFAULT is either `yes' or `no'.
1981 dnl
1982 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1983   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1984   if test $enable_long_long = yes; then
1985     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1986               [Define if code specialized for long long should be used.])
1987   fi
1988   AC_MSG_CHECKING([for enabled long long specializations])
1989   AC_MSG_RESULT([$enable_long_long])
1990 ])
1991
1992
1993 dnl
1994 dnl Check for template specializations for the 'wchar_t' type.
1995 dnl
1996 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1997 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1998 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1999 dnl       Where DEFAULT is either `yes' or `no'.
2000 dnl
2001 dnl Necessary support must also be present.
2002 dnl
2003 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2004   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2005
2006   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2007   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2008   AC_MSG_CHECKING([for mbstate_t])
2009   AC_TRY_COMPILE([#include <wchar.h>],
2010   [mbstate_t teststate;],
2011   have_mbstate_t=yes, have_mbstate_t=no)
2012   AC_MSG_RESULT($have_mbstate_t)
2013   if test x"$have_mbstate_t" = xyes; then
2014     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2015   fi
2016
2017   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2018   # ac_has_wchar_h.
2019   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2020
2021   if test x"$enable_wchar_t" = x"yes"; then
2022
2023     AC_LANG_SAVE
2024     AC_LANG_CPLUSPLUS
2025
2026     if test x"$ac_has_wchar_h" = xyes &&
2027        test x"$ac_has_wctype_h" = xyes; then
2028       AC_TRY_COMPILE([#include <wchar.h>
2029                       #include <stddef.h>
2030                       wint_t i;
2031                       long l = WEOF;
2032                       long j = WCHAR_MIN;
2033                       long k = WCHAR_MAX;
2034                       namespace test
2035                       {
2036                         using ::btowc;
2037                         using ::fgetwc;
2038                         using ::fgetws;
2039                         using ::fputwc;
2040                         using ::fputws;
2041                         using ::fwide;
2042                         using ::fwprintf;
2043                         using ::fwscanf;
2044                         using ::getwc;
2045                         using ::getwchar;
2046                         using ::mbrlen;
2047                         using ::mbrtowc;
2048                         using ::mbsinit;
2049                         using ::mbsrtowcs;
2050                         using ::putwc;
2051                         using ::putwchar;
2052                         using ::swprintf;
2053                         using ::swscanf;
2054                         using ::ungetwc;
2055                         using ::vfwprintf;
2056                         using ::vswprintf;
2057                         using ::vwprintf;
2058                         using ::wcrtomb;
2059                         using ::wcscat;
2060                         using ::wcschr;
2061                         using ::wcscmp;
2062                         using ::wcscoll;
2063                         using ::wcscpy;
2064                         using ::wcscspn;
2065                         using ::wcsftime;
2066                         using ::wcslen;
2067                         using ::wcsncat;
2068                         using ::wcsncmp;
2069                         using ::wcsncpy;
2070                         using ::wcspbrk;
2071                         using ::wcsrchr;
2072                         using ::wcsrtombs;
2073                         using ::wcsspn;
2074                         using ::wcsstr;
2075                         using ::wcstod;
2076                         using ::wcstok;
2077                         using ::wcstol;
2078                         using ::wcstoul;
2079                         using ::wcsxfrm;
2080                         using ::wctob;
2081                         using ::wmemchr;
2082                         using ::wmemcmp;
2083                         using ::wmemcpy;
2084                         using ::wmemmove;
2085                         using ::wmemset;
2086                         using ::wprintf;
2087                         using ::wscanf;
2088                       }
2089                      ],[],[], [enable_wchar_t=no])
2090     else
2091       enable_wchar_t=no
2092     fi
2093
2094     AC_LANG_RESTORE
2095   fi
2096
2097   if test x"$enable_wchar_t" = x"yes"; then
2098     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2099               [Define if code specialized for wchar_t should be used.])
2100   fi
2101
2102   AC_MSG_CHECKING([for enabled wchar_t specializations])
2103   AC_MSG_RESULT([$enable_wchar_t])
2104 ])
2105
2106
2107 dnl
2108 dnl Check to see if building and using a C++ precompiled header can be done.
2109 dnl
2110 dnl --enable-libstdcxx-pch=yes
2111 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2112 dnl may work, after some light-hearted attempts to puzzle out compiler
2113 dnl support, flip bits on in include/Makefile.am
2114 dnl
2115 dnl --disable-libstdcxx-pch
2116 dnl turns off attempts to use or build stdc++.h.gch.
2117 dnl
2118 dnl Substs:
2119 dnl  glibcxx_PCHFLAGS
2120 dnl
2121 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2122   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2123   if test $enable_libstdcxx_pch = yes; then
2124     AC_CACHE_CHECK([for compiler with PCH support],
2125       [glibcxx_cv_prog_CXX_pch],
2126       [ac_save_CXXFLAGS="$CXXFLAGS"
2127        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2128        AC_LANG_SAVE
2129        AC_LANG_CPLUSPLUS
2130        echo '#include <math.h>' > conftest.h
2131        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2132                           -o conftest.h.gch 1>&5 2>&1 &&
2133                 echo '#error "pch failed"' > conftest.h &&
2134           echo '#include "conftest.h"' > conftest.cc &&
2135                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2136        then
2137          glibcxx_cv_prog_CXX_pch=yes
2138        else
2139          glibcxx_cv_prog_CXX_pch=no
2140        fi
2141        rm -f conftest*
2142        CXXFLAGS=$ac_save_CXXFLAGS
2143        AC_LANG_RESTORE
2144       ])
2145     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2146   fi
2147
2148   AC_MSG_CHECKING([for enabled PCH])
2149   AC_MSG_RESULT([$enable_libstdcxx_pch])
2150
2151   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2152   if test $enable_libstdcxx_pch = yes; then
2153     glibcxx_PCHFLAGS="-include bits/stdc++.h"
2154   else
2155     glibcxx_PCHFLAGS=""
2156   fi
2157   AC_SUBST(glibcxx_PCHFLAGS)
2158 ])
2159
2160
2161 dnl
2162 dnl Check for atomic builtins.
2163 dnl See:
2164 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
2165 dnl
2166 dnl This checks to see if the host supports the compiler-generated
2167 dnl builtins for atomic operations. Note, this is intended to be an
2168 dnl all-or-nothing switch, so all the atomic operations that are used
2169 dnl should be checked.
2170 dnl
2171 dnl Note:
2172 dnl libgomp and libgfortran do this with a link test, instead of an asm test.
2173 dnl see: CHECK_SYNC_FETCH_AND_ADD
2174 dnl
2175 dnl Defines:
2176 dnl  _GLIBCXX_ATOMIC_BUILTINS if the compiler on this target supports atomics.
2177 dnl
2178 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2179   AC_MSG_CHECKING([for atomic builtins])
2180   AC_LANG_SAVE
2181   AC_LANG_CPLUSPLUS
2182
2183   # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2184     cat > conftest.$ac_ext << EOF
2185 [#]line __oline__ "configure"
2186 int main()
2187 {
2188   // NB: _Atomic_word not necessarily int.
2189   typedef int atomic_type;
2190   atomic_type c1;
2191   atomic_type c2;
2192   const atomic_type c3(0);
2193   if (__sync_fetch_and_add(&c1, c2) == c3)
2194     {
2195       // Do something.
2196     }
2197    return 0;
2198 }
2199 EOF
2200     old_CXXFLAGS="$CXXFLAGS"
2201     CXXFLAGS=-S
2202     if AC_TRY_EVAL(ac_compile); then
2203       if grep __sync_fetch_and_add conftest.s >/dev/null 2>&1 ; then
2204         enable_atomic_builtins=no
2205       else
2206       AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2207         [Define if builtin atomic operations are supported on this host.])
2208         enable_atomic_builtins=yes
2209         atomicity_dir=cpu/generic/atomicity_builtins
2210       fi
2211     fi
2212     CXXFLAGS="$old_CXXFLAGS"
2213     rm -f conftest*
2214
2215    # Now, if still generic, set to mutex.
2216   if test $atomicity_dir = "cpu/generic" ; then
2217         atomicity_dir=cpu/generic/atomicity_mutex
2218   fi
2219  AC_LANG_RESTORE
2220  AC_MSG_RESULT($enable_atomic_builtins)
2221 ])
2222
2223
2224 dnl
2225 dnl Check for exception handling support.  If an explicit enable/disable
2226 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2227 dnl target may or may not support call frame exceptions.
2228 dnl
2229 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2230 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2231 dnl Neither one forces an attempt at detection.
2232 dnl
2233 dnl Defines:
2234 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2235 dnl
2236 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2237   AC_MSG_CHECKING([for exception model to use])
2238   AC_LANG_SAVE
2239   AC_LANG_CPLUSPLUS
2240   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2241     [force use of builtin_setjmp for exceptions],
2242     [permit yes|no|auto])
2243
2244   if test $enable_sjlj_exceptions = auto; then
2245     # Botheration.  Now we've got to detect the exception model.  Link tests
2246     # against libgcc.a are problematic since we've not been given proper -L
2247     # bits for single-tree newlib and libgloss.
2248     #
2249     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2250     cat > conftest.$ac_ext << EOF
2251 [#]line __oline__ "configure"
2252 struct S { ~S(); };
2253 void bar();
2254 void foo()
2255 {
2256   S s;
2257   bar();
2258 }
2259 EOF
2260     old_CXXFLAGS="$CXXFLAGS"
2261     CXXFLAGS=-S
2262     if AC_TRY_EVAL(ac_compile); then
2263       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2264         enable_sjlj_exceptions=yes
2265       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2266         enable_sjlj_exceptions=no
2267       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2268         enable_sjlj_exceptions=no
2269       fi
2270     fi
2271     CXXFLAGS="$old_CXXFLAGS"
2272     rm -f conftest*
2273   fi
2274
2275   # This is a tad weird, for hysterical raisins.  We have to map
2276   # enable/disable to two different models.
2277   case $enable_sjlj_exceptions in
2278     yes)
2279       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2280         [Define if the compiler is configured for setjmp/longjmp exceptions.])
2281       ac_exception_model_name=sjlj
2282       ;;
2283     no)
2284       ac_exception_model_name="call frame"
2285       ;;
2286     *)
2287       AC_MSG_ERROR([unable to detect exception model])
2288       ;;
2289   esac
2290  AC_LANG_RESTORE
2291  AC_MSG_RESULT($ac_exception_model_name)
2292 ])
2293
2294
2295 dnl
2296 dnl Allow visibility attributes to be used on namespaces, objects, etc.
2297 dnl
2298 dnl --enable-visibility enables attempt to use visibility attributes.
2299 dnl --disable-visibility turns off all use of visibility attributes.
2300 dnl  +  Usage:  GLIBCXX_ENABLE_VISIBILITY[(DEFAULT)]
2301 dnl       Where DEFAULT is 'yes'.
2302 dnl
2303 AC_DEFUN([GLIBCXX_ENABLE_VISIBILITY], [
2304 GLIBCXX_ENABLE(visibility,$1,,[enables visibility safe usage])
2305
2306 if test x$enable_visibility = xyes ; then
2307   dnl all hail libgfortran
2308   dnl Check whether the target supports hidden visibility.
2309   AC_CACHE_CHECK([whether the target supports hidden visibility],
2310                  have_attribute_visibility, [
2311   save_CFLAGS="$CFLAGS"
2312   CFLAGS="$CFLAGS -Werror"
2313   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
2314                  [], have_attribute_visibility=yes,
2315                  have_attribute_visibility=no)
2316   CFLAGS="$save_CFLAGS"])
2317   if test $have_attribute_visibility = no; then
2318     enable_visibility=no
2319   fi
2320 fi
2321
2322 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_visibility = yes)
2323 AC_MSG_NOTICE([visibility supported: $enable_visibility])
2324 ])
2325
2326
2327 dnl
2328 dnl Add version tags to symbols in shared library (or not), additionally
2329 dnl marking other symbols as private/local (or not).
2330 dnl
2331 dnl --enable-symvers=style adds a version script to the linker call when
2332 dnl       creating the shared library.  The choice of version script is
2333 dnl       controlled by 'style'.
2334 dnl --disable-symvers does not.
2335 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
2336 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
2337 dnl       choose a default style based on linker characteristics.  Passing
2338 dnl       'no' disables versioning.
2339 dnl
2340 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
2341
2342 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
2343   [enables symbol versioning of the shared library],
2344   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
2345
2346 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
2347 # don't know enough about $LD to do tricks...
2348 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
2349
2350 # Turn a 'yes' into a suitable default.
2351 if test x$enable_symvers = xyes ; then
2352   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
2353     enable_symvers=no
2354   else
2355     if test $with_gnu_ld = yes ; then
2356       enable_symvers=gnu
2357     else
2358       case ${target_os} in
2359         darwin*)
2360           enable_symvers=darwin ;;
2361         *)
2362           enable_symvers=no ;;
2363       esac
2364     fi
2365   fi
2366 fi
2367
2368 # Check to see if 'darwin' or 'darwin-export' can win.
2369 if test x$enable_symvers = xdarwin-export ; then
2370     enable_symvers=darwin
2371 fi
2372
2373 # Check to see if 'gnu' can win.
2374 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
2375   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2376   AC_MSG_CHECKING([for shared libgcc])
2377   ac_save_CFLAGS="$CFLAGS"
2378   CFLAGS=' -lgcc_s'
2379   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
2380   CFLAGS="$ac_save_CFLAGS"
2381   if test $glibcxx_shared_libgcc = no; then
2382     cat > conftest.c <<EOF
2383 int main (void) { return 0; }
2384 EOF
2385 changequote(,)dnl
2386     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
2387                              -shared -shared-libgcc -o conftest.so \
2388                              conftest.c -v 2>&1 >/dev/null \
2389                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
2390 changequote([,])dnl
2391     rm -f conftest.c conftest.so
2392     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
2393       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
2394       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
2395       CFLAGS="$ac_save_CFLAGS"
2396     fi
2397   fi
2398   AC_MSG_RESULT($glibcxx_shared_libgcc)
2399
2400   # For GNU ld, we need at least this version.  The format is described in
2401   # GLIBCXX_CHECK_LINKER_FEATURES above.
2402   glibcxx_min_gnu_ld_version=21400
2403
2404   # If no shared libgcc, can't win.
2405   if test $glibcxx_shared_libgcc != yes; then
2406       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2407       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
2408       AC_MSG_WARN([=== Symbol versioning will be disabled.])
2409       enable_symvers=no
2410   elif test $with_gnu_ld != yes ; then
2411     # just fail for now
2412     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
2413     AC_MSG_WARN([=== you are not using the GNU linker.])
2414     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2415     enable_symvers=no
2416   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
2417     # The right tools, the right setup, but too old.  Fallbacks?
2418     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
2419     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
2420     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
2421     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
2422     AC_MSG_WARN([=== Symbol versioning will be disabled.])
2423     enable_symvers=no
2424   fi
2425 fi
2426
2427 # Everything parsed; figure out what file to use.
2428 case $enable_symvers in
2429   no)
2430     SYMVER_FILE=config/abi/pre/none.ver
2431     ;;
2432   gnu)
2433     SYMVER_FILE=config/abi/pre/gnu.ver
2434     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
2435               [Define to use GNU versioning in the shared library.])
2436     ;;
2437   gnu-versioned-namespace)
2438     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
2439     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
2440               [Define to use GNU namespace versioning in the shared library.])
2441     ;;
2442   darwin)
2443     SYMVER_FILE=config/abi/pre/gnu.ver
2444     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
2445               [Define to use darwin versioning in the shared library.])
2446     ;;
2447 esac
2448
2449 if test x$enable_symvers != xno ; then
2450   AC_DEFINE(_GLIBCXX_SYMVER, 1,
2451          [Define to use symbol versioning in the shared library.])
2452 fi
2453
2454 AC_SUBST(SYMVER_FILE)
2455 AC_SUBST(port_specific_symbol_files)
2456 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
2457 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
2458 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
2459 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
2460 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
2461
2462 # Now, set up compatibility support, if any.
2463 # In addition, need this to deal with std::size_t mangling in
2464 # src/compatibility.cc.  In a perfect world, could use
2465 # typeid(std::size_t).name()[0] to do direct substitution.
2466 AC_MSG_CHECKING([for size_t as unsigned int])
2467 ac_save_CFLAGS="$CFLAGS"
2468 CFLAGS="-Werror"
2469 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
2470                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
2471 CFLAGS=$ac_save_CFLAGS
2472 if test "$glibcxx_size_t_is_i" = yes; then
2473   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
2474 fi
2475 AC_MSG_RESULT([$glibcxx_size_t_is_i])
2476
2477 AC_MSG_CHECKING([for ptrdiff_t as int])
2478 ac_save_CFLAGS="$CFLAGS"
2479 CFLAGS="-Werror"
2480 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
2481                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
2482 CFLAGS=$ac_save_CFLAGS
2483 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
2484   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
2485 fi
2486 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
2487 ])
2488
2489
2490 dnl
2491 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
2492 dnl We must stage the required headers so that they will be installed
2493 dnl with the library (unlike libgcc, the STL implementation is provided
2494 dnl solely within headers).  Since we must not inject random user-space
2495 dnl macro names into user-provided C++ code, we first stage into <file>-in
2496 dnl and process to <file> with an output command.  The reason for a two-
2497 dnl stage process here is to correctly handle $srcdir!=$objdir without
2498 dnl having to write complex code (the sed commands to clean the macro
2499 dnl namespace are complex and fragile enough as it is).  We must also
2500 dnl add a relative path so that -I- is supported properly.
2501 dnl
2502 dnl Substs:
2503 dnl  glibcxx_thread_h
2504 dnl
2505 dnl Defines:
2506 dnl  HAVE_GTHR_DEFAULT
2507 dnl
2508 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
2509   AC_MSG_CHECKING([for thread model used by GCC])
2510   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
2511   AC_MSG_RESULT([$target_thread_file])
2512
2513   if test $target_thread_file != single; then
2514     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
2515               [Define if gthr-default.h exists
2516               (meaning that threading support is enabled).])
2517   fi
2518
2519   glibcxx_thread_h=gthr-$target_thread_file.h
2520
2521   dnl Check for __GTHREADS define.
2522   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
2523   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
2524     enable_thread=yes
2525   else
2526    enable_thread=no
2527   fi
2528
2529   AC_SUBST(glibcxx_thread_h)
2530 ])
2531
2532
2533 # Check whether LC_MESSAGES is available in <locale.h>.
2534 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2535 #
2536 # This file file be copied and used freely without restrictions.  It can
2537 # be used in projects which are not available under the GNU Public License
2538 # but which still want to provide support for the GNU gettext functionality.
2539 # Please note that the actual code is *not* freely available.
2540
2541 # serial 1
2542 AC_DEFUN([AC_LC_MESSAGES], [
2543   AC_CHECK_HEADER(locale.h, [
2544     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2545       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2546        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2547     if test $ac_cv_val_LC_MESSAGES = yes; then
2548       AC_DEFINE(HAVE_LC_MESSAGES, 1,
2549                 [Define if LC_MESSAGES is available in <locale.h>.])
2550     fi
2551   ])
2552 ])
2553
2554 # Macros from the top-level gcc directory.
2555 m4_include([../config/tls.m4])
2556