gcc/testsuite/gcc.misc-tests/options.exp

   1 # Copyright (C) 2005-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # Run the LANGUAGE compiler with GCC_OPTIONS and inspect the compiler,
  18 # assembler and linker output (from gcc -v) to make sure that they
  19 # match the patterns COMPILER_PATTERN, AS_PATTERN and LD_PATTERN,
  20 # respectively.
  21
  22 load_lib gcc-defs.exp
  23
  24 # disable for non-profile targets explitly, rather than
  25 # rely on check-effective target.  We're explicitly trying to check
  26 # profiling works, and if it doesn't check-effective-target will
  27 # simply skip the tests, rather than have this test shout at us.
  28 if [ istarget "nvptx-*-*" ] { return 0 }
  29
  30 # These tests don't run runtest_file_p consistently if it
  31 # doesn't return the same values, so disable parallelization
  32 # of this *.exp file.  The first parallel runtest to reach
  33 # this will run all the tests serially.
  34 if ![gcc_parallel_test_run_p options] {
  35     return
  36 }
  37 gcc_parallel_test_enable 0
  38
  39 proc check_for_all_options {language gcc_options compiler_pattern as_pattern ld_pattern} {
  40     set filename test-[pid]
  41     set fd [open $filename.c w]
  42     puts $fd "int main (void) \{ return 0; \}"
  43     close $fd
  44     remote_download host $filename.c
  45
  46     set test "compiler driver $gcc_options option(s)"
  47     set gcc_options "\{additional_flags=$gcc_options -v\}"
  48
  49     switch "$language" {
  50         "c" { set compiler cc1 }
  51         default { error "unknown language" }
  52     }
  53     set gcc_output [gcc_target_compile $filename.c $filename.x executable $gcc_options]
  54     remote_file build delete $filename.c $filename.x $filename.gcno
  55     set dumpfiles [glob -nocomplain $filename.c.*]
  56     foreach dumpfile $dumpfiles {
  57         remote_file build delete $dumpfile
  58     }
  59
  60     if {![regexp -- "/${compiler}(\\.exe)? \[^\r\n\]*-quiet.*$compiler_pattern" $gcc_output]} {
  61         fail "$test (compiler options)"
  62         return
  63     }
  64     if {![regexp -- " *as(\\.exe)? .*$as_pattern" $gcc_output]} {
  65         fail "$test (assembler options)"
  66         return
  67     }
  68     # Match /collect2, /ld, or *-ld.
  69     if {![regexp -- "(/collect2|\[-/\]ld)(\\.exe)? .*$ld_pattern" $gcc_output]} {
  70         fail "$test (linker options)"
  71         return
  72     }
  73     pass $test
  74 }
  75
  76 check_for_all_options c {--coverage} {-fprofile-arcs -ftest-coverage} {} {-lgcov}
  77
  78 proc get_dump_flags {} {
  79     set res [list]
  80
  81     global srcdir
  82     set file "$srcdir/../dumpfile.cc"
  83
  84     set a [open $file]
  85     set lines [split [read $a] "\n"]
  86     close $a
  87
  88     set domatch 0
  89     foreach line $lines {
  90         if { [regexp "dump_options.* =" $line] } {
  91             set domatch 1
  92         } elseif { [regexp "^\};" $line] } {
  93             set domatch 0
  94         }
  95         if { $domatch } {
  96             if { [regexp "\"(.*)\"" $line match submatch] } {
  97                 lappend res $submatch
  98             }
  99         }
 100     }
 101
 102     return $res
 103 }
 104
 105 foreach flag [get_dump_flags] {
 106     check_for_all_options c -fdump-tree-all-$flag {} {} {}
 107     check_for_all_options c -fdump-ipa-all-$flag {} {} {}
 108     check_for_all_options c -fdump-rtl-all-$flag {} {} {}
 109     check_for_all_options c -fdump-lang-all-$flag {} {} {}
 110 }
 111
 112 gcc_parallel_test_enable 1