gcc/ada/libgnat/s-casi128.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 1 2 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System.Storage_Elements; use System.Storage_Elements;
  33
  34 with Ada.Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Signed_128 is
  37
  38    type Word is range -2**127 .. 2**127 - 1;
  39    for Word'Size use 128;
  40    --  Used to process operands by 128-bit words
  41
  42    type Uword is new Word;
  43    for Uword'Alignment use 1;
  44    --  Used to process operands when unaligned
  45
  46    type WP is access Word;
  47    type UP is access Uword;
  48
  49    function W is new Ada.Unchecked_Conversion (Address, WP);
  50    function U is new Ada.Unchecked_Conversion (Address, UP);
  51
  52    ------------------------
  53    -- Compare_Array_S128 --
  54    ------------------------
  55
  56    function Compare_Array_S128
  57      (Left      : System.Address;
  58       Right     : System.Address;
  59       Left_Len  : Natural;
  60       Right_Len : Natural) return Integer
  61    is
  62       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  63       --  Number of elements left to compare
  64
  65       L : Address := Left;
  66       R : Address := Right;
  67       --  Pointers to next elements to compare
  68
  69    begin
  70       --  Case of going by aligned quadruple words
  71
  72       if Left mod Storage_Offset (16) = 0
  73         and then Right mod Storage_Offset (16) = 0
  74       then
  75          while Clen /= 0 loop
  76             if W (L).all /= W (R).all then
  77                if W (L).all > W (R).all then
  78                   return +1;
  79                else
  80                   return -1;
  81                end if;
  82             end if;
  83
  84             Clen := Clen - 1;
  85             L := L + Storage_Offset (16);
  86             R := R + Storage_Offset (16);
  87          end loop;
  88
  89       --  Case of going by unaligned quadruple words
  90
  91       else
  92          while Clen /= 0 loop
  93             if U (L).all /= U (R).all then
  94                if U (L).all > U (R).all then
  95                   return +1;
  96                else
  97                   return -1;
  98                end if;
  99             end if;
 100
 101             Clen := Clen - 1;
 102             L := L + Storage_Offset (16);
 103             R := R + Storage_Offset (16);
 104          end loop;
 105       end if;
 106
 107       --  Here if common section equal, result decided by lengths
 108
 109       if Left_Len = Right_Len then
 110          return 0;
 111       elsif Left_Len > Right_Len then
 112          return +1;
 113       else
 114          return -1;
 115       end if;
 116    end Compare_Array_S128;
 117
 118 end System.Compare_Array_Signed_128;