gcc/ada/libgnat/a-cborma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --   A D A . C O N T A I N E R S . B O U N D E D _ O R D E R E D _ M A P S  --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Iterator_Interfaces;
  35
  36 private with Ada.Containers.Red_Black_Trees;
  37 private with Ada.Streams;
  38 private with Ada.Finalization;
  39 private with Ada.Strings.Text_Buffers;
  40
  41 generic
  42    type Key_Type is private;
  43    type Element_Type is private;
  44
  45    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  46    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  47
  48 package Ada.Containers.Bounded_Ordered_Maps with
  49   SPARK_Mode => Off
  50 is
  51    pragma Annotate (CodePeer, Skip_Analysis);
  52    pragma Pure;
  53    pragma Remote_Types;
  54
  55    function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  56
  57    type Map (Capacity : Count_Type) is tagged private with
  58       Constant_Indexing => Constant_Reference,
  59       Variable_Indexing => Reference,
  60       Default_Iterator  => Iterate,
  61       Iterator_Element  => Element_Type,
  62       Aggregate         => (Empty     => Empty,
  63                             Add_Named => Insert),
  64       Preelaborable_Initialization
  65                         => Element_Type'Preelaborable_Initialization
  66                              and
  67                            Key_Type'Preelaborable_Initialization;
  68
  69    type Cursor is private with Preelaborable_Initialization;
  70
  71    Empty_Map : constant Map;
  72
  73    function Empty (Capacity : Count_Type := 10) return Map;
  74
  75    No_Element : constant Cursor;
  76
  77    function Has_Element (Position : Cursor) return Boolean;
  78
  79    package Map_Iterator_Interfaces is new
  80      Ada.Iterator_Interfaces (Cursor, Has_Element);
  81
  82    function "=" (Left, Right : Map) return Boolean;
  83
  84    function Length (Container : Map) return Count_Type;
  85
  86    function Is_Empty (Container : Map) return Boolean;
  87
  88    procedure Clear (Container : in out Map);
  89
  90    function Key (Position : Cursor) return Key_Type;
  91
  92    function Element (Position : Cursor) return Element_Type;
  93
  94    procedure Replace_Element
  95      (Container : in out Map;
  96       Position  : Cursor;
  97       New_Item  : Element_Type);
  98
  99    procedure Query_Element
 100      (Position : Cursor;
 101       Process  : not null access
 102                    procedure (Key : Key_Type; Element : Element_Type));
 103
 104    procedure Update_Element
 105      (Container : in out Map;
 106       Position  : Cursor;
 107       Process   : not null access
 108                     procedure (Key : Key_Type; Element : in out Element_Type));
 109
 110    type Constant_Reference_Type
 111       (Element : not null access constant Element_Type) is private
 112    with
 113       Implicit_Dereference => Element;
 114
 115    type Reference_Type (Element : not null access Element_Type) is private
 116    with
 117       Implicit_Dereference => Element;
 118
 119    function Constant_Reference
 120      (Container : aliased Map;
 121       Position  : Cursor) return Constant_Reference_Type;
 122
 123    function Reference
 124      (Container : aliased in out Map;
 125       Position  : Cursor) return Reference_Type;
 126
 127    function Constant_Reference
 128      (Container : aliased Map;
 129       Key       : Key_Type) return Constant_Reference_Type;
 130
 131    function Reference
 132      (Container : aliased in out Map;
 133       Key       : Key_Type) return Reference_Type;
 134
 135    procedure Assign (Target : in out Map; Source : Map);
 136
 137    function Copy (Source : Map; Capacity : Count_Type := 0) return Map;
 138
 139    procedure Move (Target : in out Map; Source : in out Map);
 140
 141    procedure Insert
 142      (Container : in out Map;
 143       Key       : Key_Type;
 144       New_Item  : Element_Type;
 145       Position  : out Cursor;
 146       Inserted  : out Boolean);
 147
 148    procedure Insert
 149      (Container : in out Map;
 150       Key       : Key_Type;
 151       Position  : out Cursor;
 152       Inserted  : out Boolean);
 153
 154    procedure Insert
 155      (Container : in out Map;
 156       Key       : Key_Type;
 157       New_Item  : Element_Type);
 158
 159    procedure Include
 160      (Container : in out Map;
 161       Key       : Key_Type;
 162       New_Item  : Element_Type);
 163
 164    procedure Replace
 165      (Container : in out Map;
 166       Key       : Key_Type;
 167       New_Item  : Element_Type);
 168
 169    procedure Exclude (Container : in out Map; Key : Key_Type);
 170
 171    procedure Delete (Container : in out Map; Key : Key_Type);
 172
 173    procedure Delete (Container : in out Map; Position : in out Cursor);
 174
 175    procedure Delete_First (Container : in out Map);
 176
 177    procedure Delete_Last (Container : in out Map);
 178
 179    function First (Container : Map) return Cursor;
 180
 181    function First_Element (Container : Map) return Element_Type;
 182
 183    function First_Key (Container : Map) return Key_Type;
 184
 185    function Last (Container : Map) return Cursor;
 186
 187    function Last_Element (Container : Map) return Element_Type;
 188
 189    function Last_Key (Container : Map) return Key_Type;
 190
 191    function Next (Position : Cursor) return Cursor;
 192
 193    procedure Next (Position : in out Cursor);
 194
 195    function Previous (Position : Cursor) return Cursor;
 196
 197    procedure Previous (Position : in out Cursor);
 198
 199    function Find (Container : Map; Key : Key_Type) return Cursor;
 200
 201    function Element (Container : Map; Key : Key_Type) return Element_Type;
 202
 203    function Floor (Container : Map; Key : Key_Type) return Cursor;
 204
 205    function Ceiling (Container : Map; Key : Key_Type) return Cursor;
 206
 207    function Contains (Container : Map; Key : Key_Type) return Boolean;
 208
 209    function "<" (Left, Right : Cursor) return Boolean;
 210
 211    function ">" (Left, Right : Cursor) return Boolean;
 212
 213    function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 214
 215    function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 216
 217    function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 218
 219    function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 220
 221    procedure Iterate
 222      (Container : Map;
 223       Process   : not null access procedure (Position : Cursor));
 224
 225    procedure Reverse_Iterate
 226      (Container : Map;
 227       Process   : not null access procedure (Position : Cursor));
 228
 229    function Iterate
 230      (Container : Map)
 231       return Map_Iterator_Interfaces.Reversible_Iterator'Class;
 232
 233    function Iterate
 234      (Container : Map;
 235       Start     : Cursor)
 236       return Map_Iterator_Interfaces.Reversible_Iterator'Class;
 237
 238 private
 239
 240    use Ada.Finalization;
 241    pragma Inline (Next);
 242    pragma Inline (Previous);
 243
 244    type Node_Type is record
 245       Parent  : Count_Type;
 246       Left    : Count_Type;
 247       Right   : Count_Type;
 248       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 249       Key     : Key_Type;
 250       Element : aliased Element_Type;
 251    end record;
 252
 253    package Tree_Types is
 254      new Red_Black_Trees.Generic_Bounded_Tree_Types (Node_Type);
 255
 256    type Map (Capacity : Count_Type) is
 257      new Tree_Types.Tree_Type (Capacity)
 258       with null record with Put_Image => Put_Image;
 259
 260    procedure Put_Image
 261      (S : in out Ada.Strings.Text_Buffers.Root_Buffer_Type'Class; V : Map);
 262
 263    use Red_Black_Trees;
 264    use Tree_Types, Tree_Types.Implementation;
 265    use Ada.Streams;
 266
 267    procedure Write
 268      (Stream    : not null access Root_Stream_Type'Class;
 269       Container : Map);
 270
 271    for Map'Write use Write;
 272
 273    procedure Read
 274      (Stream    : not null access Root_Stream_Type'Class;
 275       Container : out Map);
 276
 277    for Map'Read use Read;
 278
 279    type Map_Access is access all Map;
 280    for Map_Access'Storage_Size use 0;
 281
 282    type Cursor is record
 283       Container : Map_Access;
 284       Node      : Count_Type := 0;
 285    end record;
 286
 287    procedure Write
 288      (Stream : not null access Root_Stream_Type'Class;
 289       Item   : Cursor);
 290
 291    for Cursor'Write use Write;
 292
 293    procedure Read
 294      (Stream : not null access Root_Stream_Type'Class;
 295       Item   : out Cursor);
 296
 297    for Cursor'Read use Read;
 298
 299    subtype Reference_Control_Type is Implementation.Reference_Control_Type;
 300    --  It is necessary to rename this here, so that the compiler can find it
 301
 302    type Constant_Reference_Type
 303      (Element : not null access constant Element_Type) is
 304       record
 305          Control : Reference_Control_Type :=
 306            raise Program_Error with "uninitialized reference";
 307          --  The RM says, "The default initialization of an object of
 308          --  type Constant_Reference_Type or Reference_Type propagates
 309          --  Program_Error."
 310       end record;
 311
 312    procedure Read
 313      (Stream : not null access Root_Stream_Type'Class;
 314       Item   : out Constant_Reference_Type);
 315
 316    for Constant_Reference_Type'Read use Read;
 317
 318    procedure Write
 319      (Stream : not null access Root_Stream_Type'Class;
 320       Item   : Constant_Reference_Type);
 321
 322    for Constant_Reference_Type'Write use Write;
 323
 324    type Reference_Type (Element : not null access Element_Type) is record
 325       Control : Reference_Control_Type :=
 326         raise Program_Error with "uninitialized reference";
 327       --  The RM says, "The default initialization of an object of
 328       --  type Constant_Reference_Type or Reference_Type propagates
 329       --  Program_Error."
 330    end record;
 331
 332    procedure Read
 333      (Stream : not null access Root_Stream_Type'Class;
 334       Item   : out Reference_Type);
 335
 336    for Reference_Type'Read use Read;
 337
 338    procedure Write
 339      (Stream : not null access Root_Stream_Type'Class;
 340       Item   : Reference_Type);
 341
 342    for Reference_Type'Write use Write;
 343
 344    --  See Ada.Containers.Vectors for documentation on the following
 345
 346    procedure _Next (Position : in out Cursor) renames Next;
 347    procedure _Previous (Position : in out Cursor) renames Previous;
 348
 349    function Pseudo_Reference
 350      (Container : aliased Map'Class) return Reference_Control_Type;
 351    pragma Inline (Pseudo_Reference);
 352    --  Creates an object of type Reference_Control_Type pointing to the
 353    --  container, and increments the Lock. Finalization of this object will
 354    --  decrement the Lock.
 355
 356    type Element_Access is access all Element_Type with
 357      Storage_Size => 0;
 358
 359    function Get_Element_Access
 360      (Position : Cursor) return not null Element_Access;
 361    --  Returns a pointer to the element designated by Position.
 362
 363    Empty_Map : constant Map := Map'(Tree_Type with Capacity => 0);
 364
 365    No_Element : constant Cursor := Cursor'(null, 0);
 366
 367    type Iterator is new Limited_Controlled and
 368      Map_Iterator_Interfaces.Reversible_Iterator with
 369    record
 370       Container : Map_Access;
 371       Node      : Count_Type;
 372    end record
 373      with Disable_Controlled => not T_Check;
 374
 375    overriding procedure Finalize (Object : in out Iterator);
 376
 377    overriding function First (Object : Iterator) return Cursor;
 378    overriding function Last  (Object : Iterator) return Cursor;
 379
 380    overriding function Next
 381      (Object   : Iterator;
 382       Position : Cursor) return Cursor;
 383
 384    overriding function Previous
 385      (Object   : Iterator;
 386       Position : Cursor) return Cursor;
 387
 388 end Ada.Containers.Bounded_Ordered_Maps;