gcc/ada/par-ch7.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P A R . C H 7                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 pragma Style_Checks (All_Checks);
  27 --  Turn off subprogram body ordering check. Subprograms are in order
  28 --  by RM section rather than alphabetical
  29
  30 separate (Par)
  31 package body Ch7 is
  32
  33    ---------------------------------------------
  34    -- 7.1  Package (also 8.5.3, 10.1.3, 12.3) --
  35    ---------------------------------------------
  36
  37    --  This routine scans out a package declaration, package body, or a
  38    --  renaming declaration or generic instantiation starting with PACKAGE
  39
  40    --  PACKAGE_DECLARATION ::=
  41    --    PACKAGE_SPECIFICATION;
  42
  43    --  PACKAGE_SPECIFICATION ::=
  44    --    package DEFINING_PROGRAM_UNIT_NAME
  45    --      [ASPECT_SPECIFICATIONS]
  46    --    is
  47    --      {BASIC_DECLARATIVE_ITEM}
  48    --    [private
  49    --      {BASIC_DECLARATIVE_ITEM}]
  50    --    end [[PARENT_UNIT_NAME .] IDENTIFIER]
  51
  52    --  PACKAGE_BODY ::=
  53    --    package body DEFINING_PROGRAM_UNIT_NAME
  54    --      [ASPECT_SPECIFICATIONS]
  55    --    is
  56    --      DECLARATIVE_PART
  57    --    [begin
  58    --      HANDLED_SEQUENCE_OF_STATEMENTS]
  59    --    end [[PARENT_UNIT_NAME .] IDENTIFIER]
  60
  61    --  PACKAGE_RENAMING_DECLARATION ::=
  62    --    package DEFINING_IDENTIFIER renames package_NAME
  63    --      [ASPECT_SPECIFICATIONS];
  64
  65    --  PACKAGE_BODY_STUB ::=
  66    --    package body DEFINING_IDENTIFIER is separate
  67    --      [ASPECT_SPECIFICATIONS];
  68
  69    --  PACKAGE_INSTANTIATION ::=
  70    --    package DEFINING_PROGRAM_UNIT_NAME is
  71    --      new generic_package_NAME [GENERIC_ACTUAL_PART]
  72    --        [ASPECT_SPECIFICATIONS];
  73
  74    --  Note: in all contexts where a package specification is required, there
  75    --  is a terminating semicolon. This semicolon is scanned out in the case
  76    --  where Pf_Flags is set to Pf_Spcn, even though it is not strictly part
  77    --  of the package specification (it's just too much trouble, and really
  78    --  quite unnecessary, to deal with scanning out an END where the semicolon
  79    --  after the END is not considered to be part of the END.
  80
  81    --  The caller has checked that the initial token is PACKAGE
  82
  83    --  Error recovery: cannot raise Error_Resync
  84
  85    function P_Package (Pf_Flags : Pf_Rec) return Node_Id is
  86       Package_Node       : Node_Id;
  87       Specification_Node : Node_Id;
  88       Name_Node          : Node_Id;
  89       Package_Sloc       : Source_Ptr;
  90
  91       Aspect_Sloc : Source_Ptr := No_Location;
  92       --  Save location of WITH for scanned aspects. Left set to No_Location
  93       --  if no aspects scanned before the IS keyword.
  94
  95       Is_Sloc : Source_Ptr;
  96       --  Save location of IS token for package declaration
  97
  98       Dummy_Node : constant Node_Id :=
  99                      New_Node (N_Package_Specification, Token_Ptr);
 100       --  Dummy node to attach aspect specifications to until we properly
 101       --  figure out where they eventually belong.
 102
 103    begin
 104       Push_Scope_Stack;
 105       Scopes (Scope.Last).Etyp := E_Name;
 106       Scopes (Scope.Last).Ecol := Start_Column;
 107       Scopes (Scope.Last).Lreq := False;
 108
 109       Package_Sloc := Token_Ptr;
 110       Scan; -- past PACKAGE
 111
 112       if Token = Tok_Type then
 113          Error_Msg_SC -- CODEFIX
 114            ("TYPE not allowed here");
 115          Scan; -- past TYPE
 116       end if;
 117
 118       --  Case of package body. Note that we demand a package body if that
 119       --  is the only possibility (even if the BODY keyword is not present)
 120
 121       if Token = Tok_Body or else Pf_Flags = Pf_Pbod_Pexp then
 122          if not Pf_Flags.Pbod then
 123             Error_Msg_SC ("package body cannot appear here!");
 124          end if;
 125
 126          T_Body;
 127          Scopes (Scope.Last).Sloc := Token_Ptr;
 128          Name_Node := P_Defining_Program_Unit_Name;
 129          Scopes (Scope.Last).Labl := Name_Node;
 130          Current_Node := Name_Node;
 131
 132          if Aspect_Specifications_Present then
 133             Aspect_Sloc := Token_Ptr;
 134             P_Aspect_Specifications (Dummy_Node, Semicolon => False);
 135          end if;
 136
 137          TF_Is;
 138
 139          if Separate_Present then
 140             if not Pf_Flags.Stub then
 141                Error_Msg_SC ("body stub cannot appear here!");
 142             end if;
 143
 144             Scan; -- past SEPARATE
 145
 146             Package_Node := New_Node (N_Package_Body_Stub, Package_Sloc);
 147             Set_Defining_Identifier (Package_Node, Name_Node);
 148
 149             if Has_Aspects (Dummy_Node) then
 150                Error_Msg
 151                  ("aspect specifications must come after SEPARATE",
 152                   Aspect_Sloc);
 153             end if;
 154
 155             P_Aspect_Specifications (Package_Node, Semicolon => False);
 156             TF_Semicolon;
 157             Pop_Scope_Stack;
 158
 159          else
 160             Package_Node := New_Node (N_Package_Body, Package_Sloc);
 161             Set_Defining_Unit_Name (Package_Node, Name_Node);
 162
 163             --  Move the aspect specifications to the body node
 164
 165             Move_Aspects (From => Dummy_Node, To => Package_Node);
 166
 167             Parse_Decls_Begin_End (Package_Node);
 168          end if;
 169
 170       --  Cases other than Package_Body
 171
 172       else
 173          Scopes (Scope.Last).Sloc := Token_Ptr;
 174          Name_Node := P_Defining_Program_Unit_Name;
 175          Scopes (Scope.Last).Labl := Name_Node;
 176          Current_Node := Name_Node;
 177
 178          --  Case of renaming declaration
 179
 180          Check_Misspelling_Of (Tok_Renames);
 181
 182          if Token = Tok_Renames then
 183             if not Pf_Flags.Rnam then
 184                Error_Msg_SC ("renaming declaration cannot appear here!");
 185             end if;
 186
 187             Scan; -- past RENAMES;
 188
 189             Package_Node :=
 190               New_Node (N_Package_Renaming_Declaration, Package_Sloc);
 191             Set_Defining_Unit_Name (Package_Node, Name_Node);
 192             Set_Name (Package_Node, P_Qualified_Simple_Name);
 193
 194             No_Constraint;
 195             P_Aspect_Specifications (Package_Node, Semicolon => False);
 196             TF_Semicolon;
 197             Pop_Scope_Stack;
 198
 199          --  Generic package instantiation or package declaration
 200
 201          else
 202             if Aspect_Specifications_Present then
 203                Aspect_Sloc := Token_Ptr;
 204                P_Aspect_Specifications (Dummy_Node, Semicolon => False);
 205             end if;
 206
 207             Is_Sloc := Token_Ptr;
 208             TF_Is;
 209
 210             --  Case of generic instantiation
 211
 212             if Token = Tok_New then
 213                if not Pf_Flags.Gins then
 214                   Error_Msg_SC
 215                      ("generic instantiation cannot appear here!");
 216                end if;
 217
 218                if Aspect_Sloc /= No_Location then
 219                   Error_Msg
 220                     ("misplaced aspects for package instantiation",
 221                      Aspect_Sloc);
 222                end if;
 223
 224                Scan; -- past NEW
 225
 226                Package_Node :=
 227                  New_Node (N_Package_Instantiation, Package_Sloc);
 228                Set_Defining_Unit_Name (Package_Node, Name_Node);
 229                Set_Name (Package_Node, P_Qualified_Simple_Name);
 230                Set_Generic_Associations
 231                  (Package_Node, P_Generic_Actual_Part_Opt);
 232
 233                if Aspect_Sloc /= No_Location
 234                  and then not Aspect_Specifications_Present
 235                then
 236                   Error_Msg_SC ("info: aspect specifications belong here");
 237                   Move_Aspects (From => Dummy_Node, To => Package_Node);
 238                end if;
 239
 240                P_Aspect_Specifications (Package_Node, Semicolon => True);
 241                Pop_Scope_Stack;
 242
 243             --  Case of package declaration or package specification
 244
 245             else
 246                Specification_Node :=
 247                  New_Node (N_Package_Specification, Package_Sloc);
 248
 249                Set_Defining_Unit_Name (Specification_Node, Name_Node);
 250                Set_Visible_Declarations
 251                  (Specification_Node,
 252                   P_Basic_Declarative_Items (Declare_Expression => False));
 253
 254                if Token = Tok_Private then
 255                   Error_Msg_Col := Scopes (Scope.Last).Ecol;
 256
 257                   if RM_Column_Check then
 258                      if Token_Is_At_Start_Of_Line
 259                        and then Start_Column /= Error_Msg_Col
 260                      then
 261                         Error_Msg_SC
 262                           ("(style) PRIVATE in wrong column, should be@?l?");
 263                      end if;
 264                   end if;
 265
 266                   Scan; -- past PRIVATE
 267
 268                   Set_Private_Declarations
 269                     (Specification_Node,
 270                      P_Basic_Declarative_Items (Declare_Expression => False));
 271
 272                   --  Deal gracefully with multiple PRIVATE parts
 273
 274                   while Token = Tok_Private loop
 275                      Error_Msg_SC
 276                        ("only one private part allowed per package");
 277                      Scan; -- past PRIVATE
 278                      Append_List
 279                        (P_Basic_Declarative_Items
 280                           (Declare_Expression => False),
 281                         Private_Declarations (Specification_Node));
 282                   end loop;
 283                end if;
 284
 285                if Pf_Flags = Pf_Spcn then
 286                   Package_Node := Specification_Node;
 287                else
 288                   Package_Node :=
 289                     New_Node (N_Package_Declaration, Package_Sloc);
 290                   Set_Specification (Package_Node, Specification_Node);
 291                end if;
 292
 293                if Token = Tok_Begin then
 294                   Error_Msg_SC ("begin block not allowed in package spec");
 295                   Scan; -- past BEGIN
 296                   Discard_Junk_List (P_Sequence_Of_Statements (SS_None));
 297                end if;
 298
 299                End_Statements (Specification_Node, Empty, Is_Sloc);
 300                Move_Aspects (From => Dummy_Node, To => Package_Node);
 301             end if;
 302          end if;
 303       end if;
 304
 305       return Package_Node;
 306    end P_Package;
 307
 308    ------------------------------
 309    -- 7.1  Package Declaration --
 310    ------------------------------
 311
 312    --  Parsed by P_Package (7.1)
 313
 314    --------------------------------
 315    -- 7.1  Package Specification --
 316    --------------------------------
 317
 318    --  Parsed by P_Package (7.1)
 319
 320    -----------------------
 321    -- 7.1  Package Body --
 322    -----------------------
 323
 324    --  Parsed by P_Package (7.1)
 325
 326    -----------------------------------
 327    -- 7.3  Private Type Declaration --
 328    -----------------------------------
 329
 330    --  Parsed by P_Type_Declaration (3.2.1)
 331
 332    ----------------------------------------
 333    -- 7.3  Private Extension Declaration --
 334    ----------------------------------------
 335
 336    --  Parsed by P_Type_Declaration (3.2.1)
 337
 338 end Ch7;