gcc/ada/sem_ch8.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 8                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2019, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Types; use Types;
  27 package Sem_Ch8 is
  28
  29    -----------------------------------
  30    -- Handling extensions of System --
  31    -----------------------------------
  32
  33    --  For targets that define a much larger System package than given in
  34    --  the RM, we use a child package containing additional declarations,
  35    --  which is loaded when needed, and whose entities are conceptually
  36    --  within System itself. The presence of this auxiliary package is
  37    --  controlled with the pragma Extend_System. The following variable
  38    --  holds the entity of the auxiliary package, to simplify the special
  39    --  visibility rules that apply to it.
  40
  41    System_Aux_Id : Entity_Id := Empty;
  42
  43    -----------------
  44    -- Subprograms --
  45    -----------------
  46
  47    procedure Analyze_Exception_Renaming         (N : Node_Id);
  48    procedure Analyze_Expanded_Name              (N : Node_Id);
  49    procedure Analyze_Generic_Function_Renaming  (N : Node_Id);
  50    procedure Analyze_Generic_Package_Renaming   (N : Node_Id);
  51    procedure Analyze_Generic_Procedure_Renaming (N : Node_Id);
  52    procedure Analyze_Object_Renaming            (N : Node_Id);
  53    procedure Analyze_Package_Renaming           (N : Node_Id);
  54    procedure Analyze_Subprogram_Renaming        (N : Node_Id);
  55
  56    procedure Analyze_Use_Package (N : Node_Id; Chain : Boolean := True);
  57    --  Analyze a use package clause and control (through the Chain parameter)
  58    --  whether to add N to the use clause chain for the name denoted within
  59    --  use clause N in case we are reanalyzing a use clause because of stack
  60    --  manipulation.
  61
  62    procedure Analyze_Use_Type (N : Node_Id; Chain : Boolean := True);
  63    --  Similar to Analyze_Use_Package except the Chain parameter applies to the
  64    --  type within N's subtype mark Current_Use_Clause.
  65
  66    procedure End_Scope;
  67    --  Called at end of scope. On exit from blocks and bodies (subprogram,
  68    --  package, task, and protected bodies), the name of the current scope
  69    --  must be removed from the scope stack, and the local entities must be
  70    --  removed from their homonym chains. On exit from record declarations,
  71    --  from package specifications, and from tasks and protected type
  72    --  specifications, more specialized procedures are invoked.
  73
  74    procedure End_Use_Clauses (Clause : Node_Id);
  75    --  Invoked on scope exit, to undo the effect of local use clauses. Clause
  76    --  is the first use-clause of a scope being exited. This can be the current
  77    --  scope, or some enclosing scopes when building a clean environment to
  78    --  compile an instance body for inlining.
  79
  80    procedure End_Use_Package (N : Node_Id);
  81    procedure End_Use_Type    (N : Node_Id);
  82    --  Subsidiaries of End_Use_Clauses. Also called directly for use clauses
  83    --  appearing in context clauses.
  84
  85    procedure Find_Direct_Name
  86      (N            : Node_Id;
  87       Errors_OK    : Boolean := True;
  88       Marker_OK    : Boolean := True;
  89       Reference_OK : Boolean := True);
  90    --  Given a direct name (Identifier or Operator_Symbol), this routine scans
  91    --  the homonym chain for the name, searching for corresponding visible
  92    --  entities to find the referenced entity (or in the case of overloading,
  93    --  one candidate interpretation). On return, the Entity and Etype fields
  94    --  are set. In the non-overloaded case, these are the correct entries.
  95    --  In the overloaded case, the flag Is_Overloaded is set, Etype and Entity
  96    --  refer to an arbitrary element of the overloads set, and the appropriate
  97    --  entries have been added to the overloads table entry for the node. The
  98    --  overloading will be disambiguated during type resolution.
  99    --
 100    --  Note, when this is called during semantic analysis in the overloaded
 101    --  case, the entity set will be the most recently declared homonym. In
 102    --  particular, the caller may follow the homonym chain checking for all
 103    --  entries in the current scope, and that will give all homonyms that are
 104    --  declared before the point of call in the current scope. This is useful
 105    --  for example in the processing for pragma Inline.
 106    --
 107    --  Flag Errors_OK should be set when error diagnostics are desired. Flag
 108    --  Marker_OK should be set when a N_Variable_Reference_Marker needs to be
 109    --  generated for a SPARK object in order to detect elaboration issues. Flag
 110    --  Reference_OK should be set when N must generate a cross reference.
 111
 112    procedure Find_Selected_Component (N : Node_Id);
 113    --  Resolve various cases of selected components, recognize expanded names
 114
 115    procedure Find_Type (N : Node_Id);
 116    --  Perform name resolution, and verify that the name found is that of a
 117    --  type. On return the Entity and Etype fields of the node N are set
 118    --  appropriately. If it is an incomplete type whose full declaration has
 119    --  been seen, they are set to the entity in the full declaration. If it
 120    --  is an incomplete type associated with an interface visible through a
 121    --  limited-with clause, whose full declaration has been seen, they are
 122    --  set to the entity in the full declaration. Similarly, if the type is
 123    --  private, it has received a full declaration, and we are in the private
 124    --  part or body of the package, then the two fields are set to the entity
 125    --  of the full declaration as well. This procedure also has special
 126    --  processing for 'Class attribute references.
 127
 128    function Has_Loop_In_Inner_Open_Scopes (S : Entity_Id) return Boolean;
 129    --  S is the entity of an open scope. This function determines if there is
 130    --  an inner scope of S which is a loop (i.e. it appears somewhere in the
 131    --  scope stack after S).
 132
 133    function In_Open_Scopes (S : Entity_Id) return Boolean;
 134    --  S is the entity of a scope. This function determines if this scope is
 135    --  currently open (i.e. it appears somewhere in the scope stack).
 136
 137    procedure Initialize;
 138    --  Initializes data structures used for visibility analysis. Must be
 139    --  called before analyzing each new main source program.
 140
 141    procedure Install_Use_Clauses
 142      (Clause             : Node_Id;
 143       Force_Installation : Boolean := False);
 144    --  Applies the use clauses appearing in a given declarative part,
 145    --  when the corresponding scope has been placed back on the scope
 146    --  stack after unstacking to compile a different context (subunit or
 147    --  parent of generic body). Force_Installation is used when called from
 148    --  Analyze_Subunit.Re_Install_Use_Clauses to insure that, after the
 149    --  analysis of the subunit, the parent's environment is again identical.
 150
 151    procedure Mark_Use_Clauses (Id : Node_Or_Entity_Id);
 152    --  Mark a given entity or node Id's relevant use clauses as effective,
 153    --  including redundant ones and ones outside of the current scope.
 154
 155    procedure Push_Scope (S : Entity_Id);
 156    --  Make new scope stack entry, pushing S, the entity for a scope onto the
 157    --  top of the scope table. The current setting of the scope suppress flags
 158    --  is saved for restoration on exit.
 159
 160    procedure Pop_Scope;
 161    --  Remove top entry from scope stack, restoring the saved setting of the
 162    --  scope suppress flags.
 163
 164    function Present_System_Aux (N : Node_Id := Empty) return Boolean;
 165    --  Return True if the auxiliary system file has been successfully loaded.
 166    --  Otherwise attempt to load it, using the name supplied by a previous
 167    --  Extend_System pragma, and report on the success of the load. If N is
 168    --  present, it is a selected component whose prefix is System, or else a
 169    --  with-clause on system. N is absent when the function is called to find
 170    --  the visibility of implicit operators.
 171
 172    function Save_Scope_Stack
 173      (Handle_Use : Boolean := True) return Elist_Id;
 174    procedure Restore_Scope_Stack
 175      (List       : Elist_Id;
 176       Handle_Use : Boolean := True);
 177    --  These two subprograms are called from Semantics, when a unit U1 is to
 178    --  be compiled in the course of the compilation of another unit U2. This
 179    --  happens whenever Rtsfind is called. U1, the unit retrieved by Rtsfind,
 180    --  must be compiled in its own context, and the current scope stack
 181    --  containing U2 and local scopes must be made unreachable. This is
 182    --  achieved using a call to Save_Scope_Stack. On return, the contents
 183    --  of the scope stack must be made accessible again with a call to
 184    --  Restore_Scope_Stack.
 185    --
 186    --  The flag Handle_Use indicates whether local use clauses must be removed
 187    --  or installed. In the case of inlining of instance bodies, the visibility
 188    --  handling is done fully in Inline_Instance_Body, and use clauses are
 189    --  handled there. Save_Scope_Stack returns the list of entities which have
 190    --  been temporarily removed from visibility; that list must be passed to
 191    --  Restore_Scope_Stack to restore their visibility.
 192
 193    procedure Set_Use (L : List_Id);
 194    --  Find use clauses that are declarative items in a package declaration
 195    --  and set the potentially use-visible flags of imported entities before
 196    --  analyzing the corresponding package body.
 197
 198    procedure Update_Use_Clause_Chain;
 199    --  Called at the end of a declarative region to detect unused use type
 200    --  clauses and maintain the Current_Use_Clause for type entities.
 201
 202    procedure ws;
 203    --  Debugging routine for use in gdb: dump all entities on scope stack
 204
 205    procedure we (S : Entity_Id);
 206    --  Debugging routine for use in gdb: dump all entities in given scope
 207
 208 end Sem_Ch8;