libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   2005, 2006, 2009 Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 3, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.64)
  23 AC_INIT(package-unused, version-unused,, libobjc)
  24 AC_CONFIG_SRCDIR([objc/objc.h])
  25 GCC_TOPLEV_SUBDIRS
  26
  27 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  28 PACKAGE=libobjc
  29 # Version is pulled out to make it a bit easier to change using sed.
  30 VERSION=3:0:0
  31 AC_SUBST(VERSION)
  32
  33 # This works around the fact that libtool configuration may change LD
  34 # for this particular configuration, but some shells, instead of
  35 # keeping the changes in LD private, export them just because LD is
  36 # exported.
  37 ORIGINAL_LD_FOR_MULTILIBS=$LD
  38
  39 # -------
  40 # Options
  41 # -------
  42
  43 # We use these options to decide which functions to include.
  44 AC_ARG_WITH(target-subdir,
  45 [  --with-target-subdir=SUBDIR
  46                            configuring in a subdirectory])
  47 AC_ARG_WITH(cross-host,
  48 [  --with-cross-host=HOST  configuring with a cross compiler])
  49
  50 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  51 AC_ARG_ENABLE(version-specific-runtime-libs,
  52 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  53 [case "$enableval" in
  54  yes) version_specific_libs=yes ;;
  55  no)  version_specific_libs=no ;;
  56  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  57  esac],
  58 [version_specific_libs=no])
  59 AC_MSG_RESULT($version_specific_libs)
  60
  61 AC_ARG_ENABLE(objc-gc,
  62 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  63                           the GNU Objective-C runtime.],
  64 [case $enable_objc_gc in
  65   no)
  66     OBJC_BOEHM_GC=''
  67     OBJC_BOEHM_GC_INCLUDES=''
  68     ;;
  69   *)
  70     OBJC_BOEHM_GC=libobjc_gc.la
  71     OBJC_BOEHM_GC_INCLUDES='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
  72     ;;
  73 esac],
  74 [OBJC_BOEHM_GC=''; OBJC_BOEHM_GC_INCLUDES=''])
  75 AC_SUBST(OBJC_BOEHM_GC)
  76 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
  77
  78 # -----------
  79 # Directories
  80 # -----------
  81
  82 # Find the rest of the source tree framework.
  83 AM_ENABLE_MULTILIB(, ..)
  84
  85 AC_CANONICAL_SYSTEM
  86 ACX_NONCANONICAL_TARGET
  87
  88 # Export source directory.
  89 # These need to be absolute paths, yet at the same time need to
  90 # canonicalize only relative paths, because then amd will not unmount
  91 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  92 case $srcdir in
  93   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  94   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95 esac
  96 AC_SUBST(glibcpp_srcdir)
  97
  98 # Calculate toolexeclibdir
  99 # Also toolexecdir, though it's only used in toolexeclibdir
 100 case ${version_specific_libs} in
 101   yes)
 102     # Need the gcc compiler version to know where to install libraries
 103     # and header files if --enable-version-specific-runtime-libs option
 104     # is selected.
 105     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 106     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 107     ;;
 108   no)
 109     if test -n "$with_cross_host" &&
 110        test x"$with_cross_host" != x"no"; then
 111       # Install a library built with a cross compiler in tooldir, not libdir.
 112       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 113       toolexeclibdir='$(toolexecdir)/lib'
 114     else
 115       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 116       toolexeclibdir='$(libdir)'
 117     fi
 118     multi_os_directory=`$CC -print-multi-os-directory`
 119     case $multi_os_directory in
 120       .) ;; # Avoid trailing /.
 121       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 122     esac
 123     ;;
 124 esac
 125 AC_SUBST(toolexecdir)
 126 AC_SUBST(toolexeclibdir)
 127
 128 # Figure out if we want to name the include directory and the
 129 #  library name changes differently.
 130 includedirname=include
 131 libsuffix=
 132 case "${host}" in
 133   *-darwin*)
 134     # Darwin is the only target so far that needs a different include directory.
 135     includedirname=include-gnu-runtime
 136     libsuffix=-gnu
 137     ;;
 138 esac
 139 AC_SUBST(includedirname)
 140 AC_SUBST(libsuffix)
 141
 142 AC_CONFIG_HEADERS(config.h)
 143
 144 # --------
 145 # Programs
 146 # --------
 147
 148 GCC_NO_EXECUTABLES
 149
 150 # We must force CC to /not/ be a precious variable; otherwise
 151 # the wrong, non-multilib-adjusted value will be used in multilibs.
 152 # As a side effect, we have to subst CFLAGS ourselves.
 153 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 154 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 155 AC_PROG_CC
 156 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 157
 158 # extra LD Flags which are required for targets
 159 ACX_LT_HOST_FLAGS
 160 case "${host}" in
 161   *-darwin*)
 162     # Darwin needs -single_module when linking libobjc
 163     extra_ldflags_libobjc='$(lt_host_flags) -Wl,-single_module'
 164     ;;
 165   *-cygwin*|*-mingw*)
 166     # Tell libtool to build DLLs on Windows
 167     extra_ldflags_libobjc='$(lt_host_flags)'
 168     ;;
 169 esac
 170 AC_SUBST(extra_ldflags_libobjc)
 171
 172 AC_SUBST(CFLAGS)
 173
 174 AC_CHECK_TOOL(AS, as)
 175 AC_CHECK_TOOL(AR, ar)
 176 AC_CHECK_TOOL(RANLIB, ranlib, :)
 177 AC_PROG_INSTALL
 178
 179 AM_MAINTAINER_MODE
 180
 181 # Enable Win32 DLL on MS Windows - FIXME
 182 AC_LIBTOOL_WIN32_DLL
 183
 184 AC_PROG_LIBTOOL
 185
 186 AM_PROG_CC_C_O
 187
 188 AC_PROG_MAKE_SET
 189
 190 # -------
 191 # Headers
 192 # -------
 193
 194 # Sanity check for the cross-compilation case:
 195 AC_CHECK_HEADER(stdio.h,:,
 196   [AC_MSG_ERROR([Can't find stdio.h.
 197 You must have a usable C system for the target already installed, at least
 198 including headers and, preferably, the library, before you can configure
 199 the Objective C runtime system.  If necessary, install gcc now with
 200 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 201
 202 AC_HEADER_STDC
 203
 204 AC_CHECK_HEADERS(sched.h)
 205
 206 # -----------
 207 # Miscellanea
 208 # -----------
 209
 210 AC_MSG_CHECKING([for thread model used by GCC])
 211 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 212 AC_MSG_RESULT([$target_thread_file])
 213
 214 if test $target_thread_file != single; then
 215   AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
 216         [Define if the compiler has a thread header that is non single.])
 217 fi
 218
 219 # Check if we have thread-local storage
 220 GCC_CHECK_TLS
 221
 222 AC_MSG_CHECKING([for exception model to use])
 223 AC_LANG_PUSH(C)
 224 AC_ARG_ENABLE(sjlj-exceptions,
 225   AS_HELP_STRING([--enable-sjlj-exceptions],
 226                  [force use of builtin_setjmp for exceptions]),
 227 [:],
 228 [dnl Botheration.  Now we've got to detect the exception model.
 229 dnl Link tests against libgcc.a are problematic since -- at least
 230 dnl as of this writing -- we've not been given proper -L bits for
 231 dnl single-tree newlib and libgloss.
 232 dnl
 233 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 234 dnl conftest files before we got a change to grep them first.
 235 cat > conftest.$ac_ext << EOF
 236 [#]line __oline__ "configure"
 237 @interface Frob
 238 @end
 239 @implementation Frob
 240 @end
 241 int proc();
 242 int foo()
 243 {
 244   @try {
 245    return proc();
 246   }
 247   @catch (Frob* ex) {
 248     return 0;
 249   }
 250 }
 251 EOF
 252 old_CFLAGS="$CFLAGS"
 253 dnl work around that we don't have Objective-C support in autoconf
 254 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 255 if AC_TRY_EVAL(ac_compile); then
 256   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 257     enable_sjlj_exceptions=yes
 258   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 259     enable_sjlj_exceptions=no
 260   fi
 261 fi
 262 CFLAGS="$old_CFLAGS"
 263 rm -f conftest*])
 264 if test x$enable_sjlj_exceptions = xyes; then
 265   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 266         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 267   ac_exception_model_name=sjlj
 268 elif test x$enable_sjlj_exceptions = xno; then
 269   ac_exception_model_name="call frame"
 270 else
 271   AC_MSG_ERROR([unable to detect exception model])
 272 fi
 273 AC_LANG_POP(C)
 274 AC_MSG_RESULT($ac_exception_model_name)
 275
 276 # ------
 277 # Output
 278 # ------
 279
 280 if test ${multilib} = yes; then
 281   multilib_arg="--enable-multilib"
 282 else
 283   multilib_arg=
 284 fi
 285
 286 AC_CONFIG_FILES([Makefile])
 287 AC_OUTPUT