libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${with_multisrctop}../"
  26   else
  27     libffi_basedir="${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir=
  31 fi
  32 AC_SUBST(libffi_basedir)
  33 AC_CONFIG_AUX_DIR(${libffi_basedir}..)
  34
  35 AC_CANONICAL_HOST
  36
  37 AM_PROG_LIBTOOL
  38
  39 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  40
  41 AC_EXEEXT
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_CC
  45 AC_PROG_LIBTOOL
  46
  47 TARGETDIR="unknown"
  48 case "$host" in
  49 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  50 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  55 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  58 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  61 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  62 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  63 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  64 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  65 mips64*-*);;
  66 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  67 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  68 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  69 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  70 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  71 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  72 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  73 arm*-*-netbsdelf*) TARGET=ARM; TARGETDIR=arm;;
  74 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  75 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  76 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  77 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  78 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  79 esac
  80
  81 if test $TARGETDIR = unknown; then
  82   AC_ERROR("libffi has not been ported to $host.")
  83 fi
  84
  85 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  86 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  87 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  88 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  89 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  90 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  91 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  92 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  93 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  94 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  95 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  96 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  97 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  98 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  99 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 100 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 101 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 102
 103 if test x$TARGET = xMIPS_LINUX; then
 104   TARGET=MIPS
 105 fi
 106
 107 AC_HEADER_STDC
 108 AC_CHECK_FUNCS(memcpy)
 109 AC_FUNC_ALLOCA
 110
 111 dnl AC_CHECK_SIZEOF(char)
 112 AC_COMPILE_CHECK_SIZEOF(short)
 113 AC_COMPILE_CHECK_SIZEOF(int)
 114 AC_COMPILE_CHECK_SIZEOF(long)
 115 AC_COMPILE_CHECK_SIZEOF(long long)
 116 AC_COMPILE_CHECK_SIZEOF(float)
 117 AC_COMPILE_CHECK_SIZEOF(double)
 118 AC_COMPILE_CHECK_SIZEOF(long double)
 119
 120 AC_COMPILE_CHECK_SIZEOF(void *)
 121 AC_C_BIGENDIAN_CROSS
 122
 123 if test x$TARGET = xSPARC; then
 124     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 125         libffi_cv_as_sparc_ua_pcrel, [
 126         save_CFLAGS="$CFLAGS"
 127         save_LDFLAGS="$LDFLAGS"
 128         CFLAGS="$CFLAGS -fpic"
 129         LDFLAGS="$LDFLAGS -shared"
 130         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 131                     [libffi_cv_as_sparc_ua_pcrel=yes],
 132                     [libffi_cv_as_sparc_ua_pcrel=no])
 133         CFLAGS="$save_CFLAGS"
 134         LDFLAGS="$save_LDFLAGS"])
 135     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 136         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 137                   [Define if your assembler and linker support unaligned PC relative relocs.])
 138     fi
 139
 140     AC_CACHE_CHECK([assembler .register pseudo-op support],
 141        libffi_cv_as_register_pseudo_op, [
 142        libffi_cv_as_register_pseudo_op=unknown
 143        # Check if we have .register
 144        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 145                        [libffi_cv_as_register_pseudo_op=yes],
 146                        [libffi_cv_as_register_pseudo_op=no])
 147     ])
 148     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 149        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 150                [Define if your assembler supports .register.])
 151     fi
 152 fi
 153
 154 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 155     libffi_cv_ro_eh_frame, [
 156         libffi_cv_ro_eh_frame=no
 157         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 158         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 159             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 160                 libffi_cv_ro_eh_frame=yes
 161             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 162                  | grep -v '#write' > /dev/null; then
 163                 libffi_cv_ro_eh_frame=yes
 164             fi
 165         fi
 166         rm -f conftest.*
 167     ])
 168 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 169     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 170               [Define if .eh_frame sections should be read-only.])
 171 fi
 172
 173 AC_SUBST(TARGET)
 174 AC_SUBST(TARGETDIR)
 175
 176 AC_SUBST(SHELL)
 177
 178 AC_ARG_ENABLE(debug,
 179 [  --enable-debug          debugging mode],
 180   if test "$enable_debug" = "yes"; then
 181     AC_DEFINE(FFI_DEBUG)
 182   fi)
 183
 184 AC_ARG_ENABLE(structs,
 185 [  --disable-structs       omit code for struct support],
 186   if test "$enable_structs" = "no"; then
 187     AC_DEFINE(FFI_NO_STRUCTS)
 188   fi)
 189
 190 AC_ARG_ENABLE(raw-api,
 191 [  --disable-raw-api       make the raw api unavailable],
 192   if test "$enable_raw_api" = "no"; then
 193     AC_DEFINE(FFI_NO_RAW_API)
 194   fi)
 195
 196 AC_ARG_ENABLE(purify-safety,
 197 [  --enable-purify-safety  purify-safe mode],
 198   if test "$enable_purify_safety" = "yes"; then
 199     AC_DEFINE(USING_PURIFY)
 200   fi)
 201
 202 if test -n "$with_cross_host" &&
 203    test x"$with_cross_host" != x"no"; then
 204   toolexecdir='$(exec_prefix)/$(target_alias)'
 205   toolexeclibdir='$(toolexecdir)/lib'
 206 else
 207   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 208   toolexeclibdir='$(libdir)'
 209 fi
 210 multi_os_directory=`$CC -print-multi-os-directory`
 211 case $multi_os_directory in
 212   .) ;; # Avoid trailing /.
 213   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 214 esac
 215 AC_SUBST(toolexecdir)
 216 AC_SUBST(toolexeclibdir)
 217
 218 if test "${multilib}" = "yes"; then
 219   multilib_arg="--enable-multilib"
 220 else
 221   multilib_arg=
 222 fi
 223
 224 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
 225 [
 226 if test -n "$CONFIG_FILES"; then
 227    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 228    ac_file=Makefile . ${srcdir}/${libffi_basedir}../config-ml.in
 229 fi
 230 ],
 231 srcdir=${srcdir}
 232 host=${host}
 233 target=${target}
 234 with_multisubdir=${with_multisubdir}
 235 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 236 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 237 libffi_basedir=${libffi_basedir}
 238 CC="${CC}"
 239 DEFS="$DEFS"
 240 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 241 test ! -d include && mkdir include
 242 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 243 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 244         echo fficonfig.h unchanged
 245 else
 246         echo Moving fficonfig.h to include/fficonfig.h
 247         cp fficonfig.h include/fficonfig.h
 248 fi
 249 )
 250
 251 # Make target subdirectories if required.
 252 test -d src || mkdir src
 253 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}