gcc/ada/libgnat/g-hesorg.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                     G N A T . H E A P _ S O R T _ G                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1995-2024, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 package body GNAT.Heap_Sort_G is
  33
  34    ----------
  35    -- Sort --
  36    ----------
  37
  38    --  We are using the classical heapsort algorithm (i.e. Floyd's Treesort3)
  39    --  as described by Knuth ("The Art of Programming", Volume III, first
  40    --  edition, section 5.2.3, p. 145-147) with the modification that is
  41    --  mentioned in exercise 18. For more details on this algorithm, see
  42    --  Robert B. K. Dewar PhD thesis "The use of Computers in the X-ray
  43    --  Phase Problem". University of Chicago, 1968, which was the first
  44    --  publication of the modification, which reduces the number of compares
  45    --  from 2NlogN to NlogN.
  46
  47    procedure Sort (N : Natural) is
  48       pragma Annotate (CodePeer, Skip_Analysis);
  49       --  CodePeer is sometimes getting confused on this procedure
  50
  51       Max : Natural := N;
  52       --  Current Max index in tree being sifted
  53
  54       procedure Sift (S : Positive);
  55       --  This procedure sifts up node S, i.e. converts the subtree rooted
  56       --  at node S into a heap, given the precondition that any sons of
  57       --  S are already heaps. On entry, the contents of node S is found
  58       --  in the temporary (index 0), the actual contents of node S on
  59       --  entry are irrelevant. This is just a minor optimization to avoid
  60       --  what would otherwise be two junk moves in phase two of the sort.
  61
  62       ----------
  63       -- Sift --
  64       ----------
  65
  66       procedure Sift (S : Positive) is
  67          C      : Positive := S;
  68          Son    : Positive;
  69          Father : Positive;
  70          --  Note: by making the above all Positive, we ensure that a test
  71          --  against zero for the temporary location can be resolved on the
  72          --  basis of types when the routines are inlined.
  73
  74       begin
  75          --  This is where the optimization is done, normally we would do a
  76          --  comparison at each stage between the current node and the larger
  77          --  of the two sons, and continue the sift only if the current node
  78          --  was less than this maximum. In this modified optimized version,
  79          --  we assume that the current node will be less than the larger
  80          --  son, and unconditionally sift up. Then when we get to the bottom
  81          --  of the tree, we check parents to make sure that we did not make
  82          --  a mistake. This roughly cuts the number of comparisons in half,
  83          --  since it is almost always the case that our assumption is correct.
  84
  85          --  Loop to pull up larger sons
  86
  87          loop
  88             Son := 2 * C;
  89
  90             if Son < Max then
  91                if Lt (Son, Son + 1) then
  92                   Son := Son + 1;
  93                end if;
  94             elsif Son > Max then
  95                exit;
  96             end if;
  97
  98             Move (Son, C);
  99             C := Son;
 100          end loop;
 101
 102          --  Loop to check fathers
 103
 104          while C /= S loop
 105             Father := C / 2;
 106
 107             if Lt (Father, 0) then
 108                Move (Father, C);
 109                C := Father;
 110             else
 111                exit;
 112             end if;
 113          end loop;
 114
 115          --  Last step is to pop the sifted node into place
 116
 117          Move (0, C);
 118       end Sift;
 119
 120    --  Start of processing for Sort
 121
 122    begin
 123       --  Phase one of heapsort is to build the heap. This is done by
 124       --  sifting nodes N/2 .. 1 in sequence.
 125
 126       for J in reverse 1 .. N / 2 loop
 127          Move (J, 0);
 128          Sift (J);
 129       end loop;
 130
 131       --  In phase 2, the largest node is moved to end, reducing the size
 132       --  of the tree by one, and the displaced node is sifted down from
 133       --  the top, so that the largest node is again at the top.
 134
 135       while Max > 1 loop
 136          Move (Max, 0);
 137          Move (1, Max);
 138          Max := Max - 1;
 139          Sift (1);
 140       end loop;
 141
 142    end Sort;
 143
 144 end GNAT.Heap_Sort_G;