gcc/ada/sem_type.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ T Y P E                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This unit contains the routines used to handle type determination,
  27 --  including the routine used to support overload resolution.
  28
  29 with Types; use Types;
  30
  31 package Sem_Type is
  32
  33    ---------------------------------------------
  34    -- Data Structures for Overload Resolution --
  35    ---------------------------------------------
  36
  37    --  To determine the unique meaning of an identifier, overload resolution
  38    --  may have to be performed if the visibility rules alone identify more
  39    --  than one possible entity as the denotation of a given identifier. When
  40    --  the visibility rules find such a potential ambiguity, the set of
  41    --  possible interpretations must be attached to the identifier, and
  42    --  overload resolution must be performed over the innermost enclosing
  43    --  complete context. At the end of the resolution, either a single
  44    --  interpretation is found for all identifiers in the context, or else a
  45    --  type error (invalid type or ambiguous reference) must be signalled.
  46
  47    --  The set of interpretations of a given name is stored in a data structure
  48    --  that is separate from the syntax tree, because it corresponds to
  49    --  transient information. The interpretations themselves are stored in
  50    --  table All_Interp. A mapping from tree nodes to sets of interpretations
  51    --  called Interp_Map, is maintained by the overload resolution routines.
  52    --  Both these structures are initialized at the beginning of every complete
  53    --  context.
  54
  55    --  Corresponding to the set of interpretations for a given overloadable
  56    --  identifier, there is a set of possible types corresponding to the types
  57    --  that the overloaded call may return. We keep a 1-to-1 correspondence
  58    --  between interpretations and types: for user-defined subprograms the type
  59    --  is the declared return type. For operators, the type is determined by
  60    --  the type of the arguments. If the arguments themselves are overloaded,
  61    --  we enter the operator name in the names table for each possible result
  62    --  type. In most cases, arguments are not overloaded and only one
  63    --  interpretation is present anyway.
  64
  65    type Interp is record
  66       Nam         : Entity_Id;
  67       Typ         : Entity_Id;
  68       Abstract_Op : Entity_Id := Empty;
  69    end record;
  70
  71    --  Entity Abstract_Op is set to the abstract operation which potentially
  72    --  disables the interpretation in Ada 2005 mode.
  73
  74    No_Interp : constant Interp := (Empty, Empty, Empty);
  75
  76    type Interp_Index is new Int;
  77
  78    ---------------------
  79    -- Error Reporting --
  80    ---------------------
  81
  82    --  A common error is the use of an operator in infix notation on arguments
  83    --  of a type that is not directly visible. Rather than diagnosing a type
  84    --  mismatch, it is better to indicate that the type can be made use-visible
  85    --  with the appropriate use clause. The global variable Candidate_Type is
  86    --  set in Add_One_Interp whenever an interpretation might be legal for an
  87    --  operator if the type were directly visible. This variable is used in
  88    --  Sem_Ch4 when no legal interpretation is found.
  89
  90    Candidate_Type : Entity_Id;
  91
  92    -----------------
  93    -- Subprograms --
  94    -----------------
  95
  96    procedure Init_Interp_Tables;
  97    --  Initialize data structures for overload resolution
  98
  99    procedure Collect_Interps (N : Node_Id);
 100    --  Invoked when the name N has more than one visible interpretation. This
 101    --  is the high level routine which accumulates the possible interpretations
 102    --  of the node. The first meaning and type of N have already been stored
 103    --  in N. If the name is an expanded name, the homonyms are only those that
 104    --  belong to the same scope.
 105
 106    function Is_Visible_Operator (N : Node_Id; Typ : Entity_Id) return Boolean;
 107    --  Determine whether a predefined operation is performed in a context where
 108    --  the predefined operators of base type Typ are visible. The existence of
 109    --  this routine is an implementation artifact. A more straightforward but
 110    --  more space-consuming choice would be to make all inherited operators
 111    --  explicit in the symbol table. See also Sem_ch8.Has_Implicit_Operator.
 112
 113    procedure List_Interps (Nam : Node_Id; Err : Node_Id);
 114    --  List candidate interpretations of an overloaded name. Used for various
 115    --  error reports.
 116
 117    procedure Add_One_Interp
 118      (N         : Node_Id;
 119       E         : Entity_Id;
 120       T         : Entity_Id;
 121       Opnd_Type : Entity_Id := Empty);
 122    --  Add (E, T) to the list of interpretations of the node being resolved.
 123    --  For calls and operators, i.e. for nodes that have a name field, E is an
 124    --  overloadable entity, and T is its type. For constructs such as indexed
 125    --  expressions, the caller sets E equal to T, because the overloading comes
 126    --  from other fields, and the node itself has no name to resolve. Hidden
 127    --  denotes whether an interpretation has been disabled by an abstract
 128    --  operator. Add_One_Interp includes semantic processing to deal with
 129    --  adding entries that hide one another etc.
 130    --
 131    --  For operators, the legality of the operation depends on the visibility
 132    --  of T and its scope. If the operator is an equality or comparison, T is
 133    --  always Boolean, and we use Opnd_Type, which is a candidate type for one
 134    --  of the operands of N, to check visibility.
 135
 136    procedure Get_First_Interp
 137      (N  : Node_Id;
 138       I  : out Interp_Index;
 139       It : out Interp);
 140    --  Initialize iteration over set of interpretations for Node N. The first
 141    --  interpretation is placed in It, and I is initialized for subsequent
 142    --  calls to Get_Next_Interp.
 143
 144    procedure Get_Next_Interp (I : in out Interp_Index; It : out Interp);
 145    --  Iteration step over set of interpretations. Using the value in I, which
 146    --  was set by a previous call to Get_First_Interp or Get_Next_Interp, the
 147    --  next interpretation is placed in It, and I is updated for the next call.
 148    --  The end of the list of interpretations is signalled by It.Nam = Empty.
 149
 150    procedure Remove_Interp (I : in out Interp_Index);
 151    --  Remove an interpretation that is hidden by another, or that does not
 152    --  match the context. The value of I on input was set by a call to either
 153    --  Get_First_Interp or Get_Next_Interp and references the interpretation
 154    --  to be removed. The only allowed use of the exit value of I is as input
 155    --  to a subsequent call to Get_Next_Interp, which yields the interpretation
 156    --  following the removed one.
 157
 158    procedure Save_Interps (Old_N : Node_Id; New_N : Node_Id);
 159    --  If an overloaded node is rewritten during semantic analysis, its
 160    --  possible interpretations must be linked to the copy. This procedure
 161    --  transfers the overload information (Is_Overloaded flag, and list of
 162    --  interpretations) from Old_N, the old node, to New_N, its new copy.
 163    --  It has no effect in the non-overloaded case.
 164
 165    function Covers (T1, T2 : Entity_Id) return Boolean;
 166    --  This is the basic type compatibility routine. T1 is the expected type,
 167    --  imposed by context, and T2 is the actual type. The processing reflects
 168    --  both the definition of type coverage and the rules for operand matching;
 169    --  that is, this does not exactly match the RM definition of "covers".
 170
 171    function Disambiguate
 172      (N      : Node_Id;
 173       I1, I2 : Interp_Index;
 174       Typ    : Entity_Id) return Interp;
 175    --  If more than one interpretation of a name in a call is legal, apply
 176    --  preference rules (universal types first) and operator visibility in
 177    --  order to remove ambiguity. I1 and I2 are the first two interpretations
 178    --  that are compatible with the context, but there may be others.
 179
 180    function Entity_Matches_Spec (Old_S,  New_S : Entity_Id) return Boolean;
 181    --  To resolve subprogram renaming and default formal subprograms in generic
 182    --  definitions. Old_S is a possible interpretation of the entity being
 183    --  renamed, New_S has an explicit signature. If Old_S is a subprogram, as
 184    --  opposed to an operator, type and mode conformance are required.
 185
 186    function Find_Unique_Type (L : Node_Id; R : Node_Id) return Entity_Id;
 187    --  Used in type resolution for equality and comparison nodes. L and R are
 188    --  the operands, whose type is known to be correct or Any_Type in case of
 189    --  ambiguity. Return the type intersection of the two.
 190
 191    function Has_Compatible_Type (N : Node_Id; Typ : Entity_Id) return Boolean;
 192    --  Verify that some interpretation of the node N has a type compatible with
 193    --  Typ. If N is not overloaded, then its unique type must be compatible
 194    --  with Typ. Otherwise iterate through the interpretations of N looking for
 195    --  a compatible one.
 196
 197    function Hides_Op (F : Entity_Id; Op : Entity_Id) return Boolean;
 198    --  A user-defined function hides a predefined operator if it matches the
 199    --  signature of the operator, and is declared in an open scope, or in the
 200    --  scope of the result type.
 201
 202    function Interface_Present_In_Ancestor
 203      (Typ   : Entity_Id;
 204       Iface : Entity_Id) return Boolean;
 205    --  Ada 2005 (AI-251): Typ must be a tagged record type/subtype and Iface
 206    --  must be an abstract interface type (or a class-wide abstract interface).
 207    --  This function is used to check if Typ or some ancestor of Typ implements
 208    --  Iface (returning True only if so).
 209
 210    function Intersect_Types (L, R : Node_Id) return Entity_Id;
 211    --  Find the common interpretation to two analyzed nodes. If one of the
 212    --  interpretations is universal, choose the non-universal one. If either
 213    --  node is overloaded, find single common interpretation.
 214
 215    function In_Generic_Actual (Exp : Node_Id) return Boolean;
 216    --  Determine whether the expression is part of a generic actual. At the
 217    --  time the actual is resolved the scope is already that of the instance,
 218    --  but conceptually the resolution of the actual takes place in the
 219    --  enclosing context and no special disambiguation rules should be applied.
 220
 221    function Is_Ancestor
 222      (T1            : Entity_Id;
 223       T2            : Entity_Id;
 224       Use_Full_View : Boolean := False) return Boolean;
 225    --  T1 is a type (not class-wide). Verify that it is one of the ancestors of
 226    --  type T2 (which may or not be class-wide). If Use_Full_View is True, then
 227    --  the full view of private parents is used when climbing T2's parents.
 228    --
 229    --  Note: For analysis purposes the flag Use_Full_View must be set to False
 230    --  (otherwise we break the privacy contract since this routine returns true
 231    --  for hidden ancestors of private types). For expansion purposes this flag
 232    --  is generally set to True since the expander must know with precision the
 233    --  ancestors of a tagged type. For example, if a private type derives from
 234    --  an interface type then the interface may not be an ancestor of its full
 235    --  view since the full-view is only required to cover the interface (RM 7.3
 236    --  (7.3/2))) and this knowledge affects construction of dispatch tables.
 237
 238    function Is_Progenitor
 239      (Iface : Entity_Id;
 240       Typ   : Entity_Id) return Boolean;
 241    --  Determine whether the interface Iface is implemented by Typ. It requires
 242    --  traversing the list of abstract interfaces of the type, as well as that
 243    --  of the ancestor types. The predicate is used to determine when a formal
 244    --  in the signature of an inherited operation must carry the derived type.
 245
 246    function Is_Subtype_Of (T1 : Entity_Id; T2 : Entity_Id) return Boolean;
 247    --  Checks whether T1 is any subtype of T2 directly or indirectly
 248
 249    function Operator_Matches_Spec (Op, New_S : Entity_Id) return Boolean;
 250    --  Used to resolve subprograms renaming operators, and calls to user
 251    --  defined operators. Determines whether a given operator Op, matches
 252    --  a specification, New_S.
 253
 254    procedure Set_Abstract_Op (I : Interp_Index; V : Entity_Id);
 255    --  Set the abstract operation field of an interpretation
 256
 257    function Specific_Type (Typ_1, Typ_2 : Entity_Id) return Entity_Id;
 258    --  If Typ_1 and Typ_2 are compatible, return the one that is not universal
 259    --  or is not a "class" type (any_character, etc).
 260
 261    function Valid_Boolean_Arg (T : Entity_Id) return Boolean;
 262    --  A valid argument of a predefined boolean operator must be a boolean type
 263    --  or a 1-dimensional array of boolean type.
 264
 265    function Valid_Comparison_Arg (T : Entity_Id) return Boolean;
 266    --  A valid argument of a predefined comparison operator must be a discrete
 267    --  type, real type or a 1-dimensional array with a discrete component type.
 268
 269    function Valid_Equality_Arg (T : Entity_Id) return Boolean;
 270    --  A valid argument of a predefined equality operator must be a nonlimited
 271    --  type or an array with a limited private component whose full view is not
 272    --  limited.
 273
 274    procedure Write_Interp (It : Interp);
 275    --  Debugging procedure to display an Interp
 276
 277    procedure Write_Overloads (N : Node_Id);
 278    --  Debugging procedure to output info on possibly overloaded entities for
 279    --  specified node.
 280
 281 end Sem_Type;