gcc/ada/libgnat/a-timoio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --               A D A . T E X T _ I O . M O D U L A R _ I O                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Ada.Text_IO.Integer_Aux;
  33 with System.Img_BIU; use System.Img_BIU;
  34 with System.Img_Uns; use System.Img_Uns;
  35 with System.Img_LLB; use System.Img_LLB;
  36 with System.Img_LLU; use System.Img_LLU;
  37 with System.Img_LLW; use System.Img_LLW;
  38 with System.Img_WIU; use System.Img_WIU;
  39 with System.Unsigned_Types;
  40 with System.Val_Uns; use System.Val_Uns;
  41 with System.Val_LLU; use System.Val_LLU;
  42
  43 package body Ada.Text_IO.Modular_IO is
  44
  45    subtype Unsigned is System.Unsigned_Types.Unsigned;
  46
  47    package Aux_Uns is new
  48      Ada.Text_IO.Integer_Aux
  49        (Unsigned,
  50         Scan_Unsigned,
  51         Set_Image_Unsigned,
  52         Set_Image_Width_Unsigned,
  53         Set_Image_Based_Unsigned);
  54
  55    subtype Long_Long_Unsigned is System.Unsigned_Types.Long_Long_Unsigned;
  56
  57    package Aux_LLU is new
  58      Ada.Text_IO.Integer_Aux
  59        (Long_Long_Unsigned,
  60         Scan_Long_Long_Unsigned,
  61         Set_Image_Long_Long_Unsigned,
  62         Set_Image_Width_Long_Long_Unsigned,
  63         Set_Image_Based_Long_Long_Unsigned);
  64
  65    Need_LLU : constant Boolean := Num'Base'Size > Unsigned'Size;
  66    --  Throughout this generic body, we distinguish between the case where type
  67    --  Unsigned is acceptable, and where a Long_Long_Unsigned is needed. This
  68    --  Boolean is used to test for these cases and since it is a constant, only
  69    --  code for the relevant case will be included in the instance.
  70
  71    ---------
  72    -- Get --
  73    ---------
  74
  75    procedure Get
  76      (File  : File_Type;
  77       Item  : out Num;
  78       Width : Field := 0)
  79    is
  80       --  We depend on a range check to get Data_Error
  81
  82       pragma Unsuppress (Range_Check);
  83
  84    begin
  85       if Need_LLU then
  86          Aux_LLU.Get (File, Long_Long_Unsigned (Item), Width);
  87       else
  88          Aux_Uns.Get (File, Unsigned (Item), Width);
  89       end if;
  90
  91    exception
  92       when Constraint_Error => raise Data_Error;
  93    end Get;
  94
  95    procedure Get
  96      (Item  : out Num;
  97       Width : Field := 0)
  98    is
  99    begin
 100       Get (Current_In, Item, Width);
 101    end Get;
 102
 103    procedure Get
 104      (From : String;
 105       Item : out Num;
 106       Last : out Positive)
 107    is
 108       --  We depend on a range check to get Data_Error
 109
 110       pragma Unsuppress (Range_Check);
 111
 112    begin
 113       if Need_LLU then
 114          Aux_LLU.Gets (From, Long_Long_Unsigned (Item), Last);
 115       else
 116          Aux_Uns.Gets (From, Unsigned (Item), Last);
 117       end if;
 118
 119    exception
 120       when Constraint_Error => raise Data_Error;
 121    end Get;
 122
 123    ---------
 124    -- Put --
 125    ---------
 126
 127    procedure Put
 128      (File  : File_Type;
 129       Item  : Num;
 130       Width : Field := Default_Width;
 131       Base  : Number_Base := Default_Base)
 132    is
 133    begin
 134       if Need_LLU then
 135          Aux_LLU.Put (File, Long_Long_Unsigned (Item), Width, Base);
 136       else
 137          Aux_Uns.Put (File, Unsigned (Item), Width, Base);
 138       end if;
 139    end Put;
 140
 141    procedure Put
 142      (Item  : Num;
 143       Width : Field := Default_Width;
 144       Base  : Number_Base := Default_Base)
 145    is
 146    begin
 147       Put (Current_Out, Item, Width, Base);
 148    end Put;
 149
 150    procedure Put
 151      (To   : out String;
 152       Item : Num;
 153       Base : Number_Base := Default_Base)
 154    is
 155    begin
 156       if Need_LLU then
 157          Aux_LLU.Puts (To, Long_Long_Unsigned (Item), Base);
 158       else
 159          Aux_Uns.Puts (To, Unsigned (Item), Base);
 160       end if;
 161    end Put;
 162
 163 end Ada.Text_IO.Modular_IO;