gcc/ada/a-cihase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --               I N D E F I N I T E _ H A S H E D _ S E T S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Hash_Tables;
  38 with Ada.Streams;
  39 with Ada.Finalization;
  40
  41 generic
  42    type Element_Type (<>) is private;
  43
  44    with function Hash (Element : Element_Type) return Hash_Type;
  45
  46    with function Equivalent_Elements (Left, Right : Element_Type)
  47                                      return Boolean;
  48
  49    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  50
  51 package Ada.Containers.Indefinite_Hashed_Sets is
  52    pragma Preelaborate;
  53
  54    type Set is tagged private;
  55
  56    type Cursor is private;
  57
  58    Empty_Set : constant Set;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Set) return Boolean;
  63
  64    function Equivalent_Sets (Left, Right : Set) return Boolean;
  65
  66    function To_Set (New_Item : Element_Type) return Set;
  67
  68    function Capacity (Container : Set) return Count_Type;
  69
  70    procedure Reserve_Capacity
  71      (Container : in out Set;
  72       Capacity  : Count_Type);
  73
  74    function Length (Container : Set) return Count_Type;
  75
  76    function Is_Empty (Container : Set) return Boolean;
  77
  78    procedure Clear (Container : in out Set);
  79
  80    function Element (Position : Cursor) return Element_Type;
  81
  82    procedure Replace_Element
  83      (Container : in out Set;
  84       Position  : Cursor;
  85       New_Item  : Element_Type);
  86
  87    procedure Query_Element
  88      (Position : Cursor;
  89       Process  : not null access procedure (Element : Element_Type));
  90
  91    procedure Move
  92      (Target : in out Set;
  93       Source : in out Set);
  94
  95    procedure Insert
  96      (Container : in out Set;
  97       New_Item  : Element_Type;
  98       Position  : out Cursor;
  99       Inserted  : out Boolean);
 100
 101    procedure Insert  (Container : in out Set; New_Item : Element_Type);
 102
 103    procedure Include (Container : in out Set; New_Item : Element_Type);
 104
 105    procedure Replace (Container : in out Set; New_Item : Element_Type);
 106
 107    procedure Exclude (Container : in out Set; Item : Element_Type);
 108
 109    procedure Delete  (Container : in out Set; Item : Element_Type);
 110
 111    procedure Delete (Container : in out Set; Position  : in out Cursor);
 112
 113    procedure Union (Target : in out Set; Source : Set);
 114
 115    function Union (Left, Right : Set) return Set;
 116
 117    function "or" (Left, Right : Set) return Set renames Union;
 118
 119    procedure Intersection (Target : in out Set; Source : Set);
 120
 121    function Intersection (Left, Right : Set) return Set;
 122
 123    function "and" (Left, Right : Set) return Set renames Intersection;
 124
 125    procedure Difference (Target : in out Set; Source : Set);
 126
 127    function Difference (Left, Right : Set) return Set;
 128
 129    function "-" (Left, Right : Set) return Set renames Difference;
 130
 131    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 132
 133    function Symmetric_Difference (Left, Right : Set) return Set;
 134
 135    function "xor" (Left, Right : Set) return Set
 136      renames Symmetric_Difference;
 137
 138    function Overlap (Left, Right : Set) return Boolean;
 139
 140    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 141
 142    function First (Container : Set) return Cursor;
 143
 144    function Next (Position : Cursor) return Cursor;
 145
 146    procedure Next (Position : in out Cursor);
 147
 148    function Find (Container : Set; Item : Element_Type) return Cursor;
 149
 150    function Contains (Container : Set; Item : Element_Type) return Boolean;
 151
 152    function Has_Element (Position : Cursor) return Boolean;
 153
 154    function Equivalent_Elements (Left, Right : Cursor) return Boolean;
 155
 156    function Equivalent_Elements
 157      (Left  : Cursor;
 158       Right : Element_Type) return Boolean;
 159
 160    function Equivalent_Elements
 161      (Left  : Element_Type;
 162       Right : Cursor) return Boolean;
 163
 164    procedure Iterate
 165      (Container : Set;
 166       Process   : not null access procedure (Position : Cursor));
 167
 168    generic
 169       type Key_Type (<>) is private;
 170
 171       with function Key (Element : Element_Type) return Key_Type;
 172
 173       with function Hash (Key : Key_Type) return Hash_Type;
 174
 175       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 176
 177    package Generic_Keys is
 178
 179       function Key (Position : Cursor) return Key_Type;
 180
 181       function Element (Container : Set; Key : Key_Type) return Element_Type;
 182
 183       procedure Replace
 184         (Container : in out Set;
 185          Key       : Key_Type;
 186          New_Item  : Element_Type);
 187
 188       procedure Exclude (Container : in out Set; Key : Key_Type);
 189
 190       procedure Delete (Container : in out Set; Key : Key_Type);
 191
 192       function Find (Container : Set; Key : Key_Type) return Cursor;
 193
 194       function Contains (Container : Set; Key : Key_Type) return Boolean;
 195
 196       procedure Update_Element_Preserving_Key
 197         (Container : in out Set;
 198          Position  : Cursor;
 199          Process   : not null access
 200                        procedure (Element : in out Element_Type));
 201
 202    end Generic_Keys;
 203
 204 private
 205    type Node_Type;
 206    type Node_Access is access Node_Type;
 207
 208    type Element_Access is access Element_Type;
 209
 210    type Node_Type is
 211       limited record
 212          Element : Element_Access;
 213          Next    : Node_Access;
 214       end record;
 215
 216    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 217      (Node_Type,
 218       Node_Access);
 219
 220    type Set is new Ada.Finalization.Controlled with record
 221       HT : HT_Types.Hash_Table_Type;
 222    end record;
 223
 224    procedure Adjust (Container : in out Set);
 225
 226    procedure Finalize (Container : in out Set);
 227
 228    use HT_Types;
 229    use Ada.Finalization;
 230    use Ada.Streams;
 231
 232    type Set_Access is access all Set;
 233    for Set_Access'Storage_Size use 0;
 234
 235    type Cursor is
 236       record
 237          Container : Set_Access;
 238          Node      : Node_Access;
 239       end record;
 240
 241    procedure Write
 242      (Stream : access Root_Stream_Type'Class;
 243       Item   : Cursor);
 244
 245    for Cursor'Write use Write;
 246
 247    procedure Read
 248      (Stream : access Root_Stream_Type'Class;
 249       Item   : out Cursor);
 250
 251    for Cursor'Read use Read;
 252
 253    No_Element : constant Cursor :=
 254                   (Container => null,
 255                    Node      => null);
 256
 257    procedure Write
 258      (Stream    : access Root_Stream_Type'Class;
 259       Container : Set);
 260
 261    for Set'Write use Write;
 262
 263    procedure Read
 264      (Stream    : access Root_Stream_Type'Class;
 265       Container : out Set);
 266
 267    for Set'Read use Read;
 268
 269    Empty_Set : constant Set := (Controlled with HT => (null, 0, 0, 0));
 270
 271 end Ada.Containers.Indefinite_Hashed_Sets;