gcc/ada/libgnat/s-casi16.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 1 6        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System.Storage_Elements; use System.Storage_Elements;
  33
  34 with Ada.Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Signed_16 is
  37
  38    type Word is mod 2 ** 32;
  39    --  Used to process operands by words
  40
  41    type Half is range -(2 ** 15) .. (2 ** 15) - 1;
  42    for Half'Size use 16;
  43    --  Used to process operands by half words
  44
  45    type Uhalf is new Half;
  46    for Uhalf'Alignment use 1;
  47    --  Used to process operands when unaligned
  48
  49    type WP is access Word;
  50    type HP is access Half;
  51    type UP is access Uhalf;
  52
  53    function W is new Ada.Unchecked_Conversion (Address, WP);
  54    function H is new Ada.Unchecked_Conversion (Address, HP);
  55    function U is new Ada.Unchecked_Conversion (Address, UP);
  56
  57    -----------------------
  58    -- Compare_Array_S16 --
  59    -----------------------
  60
  61    pragma Annotate (Gnatcheck, Exempt_On, "Improper_Returns",
  62                     "early returns for performance");
  63
  64    function Compare_Array_S16
  65      (Left      : System.Address;
  66       Right     : System.Address;
  67       Left_Len  : Natural;
  68       Right_Len : Natural) return Integer
  69    is
  70       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  71       --  Number of elements left to compare
  72
  73       L : Address := Left;
  74       R : Address := Right;
  75       --  Pointers to next elements to compare
  76
  77    begin
  78       --  Go by words if possible
  79
  80       if Left mod Storage_Offset (4) = 0
  81         and then Right mod Storage_Offset (4) = 0
  82       then
  83          while Clen > 1
  84            and then W (L).all = W (R).all
  85          loop
  86             Clen := Clen - 2;
  87             L := L + Storage_Offset (4);
  88             R := R + Storage_Offset (4);
  89          end loop;
  90       end if;
  91
  92       --  Case of going by aligned half words
  93
  94       if Left mod Storage_Offset (2) = 0
  95         and then Right mod Storage_Offset (2) = 0
  96       then
  97          while Clen /= 0 loop
  98             if H (L).all /= H (R).all then
  99                if H (L).all > H (R).all then
 100                   return +1;
 101                else
 102                   return -1;
 103                end if;
 104             end if;
 105
 106             Clen := Clen - 1;
 107             L := L + Storage_Offset (2);
 108             R := R + Storage_Offset (2);
 109          end loop;
 110
 111       --  Case of going by unaligned half words
 112
 113       else
 114          while Clen /= 0 loop
 115             if U (L).all /= U (R).all then
 116                if U (L).all > U (R).all then
 117                   return +1;
 118                else
 119                   return -1;
 120                end if;
 121             end if;
 122
 123             Clen := Clen - 1;
 124             L := L + Storage_Offset (2);
 125             R := R + Storage_Offset (2);
 126          end loop;
 127       end if;
 128
 129       --  Here if common section equal, result decided by lengths
 130
 131       if Left_Len = Right_Len then
 132          return 0;
 133       elsif Left_Len > Right_Len then
 134          return +1;
 135       else
 136          return -1;
 137       end if;
 138    end Compare_Array_S16;
 139
 140    pragma Annotate (Gnatcheck, Exempt_Off, "Improper_Returns");
 141 end System.Compare_Array_Signed_16;