libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(LD, ld)
 117 AC_CHECK_TOOL(AR, ar)
 118 AC_CHECK_TOOL(RANLIB, ranlib, :)
 119 AC_PROG_AWK
 120 AC_CHECK_PROGS([JAR], [jar fastjar], no)
 121 AC_PATH_PROG([ZIP], [zip], no)
 122 AC_PATH_PROG([UNZIP], [unzip], unzip)
 123 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 124 if test "$ZIP" = no; then
 125   if test "$JAR" = no; then
 126     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 127   fi
 128 else
 129   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 130   JAR=`pwd`/scripts/jar
 131 fi
 132
 133 AC_PROG_INSTALL
 134
 135 AM_MAINTAINER_MODE
 136
 137 AC_EXEEXT
 138
 139 # configure.host sets the following important variables
 140 #       libgcj_cflags    - host specific C compiler flags
 141 #       libgcj_cxxflags  - host specific C++ compiler flags
 142 #       libgcj_javaflags - host specific Java compiler flags
 143
 144 libgcj_cflags=
 145 libgcj_cxxflags=
 146 libgcj_javaflags=
 147
 148 . ${srcdir}/configure.host
 149
 150 LIBGCJ_CFLAGS="${libgcj_cflags}"
 151 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 152 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 153 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 154 AC_SUBST(LIBGCJ_CFLAGS)
 155 AC_SUBST(LIBGCJ_CXXFLAGS)
 156 AC_SUBST(LIBGCJ_JAVAFLAGS)
 157 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 158
 159 # Only use libltdl for non-newlib builds.
 160 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 161    AC_LTDL_SHLIBPATH
 162 fi
 163
 164 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 165
 166 # See if the user has requested runtime debugging.
 167 LIBGCJDEBUG="disable"
 168 AC_SUBST(LIBGCJDEBUG)
 169 AC_ARG_ENABLE(libgcj-debug,
 170   AS_HELP_STRING([--enable-libgcj-debug],
 171                  [enable runtime debugging code]),
 172   [if test "$enable_libgcj_debug" = yes; then
 173     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 174     LIBGCJDEBUG="enable"
 175   fi])
 176
 177 # Determine which AWT peer libraries to build
 178 AC_ARG_ENABLE(java-awt,
 179   AS_HELP_STRING([--enable-java-awt],
 180                  [list of AWT peer implementations to be built]))
 181
 182 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 183 use_xlib_awt=""
 184 use_gtk_awt=""
 185 use_qt_awt=""
 186 # The default toolkit to use is the first one specified.
 187 TOOLKIT=
 188 AC_SUBST(TOOLKIT)
 189
 190 for peer in $peerlibs ; do
 191   case $peer in
 192     xlib)
 193       if test "$no_x" = yes; then
 194         echo "*** xlib peers requested but no X library available" 1>&2
 195         exit 1
 196       else
 197         use_xlib_awt="yes"
 198         if test -z "$TOOLKIT"; then
 199            TOOLKIT=gnu.awt.xlib.XToolkit
 200         fi
 201       fi
 202       ;;
 203     gtk)
 204       if test "$no_x" = yes; then
 205          echo "*** gtk peers requested but no X library available" 1>&2
 206          exit 1
 207       else
 208          use_gtk_awt=yes
 209          if test -z "$TOOLKIT"; then
 210             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 211          fi
 212       fi
 213       ;;
 214     qt)
 215       if test "$no_x" = yes; then
 216          # Perhaps we should admit the possibility of embedded Qt.
 217          echo "*** Qt peers requested but no X library available" 1>&2
 218          exit 1
 219       else
 220          use_qt_awt=yes
 221          if test -z "$TOOLKIT"; then
 222             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 223          fi
 224       fi
 225       ;;
 226     no)
 227       use_xlib_awt=
 228       use_gtk_awt=
 229       use_qt_awt=
 230       break
 231       ;;
 232     *)
 233       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 234       exit 1
 235   esac
 236 done
 237
 238 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 239 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 240
 241 # Create standard.omit based on decisions we just made.
 242 cp $srcdir/standard.omit.in standard.omit
 243 if test "$use_xlib_awt" != yes; then
 244    echo gnu/awt/xlib >> standard.omit
 245    echo gnu/gcj/xlib >> standard.omit
 246 fi
 247 if test "$use_qt_awt" != yes; then
 248    echo gnu/java/awt/peer/qt >> standard.omit
 249 fi
 250
 251 if test -z "${with_multisubdir}"; then
 252    builddotdot=.
 253 else
 254    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 255 fi
 256
 257 NATIVE=yes
 258
 259 # Which gcj do we use?
 260 which_gcj=default
 261 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 262 if test -n "${with_cross_host}"; then
 263   # We are being configured with a cross compiler. We can't
 264   # use ac_exeext, because that is for the target platform.
 265   NATIVE=no
 266   cross_host_exeext=
 267   case "${with_cross_host}" in
 268      *mingw* | *cygwin*)
 269          cross_host_exeext=.exe
 270      ;;
 271   esac
 272   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 273      if test x"$build_noncanonical" = x"$with_cross_host"; then
 274         # Ordinary cross (host!=target and host=build)
 275         which_gcj=built
 276      else
 277         # Canadian cross (host!=target and host!=build)
 278         which_gcj=cross
 279      fi
 280   else
 281      which_gcj=cross
 282   fi
 283 else
 284   # We are being configured with a native or crossed-native compiler
 285   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 286      if test x"$build" = x"$host"; then
 287         # True native build (host=target and host=build)
 288         which_gcj=built
 289      else
 290         # Crossed-native build (host=target and host!=build)
 291         which_gcj=cross
 292      fi
 293   else
 294      which_gcj=path
 295   fi
 296 fi
 297 case "${which_gcj}" in
 298    built)
 299       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 300       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 301    ;;
 302    cross)
 303       if test "x${with_newlib}" = "xyes"; then
 304          # FIXME (comment): Why is this needed?
 305          GCC_UNWIND_INCLUDE=
 306          GCJ="${target_noncanonical}-gcj"
 307       else
 308          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 309       fi
 310       GCJH='$(target_noncanonical)-gcjh'
 311    ;;
 312    path)
 313       GCJ="gcj -B`${PWDCMD-pwd}`/"
 314       GCJH=gcjh
 315    ;;
 316 esac
 317
 318 AC_SUBST(GCJH)
 319
 320 # Create it, so that compile/link tests don't fail
 321 test -f libgcj.spec || touch libgcj.spec
 322
 323
 324
 325 # Set up to configure Classpath.
 326 # FIXME: no supported way to pass args in autoconf.
 327 ac_configure_args="$ac_configure_args --disable-load-library"
 328 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 329 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 330 dir1=`cd $srcdir && pwd`
 331 dir2=`pwd`
 332 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 333 ac_configure_args="$ac_configure_args --disable-core-jni"
 334 dnl FIXME?
 335 ac_configure_args="$ac_configure_args --disable-examples"
 336 ac_configure_args="$ac_configure_args --with-glibj=build"
 337 if test "$use_gtk_awt" != yes; then
 338   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 339 fi
 340 if test "$use_qt_awt" != yes; then
 341   ac_configure_args="$ac_configure_args --disable-qt-peer"
 342 else
 343   # We need this as qt is disabled by default in classpath.
 344   ac_configure_args="$ac_configure_args --enable-qt-peer"
 345 fi
 346 dnl --with-gcj=$GCJ
 347 dnl --with-javah=$GCJH
 348 dnl gjdoc?
 349 dnl gtk-cairo -- just export here...
 350 dnl --enable-regen-headers?
 351
 352 # Only use libltdl for non-newlib builds.
 353 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 354    AC_LIBLTDL_CONVENIENCE
 355    AC_LIBTOOL_DLOPEN
 356    DIRLTDL=libltdl
 357    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 358    # Sigh.  Libtool's macro doesn't do the right thing.
 359    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 360    # FIXME: this is a hack.
 361    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 362    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 363 fi
 364 AC_SUBST(INCLTDL)
 365 AC_SUBST(LIBLTDL)
 366 AC_SUBST(DIRLTDL)
 367 AC_PROG_LIBTOOL
 368 AM_PROG_GCJ
 369 AM_PROG_CC_C_O
 370
 371 AC_CONFIG_SUBDIRS(classpath libltdl)
 372
 373 # The -no-testsuite modules omit the test subdir.
 374 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 375
 376 # Should the runtime set system properties by examining the
 377 # environment variable GCJ_PROPERTIES?
 378 AC_ARG_ENABLE(getenv-properties,
 379   AS_HELP_STRING([--disable-getenv-properties],
 380                  [don't set system properties from GCJ_PROPERTIES]))
 381
 382 # Whether GCJ_PROPERTIES is used depends on the target.
 383 if test -z "$enable_getenv_properties"; then
 384    enable_getenv_properties=${enable_getenv_properties_default-yes}
 385 fi
 386 if test "$enable_getenv_properties" = no; then
 387    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 388      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 389 fi
 390
 391 # Whether we should use arguments to main()
 392 if test -z "$enable_main_args"; then
 393    enable_main_args=${enable_main_args_default-yes}
 394 fi
 395 if test "$enable_main_args" = no; then
 396    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 397 fi
 398
 399
 400 # Should we use hashtable-based synchronization?
 401 # Currently works only for Linux X86/ia64
 402 # Typically faster and more space-efficient
 403 AC_ARG_ENABLE(hash-synchronization,
 404   AS_HELP_STRING([--enable-hash-synchronization],
 405                  [use global hash table for monitor locks]))
 406
 407 if test -z "$enable_hash_synchronization"; then
 408    enable_hash_synchronization=$enable_hash_synchronization_default
 409 fi
 410
 411 AC_ARG_WITH(java-home,
 412   AS_HELP_STRING([--with-java-home=DIRECTORY],
 413                  [value of java.home system property]),
 414                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 415 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 416 AC_SUBST(JAVA_HOME)
 417
 418 # What is the native OS API for MinGW?
 419 AC_ARG_WITH(win32-nlsapi,
 420   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 421                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 422 [case "${withval}" in
 423   ansi) with_win32_nlsapi=ansi ;;
 424   unicows) with_win32_nlsapi=unicows ;;
 425   unicode) with_win32_nlsapi=unicode ;;
 426   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 427 esac],[with_win32_nlsapi=ansi])
 428
 429 case "${with_win32_nlsapi}" in
 430   unicows | unicode)
 431     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 432       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 433     ;;
 434 esac
 435
 436 # configure.host sets slow_pthread_self if the synchronization code should
 437 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 438 if test "${slow_pthread_self}" = "yes"; then
 439   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 440     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 441 fi
 442
 443 # Check for gc debugging.  This option is handled both here and in the GC.
 444 AC_ARG_ENABLE(gc-debug,
 445    AS_HELP_STRING([--enable-gc-debug],
 446                   [include full support for pointer backtracing etc.]),
 447 [ if test "$enable_gc_debug" = "yes"; then
 448     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 449               [Define if we want to use debug calls into the garbage collector.])
 450   fi])
 451
 452 # See if the user has the interpreter included.
 453 AC_ARG_ENABLE(interpreter,
 454   AS_HELP_STRING([--enable-interpreter],
 455                  [enable interpreter]),
 456   [if test "$enable_interpreter" = yes; then
 457     # This can also be set in configure.host.
 458     libgcj_interpreter=yes
 459   elif test "$enable_interpreter" = no; then
 460     libgcj_interpreter=no
 461   fi])
 462
 463 if test "$libgcj_interpreter" = yes; then
 464    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 465 fi
 466 INTERPRETER="$libgcj_interpreter"
 467 AC_SUBST(INTERPRETER)
 468
 469 AC_MSG_CHECKING([for exception model to use])
 470 AC_LANG_PUSH(C++)
 471 AC_ARG_ENABLE(sjlj-exceptions,
 472   AS_HELP_STRING([--enable-sjlj-exceptions],
 473                  [force use of builtin_setjmp for exceptions]),
 474 [:],
 475 [dnl Botheration.  Now we've got to detect the exception model.
 476 dnl Link tests against libgcc.a are problematic since -- at least
 477 dnl as of this writing -- we've not been given proper -L bits for
 478 dnl single-tree newlib and libgloss.
 479 dnl
 480 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 481 dnl conftest files before we got a change to grep them first.
 482 cat > conftest.$ac_ext << EOF
 483 [#]line __oline__ "configure"
 484 struct S { ~S(); };
 485 void bar();
 486 void foo()
 487 {
 488   S s;
 489   bar();
 490 }
 491 EOF
 492 old_CXXFLAGS="$CXXFLAGS"
 493 CXXFLAGS=-S
 494 if AC_TRY_EVAL(ac_compile); then
 495   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 496     enable_sjlj_exceptions=yes
 497   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 498     enable_sjlj_exceptions=no
 499   fi
 500 fi
 501 CXXFLAGS="$old_CXXFLAGS"
 502 rm -f conftest*])
 503 if test x$enable_sjlj_exceptions = xyes; then
 504   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 505         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 506   ac_exception_model_name=sjlj
 507 elif test x$enable_sjlj_exceptions = xno; then
 508   ac_exception_model_name="call frame"
 509 else
 510   AC_MSG_ERROR([unable to detect exception model])
 511 fi
 512 AC_LANG_POP(C++)
 513 AC_MSG_RESULT($ac_exception_model_name)
 514
 515 # If we are non using SJLJ exceptions, and this host does not have support
 516 # for unwinding from a signal handler, enable checked dereferences and divides.
 517 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 518   CHECKREFSPEC=-fcheck-references
 519   DIVIDESPEC=-fuse-divide-subroutine
 520   EXCEPTIONSPEC=
 521 fi
 522
 523 # See if the user wants to disable java.net.  This is the mildly
 524 # ugly way that we admit that target-side configuration sucks.
 525 AC_ARG_ENABLE(java-net,
 526   AS_HELP_STRING([--disable-java-net],
 527                  [disable java.net]))
 528
 529 # Whether java.net is built by default can depend on the target.
 530 if test -z "$enable_java_net"; then
 531    enable_java_net=${enable_java_net_default-yes}
 532 fi
 533 if test "$enable_java_net" = no; then
 534    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 535 fi
 536
 537 # See if the user wants to configure without libffi.  Some
 538 # architectures don't support it, and default values are set in
 539 # configure.host.
 540 AC_ARG_WITH(libffi,
 541   AS_HELP_STRING([--without-libffi],
 542                  [don't use libffi]),
 543   [:],
 544   [with_libffi=${with_libffi_default-yes}])
 545
 546 LIBFFI=
 547 LIBFFIINCS=
 548 if test "$with_libffi" != no; then
 549    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 550    LIBFFI=../libffi/libffi_convenience.la
 551    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 552 fi
 553 AC_SUBST(LIBFFI)
 554 AC_SUBST(LIBFFIINCS)
 555
 556 # See if the user wants to disable JVMPI support.
 557 AC_ARG_ENABLE(jvmpi,
 558   AS_HELP_STRING([--disable-jvmpi],
 559                  [disable JVMPI support]))
 560
 561 if test "$enable_jvmpi" != no; then
 562     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 563 fi
 564
 565 # If the target is an eCos system, use the appropriate eCos
 566 # I/O routines.
 567 # FIXME: this should not be a local option but a global target
 568 # system; at present there is no eCos target.
 569 TARGET_ECOS=${PROCESS-"no"}
 570 AC_ARG_WITH(ecos,
 571 [  --with-ecos             enable runtime eCos target support],
 572 TARGET_ECOS="$with_ecos"
 573 )
 574
 575 PLATFORM_INNER_NAT_HDRS=
 576 case "$TARGET_ECOS" in
 577    no) case "$host" in
 578       *mingw*)
 579             PLATFORM=Win32
 580             PLATFORMNET=Win32
 581             PLATFORMH=win32.h
 582         CHECK_FOR_BROKEN_MINGW_LD
 583       ;;
 584       *)
 585             PLATFORM=Posix
 586             PLATFORMNET=Posix
 587             PLATFORMH=posix.h
 588             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 589       ;;
 590       esac
 591       ;;
 592    *)
 593       PLATFORM=Ecos
 594       PLATFORMNET=NoNet
 595       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 596       PLATFORMH=posix.h
 597       ;;
 598 esac
 599 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 600 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 601
 602 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 603                                       [Define if you have int32_t and uint32_t.]))
 604 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 605                                         [Define if you have int32_t and uint32_t.]))
 606 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 607                                           [Define if you have u_int32_t]))
 608 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 609                                            [Define if you have u_int32_t]))
 610
 611 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 612 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 613
 614 case "$host" in
 615   *-darwin*) DARWIN_CRT=true ;;
 616   *) DARWIN_CRT=false ;;
 617 esac
 618 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 619
 620 # These may not be defined in a non-ANS conformant embedded system.
 621 # FIXME: Should these case a runtime exception in that case?
 622 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 623                                   [Define is you have 'mktime' in <time.h>]))
 624 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 625                                   [Define is you have 'localtime' in <time.h>]))
 626
 627 # Create the subdirectory for natFile.cc, or the attempt
 628 # to create the link will fail.
 629 test -d java || mkdir java
 630 test -d java/io || mkdir java/io
 631 test -d gnu || mkdir gnu
 632 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 633
 634 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 635 test -d java/lang || mkdir java/lang
 636 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 637 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 638
 639 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 640 test -d java/net || mkdir java/net
 641 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 642 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 643
 644 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 645 test -d gnu/java || mkdir gnu/java
 646 test -d gnu/java/net || mkdir gnu/java/net
 647 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 648 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 649
 650 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 651 test -d gnu/java/nio || mkdir gnu/java/nio
 652 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 653 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 654 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 655 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 656
 657 case "${host}" in
 658     *mingw*)
 659       SYSTEMSPEC="-lgdi32 -lws2_32"
 660       if test "${with_win32_nlsapi}" = "unicows"; then
 661         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 662       fi
 663     ;;
 664     *)
 665       SYSTEMSPEC=
 666     ;;
 667 esac
 668 AC_SUBST(SYSTEMSPEC)
 669
 670 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 671 AC_SUBST(LIBGCJTESTSPEC)
 672
 673 AC_ARG_WITH(system-zlib,
 674   AS_HELP_STRING([--with-system-zlib],
 675                  [use installed libz]))
 676 ZLIBSPEC=
 677 AC_SUBST(ZLIBSPEC)
 678 ZLIBTESTSPEC=
 679 AC_SUBST(ZLIBTESTSPEC)
 680
 681 AC_PATH_XTRA
 682
 683 # determine whether to enable the cairo GTK Graphics2D backend
 684 AC_ARG_ENABLE(gtk-cairo,
 685   AS_HELP_STRING([--enable-gtk-cairo],
 686                  [build the cairo Graphics2D implementation on GTK]))
 687 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 688 if test "x${enable_gtk_cairo}" = xyes
 689 then
 690         PKG_CHECK_MODULES(CAIRO, cairo)
 691         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 692 fi
 693 AC_SUBST(CAIRO_LIBS)
 694 AC_SUBST(CAIRO_CFLAGS)
 695 AC_SUBST(PANGOFT2_LIBS)
 696 AC_SUBST(PANGOFT2_CFLAGS)
 697
 698 # FIXME: this should be _libs on some hosts.
 699 libsubdir=.libs
 700
 701 # extra LD Flags which are required for targets
 702 case "${host}" in
 703 *-*-darwin[[0-7]].*)
 704     # For now we have to disable it on darwin[8-9] because it slows down
 705     # the linking phase. A possible bug in ld?
 706     # on Darwin -single_module speeds up loading of the dynamic libraries.
 707     extra_ldflags_libjava=-Wl,-single_module
 708     ;;
 709 esac
 710 AC_SUBST(extra_ldflags_libjava)
 711
 712 # Allow the GC to be disabled.  Can be useful when debugging.
 713 AC_MSG_CHECKING([for garbage collector to use])
 714 AC_ARG_ENABLE(java-gc,
 715   AS_HELP_STRING([--enable-java-gc=TYPE],
 716                  [choose garbage collector (default is boehm)]),
 717   [GC=$enableval],
 718   [GC=boehm])
 719 GCLIBS=
 720 GCINCS=
 721 GCDEPS=
 722 GCSPEC=
 723 JC1GCSPEC=
 724 GCTESTSPEC=
 725 case "$GC" in
 726  boehm)
 727     AC_MSG_RESULT(boehm)
 728     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 729     JC1GCSPEC='-fuse-boehm-gc'
 730     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 731     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 732     GCOBJS=boehm.lo
 733     GCHDR=boehm-gc.h
 734     # The POSIX thread support needs to know this.
 735     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 736     ;;
 737  no)
 738     AC_MSG_RESULT(none)
 739     GCHDR=no-gc.h
 740     ;;
 741  *)
 742     AC_MSG_ERROR([unrecognized collector "$GC"])
 743     ;;
 744 esac
 745 AC_SUBST(GCLIBS)
 746 AC_SUBST(GCINCS)
 747 AC_SUBST(GCDEPS)
 748 AC_SUBST(GCSPEC)
 749 AC_SUBST(JC1GCSPEC)
 750 AC_SUBST(GCTESTSPEC)
 751 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 752 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 753 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 754
 755
 756 AC_MSG_CHECKING([for thread model used by GCC])
 757 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 758 AC_MSG_RESULT([$THREADS])
 759
 760 case "$THREADS" in
 761  no | none | single)
 762     THREADS=none
 763     ;;
 764  posix | posix95 | pthreads)
 765     THREADS=posix
 766     case "$host" in
 767      *-*-linux*)
 768         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 769         ;;
 770     esac
 771     ;;
 772  win32)
 773     ;;
 774  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 775     AC_MSG_ERROR(thread package $THREADS not yet supported)
 776     ;;
 777  *)
 778     AC_MSG_ERROR($THREADS is an unknown thread package)
 779     ;;
 780 esac
 781
 782 THREADCXXFLAGS=
 783 THREADLDFLAGS=
 784 THREADLIBS=
 785 THREADINCS=
 786 THREADDEPS=
 787 THREADH=
 788 THREADSPEC=
 789 case "$THREADS" in
 790  posix)
 791     case "$host" in
 792      *-*-cygwin*)
 793         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 794         ;;
 795      *-*-freebsd[[1234]]*)
 796         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 797         # merely adds pthread_* functions) but it does have a -pthread switch
 798         # which is required at link-time to select -lc_r *instead* of -lc.
 799         THREADLDFLAGS=-pthread
 800         # Don't set THREADSPEC here as might be expected since -pthread is
 801         # not processed when found within a spec file, it must come from
 802         # the command line.  For now, the user must provide the -pthread
 803         # switch to link code compiled with gcj.  In future, consider adding
 804         # support for weak references to pthread_* functions ala gthr.h API.
 805         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 806         ;;
 807      *-*-freebsd*)
 808         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 809         # systems which support threads and -lpthread.
 810         THREADLDFLAGS=-pthread
 811         THREADSPEC=-lpthread
 812         ;;
 813      alpha*-dec-osf* | hppa*-hp-hpux*)
 814         THREADCXXFLAGS=-pthread
 815         # boehm-gc needs some functions from librt, so link that too.
 816         THREADLIBS='-lpthread -lrt'
 817         THREADSPEC='-lpthread -lrt'
 818         ;;
 819      *)
 820         THREADLIBS=-lpthread
 821         THREADSPEC=-lpthread
 822         ;;
 823     esac
 824     THREADH=posix-threads.h
 825     # MIT pthreads doesn't seem to have the mutexattr functions.
 826     # But for now we don't check for it.  We just assume you aren't
 827     # using MIT pthreads.
 828     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 829
 830     # If we're using the Boehm GC, then we happen to know that it
 831     # defines _REENTRANT, so we don't bother.  Eww.
 832     if test "$GC" != boehm; then
 833        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 834     fi
 835     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 836     ;;
 837
 838  win32)
 839     THREADH=win32-threads.h
 840     ;;
 841
 842  none)
 843     THREADH=no-threads.h
 844     ;;
 845 esac
 846 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 847 AC_SUBST(THREADLIBS)
 848 AC_SUBST(THREADINCS)
 849 AC_SUBST(THREADDEPS)
 850 AC_SUBST(THREADSPEC)
 851 AC_SUBST(THREADLDFLAGS)
 852 AC_SUBST(THREADCXXFLAGS)
 853 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 854 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 855 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 856
 857 if test -d sysdep; then true; else mkdir sysdep; fi
 858 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 859 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 860 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 861
 862 HASH_SYNC_SPEC=
 863 # Hash synchronization is only useful with posix threads right now.
 864 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 865    HASH_SYNC_SPEC=-fhash-synchronization
 866    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 867 fi
 868 AC_SUBST(HASH_SYNC_SPEC)
 869
 870 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 871
 872 # We're in the tree with gcc, and need to include some of its headers.
 873 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 874
 875 if test "x${with_newlib}" = "xyes"; then
 876    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 877    # may not work correctly, because the compiler may not be able to
 878    # link executables.
 879
 880    # We assume newlib.  This lets us hard-code the functions we know
 881    # we'll have.
 882    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 883    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 884    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 885    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 886    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 887    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 888    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 889    # This is only for POSIX threads.
 890    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 891    # We also assume we are using gcc, which provides alloca.
 892    AC_DEFINE(HAVE_ALLOCA)
 893
 894    # Assume we do not have getuid and friends.
 895    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 896    PLATFORMNET=NoNet
 897 else
 898    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 899                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 900                    access stat mkdir rename rmdir unlink realpath utime chmod \
 901                    nl_langinfo setlocale \
 902                    inet_pton uname inet_ntoa \
 903                    fork execvp pipe sigaction ftruncate mmap])
 904    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 905    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 906    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 907    AC_CHECK_LIB(dl, dladdr, [
 908        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 909        AC_CHECK_LIB(dld, dladdr, [
 910        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 911
 912    if test x"$build" = x"$host"; then
 913      AC_CHECK_FILES(/proc/self/exe, [
 914        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 915    else
 916      case $host in
 917      *-linux*)
 918        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 919        ;;
 920      esac
 921    fi
 922
 923    AM_ICONV
 924    AM_LC_MESSAGES
 925    AC_STRUCT_TIMEZONE
 926
 927    AC_CHECK_FUNCS(gethostbyname_r, [
 928      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 929        [Define if you have the 'gethostbyname_r' function.])
 930      # There are two different kinds of gethostbyname_r.
 931      # We look for the one that returns `int'.
 932      # Hopefully this check is robust enough.
 933      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 934        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 935
 936      case " $GCINCS " in
 937      *" -D_REENTRANT "*) ;;
 938      *)
 939         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 940         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 941         [libjava_cv_gethostbyname_r_needs_reentrant],
 942         [ AC_LANG_PUSH(C++)
 943           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 944             [[gethostbyname_r("", 0, 0);]])],
 945             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 946                 CPPFLAGS_SAVE="$CPPFLAGS"
 947                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 948                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 949                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 950                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 951                 CPPFLAGS="$CPPFLAGS_SAVE"
 952           ])
 953           AC_LANG_POP(C++)
 954         ])
 955         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 956           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 957         fi
 958      ;;
 959      esac
 960
 961      AC_CACHE_CHECK([for struct hostent_data],
 962         [libjava_cv_struct_hostent_data], [dnl
 963         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 964 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 965 # define _REENTRANT 1
 966 #endif
 967 #include <netdb.h>]], [[struct hostent_data data;]])],
 968           [libjava_cv_struct_hostent_data=yes],
 969           [libjava_cv_struct_hostent_data=no])])
 970      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 971        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 972          [Define if struct hostent_data is defined in netdb.h])
 973      fi
 974    ])
 975
 976    # FIXME: libjava source code expects to find a prototype for
 977    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 978    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 979    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 980    # linkage check is enough, yet C++ code requires proper prototypes.)
 981    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 982    AC_CHECK_FUNCS(gethostbyaddr_r, [
 983      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 984        [Define if you have the 'gethostbyaddr_r' function.])
 985      # There are two different kinds of gethostbyaddr_r.
 986      # We look for the one that returns `int'.
 987      # Hopefully this check is robust enough.
 988      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 989        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 990          [Define if gethostbyaddr_r returns 'int'.])])])])
 991
 992    AC_CHECK_FUNCS(gethostname, [
 993      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 994        [Define if you have the 'gethostname' function.])
 995      AC_EGREP_HEADER(gethostname, unistd.h, [
 996        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 997          [Define if gethostname is declared in <unistd.h>.])])])
 998
 999    AC_CHECK_FUNCS(usleep, [
1000      AC_EGREP_HEADER(usleep, unistd.h, [
1001        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1002           [Define if usleep is declared in <unistd.h>.])])])
1003
1004    # Look for these functions in the thread library, but only bother
1005    # if using POSIX threads.
1006    if test "$THREADS" = posix; then
1007       save_LIBS="$LIBS"
1008       LIBS="$LIBS $THREADLIBS"
1009       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1010       # E.g., Solaris.
1011       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1012
1013       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1014       # Solaris 7 the name librt is preferred.
1015       AC_CHECK_FUNCS(sched_yield, , [
1016         AC_CHECK_LIB(rt, sched_yield, [
1017           AC_DEFINE(HAVE_SCHED_YIELD)
1018           THREADLIBS="$THREADLIBS -lrt"
1019           THREADSPEC="$THREADSPEC -lrt"], [
1020           AC_CHECK_LIB(posix4, sched_yield, [
1021             AC_DEFINE(HAVE_SCHED_YIELD)
1022             THREADLIBS="$THREADLIBS -lposix4"
1023             THREADSPEC="$THREADSPEC -lposix4"])])])
1024
1025       AC_CHECK_LIB(rt, clock_gettime, [
1026          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1027          case "$THREADSPEC" in
1028            *-lrt*) ;;
1029            *)
1030              THREADSPEC="$THREADSPEC -lrt"
1031              THREADLIBS="$THREADLIBS -lrt"
1032              ;;
1033          esac])
1034
1035       LIBS="$save_LIBS"
1036
1037       # We can save a little space at runtime if the mutex has m_count
1038       # or __m_count.  This is a nice hack for Linux.
1039       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1040           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1041         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1042              [Define if pthread_mutex_t has m_count member.]), [
1043         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1044             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1045           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1046             [Define if pthread_mutex_t has __m_count member.]))])
1047    fi
1048
1049    # We require a way to get the time.
1050    time_found=no
1051    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1052    if test "$time_found" = no; then
1053       AC_MSG_ERROR([no function found to get the time])
1054    fi
1055
1056    AC_CHECK_FUNCS(memmove)
1057
1058    # We require memcpy.
1059    memcpy_found=no
1060    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1061    if test "$memcpy_found" = no; then
1062       AC_MSG_ERROR([memcpy is required])
1063    fi
1064    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1065    AC_CHECK_LIB(dl, dlopen, [
1066        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1067        AC_CHECK_LIB(dld, dlopen, [
1068        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1069
1070    # Some library-finding code we stole from Tcl.
1071    #--------------------------------------------------------------------
1072    #    Check for the existence of the -lsocket and -lnsl libraries.
1073    #    The order here is important, so that they end up in the right
1074    #    order in the command line generated by make.  Here are some
1075    #    special considerations:
1076    #    1. Use "connect" and "accept" to check for -lsocket, and
1077    #       "gethostbyname" to check for -lnsl.
1078    #    2. Use each function name only once:  can't redo a check because
1079    #       autoconf caches the results of the last check and won't redo it.
1080    #    3. Use -lnsl and -lsocket only if they supply procedures that
1081    #       aren't already present in the normal libraries.  This is because
1082    #       IRIX 5.2 has libraries, but they aren't needed and they're
1083    #       bogus:  they goof up name resolution if used.
1084    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1085    #       To get around this problem, check for both libraries together
1086    #       if -lsocket doesn't work by itself.
1087    #--------------------------------------------------------------------
1088
1089    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1090     [gcj_cv_lib_sockets=
1091      gcj_checkBoth=0
1092      unset ac_cv_func_connect
1093      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1094      if test "$gcj_checkSocket" = 1; then
1095          unset ac_cv_func_connect
1096          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1097                       gcj_checkBoth=1)
1098      fi
1099      if test "$gcj_checkBoth" = 1; then
1100          gcj_oldLibs=$LIBS
1101          LIBS="$LIBS -lsocket -lnsl"
1102          unset ac_cv_func_accept
1103          AC_CHECK_FUNC(accept,
1104                        [gcj_checkNsl=0
1105                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1106          unset ac_cv_func_accept
1107          LIBS=$gcj_oldLibs
1108      fi
1109      unset ac_cv_func_gethostbyname
1110      gcj_oldLibs=$LIBS
1111      LIBS="$LIBS $gcj_cv_lib_sockets"
1112      AC_CHECK_FUNC(gethostbyname, ,
1113                    [AC_CHECK_LIB(nsl, main,
1114                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1115      unset ac_cv_func_gethostbyname
1116      LIBS=$gcj_oldLIBS
1117    ])
1118    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1119
1120    if test "$with_system_zlib" = yes; then
1121       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1122    fi
1123
1124    # Test for Gtk stuff, if asked for.
1125    if test "$use_gtk_awt" = yes; then
1126       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1127       AC_SUBST(GTK_CFLAGS)
1128       AC_SUBST(GTK_LIBS)
1129
1130       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1131       AC_SUBST(GLIB_CFLAGS)
1132       AC_SUBST(GLIB_LIBS)
1133
1134       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1135       AC_SUBST(LIBART_CFLAGS)
1136       AC_SUBST(LIBART_LIBS)
1137
1138       # We require the XTest Extension to support java.awt.Robot.
1139       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1140                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1141                    [${X_LIBS}])
1142    fi
1143
1144    # On Solaris, and maybe other architectures, the Boehm collector
1145    # requires -ldl.
1146    if test "$GC" = boehm; then
1147       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1148    fi
1149 fi
1150
1151 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1152 case $build in
1153     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1154     *)         CLASSPATH_SEPARATOR=':' ;;
1155 esac
1156 AC_SUBST(CLASSPATH_SEPARATOR)
1157
1158 # We must search the source tree for java.lang, since we still don't
1159 # have libgcj.jar nor java/lang/*.class
1160 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1161 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1162
1163 # Since some classes depend on this one, we need its source available
1164 # before we can do any GCJ compilation test :-(
1165 if test ! -f gnu/classpath/Configuration.java; then
1166   test -d gnu || mkdir gnu
1167   test -d gnu/classpath || mkdir gnu/classpath
1168   # Note that it is not crucial that all the values here be correct.
1169   sed -e "s,@prefix@,$prefix," \
1170       -e "s,@VERSION@,$VERSION," \
1171       -e "s,@LIBDEBUG@,false," \
1172       -e "s,@INIT_LOAD_LIBRARY@,false," \
1173       -e "s,@@,$LIBGCJDEBUG," \
1174       -e "s,@default_toolkit@,$TOOLKIT," \
1175       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1176       -e "s,@GTK_CAIRO_ENABLED@,false," \
1177         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1178         > gnu/classpath/Configuration.java
1179   # We do not want to redirect the output of the grep below to /dev/null,
1180   # but we add /dev/null to the input list so that grep will print the
1181   # filename of Configuration.java in case it finds any matches.
1182   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1183     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1184   fi
1185 fi
1186
1187 LT_AC_PROG_GCJ
1188
1189 # Now remove it.
1190 rm -f gnu/classpath/Configuration.java
1191
1192 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1193
1194 AC_CHECK_SIZEOF(void *)
1195
1196 AC_C_BIGENDIAN
1197
1198 ZLIBS=
1199 SYS_ZLIBS=
1200 ZINCS=
1201
1202 if test -z "$ZLIBSPEC"; then
1203    # Use zlib from the GCC tree.
1204    ZINCS='-I$(top_srcdir)/../zlib'
1205    ZLIBS=../zlib/libzgcj_convenience.la
1206 else
1207    # System's zlib.
1208    SYS_ZLIBS="$ZLIBSPEC"
1209 fi
1210 AC_SUBST(ZLIBS)
1211 AC_SUBST(SYS_ZLIBS)
1212 AC_SUBST(ZINCS)
1213 AC_SUBST(DIVIDESPEC)
1214 AC_SUBST(CHECKREFSPEC)
1215 AC_SUBST(EXCEPTIONSPEC)
1216 AC_SUBST(BACKTRACESPEC)
1217 AC_SUBST(IEEESPEC)
1218
1219 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1220 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1221 AC_SUBST(GCC_UNWIND_INCLUDE)
1222
1223 # Process the option "--enable-version-specific-runtime-libs"
1224 # Calculate toolexeclibdir
1225 case ${version_specific_libs} in
1226   yes)
1227     # Need the gcc compiler version to know where to install libraries
1228     # and header files if --enable-version-specific-runtime-libs option
1229     # is selected.
1230     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1231     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1232     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1233     toolexeclibdir=$toolexecmainlibdir
1234     ;;
1235   no)
1236     if test -n "$with_cross_host" &&
1237        test x"$with_cross_host" != x"no"; then
1238       # Install a library built with a cross compiler in tooldir, not libdir.
1239       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1240       toolexecmainlibdir='$(toolexecdir)/lib'
1241     else
1242       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1243       toolexecmainlibdir='$(libdir)'
1244     fi
1245     multi_os_directory=`$CC -print-multi-os-directory`
1246     case $multi_os_directory in
1247       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1248       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1249     esac
1250     ;;
1251 esac
1252 AC_SUBST(toolexecdir)
1253 AC_SUBST(toolexecmainlibdir)
1254 AC_SUBST(toolexeclibdir)
1255
1256 # Determine where the standard .db file is found.
1257 multi_os_directory=`$CC -print-multi-os-directory`
1258 case $multi_os_directory in
1259   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1260   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1261 esac
1262 AC_SUBST(dbexecdir)
1263
1264 # Determine gcj version number.
1265 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1266 GCJVERSION=$gcjversion
1267 AC_SUBST(GCJVERSION)
1268 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1269
1270 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1271 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1272
1273 TL_AC_GXX_INCLUDE_DIR
1274
1275 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1276 # On that system, sys/ioctl.h will not include sys/filio.h unless
1277 # BSD_COMP is defined; just including sys/filio.h is simpler.
1278 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1279 # for now.  If you change this, you also must update natFile.cc.
1280 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1281                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1282                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1283                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1284                   dirent.h sys/rw_lock.h])
1285 AC_CHECK_HEADERS(inttypes.h, [
1286     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1287     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1288 ])
1289 AC_HEADER_SYS_WAIT
1290
1291 AC_CHECK_TYPE([ssize_t], [int])
1292
1293 AC_MSG_CHECKING([for in_addr_t])
1294 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1295 #if STDC_HEADERS
1296 #include <stdlib.h>
1297 #include <stddef.h>
1298 #endif
1299 #if HAVE_NETINET_IN_H
1300 #include <netinet/in.h>
1301 #endif]], [[in_addr_t foo;]])],
1302   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1303      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1304    AC_MSG_RESULT(yes)],
1305   [AC_MSG_RESULT(no)])
1306
1307 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1308 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1309   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1310      [Define if struct ip_mreq is defined in netinet/in.h.])
1311    AC_MSG_RESULT(yes)],
1312   [AC_MSG_RESULT(no)])
1313
1314 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1315 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1316   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1317      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1318    AC_MSG_RESULT(yes)],
1319   [AC_MSG_RESULT(no)])
1320
1321 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1323   [AC_DEFINE(HAVE_INET6, 1,
1324      [Define if inet6 structures are defined in netinet/in.h.])
1325    AC_MSG_RESULT(yes)],
1326   [AC_MSG_RESULT(no)])
1327
1328 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1329 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1330 #include <sys/types.h>
1331 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1332   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1333    AC_MSG_RESULT(yes)],
1334   [AC_MSG_RESULT(no)])
1335
1336 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1337 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1338   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1339    AC_MSG_RESULT(yes)],
1340   [AC_MSG_RESULT(no)
1341    AC_MSG_CHECKING([for global timezone variable])
1342    dnl FIXME: we don't want a link check here because that won't work
1343    dnl when cross-compiling.  So instead we make an assumption that
1344    dnl the header file will mention timezone if it exists.
1345    dnl Don't find the win32 function timezone
1346    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1347      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1348       AC_MSG_RESULT(yes)],
1349      [AC_MSG_RESULT(no)
1350        AC_MSG_CHECKING([for global _timezone variable])
1351        dnl FIXME: As above, don't want link check
1352        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1353          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1354             [Define if your platform has the global _timezone variable.])
1355           AC_MSG_RESULT(yes)],
1356           [AC_MSG_RESULT(no)])])])
1357
1358 AC_FUNC_ALLOCA
1359
1360 AC_CHECK_PROGS(PERL, perl, false)
1361
1362 SYSDEP_SOURCES=
1363 SIGNAL_HANDLER_AUX=
1364
1365 case "${host}" in
1366  i?86-*-linux*)
1367     SIGNAL_HANDLER=include/i386-signal.h
1368     ;;
1369  sparc*-sun-solaris*)
1370     SIGNAL_HANDLER=include/sparc-signal.h
1371     ;;
1372 # ia64-*)
1373 #    SYSDEP_SOURCES=sysdep/ia64.c
1374 #    test -d sysdep || mkdir sysdep
1375 #    ;;
1376  hppa*-*-linux*)
1377     SIGNAL_HANDLER=include/pa-signal.h
1378     ;;
1379  hppa*-hp-hpux*)
1380     SIGNAL_HANDLER=include/hppa-signal.h
1381     ;;
1382  ia64-*-linux*)
1383     SIGNAL_HANDLER=include/dwarf2-signal.h
1384     ;;
1385  powerpc*-*-linux*)
1386     SIGNAL_HANDLER=include/powerpc-signal.h
1387     ;;
1388  alpha*-*-linux*)
1389     SIGNAL_HANDLER=include/dwarf2-signal.h
1390     ;;
1391  s390*-*-linux*)
1392     SIGNAL_HANDLER=include/s390-signal.h
1393     ;;
1394  x86_64*-*-linux*)
1395     SIGNAL_HANDLER=include/x86_64-signal.h
1396     SIGNAL_HANDLER_AUX=include/i386-signal.h
1397     ;;
1398  sparc*-*-linux*)
1399     SIGNAL_HANDLER=include/dwarf2-signal.h
1400     ;;
1401  sh*-*-linux*)
1402     SIGNAL_HANDLER=include/sh-signal.h
1403     ;;
1404  *mingw*)
1405     SIGNAL_HANDLER=include/win32-signal.h
1406     ;;
1407  mips*-*-linux*)
1408     SIGNAL_HANDLER=include/mips-signal.h
1409     ;;
1410  *-*-darwin*)
1411     SIGNAL_HANDLER=include/darwin-signal.h
1412     ;;
1413  *)
1414     SIGNAL_HANDLER=include/default-signal.h
1415     ;;
1416 esac
1417
1418 # If we're using sjlj exceptions, forget what we just learned.
1419 if test "$enable_sjlj_exceptions" = yes; then
1420    SIGNAL_HANDLER=include/default-signal.h
1421    SIGNAL_HANDLER_AUX=
1422 fi
1423
1424 AC_SUBST(SYSDEP_SOURCES)
1425
1426 if test -z "$SIGNAL_HANDLER_AUX"; then
1427   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1428 fi
1429
1430 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1431                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1432
1433 if test "${multilib}" = "yes"; then
1434   multilib_arg="--enable-multilib"
1435 else
1436   multilib_arg=
1437 fi
1438
1439 # See if we support thread-local storage.
1440 GCC_CHECK_TLS
1441
1442 # Check if linker supports static linking on a per library basis
1443 LD_START_STATIC_SPEC=
1444 LD_FINISH_STATIC_SPEC=
1445 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1446   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1447     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1448     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1449   fi
1450 fi
1451 AC_SUBST(LD_START_STATIC_SPEC)
1452 AC_SUBST(LD_FINISH_STATIC_SPEC)
1453
1454 here=`${PWDCMD-pwd}`
1455 AC_SUBST(here)
1456
1457 # We get this from the environment.
1458 AC_SUBST(GCJFLAGS)
1459
1460 AC_CONFIG_FILES([
1461 Makefile
1462 libgcj.pc
1463 libgcj.spec
1464 libgcj-test.spec
1465 gcj/Makefile
1466 include/Makefile
1467 testsuite/Makefile
1468 ])
1469
1470 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1471
1472 AC_CONFIG_COMMANDS([default],
1473 [# Only add multilib support code if we just rebuilt top-level Makefile.
1474 case " $CONFIG_FILES " in
1475  *" Makefile "*)
1476    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1477    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1478    ;;
1479 esac
1480 for ac_multi_file in $CONFIG_FILES; do
1481   case $ac_multi_file in
1482   */Makefile)
1483     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1484   esac
1485 done
1486 ],
1487 srcdir=${srcdir}
1488 host=${host}
1489 target=${target}
1490 with_multisubdir=${with_multisubdir}
1491 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1492 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1493 libgcj_basedir=${libgcj_basedir}
1494 CC="${CC}"
1495 CXX="${CXX}"
1496 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1497 )
1498
1499 AC_OUTPUT