gcc/ada/libgnat/a-cbsyqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                ADA.CONTAINERS.BOUNDED_SYNCHRONIZED_QUEUES                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2011-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35 with Ada.Containers.Synchronized_Queue_Interfaces;
  36
  37 generic
  38    with package Queue_Interfaces is
  39      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  40
  41    Default_Capacity : Count_Type;
  42    Default_Ceiling  : System.Any_Priority := System.Priority'Last;
  43
  44 package Ada.Containers.Bounded_Synchronized_Queues with
  45   SPARK_Mode => Off
  46 is
  47    pragma Annotate (CodePeer, Skip_Analysis);
  48    pragma Preelaborate;
  49
  50    package Implementation is
  51
  52       --  All identifiers in this unit are implementation defined
  53
  54       pragma Implementation_Defined;
  55
  56       type List_Type (Capacity : Count_Type) is tagged limited private;
  57
  58       procedure Enqueue
  59         (List     : in out List_Type;
  60          New_Item : Queue_Interfaces.Element_Type);
  61
  62       procedure Dequeue
  63         (List    : in out List_Type;
  64          Element : out Queue_Interfaces.Element_Type);
  65
  66       function Length (List : List_Type) return Count_Type;
  67
  68       function Max_Length (List : List_Type) return Count_Type;
  69
  70    private
  71
  72       --  Need proper heap data structure here ???
  73
  74       --  We suppress warnings here, which might otherwise be triggered
  75       --  by the box initialization of the Elements array below. This
  76       --  initialization is needed to preserve constraints, such as
  77       --  discriminant values, that the actual for Element_Type might
  78       --  carry.
  79
  80       pragma Warnings (Off);
  81
  82       type Element_Array is
  83         array (Count_Type range <>) of Queue_Interfaces.Element_Type;
  84
  85       type List_Type (Capacity : Count_Type) is tagged limited record
  86          First, Last : Count_Type := 0;
  87          Length      : Count_Type := 0;
  88          Max_Length  : Count_Type := 0;
  89          Elements    : Element_Array (1 .. Capacity) := (others => <>);
  90       end record;
  91
  92    end Implementation;
  93
  94    protected type Queue
  95      (Capacity : Count_Type := Default_Capacity;
  96       Ceiling  : System.Any_Priority := Default_Ceiling)
  97    with
  98      Priority => Ceiling
  99    is new Queue_Interfaces.Queue with
 100
 101       overriding entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 102
 103       overriding entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 104
 105       overriding function Current_Use return Count_Type;
 106
 107       overriding function Peak_Use return Count_Type;
 108
 109    private
 110       List : Implementation.List_Type (Capacity);
 111    end Queue;
 112
 113 end Ada.Containers.Bounded_Synchronized_Queues;