gcc/ada/s-rident.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . R I D E N T                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the GNU Public License.                                       --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package defines the set of restriction identifiers. It is a generic
  35 --  package that is instantiated by the compiler/binder in package Rident, and
  36 --  is instantiated in package System.Restrictions for use at run-time.
  37
  38 --  The reason that we make this a generic package is so that in the case of
  39 --  the instantiation in Rident for use at compile time and bind time, we can
  40 --  generate normal image tables for the enumeration types, which are needed
  41 --  for diagnostic and informational messages. At run-time we really do not
  42 --  want to waste the space for these image tables, and they are not needed,
  43 --  so we can do the instantiation under control of Discard_Names to remove
  44 --  the tables.
  45
  46 generic
  47 package System.Rident is
  48
  49    --  The following enumeration type defines the set of restriction
  50    --  identifiers that are implemented in GNAT.
  51
  52    --  To add a new restriction identifier, add an entry with the name
  53    --  to be used in the pragma, and add appropriate calls to the
  54    --  Restrict.Check_Restriction routine.
  55
  56    type Restriction_Id is
  57
  58       --  The following cases are checked for consistency in the binder
  59
  60      (Simple_Barriers,                         -- GNAT (Ravenscar)
  61       No_Abort_Statements,                     -- (RM D.7(5), H.4(3))
  62       No_Access_Subprograms,                   -- (RM H.4(17))
  63       No_Allocators,                           -- (RM H.4(7))
  64       No_Asynchronous_Control,                 -- (RM D.7(10))
  65       No_Calendar,                             -- GNAT
  66       No_Delay,                                -- (RM H.4(21))
  67       No_Direct_Boolean_Operators,             -- GNAT
  68       No_Dispatch,                             -- (RM H.4(19))
  69       No_Dispatching_Calls,                    -- GNAT
  70       No_Dynamic_Attachment,                   -- GNAT
  71       No_Dynamic_Priorities,                   -- (RM D.9(9))
  72       No_Enumeration_Maps,                     -- GNAT
  73       No_Entry_Calls_In_Elaboration_Code,      -- GNAT
  74       No_Entry_Queue,                          -- GNAT (Ravenscar)
  75       No_Exception_Handlers,                   -- GNAT
  76       No_Exception_Registration,               -- GNAT
  77       No_Exceptions,                           -- (RM H.4(12))
  78       No_Finalization,                         -- GNAT
  79       No_Fixed_Point,                          -- (RM H.4(15))
  80       No_Floating_Point,                       -- (RM H.4(14))
  81       No_IO,                                   -- (RM H.4(20))
  82       No_Implicit_Conditionals,                -- GNAT
  83       No_Implicit_Dynamic_Code,                -- GNAT
  84       No_Implicit_Heap_Allocations,            -- (RM D.8(8), H.4(3))
  85       No_Implicit_Loops,                       -- GNAT
  86       No_Initialize_Scalars,                   -- GNAT
  87       No_Local_Allocators,                     -- (RM H.4(8))
  88       No_Local_Protected_Objects,              -- GNAT
  89       No_Nested_Finalization,                  -- (RM D.7(4))
  90       No_Protected_Type_Allocators,            -- GNAT
  91       No_Protected_Types,                      -- (RM H.4(5))
  92       No_Recursion,                            -- (RM H.4(22))
  93       No_Reentrancy,                           -- (RM H.4(23))
  94       No_Relative_Delay,                       -- GNAT (Ravenscar)
  95       No_Requeue_Statements,                   -- GNAT
  96       No_Secondary_Stack,                      -- GNAT
  97       No_Select_Statements,                    -- GNAT (Ravenscar)
  98       No_Standard_Storage_Pools,               -- GNAT
  99       No_Streams,                              -- GNAT
 100       No_Task_Allocators,                      -- (RM D.7(7))
 101       No_Task_Attributes_Package,              -- GNAT
 102       No_Task_Hierarchy,                       -- (RM D.7(3), H.4(3))
 103       No_Task_Termination,                     -- GNAT (Ravenscar)
 104       No_Tasking,                              -- GNAT
 105       No_Terminate_Alternatives,               -- (RM D.7(6))
 106       No_Unchecked_Access,                     -- (RM H.4(18))
 107       No_Unchecked_Conversion,                 -- (RM H.4(16))
 108       No_Unchecked_Deallocation,               -- (RM H.4(9))
 109       Static_Priorities,                       -- GNAT
 110       Static_Storage_Size,                     -- GNAT
 111
 112       --  The following cases do not require partition-wide checks
 113
 114       Immediate_Reclamation,                   -- (RM H.4(10))
 115       No_Implementation_Attributes,            -- Ada 2005 AI-257
 116       No_Implementation_Pragmas,               -- Ada 2005 AI-257
 117       No_Implementation_Restrictions,          -- GNAT
 118       No_Elaboration_Code,                     -- GNAT
 119       No_Obsolescent_Features,                 -- Ada 2005 AI-368
 120       No_Wide_Characters,                      -- GNAT
 121
 122       --  The following cases require a parameter value
 123
 124       --  The following entries are fully checked at compile/bind time,
 125       --  which means that the compiler can in general tell the minimum
 126       --  value which could be used with a restrictions pragma. The binder
 127       --  can deduce the appropriate minimum value for the partition by
 128       --  taking the maximum value required by any unit.
 129
 130       Max_Protected_Entries,                   -- (RM D.7(14))
 131       Max_Select_Alternatives,                 -- (RM D.7(12))
 132       Max_Task_Entries,                        -- (RM D.7(13), H.4(3))
 133
 134       --  The following entries are also fully checked at compile/bind
 135       --  time, and the compiler can also at least in some cases tell
 136       --  the minimum value which could be used with a restriction pragma.
 137       --  The difference is that the contributions are additive, so the
 138       --  binder deduces this value by adding the unit contributions.
 139
 140       Max_Tasks,                               -- (RM D.7(19), H.4(3))
 141
 142       --  The following entries are checked at compile time only for
 143       --  zero/nonzero entries. This means that the compiler can tell
 144       --  at compile time if a restriction value of zero is (would be)
 145       --  violated, but that is all. The compiler cannot distinguish
 146       --  between different non-zero values.
 147
 148       Max_Asynchronous_Select_Nesting,         -- (RM D.7(18), H.4(3))
 149       Max_Entry_Queue_Length,                  -- GNAT
 150
 151       --  The remaining entries are not checked at compile/bind time
 152
 153       Max_Storage_At_Blocking,                 -- (RM D.7(17))
 154
 155       Not_A_Restriction_Id);
 156
 157    --  Synonyms permitted for historical purposes of compatibility.
 158    --  Must be coordinated with Restrict.Process_Restriction_Synonym.
 159
 160    Boolean_Entry_Barriers : Restriction_Id renames Simple_Barriers;
 161    Max_Entry_Queue_Depth  : Restriction_Id renames Max_Entry_Queue_Length;
 162    No_Dynamic_Interrupts  : Restriction_Id renames No_Dynamic_Attachment;
 163    No_Requeue             : Restriction_Id renames No_Requeue_Statements;
 164    No_Task_Attributes     : Restriction_Id renames No_Task_Attributes_Package;
 165
 166    subtype All_Restrictions is Restriction_Id range
 167      Simple_Barriers .. Max_Storage_At_Blocking;
 168    --  All restrictions (excluding only Not_A_Restriction_Id)
 169
 170    subtype All_Boolean_Restrictions is Restriction_Id range
 171      Simple_Barriers .. No_Wide_Characters;
 172    --  All restrictions which do not take a parameter
 173
 174    subtype Partition_Boolean_Restrictions is All_Boolean_Restrictions range
 175      Simple_Barriers .. Static_Storage_Size;
 176    --  Boolean restrictions that are checked for partition consistency.
 177    --  Note that all parameter restrictions are checked for partition
 178    --  consistency by default, so this distinction is only needed in the
 179    --  case of Boolean restrictions.
 180
 181    subtype Cunit_Boolean_Restrictions is All_Boolean_Restrictions range
 182      Immediate_Reclamation .. No_Wide_Characters;
 183    --  Boolean restrictions that are not checked for partition consistency
 184    --  and that thus apply only to the current unit. Note that for these
 185    --  restrictions, the compiler does not apply restrictions found in
 186    --  with'ed units, parent specs etc to the main unit.
 187
 188    subtype All_Parameter_Restrictions is
 189      Restriction_Id range
 190        Max_Protected_Entries .. Max_Storage_At_Blocking;
 191    --  All restrictions that are take a parameter
 192
 193    subtype Checked_Parameter_Restrictions is
 194      All_Parameter_Restrictions range
 195        Max_Protected_Entries .. Max_Entry_Queue_Length;
 196    --  These are the parameter restrictions that can be at least partially
 197    --  checked at compile/binder time. Minimally, the compiler can detect
 198    --  violations of a restriction pragma with a value of zero reliably.
 199
 200    subtype Checked_Max_Parameter_Restrictions is
 201      Checked_Parameter_Restrictions range
 202        Max_Protected_Entries .. Max_Task_Entries;
 203    --  Restrictions with parameters that can be checked in some cases by
 204    --  maximizing among statically detected instances where the compiler
 205    --  can determine the count.
 206
 207    subtype Checked_Add_Parameter_Restrictions is
 208      Checked_Parameter_Restrictions range
 209        Max_Tasks .. Max_Tasks;
 210    --  Restrictions with parameters that can be checked in some cases by
 211    --  summing the statically detected instances where the compiler can
 212    --  determine the count.
 213
 214    subtype Checked_Val_Parameter_Restrictions is
 215      Checked_Parameter_Restrictions range
 216        Max_Protected_Entries .. Max_Tasks;
 217    --  Restrictions with parameter where the count is known at least in
 218    --  some cases by the compiler/binder.
 219
 220    subtype Checked_Zero_Parameter_Restrictions is
 221      Checked_Parameter_Restrictions range
 222        Max_Asynchronous_Select_Nesting .. Max_Entry_Queue_Length;
 223    --  Restrictions with parameters where the compiler can detect the use of
 224    --  the feature, and hence violations of a restriction specifying a value
 225    --  of zero, but cannot detect specific values other than zero/nonzero.
 226
 227    subtype Unchecked_Parameter_Restrictions is
 228      All_Parameter_Restrictions range
 229        Max_Storage_At_Blocking .. Max_Storage_At_Blocking;
 230    --  Restrictions with parameters where the compiler cannot ever detect
 231    --  corresponding compile time usage, so the binder and compiler never
 232    --  detect violations of any restriction.
 233
 234    -------------------------------------
 235    -- Restriction Status Declarations --
 236    -------------------------------------
 237
 238    --  The following declarations are used to record the current status
 239    --  or restrictions (for the current unit, or related units, at compile
 240    --  time, and for all units in a partition at bind time or run time).
 241
 242    type Restriction_Flags  is array (All_Restrictions)           of Boolean;
 243    type Restriction_Values is array (All_Parameter_Restrictions) of Natural;
 244    type Parameter_Flags    is array (All_Parameter_Restrictions) of Boolean;
 245
 246    type Restrictions_Info is record
 247       Set : Restriction_Flags := (others => False);
 248       --  An entry is True in the Set array if a restrictions pragma has
 249       --  been encountered for the given restriction. If the value is
 250       --  True for a parameter restriction, then the corresponding entry
 251       --  in the Value array gives the minimum value encountered for any
 252       --  such restriction.
 253
 254       Value : Restriction_Values;
 255       --  If the entry for a parameter restriction in Set is True (i.e. a
 256       --  restrictions pragma for the restriction has been encountered), then
 257       --  the corresponding entry in the Value array is the minimum value
 258       --  specified by any such restrictions pragma. Note that a restrictions
 259       --  pragma specifying a value greater than Int'Last is simply ignored.
 260
 261       Violated : Restriction_Flags := (others => False);
 262       --  An entry is True in the violations array if the compiler has
 263       --  detected a violation of the restriction. For a parameter
 264       --  restriction, the Count and Unknown arrays have additional
 265       --  information.
 266
 267       Count : Restriction_Values := (others => 0);
 268       --  If an entry for a parameter restriction is True in Violated,
 269       --  the corresponding entry in the Count array may record additional
 270       --  information. If the actual minimum count is known (by taking
 271       --  maximums, or sums, depending on the restriction), it will be
 272       --  recorded in this array. If not, then the value will remain zero.
 273
 274       Unknown : Parameter_Flags := (others => False);
 275       --  If an entry for a parameter restriction is True in Violated,
 276       --  the corresponding entry in the Unknown array may record additional
 277       --  information. If the actual count is not known by the compiler (but
 278       --  is known to be non-zero), then the entry in Unknown will be True.
 279       --  This indicates that the value in Count is not known to be exact,
 280       --  and the actual violation count may be higher.
 281
 282       --  Note: If Violated (K) is True, then either Count (K) > 0 or
 283       --  Unknown (K) = True. It is possible for both these to be set.
 284       --  For example, if Count (K) = 3 and Unknown (K) is True, it means
 285       --  that the actual violation count is at least 3 but might be higher.
 286    end record;
 287
 288    ----------------------------------
 289    -- Profile Definitions and Data --
 290    ----------------------------------
 291
 292    type Profile_Name is (Ravenscar, Restricted);
 293    --  Names of recognized pfofiles
 294
 295    type Profile_Data is record
 296       Set : Restriction_Flags;
 297       --  Set to True if given restriction must be set for the profile,
 298       --  and False if it need not be set (False does not mean that it
 299       --  must not be set, just that it need not be set). If the flag
 300       --  is True for a parameter restriction, then the Value array
 301       --  gives the maximum value permitted by the profile.
 302
 303       Value : Restriction_Values;
 304       --  An entry in this array is meaningful only if the corresponding
 305       --  flag in Set is True. In that case, the value in this array is
 306       --  the maximum value of the parameter permitted by the profile.
 307    end record;
 308
 309    Profile_Info : array (Profile_Name) of Profile_Data :=
 310
 311                      --  Restricted Profile
 312
 313                     (Restricted =>
 314
 315                         --  Restrictions for Restricted profile
 316
 317                        (Set   =>
 318                           (No_Abort_Statements             => True,
 319                            No_Asynchronous_Control         => True,
 320                            No_Dynamic_Attachment           => True,
 321                            No_Dynamic_Priorities           => True,
 322                            No_Entry_Queue                  => True,
 323                            No_Local_Protected_Objects      => True,
 324                            No_Protected_Type_Allocators    => True,
 325                            No_Requeue_Statements           => True,
 326                            No_Task_Allocators              => True,
 327                            No_Task_Attributes_Package      => True,
 328                            No_Task_Hierarchy               => True,
 329                            No_Terminate_Alternatives       => True,
 330                            Max_Asynchronous_Select_Nesting => True,
 331                            Max_Protected_Entries           => True,
 332                            Max_Select_Alternatives         => True,
 333                            Max_Task_Entries                => True,
 334                            others                          => False),
 335
 336                         --  Value settings for Restricted profile
 337
 338                         Value =>
 339                           (Max_Asynchronous_Select_Nesting => 0,
 340                            Max_Protected_Entries           => 1,
 341                            Max_Select_Alternatives         => 0,
 342                            Max_Task_Entries                => 0,
 343                            others                          => 0)),
 344
 345                      --  Ravenscar Profile
 346
 347                      --  Note: the table entries here only represent the
 348                      --  required restriction profile for Ravenscar. The
 349                      --  full Ravenscar profile also requires:
 350
 351                      --    pragma Dispatching_Policy (FIFO_Within_Priorities);
 352                      --    pragma Locking_Policy (Ceiling_Locking);
 353                      --    pragma Detect_Blocking
 354
 355                      Ravenscar  =>
 356
 357                      --  Restrictions for Ravenscar = Restricted profile ..
 358
 359                        (Set   =>
 360                           (No_Abort_Statements             => True,
 361                            No_Asynchronous_Control         => True,
 362                            No_Dynamic_Attachment           => True,
 363                            No_Dynamic_Priorities           => True,
 364                            No_Entry_Queue                  => True,
 365                            No_Local_Protected_Objects      => True,
 366                            No_Protected_Type_Allocators    => True,
 367                            No_Requeue_Statements           => True,
 368                            No_Task_Allocators              => True,
 369                            No_Task_Attributes_Package      => True,
 370                            No_Task_Hierarchy               => True,
 371                            No_Terminate_Alternatives       => True,
 372                            Max_Asynchronous_Select_Nesting => True,
 373                            Max_Protected_Entries           => True,
 374                            Max_Select_Alternatives         => True,
 375                            Max_Task_Entries                => True,
 376
 377                            --  plus these additional restrictions:
 378
 379                            No_Calendar                     => True,
 380                            No_Implicit_Heap_Allocations    => True,
 381                            No_Relative_Delay               => True,
 382                            No_Select_Statements            => True,
 383                            No_Task_Termination             => True,
 384                            Simple_Barriers                 => True,
 385                            others                          => False),
 386
 387                         --  Value settings for Ravenscar (same as Restricted)
 388
 389                         Value =>
 390                           (Max_Asynchronous_Select_Nesting => 0,
 391                            Max_Protected_Entries           => 1,
 392                            Max_Select_Alternatives         => 0,
 393                            Max_Task_Entries                => 0,
 394                            others                          => 0)));
 395
 396 end System.Rident;