libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2013 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.64)
  33 AC_INIT(package-unused, version-unused,, libbacktrace)
  34 AC_CONFIG_SRCDIR(backtrace.h)
  35 AC_CONFIG_HEADER(config.h)
  36
  37 AC_CANONICAL_SYSTEM
  38 target_alias=${target_alias-$host_alias}
  39
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 libtool_VERSION=1:0:0
  43 AC_SUBST(libtool_VERSION)
  44
  45 # 1.11.1: Require that version of automake.
  46 # foreign: Don't require README, INSTALL, NEWS, etc.
  47 # no-define: Don't define PACKAGE and VERSION.
  48 # no-dependencies: Don't generate automatic dependencies.
  49 #    (because it breaks when using bootstrap-lean, since some of the
  50 #    headers are gone at "make install" time).
  51 # -Wall: Issue all automake warnings.
  52 # -Wno-portability: Don't warn about constructs supported by GNU make.
  53 #    (because GCC requires GNU make anyhow).
  54 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  55
  56 AM_MAINTAINER_MODE
  57
  58 AC_ARG_WITH(target-subdir,
  59 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  60
  61 # We must force CC to /not/ be precious variables; otherwise
  62 # the wrong, non-multilib-adjusted value will be used in multilibs.
  63 # As a side effect, we have to subst CFLAGS ourselves.
  64 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  65 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  66 AC_PROG_CC
  67 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  68
  69 AC_SUBST(CFLAGS)
  70
  71 AC_PROG_RANLIB
  72
  73 AC_PROG_AWK
  74 case "$AWK" in
  75 "") AC_MSG_ERROR([can't build without awk]) ;;
  76 esac
  77
  78 LT_INIT([disable-shared])
  79 AM_PROG_LIBTOOL
  80
  81 backtrace_supported=yes
  82
  83 if test -n "${with_target_subdir}"; then
  84   # We are compiling a GCC library.  We can assume that the unwind
  85   # library exists.
  86   AM_ENABLE_MULTILIB(, ..)
  87   BACKTRACE_FILE="backtrace.lo simple.lo"
  88 else
  89   AC_CHECK_HEADER([unwind.h],
  90     [AC_CHECK_FUNC([_Unwind_Backtrace],
  91                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  92                    [BACKTRACE_FILE="nounwind.lo"
  93                     backtrace_supported=no])],
  94     [BACKTRACE_FILE="nounwind.lo"
  95      backtrace_supported=no])
  96 fi
  97 AC_SUBST(BACKTRACE_FILE)
  98
  99 EXTRA_FLAGS=
 100 if test -n "${with_target_subdir}"; then
 101   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 102 else
 103   AC_CACHE_CHECK([for -funwind-tables option],
 104     [libbacktrace_cv_c_unwind_tables],
 105     [CFLAGS_hold="$CFLAGS"
 106      CFLAGS="$CFLAGS -funwind-tables"
 107      AC_COMPILE_IFELSE(
 108        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 109        [libbacktrace_cv_c_unwind_tables=yes],
 110        [libbacktrace_cv_c_unwind_tables=no])
 111      CFLAGS="$CFLAGS_hold"])
 112   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 113     EXTRA_FLAGS=-funwind-tables
 114   fi
 115   AC_CACHE_CHECK([for -frandom-seed=string option],
 116     [libbacktrace_cv_c_random_seed_string],
 117     [CFLAGS_hold="$CFLAGS"
 118      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 119      AC_COMPILE_IFELSE(
 120        [AC_LANG_PROGRAM([], [return 0;])],
 121        [libbacktrace_cv_c_random_seed_string=yes],
 122        [libbacktrace_cv_c_random_seed_string=no])
 123      CFLAGS="$CFLAGS_hold"])
 124   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 125     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 126   fi
 127 fi
 128 AC_SUBST(EXTRA_FLAGS)
 129
 130 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 131                           -Wmissing-prototypes -Wold-style-definition \
 132                           -Wmissing-format-attribute -Wcast-qual],
 133                           [WARN_FLAGS])
 134
 135 if test -n "${with_target_subdir}"; then
 136   WARN_FLAGS="$WARN_FLAGS -Werror"
 137 fi
 138
 139 AC_SUBST(WARN_FLAGS)
 140
 141 if test -n "${with_target_subdir}"; then
 142   GCC_CHECK_UNWIND_GETIPINFO
 143 else
 144   ac_save_CFFLAGS="$CFLAGS"
 145   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 146   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 147   AC_COMPILE_IFELSE(
 148     [AC_LANG_PROGRAM(
 149        [#include "unwind.h"
 150         struct _Unwind_Context *context;
 151         int ip_before_insn = 0;],
 152         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 153         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 154   CFLAGS="$ac_save_CFLAGS"
 155   AC_MSG_RESULT([$have_unwind_getipinfo])
 156   if test "$have_unwind_getipinfo" = "yes"; then
 157     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 158   fi
 159 fi
 160
 161 # When building as a target library, shared libraries may want to link
 162 # this in.  We don't want to provide another shared library to
 163 # complicate dependencies.  Instead, we just compile with -fPIC.
 164 PIC_FLAG=
 165 if test -n "${with_target_subdir}"; then
 166   PIC_FLAG=-fPIC
 167 fi
 168 AC_SUBST(PIC_FLAG)
 169
 170 # Test for __sync support.
 171 AC_CACHE_CHECK([__sync extensions],
 172 [libbacktrace_cv_sys_sync],
 173 [if test -n "${with_target_subdir}"; then
 174    libbacktrace_cv_sys_sync=yes
 175  else
 176    AC_LINK_IFELSE(
 177      [AC_LANG_PROGRAM([int i;],
 178                       [__sync_bool_compare_and_swap (&i, i, i);
 179                        __sync_lock_test_and_set (&i, 1);
 180                        __sync_lock_release (&i);])],
 181      [libbacktrace_cv_sys_sync=yes],
 182      [libbacktrace_cv_sys_sync=no])
 183  fi])
 184 BACKTRACE_SUPPORTS_THREADS=0
 185 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 186   BACKTRACE_SUPPORTS_THREADS=1
 187   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 188             [Define to 1 if you have the __sync functions])
 189 fi
 190 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 191
 192 # The library needs to be able to read the executable itself.  Compile
 193 # a file to determine the executable format.  The awk script
 194 # filetype.awk prints out the file type.
 195 AC_CACHE_CHECK([output filetype],
 196 [libbacktrace_cv_sys_filetype],
 197 [filetype=
 198 AC_COMPILE_IFELSE(
 199   [AC_LANG_PROGRAM([int i;], [int j;])],
 200   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 201   [AC_MSG_FAILURE([compiler failed])])
 202 libbacktrace_cv_sys_filetype=$filetype])
 203
 204 # Match the file type to decide what files to compile.
 205 FORMAT_FILE=
 206 case "$libbacktrace_cv_sys_filetype" in
 207 elf*) FORMAT_FILE="elf.lo" ;;
 208 *) AC_MSG_WARN([could not determine output file type])
 209    FORMAT_FILE="unknown.lo"
 210    backtrace_supported=no
 211    ;;
 212 esac
 213 AC_SUBST(FORMAT_FILE)
 214
 215 # ELF defines.
 216 elfsize=
 217 case "$libbacktrace_cv_sys_filetype" in
 218 elf32) elfsize=32 ;;
 219 elf64) elfsize=64 ;;
 220 esac
 221 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 222
 223 BACKTRACE_SUPPORTED=0
 224 if test "$backtrace_supported" = "yes"; then
 225   BACKTRACE_SUPPORTED=1
 226 fi
 227 AC_SUBST(BACKTRACE_SUPPORTED)
 228
 229 GCC_HEADER_STDINT(gstdint.h)
 230
 231 AC_CHECK_HEADERS(sys/mman.h)
 232 if test "$ac_cv_header_sys_mman_h" = "no"; then
 233   have_mmap=no
 234 else
 235   if test -n "${with_target_subdir}"; then
 236     # When built as a GCC target library, we can't do a link test.  We
 237     # simply assume that if we have mman.h, we have mmap.
 238     have_mmap=yes
 239   else
 240     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 241   fi
 242 fi
 243 if test "$have_mmap" = "no"; then
 244   VIEW_FILE=read.lo
 245   ALLOC_FILE=alloc.lo
 246 else
 247   VIEW_FILE=mmapio.lo
 248   AC_PREPROC_IFELSE([
 249 #include <sys/mman.h>
 250 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 251   #error no MAP_ANONYMOUS
 252 #endif
 253 ], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 254 fi
 255 AC_SUBST(VIEW_FILE)
 256 AC_SUBST(ALLOC_FILE)
 257
 258 BACKTRACE_USES_MALLOC=0
 259 if test "$ALLOC_FILE" = "alloc.lo"; then
 260   BACKTRACE_USES_MALLOC=1
 261 fi
 262 AC_SUBST(BACKTRACE_USES_MALLOC)
 263
 264 # Check for dl_iterate_phdr.
 265 AC_CHECK_HEADERS(link.h)
 266 if test "$ac_cv_header_link_h" = "no"; then
 267   have_dl_iterate_phdr=no
 268 else
 269   if test -n "${with_target_subdir}"; then
 270     # When built as a GCC target library, we can't do a link test.
 271     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 272                     [have_dl_iterate_phdr=no])
 273     case "${host}" in
 274     *-*-solaris2.10*)
 275         # Avoid dl_iterate_phdr on Solaris 10, where it is in the
 276         # header file but is only in -ldl.
 277         have_dl_iterate_phdr=no ;;
 278     esac
 279   else
 280     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 281                   [have_dl_iterate_phdr=no])
 282   fi
 283 fi
 284 if test "$have_dl_iterate_phdr" = "yes"; then
 285   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 286 fi
 287
 288 # Check for the fcntl function.
 289 if test -n "${with_target_subdir}"; then
 290    case "${host}" in
 291    *-*-mingw*) have_fcntl=no ;;
 292    *) have_fcntl=yes ;;
 293    esac
 294 else
 295   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 296 fi
 297 if test "$have_fcntl" = "yes"; then
 298   AC_DEFINE([HAVE_FCNTL], 1,
 299             [Define to 1 if you have the fcntl function])
 300 fi
 301
 302 AC_CHECK_DECLS(strnlen)
 303
 304 # Check for getexecname function.
 305 if test -n "${with_target_subdir}"; then
 306    case "${host}" in
 307    *-*-solaris2*) have_getexecname=yes ;;
 308    *) have_getexecname=no ;;
 309    esac
 310 else
 311   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 312 fi
 313 if test "$have_getexecname" = "yes"; then
 314   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 315 fi
 316
 317 AC_CACHE_CHECK([whether tests can run],
 318   [libbacktrace_cv_sys_native],
 319   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 320      [libbacktrace_cv_sys_native=yes],
 321      [libbacktrace_cv_sys_native=no],
 322      [libbacktrace_cv_sys_native=no])])
 323 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 324
 325 if test "${multilib}" = "yes"; then
 326   multilib_arg="--enable-multilib"
 327 else
 328   multilib_arg=
 329 fi
 330
 331 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 332
 333 # We need multilib support, but only if configuring for the target.
 334 AC_CONFIG_COMMANDS([default],
 335 [if test -n "$CONFIG_FILES"; then
 336    if test -n "${with_target_subdir}"; then
 337      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 338      # that multilib installs will end up installed in the correct place.
 339      # The testsuite needs it for multilib-aware ABI baseline files.
 340      # To work around this not being passed down from config-ml.in ->
 341      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 342      # append it here.  Only modify Makefiles that have just been created.
 343      #
 344      # Also, get rid of this simulated-VPATH thing that automake does.
 345      cat > vpsed << \_EOF
 346   s!`test -f '$<' || echo '$(srcdir)/'`!!
 347 _EOF
 348      for i in $SUBDIRS; do
 349       case $CONFIG_FILES in
 350        *${i}/Makefile*)
 351          #echo "Adding MULTISUBDIR to $i/Makefile"
 352          sed -f vpsed $i/Makefile > tmp
 353          grep '^MULTISUBDIR =' Makefile >> tmp
 354          mv tmp $i/Makefile
 355          ;;
 356       esac
 357      done
 358      rm vpsed
 359    fi
 360  fi
 361 ],
 362 [
 363 # Variables needed in config.status (file generation) which aren't already
 364 # passed by autoconf.
 365 SUBDIRS="$SUBDIRS"
 366 ])
 367
 368 AC_OUTPUT