gcc-4_7-integration/libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   2005, 2006, 2009, 2011 Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 3, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.64)
  23 AC_INIT(package-unused, version-unused,, libobjc)
  24 AC_CONFIG_SRCDIR([objc/objc.h])
  25 GCC_TOPLEV_SUBDIRS
  26
  27 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  28 PACKAGE=libobjc
  29 # Version is pulled out to make it a bit easier to change using sed.
  30 VERSION=4:0:0
  31 AC_SUBST(VERSION)
  32
  33 # This works around the fact that libtool configuration may change LD
  34 # for this particular configuration, but some shells, instead of
  35 # keeping the changes in LD private, export them just because LD is
  36 # exported.
  37 ORIGINAL_LD_FOR_MULTILIBS=$LD
  38
  39 # -------
  40 # Options
  41 # -------
  42
  43 # We use these options to decide which functions to include.
  44 AC_ARG_WITH(target-subdir,
  45 [  --with-target-subdir=SUBDIR
  46                            configuring in a subdirectory])
  47 AC_ARG_WITH(cross-host,
  48 [  --with-cross-host=HOST  configuring with a cross compiler])
  49
  50 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  51 AC_ARG_ENABLE(version-specific-runtime-libs,
  52 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  53 [case "$enableval" in
  54  yes) version_specific_libs=yes ;;
  55  no)  version_specific_libs=no ;;
  56  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  57  esac],
  58 [version_specific_libs=no])
  59 AC_MSG_RESULT($version_specific_libs)
  60
  61 AC_ARG_ENABLE(objc-gc,
  62 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  63                           the GNU Objective-C runtime.],
  64 [case $enable_objc_gc in
  65   no)
  66     OBJC_GCFLAGS=''
  67     OBJC_BOEHM_GC=''
  68     OBJC_BOEHM_GC_INCLUDES=''
  69     ;;
  70   *)
  71     OBJC_GCFLAGS='-DOBJC_WITH_GC=1'
  72     OBJC_BOEHM_GC='libobjc_gc$(libsuffix).la'
  73     OBJC_BOEHM_GC_INCLUDES='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
  74     case "${host}" in
  75       alpha*-dec-osf*)
  76         # boehm-gc headers include <pthread.h>, which needs to be compiled
  77         # with -pthread on Tru64 UNIX.
  78         OBJC_GCFLAGS="${OBJC_GCFLAGS} -pthread"
  79         ;;
  80     esac
  81     ;;
  82 esac],
  83 [OBJC_GCFLAGS=''; OBJC_BOEHM_GC=''; OBJC_BOEHM_GC_INCLUDES=''])
  84 AC_SUBST(OBJC_GCFLAGS)
  85 AC_SUBST(OBJC_BOEHM_GC)
  86 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
  87
  88 # -----------
  89 # Directories
  90 # -----------
  91
  92 # Find the rest of the source tree framework.
  93 AM_ENABLE_MULTILIB(, ..)
  94
  95 AC_CANONICAL_SYSTEM
  96 ACX_NONCANONICAL_TARGET
  97
  98 # Export source directory.
  99 # These need to be absolute paths, yet at the same time need to
 100 # canonicalize only relative paths, because then amd will not unmount
 101 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 102 case $srcdir in
 103   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
 104   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 105 esac
 106 AC_SUBST(glibcpp_srcdir)
 107
 108 # Calculate toolexeclibdir
 109 # Also toolexecdir, though it's only used in toolexeclibdir
 110 case ${version_specific_libs} in
 111   yes)
 112     # Need the gcc compiler version to know where to install libraries
 113     # and header files if --enable-version-specific-runtime-libs option
 114     # is selected.
 115     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 116     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 117     ;;
 118   no)
 119     if test -n "$with_cross_host" &&
 120        test x"$with_cross_host" != x"no"; then
 121       # Install a library built with a cross compiler in tooldir, not libdir.
 122       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 123       toolexeclibdir='$(toolexecdir)/lib'
 124     else
 125       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 126       toolexeclibdir='$(libdir)'
 127     fi
 128     multi_os_directory=`$CC -print-multi-os-directory`
 129     case $multi_os_directory in
 130       .) ;; # Avoid trailing /.
 131       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 132     esac
 133     ;;
 134 esac
 135 AC_SUBST(toolexecdir)
 136 AC_SUBST(toolexeclibdir)
 137
 138 # Figure out if we want to name the include directory and the
 139 #  library name changes differently.
 140 includedirname=include
 141 libsuffix=
 142 case "${host}" in
 143   *-darwin*)
 144     # Darwin is the only target so far that needs a different include directory.
 145     includedirname=include-gnu-runtime
 146     libsuffix=-gnu
 147     ;;
 148 esac
 149 AC_SUBST(includedirname)
 150 AC_SUBST(libsuffix)
 151
 152 AC_CONFIG_HEADERS(config.h)
 153
 154 # --------
 155 # Programs
 156 # --------
 157
 158 GCC_NO_EXECUTABLES
 159
 160 # We must force CC to /not/ be a precious variable; otherwise
 161 # the wrong, non-multilib-adjusted value will be used in multilibs.
 162 # As a side effect, we have to subst CFLAGS ourselves.
 163 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 164 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 165 AC_PROG_CC
 166 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 167
 168 # extra LD Flags which are required for targets
 169 ACX_LT_HOST_FLAGS
 170 case "${host}" in
 171   *-darwin*)
 172     # Darwin needs -single_module when linking libobjc
 173     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 174     ;;
 175   *-cygwin*|*-mingw*)
 176     # Tell libtool to build DLLs on Windows
 177     extra_ldflags_libobjc='$(lt_host_flags)'
 178     ;;
 179 esac
 180 AC_SUBST(extra_ldflags_libobjc)
 181
 182 AC_SUBST(CFLAGS)
 183
 184 AC_CHECK_TOOL(AS, as)
 185 AC_CHECK_TOOL(AR, ar)
 186 AC_CHECK_TOOL(RANLIB, ranlib, :)
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 # Enable Win32 DLL on MS Windows - FIXME
 192 AC_LIBTOOL_WIN32_DLL
 193
 194 AC_PROG_LIBTOOL
 195
 196 AM_PROG_CC_C_O
 197
 198 AC_PROG_MAKE_SET
 199
 200 # -------
 201 # Headers
 202 # -------
 203
 204 # Sanity check for the cross-compilation case:
 205 AC_CHECK_HEADER(stdio.h,:,
 206   [AC_MSG_ERROR([Can't find stdio.h.
 207 You must have a usable C system for the target already installed, at least
 208 including headers and, preferably, the library, before you can configure
 209 the Objective C runtime system.  If necessary, install gcc now with
 210 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 211
 212 AC_HEADER_STDC
 213
 214 AC_CHECK_HEADERS(sched.h)
 215
 216 # -----------
 217 # Miscellanea
 218 # -----------
 219
 220 # Check if we have thread-local storage
 221 GCC_CHECK_TLS
 222
 223 AC_MSG_CHECKING([for exception model to use])
 224 AC_LANG_PUSH(C)
 225 AC_ARG_ENABLE(sjlj-exceptions,
 226   AS_HELP_STRING([--enable-sjlj-exceptions],
 227                  [force use of builtin_setjmp for exceptions]),
 228 [:],
 229 [dnl Botheration.  Now we've got to detect the exception model.
 230 dnl Link tests against libgcc.a are problematic since -- at least
 231 dnl as of this writing -- we've not been given proper -L bits for
 232 dnl single-tree newlib and libgloss.
 233 dnl
 234 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 235 dnl conftest files before we got a change to grep them first.
 236 cat > conftest.$ac_ext << EOF
 237 [#]line __oline__ "configure"
 238 @interface Frob
 239 @end
 240 @implementation Frob
 241 @end
 242 int proc();
 243 int foo()
 244 {
 245   @try {
 246    return proc();
 247   }
 248   @catch (Frob* ex) {
 249     return 0;
 250   }
 251 }
 252 EOF
 253 old_CFLAGS="$CFLAGS"
 254 dnl work around that we don't have Objective-C support in autoconf
 255 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 256 if AC_TRY_EVAL(ac_compile); then
 257   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 258     enable_sjlj_exceptions=yes
 259   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 260     enable_sjlj_exceptions=no
 261   fi
 262 fi
 263 CFLAGS="$old_CFLAGS"
 264 rm -f conftest*])
 265 if test x$enable_sjlj_exceptions = xyes; then
 266   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 267         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 268   ac_exception_model_name=sjlj
 269 elif test x$enable_sjlj_exceptions = xno; then
 270   ac_exception_model_name="call frame"
 271 else
 272   AC_MSG_ERROR([unable to detect exception model])
 273 fi
 274 AC_LANG_POP(C)
 275 AC_MSG_RESULT($ac_exception_model_name)
 276
 277 # ------
 278 # Output
 279 # ------
 280
 281 if test ${multilib} = yes; then
 282   multilib_arg="--enable-multilib"
 283 else
 284   multilib_arg=
 285 fi
 286
 287 AC_CONFIG_FILES([Makefile])
 288 AC_OUTPUT