libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar >/dev/null 2>&1
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 # for windows native targets enforce export of all symbols for shared libgcj.
 218 libgcj_ld_export_all=
 219 case "$host" in
 220       *mingw*)
 221         libgcj_ld_export_all=-Wl,--export-all-symbols
 222         ;;
 223       *)
 224         ;;
 225 esac
 226
 227 LIBGCJ_CFLAGS="${libgcj_cflags}"
 228 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 229 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 230 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 231 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 232 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 233 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 234 LIBGCJ_LD_EXPORT_ALL="${libgcj_ld_export_all}"
 235 AC_SUBST(LIBGCJ_CFLAGS)
 236 AC_SUBST(LIBGCJ_CXXFLAGS)
 237 AC_SUBST(LIBGCJ_JAVAFLAGS)
 238 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 239 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 240 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 241 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 242 AC_SUBST(LIBGCJ_LD_EXPORT_ALL)
 243
 244 # Only use libltdl for non-newlib builds.
 245 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 246    AC_LTDL_SHLIBPATH
 247 fi
 248
 249 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 250
 251 # Possibly build libgcj as many sub-libraries.
 252 AC_ARG_ENABLE(libgcj-sublibs,
 253   AS_HELP_STRING([--enable-libgcj-sublibs],
 254                  [build libgcj as many sub-libraries]))
 255
 256 if test -z "$enable_libgcj_sublibs"; then
 257    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 258 fi
 259 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 260 if test "$enable_libgcj_sublibs" = yes ; then
 261   # In theory we could make do with only one override and simply
 262   # tag "_bc" onto the end of it when we use it to generate the
 263   # spec, but that's an ugly thing to do when there are multiple
 264   # words in the string and you're relying on the ordering to
 265   # append the correct one.
 266   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 267   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 268 fi
 269
 270
 271 # See if the user has requested runtime debugging.
 272 LIBGCJDEBUG="disable"
 273 AC_SUBST(LIBGCJDEBUG)
 274 AC_ARG_ENABLE(libgcj-debug,
 275   AS_HELP_STRING([--enable-libgcj-debug],
 276                  [enable runtime debugging code]),
 277   [if test "$enable_libgcj_debug" = yes; then
 278     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 279     LIBGCJDEBUG="enable"
 280   fi])
 281
 282 AC_ARG_WITH([escher],
 283          AS_HELP_STRING([--with-escher=ABS.PATH],
 284                         [specify path to escher dir or JAR for X peers]))
 285 case "$with_escher" in
 286 "")
 287         use_escher=false
 288         ;;
 289 "no")
 290         use_escher=false
 291         ;;
 292 "yes")
 293         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 294         ;;
 295 *)
 296         use_escher=true
 297         ;;
 298 esac
 299
 300 # Determine which AWT peer libraries to build
 301 AC_ARG_ENABLE(java-awt,
 302   AS_HELP_STRING([--enable-java-awt],
 303                  [list of AWT peer implementations to be built]))
 304
 305 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 306 use_xlib_awt=""
 307 use_gtk_awt=""
 308 use_qt_awt=""
 309 use_x_awt=""
 310 # The default toolkit to use is the first one specified.
 311 TOOLKIT=
 312 AC_SUBST(TOOLKIT)
 313
 314 for peer in $peerlibs ; do
 315   case $peer in
 316     xlib)
 317       if test "$no_x" = yes; then
 318         echo "*** xlib peers requested but no X library available" 1>&2
 319         exit 1
 320       else
 321         use_xlib_awt="yes"
 322         if test -z "$TOOLKIT"; then
 323            TOOLKIT=gnu.awt.xlib.XToolkit
 324         fi
 325       fi
 326       ;;
 327     gtk)
 328       if test "$no_x" = yes; then
 329          echo "*** gtk peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_gtk_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 335          fi
 336       fi
 337       ;;
 338     qt)
 339       if test "$no_x" = yes; then
 340          # Perhaps we should admit the possibility of embedded Qt.
 341          echo "*** Qt peers requested but no X library available" 1>&2
 342          exit 1
 343       else
 344          use_qt_awt=yes
 345          if test -z "$TOOLKIT"; then
 346             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 347          fi
 348       fi
 349       ;;
 350     x)
 351       use_x_awt=yes
 352       if test -z "$TOOLKIT"; then
 353          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 354       fi
 355       ;;
 356     no)
 357       use_xlib_awt=
 358       use_gtk_awt=
 359       use_qt_awt=
 360       use_x_awt=
 361       break
 362       ;;
 363     *)
 364       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 365       exit 1
 366   esac
 367 done
 368
 369 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 370 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 371
 372 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 373
 374 expanded_prefix=$prefix
 375 if test "X$prefix" = XNONE; then
 376   expanded_prefix=${ac_default_prefix}
 377 fi
 378
 379 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 380
 381 # Create standard.omit based on decisions we just made.
 382 cp $srcdir/standard.omit.in standard.omit
 383 if test "$use_xlib_awt" != yes; then
 384    echo gnu/awt/xlib >> standard.omit
 385    echo gnu/gcj/xlib >> standard.omit
 386 fi
 387 if test "$use_x_awt" != yes; then
 388    echo gnu/java/awt/peer/x >> standard.omit
 389 fi
 390
 391 # Tools that need to be compiled against classpath's tools classes
 392 : > vm-tools-packages
 393 for package in gnu/gcj/tools/gc_analyze ; do
 394     echo $package >> standard.omit
 395     echo $package >> vm-tools-packages
 396 done
 397
 398 if test -z "${with_multisubdir}"; then
 399    builddotdot=.
 400 else
 401    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 402 fi
 403
 404 NATIVE=yes
 405
 406 # Which gcj and host gcj (for ecjx) do we use?
 407 which_gcj=default
 408 host_exeext=${ac_exeext}
 409 GCJ_FOR_ECJX='$(GCJ)'
 410 GCC_FOR_ECJX='$(CXX)'
 411 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 412 if test -n "${with_cross_host}"; then
 413   # We are being configured with a cross compiler. We can't
 414   # use ac_exeext, because that is for the target platform.
 415   NATIVE=no
 416   cross_host_exeext=
 417   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 418   GCC_FOR_ECJX="${with_cross_host}-gcc"
 419   case "${with_cross_host}" in
 420      *mingw* | *cygwin*)
 421          cross_host_exeext=.exe
 422      ;;
 423   esac
 424   host_exeext=${cross_host_exeext}
 425   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 426      if test x"$build_noncanonical" = x"$with_cross_host"; then
 427         # Ordinary cross (host!=target and host=build)
 428         which_gcj=built
 429      else
 430         # Canadian cross (host!=target and host!=build)
 431         which_gcj=cross
 432      fi
 433   else
 434      which_gcj=cross
 435   fi
 436 else
 437   # We are being configured with a native or crossed-native compiler
 438   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 439      if test x"$build" = x"$host"; then
 440         # True native build (host=target and host=build)
 441         which_gcj=built
 442      else
 443         # Crossed-native build (host=target and host!=build)
 444         which_gcj=cross
 445      fi
 446   else
 447      which_gcj=path
 448   fi
 449 fi
 450 libgcjdir=`${PWDCMD-pwd}`
 451 case $GCJ in
 452 *" -B"*)
 453   # Just in case there is a comma in the build dir, quote it for the
 454   # sed command below.
 455   case $libgcjdir in
 456   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 457   *) qlibgcjdir=$libgcjdir;;
 458   esac
 459   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 460   ;;
 461 *)
 462   GCJ=$GCJ" -B$libgcjdir/"
 463   ;;
 464 esac
 465 case "${which_gcj}" in
 466    built)
 467       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 468    ;;
 469    cross)
 470       if test "x${with_newlib}" = "xyes"; then
 471          # FIXME (comment): Why is this needed?
 472          LIBGCC_UNWIND_INCLUDE=
 473       fi
 474       GCJH='$(target_noncanonical)-gcjh'
 475    ;;
 476    path)
 477       GCJH=gcjh
 478    ;;
 479 esac
 480 JAVAC="$GCJ -C"
 481 export JAVAC
 482
 483 AC_SUBST(GCJ_FOR_ECJX)
 484 AC_SUBST(GCC_FOR_ECJX)
 485 AC_SUBST(GCJH)
 486 AC_SUBST(host_exeext)
 487
 488 # Create it, so that compile/link tests don't fail
 489 test -f libgcj.spec || touch libgcj.spec
 490
 491
 492
 493 # Set up to configure Classpath.
 494 # FIXME: no supported way to pass args in autoconf.
 495 # Disable tool wrappers to avoid ltdl.h configure check.
 496 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 497 ac_configure_args="$ac_configure_args --disable-load-library"
 498 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 499 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 500 dir1=`cd $srcdir && pwd`
 501 dir2=`pwd`
 502 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 503 ac_configure_args="$ac_configure_args --disable-core-jni"
 504 dnl FIXME?
 505 ac_configure_args="$ac_configure_args --disable-examples"
 506 ac_configure_args="$ac_configure_args --with-glibj=build"
 507 if test "$browser_plugin_enabled" != yes; then
 508   ac_configure_args="$ac_configure_args --disable-plugin"
 509 else
 510   ac_configure_args="$ac_configure_args --enable-plugin"
 511 fi
 512 if test "$gconf_enabled" != yes; then
 513   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 514   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 515 fi
 516 if test "$use_gtk_awt" != yes; then
 517   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 518 fi
 519 if test "$use_qt_awt" != yes; then
 520   ac_configure_args="$ac_configure_args --disable-qt-peer"
 521 else
 522   # We need this as qt is disabled by default in classpath.
 523   ac_configure_args="$ac_configure_args --enable-qt-peer"
 524 fi
 525 if test "$use_x_awt" != yes; then
 526   ac_configure_args="$ac_configure_args --without-escher"
 527 else
 528   # We need this as escher is disabled by default in classpath.
 529   if test "$use_escher" != true; then
 530     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 531   else
 532     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 533   fi
 534 fi
 535 if test "x$BUILD_GJDOC" = xno; then
 536   ac_configure_args="$ac_configure_args --disable-gjdoc"
 537 fi
 538 # -Werror causes unavoidable problems in code using alsa.
 539 ac_configure_args="$ac_configure_args --disable-regen-headers"
 540 ac_configure_args="$ac_configure_args --disable-Werror"
 541 dnl --with-gcj=$GCJ
 542 dnl --with-javah=$GCJH
 543 dnl gtk-cairo -- just export here...
 544 dnl --enable-regen-headers?
 545
 546 # Only use libltdl for non-newlib builds.
 547 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 548    AC_LIBLTDL_CONVENIENCE
 549    AC_LIBTOOL_DLOPEN
 550    DIRLTDL=libltdl
 551    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 552    # Sigh.  Libtool's macro doesn't do the right thing.
 553    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 554    # FIXME: this is a hack.
 555    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 556    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 557 fi
 558 AC_SUBST(INCLTDL)
 559 AC_SUBST(LIBLTDL)
 560 AC_SUBST(DIRLTDL)
 561 AC_PROG_LIBTOOL
 562 ACX_LT_HOST_FLAGS
 563 AM_PROG_GCJ
 564 AM_PROG_CC_C_O
 565
 566 AC_CONFIG_SUBDIRS(classpath libltdl)
 567
 568 # The -no-testsuite modules omit the test subdir.
 569 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 570
 571 # Should the runtime set system properties by examining the
 572 # environment variable GCJ_PROPERTIES?
 573 AC_ARG_ENABLE(getenv-properties,
 574   AS_HELP_STRING([--disable-getenv-properties],
 575                  [don't set system properties from GCJ_PROPERTIES]))
 576
 577 # Whether GCJ_PROPERTIES is used depends on the target.
 578 if test -z "$enable_getenv_properties"; then
 579    enable_getenv_properties=${enable_getenv_properties_default-yes}
 580 fi
 581 if test "$enable_getenv_properties" = no; then
 582    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 583      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 584 fi
 585
 586 # Whether we should use arguments to main()
 587 if test -z "$enable_main_args"; then
 588    enable_main_args=${enable_main_args_default-yes}
 589 fi
 590 if test "$enable_main_args" = no; then
 591    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 592 fi
 593
 594
 595 # Should we use hashtable-based synchronization?
 596 # Currently works only for Linux X86/ia64
 597 # Typically faster and more space-efficient
 598 AC_ARG_ENABLE(hash-synchronization,
 599   AS_HELP_STRING([--enable-hash-synchronization],
 600                  [use global hash table for monitor locks]))
 601
 602 if test -z "$enable_hash_synchronization"; then
 603    enable_hash_synchronization=$enable_hash_synchronization_default
 604 fi
 605
 606
 607 install_ecj_jar=no
 608 ECJ_BUILD_JAR=
 609 ECJ_JAR=
 610 AC_ARG_WITH(ecj-jar,
 611         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 612         [ECJ_JAR=$withval],
 613         [if test -f $multi_basedir/ecj.jar; then
 614            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 615            ECJ_JAR='$(jardir)/ecj.jar'
 616            install_ecj_jar=yes
 617          fi])
 618 AC_SUBST(ECJ_BUILD_JAR)
 619 AC_SUBST(ECJ_JAR)
 620 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 621 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 622
 623 AC_ARG_WITH(java-home,
 624   AS_HELP_STRING([--with-java-home=DIRECTORY],
 625                  [value of java.home system property]),
 626                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 627 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 628 AC_SUBST(JAVA_HOME)
 629
 630 suppress_libgcj_bc=no
 631 AC_ARG_ENABLE(libgcj-bc,
 632   AS_HELP_STRING([--enable-libgcj-bc],
 633                  [enable(default) or disable BC ABI for portions of libgcj]),
 634   [if test "$enable_libgcj_bc" = "no"; then
 635      suppress_libgcj_bc=yes
 636    fi])
 637 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 638
 639 build_libgcj_reduced_reflection=no
 640 AC_ARG_ENABLE(reduced-reflection,
 641   AS_HELP_STRING([--enable-reduced-reflection],
 642                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 643   [if test "$enable_reduced_reflection" = "yes"; then
 644      build_libgcj_reduced_reflection=yes
 645    fi])
 646 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 647
 648 # What is the native OS API for MinGW?
 649 AC_ARG_WITH(win32-nlsapi,
 650   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 651                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 652 [case "${withval}" in
 653   ansi) with_win32_nlsapi=ansi ;;
 654   unicows) with_win32_nlsapi=unicows ;;
 655   unicode) with_win32_nlsapi=unicode ;;
 656   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 657 esac],[with_win32_nlsapi=ansi])
 658
 659 case "${with_win32_nlsapi}" in
 660   unicows | unicode)
 661     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 662       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 663     ;;
 664 esac
 665
 666 # configure.host sets slow_pthread_self if the synchronization code should
 667 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 668 if test "${slow_pthread_self}" = "yes"; then
 669   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 670     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 671 fi
 672
 673 # Check for gc debugging.  This option is handled both here and in the GC.
 674 AC_ARG_ENABLE(gc-debug,
 675    AS_HELP_STRING([--enable-gc-debug],
 676                   [include full support for pointer backtracing etc.]),
 677 [ if test "$enable_gc_debug" = "yes"; then
 678     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 679               [Define if we want to use debug calls into the garbage collector.])
 680   fi])
 681
 682 # See if the user has the interpreter included.
 683 AC_ARG_ENABLE(interpreter,
 684   AS_HELP_STRING([--enable-interpreter],
 685                  [enable interpreter]),
 686   [if test "$enable_interpreter" = yes; then
 687     # This can also be set in configure.host.
 688     libgcj_interpreter=yes
 689   elif test "$enable_interpreter" = no; then
 690     libgcj_interpreter=no
 691   fi])
 692
 693 if test "$libgcj_interpreter" = yes; then
 694    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 695 fi
 696 INTERPRETER="$libgcj_interpreter"
 697 AC_SUBST(INTERPRETER)
 698 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 699
 700 AC_MSG_CHECKING([for exception model to use])
 701 AC_LANG_PUSH(C++)
 702 AC_ARG_ENABLE(sjlj-exceptions,
 703   AS_HELP_STRING([--enable-sjlj-exceptions],
 704                  [force use of builtin_setjmp for exceptions]),
 705 [:],
 706 [dnl Botheration.  Now we've got to detect the exception model.
 707 dnl Link tests against libgcc.a are problematic since -- at least
 708 dnl as of this writing -- we've not been given proper -L bits for
 709 dnl single-tree newlib and libgloss.
 710 dnl
 711 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 712 dnl conftest files before we got a change to grep them first.
 713 cat > conftest.$ac_ext << EOF
 714 [#]line __oline__ "configure"
 715 struct S { ~S(); };
 716 void bar();
 717 void foo()
 718 {
 719   S s;
 720   bar();
 721 }
 722 EOF
 723 old_CXXFLAGS="$CXXFLAGS"
 724 CXXFLAGS=-S
 725 if AC_TRY_EVAL(ac_compile); then
 726   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 727     enable_sjlj_exceptions=yes
 728   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 729     enable_sjlj_exceptions=no
 730   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 731     # ARM EH ABI.
 732     enable_sjlj_exceptions=no
 733   fi
 734 fi
 735 CXXFLAGS="$old_CXXFLAGS"
 736 rm -f conftest*])
 737 if test x$enable_sjlj_exceptions = xyes; then
 738   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 739         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 740   ac_exception_model_name=sjlj
 741 elif test x$enable_sjlj_exceptions = xno; then
 742   ac_exception_model_name="call frame"
 743 else
 744   AC_MSG_ERROR([unable to detect exception model])
 745 fi
 746 AC_LANG_POP(C++)
 747 AC_MSG_RESULT($ac_exception_model_name)
 748
 749 # If we are non using SJLJ exceptions, and this host does not have support
 750 # for unwinding from a signal handler, enable checked dereferences and divides.
 751 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 752   CHECKREFSPEC=-fcheck-references
 753   DIVIDESPEC=-fuse-divide-subroutine
 754   EXCEPTIONSPEC=
 755 fi
 756
 757 # See if the user wants to disable java.net.  This is the mildly
 758 # ugly way that we admit that target-side configuration sucks.
 759 AC_ARG_ENABLE(java-net,
 760   AS_HELP_STRING([--disable-java-net],
 761                  [disable java.net]))
 762
 763 # Whether java.net is built by default can depend on the target.
 764 if test -z "$enable_java_net"; then
 765    enable_java_net=${enable_java_net_default-yes}
 766 fi
 767 if test "$enable_java_net" = no; then
 768    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 769 fi
 770
 771 # See if the user wants to configure without libffi.  Some
 772 # architectures don't support it, and default values are set in
 773 # configure.host.
 774 AC_ARG_WITH(libffi,
 775   AS_HELP_STRING([--without-libffi],
 776                  [don't use libffi]),
 777   [:],
 778   [with_libffi=${with_libffi_default-yes}])
 779
 780 LIBFFI=
 781 LIBFFIINCS=
 782 if test "$with_libffi" != no; then
 783    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 784    LIBFFI=../libffi/libffi_convenience.la
 785    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 786 fi
 787 AC_SUBST(LIBFFI)
 788 AC_SUBST(LIBFFIINCS)
 789
 790 # See if the user wants to disable JVMPI support.
 791 AC_ARG_ENABLE(jvmpi,
 792   AS_HELP_STRING([--disable-jvmpi],
 793                  [disable JVMPI support]))
 794
 795 if test "$enable_jvmpi" != no; then
 796     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 797 fi
 798
 799 # If the target is an eCos system, use the appropriate eCos
 800 # I/O routines.
 801 # FIXME: this should not be a local option but a global target
 802 # system; at present there is no eCos target.
 803 TARGET_ECOS=${PROCESS-"no"}
 804 AC_ARG_WITH(ecos,
 805 [  --with-ecos             enable runtime eCos target support],
 806 TARGET_ECOS="$with_ecos"
 807 )
 808
 809 case "$TARGET_ECOS" in
 810    no) case "$host" in
 811       *mingw*)
 812             PLATFORM=Win32
 813             PLATFORMNET=Win32
 814             PLATFORMH=win32.h
 815         CHECK_FOR_BROKEN_MINGW_LD
 816       ;;
 817       *)
 818             PLATFORM=Posix
 819             PLATFORMNET=Posix
 820             PLATFORMH=posix.h
 821       ;;
 822       esac
 823       ;;
 824    *)
 825       PLATFORM=Ecos
 826       PLATFORMNET=NoNet
 827       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 828       PLATFORMH=posix.h
 829       ;;
 830 esac
 831 AC_SUBST(PLATFORM)
 832 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 833
 834 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 835                                       [Define if you have int32_t and uint32_t.]))
 836 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 837                                         [Define if you have int32_t and uint32_t.]))
 838 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 839                                           [Define if you have u_int32_t]))
 840 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 841                                            [Define if you have u_int32_t]))
 842
 843 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 844 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 845
 846 case "$host" in
 847   *-darwin*) DARWIN_CRT=true ;;
 848   *) DARWIN_CRT=false ;;
 849 esac
 850 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 851
 852 # This may not be defined in a non-ANS conformant embedded system.
 853 # FIXME: Should these case a runtime exception in that case?
 854 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 855                                   [Define is you have 'localtime' in <time.h>]))
 856
 857 # Create the subdirectory for natFile.cc, or the attempt
 858 # to create the link will fail.
 859 test -d java || mkdir java
 860 test -d java/io || mkdir java/io
 861 test -d gnu || mkdir gnu
 862 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 863
 864 # Likewise for natConcreteProcess.cc.
 865 test -d java/lang || mkdir java/lang
 866 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 867
 868 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 869 test -d java/net || mkdir java/net
 870 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 871 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 872
 873 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 874 test -d gnu/java || mkdir gnu/java
 875 test -d gnu/java/net || mkdir gnu/java/net
 876 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 877 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 878
 879 # Likewise for natVMPipe.cc and natVMSelector.cc.
 880 test -d gnu/java/nio || mkdir gnu/java/nio
 881 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 882 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 883
 884 # Likewise for natFileChannelImpl.cc
 885 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 886 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 887
 888 # Likewise for natVMSecureRandom.cc
 889 test -d gnu/java/security || mkdir gnu/java/security
 890 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 891 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 892 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 893
 894 case "${host}" in
 895     *mingw*)
 896       SYSTEMSPEC="-lgdi32 -lws2_32"
 897       if test "${with_win32_nlsapi}" = "unicows"; then
 898         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 899       fi
 900     ;;
 901     *-*-darwin9*)
 902       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 903     ;;
 904     *-*-darwin[[12]]*)
 905       # Something is incompatible with pie, would be nice to fix it and
 906       # remove -no_pie.  PR49461
 907       SYSTEMSPEC="-no_pie %{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 908     ;;
 909     *)
 910       SYSTEMSPEC=
 911     ;;
 912 esac
 913 AC_SUBST(SYSTEMSPEC)
 914
 915 AC_ARG_WITH(system-zlib,
 916   AS_HELP_STRING([--with-system-zlib],
 917                  [use installed libz]))
 918 ZLIBSPEC=
 919 AC_SUBST(ZLIBSPEC)
 920 ZLIBTESTSPEC=
 921 AC_SUBST(ZLIBTESTSPEC)
 922
 923 AC_PATH_XTRA
 924
 925 # FIXME: this should be _libs on some hosts.
 926 libsubdir=.libs
 927
 928 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 929
 930 LIBSTDCXXSPEC=
 931 # extra LD Flags which are required for targets
 932 case "${host}" in
 933 *-*-darwin[[0-7]].*)
 934     # For now we have to disable it on darwin[8-9] because it slows down
 935     # the linking phase. A possible bug in ld?
 936     # on Darwin -single_module speeds up loading of the dynamic libraries.
 937     extra_ldflags_libjava=-Wl,-single_module
 938     ;;
 939 arm*linux*eabi)
 940     # Some of the ARM unwinder code is actually in libstdc++.  We
 941     # could in principle replicate it in libgcj, but it's better to
 942     # have a dependency on libstdc++.
 943     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 944     LIBSTDCXXSPEC=-lstdc++
 945     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 946     ;;
 947 *-*-cygwin)
 948     extra_ldflags_libjava=-liconv
 949     ;;
 950 *-*-mingw*)
 951     extra_ldflags_libjava=-lws2_32
 952     ;;
 953 esac
 954
 955 LIBMATHSPEC=
 956 # extra LD Flags which are required for targets
 957 case "${host}" in
 958 *-*-darwin*)
 959      ;;
 960 *)
 961      LIBMATHSPEC=-lm
 962      ;;
 963 esac
 964
 965 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 966 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 967   [saved_ldflags="$LDFLAGS"
 968    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 969    # The IRIX 6 ld doesn't recognize --no-merge-exidx-entries, but only
 970    # warns about unknown options, which breaks the testsuite.  So enable
 971    # AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 972    # it off again.  As a workaround, save and restore werror flag like
 973    # AC_PATH_XTRA.
 974    ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 975    AC_LANG_WERROR
 976    AC_LINK_IFELSE([int main(void){ return 0;} ],
 977                       [eval "libgcj_cv_exidx=yes"],
 978                       [eval "libgcj_cv_exidx=no"])
 979    ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 980    LDFLAGS="${saved_ldflags}"]
 981 )
 982 if test "${libgcj_cv_exidx}" = "yes"; then
 983   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 984   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 985 fi
 986
 987 AC_SUBST(extra_ldflags_libjava)
 988 AC_SUBST(extra_ldflags)
 989 AC_SUBST(LIBSTDCXXSPEC)
 990 AC_SUBST(LIBMATHSPEC)
 991
 992 AC_SUBST(LIBGCJTESTSPEC)
 993
 994 # Allow the GC to be disabled.  Can be useful when debugging.
 995 AC_MSG_CHECKING([for garbage collector to use])
 996 AC_ARG_ENABLE(java-gc,
 997   AS_HELP_STRING([--enable-java-gc=TYPE],
 998                  [choose garbage collector (default is boehm)]),
 999   [GC=$enableval],
1000   [GC=boehm])
1001 GCLIBS=
1002 GCINCS=
1003 GCDEPS=
1004 GCSPEC=
1005 JC1GCSPEC=
1006 GCTESTSPEC=
1007 case "$GC" in
1008  boehm)
1009     AC_MSG_RESULT(boehm)
1010     GCLIBS=../boehm-gc/libgcjgc_convenience.la
1011     JC1GCSPEC='-fuse-boehm-gc'
1012     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
1013     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
1014     GCOBJS=boehm.lo
1015     GCHDR=boehm-gc.h
1016     # The POSIX thread support needs to know this.
1017     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
1018     ;;
1019  no)
1020     AC_MSG_RESULT(none)
1021     GCHDR=no-gc.h
1022     ;;
1023  *)
1024     AC_MSG_ERROR([unrecognized collector "$GC"])
1025     ;;
1026 esac
1027 AC_SUBST(GCLIBS)
1028 AC_SUBST(GCINCS)
1029 AC_SUBST(GCDEPS)
1030 AC_SUBST(GCSPEC)
1031 AC_SUBST(JC1GCSPEC)
1032 AC_SUBST(GCTESTSPEC)
1033 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1034 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1035 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1036
1037
1038 AC_MSG_CHECKING([for thread model used by GCC])
1039 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1040 AC_MSG_RESULT([$THREADS])
1041
1042 case "$THREADS" in
1043  no | none | single)
1044     THREADS=none
1045     ;;
1046  aix | posix | pthreads)
1047     THREADS=posix
1048     case "$host" in
1049      *-*-linux*)
1050         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1051         ;;
1052     esac
1053     ;;
1054  win32)
1055     ;;
1056  dce | vxworks)
1057     AC_MSG_ERROR(thread package $THREADS not yet supported)
1058     ;;
1059  *)
1060     AC_MSG_ERROR($THREADS is an unknown thread package)
1061     ;;
1062 esac
1063
1064 THREADCXXFLAGS=
1065 THREADLDFLAGS=
1066 THREADLIBS=
1067 THREADINCS=
1068 THREADDEPS=
1069 THREADH=
1070 THREADSPEC=
1071 THREADSTARTFILESPEC=
1072 case "$THREADS" in
1073  posix)
1074     case "$host" in
1075      *-*-cygwin*)
1076         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1077         ;;
1078      *-*-freebsd[[34]].*)
1079         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1080         # merely adds pthread_* functions) but it does have a -pthread switch
1081         # which is required at link-time to select -lc_r *instead* of -lc.
1082         THREADLDFLAGS=-pthread
1083         # Don't set THREADSPEC here as might be expected since -pthread is
1084         # not processed when found within a spec file, it must come from
1085         # the command line.  For now, the user must provide the -pthread
1086         # switch to link code compiled with gcj.  In future, consider adding
1087         # support for weak references to pthread_* functions ala gthr.h API.
1088         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1089         ;;
1090      *-*-freebsd*)
1091         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1092         # systems which support threads and -lpthread.
1093         THREADLDFLAGS=-pthread
1094         THREADSPEC=-lpthread
1095         ;;
1096      alpha*-dec-osf* | hppa*-hp-hpux*)
1097         THREADCXXFLAGS=-pthread
1098         # boehm-gc needs some functions from librt, so link that too.
1099         THREADLIBS='-lpthread -lrt'
1100         THREADSPEC='-lpthread -lrt'
1101         ;;
1102      *-*-solaris2.8)
1103         # Always use alternate thread library on Solaris 8.  Need libthread
1104         # for TLS support.
1105         # Need -Wl,-R to get it through libtool ...
1106         THREADLIBS='-L/usr/lib/lwp$(MULTISUBDIR) -Wl,-R -Wl,/usr/lib/lwp$(MULTISUBDIR) -lpthread -lthread'
1107         # ... while ld only accepts -R.
1108         THREADSPEC='-L/usr/lib/lwp%{m64:/64} -R/usr/lib/lwp%{m64:/64} -lpthread -lthread'
1109         ;;
1110      *-*-solaris2.9)
1111         # As on Solaris 8, need libthread for TLS support.
1112         THREADLIBS='-lpthread -lthread'
1113         THREADSPEC='-lpthread -lthread'
1114         ;;
1115      *-*-darwin*)
1116         # Don't set THREADLIBS or THREADSPEC as Darwin already
1117         # provides pthread via libSystem.
1118         ;;
1119      *)
1120         THREADLIBS=-lpthread
1121         THREADSPEC=-lpthread
1122         ;;
1123     esac
1124     THREADH=posix-threads.h
1125     # MIT pthreads doesn't seem to have the mutexattr functions.
1126     # But for now we don't check for it.  We just assume you aren't
1127     # using MIT pthreads.
1128     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1129
1130     # If we're using the Boehm GC, then we happen to know that it
1131     # defines _REENTRANT, so we don't bother.  Eww.
1132     if test "$GC" != boehm; then
1133        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1134     fi
1135     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1136     ;;
1137
1138  win32)
1139     THREADH=win32-threads.h
1140     THREADCXXFLAGS=-mthreads
1141     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1142     # But we do not want the executables created to be dependent on
1143     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1144     # exception handling contexts.  The following kludge achieves this effect
1145     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1146     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1147     # A workaround is to explicitly use -mthreads while linking Java programs.
1148     # See PR libgcj/28263.
1149     #
1150     # FIXME: In Java we are able to detect thread death at the end of
1151     # Thread.run() so we should be able to clean up the exception handling
1152     # contexts ourselves.
1153     THREADSTARTFILESPEC='crtmt%O%s'
1154     ;;
1155
1156  none)
1157     THREADH=no-threads.h
1158     ;;
1159 esac
1160 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1161 AC_SUBST(THREADLIBS)
1162 AC_SUBST(THREADINCS)
1163 AC_SUBST(THREADDEPS)
1164 AC_SUBST(THREADSPEC)
1165 AC_SUBST(THREADSTARTFILESPEC)
1166 AC_SUBST(THREADLDFLAGS)
1167 AC_SUBST(THREADCXXFLAGS)
1168 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1169 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1170 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1171 if test "$enable_shared" != yes; then
1172   use_libgcj_bc=no
1173 fi
1174 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1175
1176 if test -d sysdep; then true; else mkdir sysdep; fi
1177 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1178 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1179 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1180
1181 LIBGCJ_SPEC_LGCJ=-lgcj
1182 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1183 if test x"$libgcj_spec_lgcj_override" != x ; then
1184   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1185 fi
1186 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1187   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1188 fi
1189 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1190 if test "$use_libgcj_bc" = yes; then
1191   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1192   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1193 fi
1194 AC_SUBST(LIBGCJ_SPEC)
1195 AC_SUBST(LIBGCJ_BC_SPEC)
1196
1197 HASH_SYNC_SPEC=
1198 # Hash synchronization is only useful with posix threads right now.
1199 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1200    HASH_SYNC_SPEC=-fhash-synchronization
1201    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1202 fi
1203 AC_SUBST(HASH_SYNC_SPEC)
1204
1205 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1206
1207 # We're in the tree with libgcc, and need to include some of its headers.
1208 LIBGCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../libgcc'
1209
1210 if test "x${with_newlib}" = "xyes"; then
1211    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1212    # may not work correctly, because the compiler may not be able to
1213    # link executables.
1214
1215    # We assume newlib.  This lets us hard-code the functions we know
1216    # we'll have.
1217    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1218    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1219    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1220    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1221    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1222    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1223    # This is only for POSIX threads.
1224    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1225
1226    # Assume we do not have getuid and friends.
1227    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1228    PLATFORMNET=NoNet
1229 else
1230    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1231                    localtime_r getpwuid_r getcwd \
1232                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1233                    nl_langinfo setlocale \
1234                    inet_pton uname inet_ntoa \
1235                    getrlimit sigaction ftruncate mmap \
1236                    getifaddrs])
1237    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1238    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1239    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1240    AC_CHECK_LIB(dl, dladdr, [
1241        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1242        AC_CHECK_LIB(dld, dladdr, [
1243        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1244
1245    if test x"$cross_compiling" = x"no"; then
1246      AC_CHECK_FILES(/proc/self/exe, [
1247        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1248      AC_CHECK_FILES(/proc/self/maps, [
1249        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1250          [Define if you have /proc/self/maps])])
1251    else
1252      case $host in
1253      *-linux*)
1254        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1255        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1256        ;;
1257      esac
1258    fi
1259
1260    AM_ICONV
1261    AM_LC_MESSAGES
1262    AC_STRUCT_TIMEZONE
1263    LDLIBICONV=`echo " $LIBICONV " | sed "s/${acl_cv_wl--Wl,}/ /g; s/,/ /g"`
1264    AC_SUBST([LDLIBICONV])
1265
1266    AC_CHECK_FUNCS(gethostbyname_r, [
1267      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1268        [Define if you have the 'gethostbyname_r' function.])
1269      # There are two different kinds of gethostbyname_r.
1270      # We look for the one that returns `int'.
1271      # Hopefully this check is robust enough.
1272      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1273        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1274
1275      case " $GCINCS " in
1276      *" -D_REENTRANT "*) ;;
1277      *)
1278         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1279         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1280         [libjava_cv_gethostbyname_r_needs_reentrant],
1281         [ AC_LANG_PUSH(C++)
1282           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1283             [[gethostbyname_r("", 0, 0);]])],
1284             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1285                 CPPFLAGS_SAVE="$CPPFLAGS"
1286                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1287                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1288                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1289                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1290                 CPPFLAGS="$CPPFLAGS_SAVE"
1291           ])
1292           AC_LANG_POP(C++)
1293         ])
1294         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1295           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1296         fi
1297      ;;
1298      esac
1299
1300      AC_CACHE_CHECK([for struct hostent_data],
1301         [libjava_cv_struct_hostent_data], [dnl
1302         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1303 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1304 # define _REENTRANT 1
1305 #endif
1306 #include <netdb.h>]], [[struct hostent_data data;]])],
1307           [libjava_cv_struct_hostent_data=yes],
1308           [libjava_cv_struct_hostent_data=no])])
1309      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1310        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1311          [Define if struct hostent_data is defined in netdb.h])
1312      fi
1313    ])
1314
1315    # FIXME: libjava source code expects to find a prototype for
1316    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1317    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1318    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1319    # linkage check is enough, yet C++ code requires proper prototypes.)
1320    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1321    AC_CHECK_FUNCS(gethostbyaddr_r, [
1322      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1323        [Define if you have the 'gethostbyaddr_r' function.])
1324      # There are two different kinds of gethostbyaddr_r.
1325      # We look for the one that returns `int'.
1326      # Hopefully this check is robust enough.
1327      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1328        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1329          [Define if gethostbyaddr_r returns 'int'.])])])])
1330
1331    AC_CHECK_FUNCS(gethostname, [
1332      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1333        [Define if you have the 'gethostname' function.])
1334      AC_EGREP_HEADER(gethostname, unistd.h, [
1335        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1336          [Define if gethostname is declared in <unistd.h>.])])])
1337
1338    AC_CHECK_FUNCS(usleep, [
1339      AC_EGREP_HEADER(usleep, unistd.h, [
1340        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1341           [Define if usleep is declared in <unistd.h>.])])])
1342
1343    # Look for these functions in the thread library, but only bother
1344    # if using POSIX threads.
1345    if test "$THREADS" = posix; then
1346       save_LIBS="$LIBS"
1347       LIBS="$LIBS $THREADLIBS"
1348
1349       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1350       # Solaris 7 the name librt is preferred.
1351       AC_CHECK_FUNCS(sched_yield, , [
1352         AC_CHECK_LIB(rt, sched_yield, [
1353           AC_DEFINE(HAVE_SCHED_YIELD)
1354           THREADLIBS="$THREADLIBS -lrt"
1355           THREADSPEC="$THREADSPEC -lrt"], [
1356           AC_CHECK_LIB(posix4, sched_yield, [
1357             AC_DEFINE(HAVE_SCHED_YIELD)
1358             THREADLIBS="$THREADLIBS -lposix4"
1359             THREADSPEC="$THREADSPEC -lposix4"])])])
1360
1361       AC_CHECK_LIB(rt, clock_gettime, [
1362          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1363          case "$THREADSPEC" in
1364            *-lrt*) ;;
1365            *)
1366              THREADSPEC="$THREADSPEC -lrt"
1367              THREADLIBS="$THREADLIBS -lrt"
1368              ;;
1369          esac])
1370
1371       LIBS="$save_LIBS"
1372
1373       # We can save a little space at runtime if the mutex has m_count
1374       # or __m_count.  This is a nice hack for Linux.
1375       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1376           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1377         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1378              [Define if pthread_mutex_t has m_count member.]), [
1379         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1380             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1381           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1382             [Define if pthread_mutex_t has __m_count member.]))])
1383    fi
1384
1385    # We require a way to get the time.
1386    time_found=no
1387    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1388    if test "$time_found" = no; then
1389       AC_MSG_ERROR([no function found to get the time])
1390    fi
1391
1392    AC_CHECK_FUNCS(memmove)
1393
1394    # We require memcpy.
1395    memcpy_found=no
1396    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1397    if test "$memcpy_found" = no; then
1398       AC_MSG_ERROR([memcpy is required])
1399    fi
1400    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1401    AC_CHECK_LIB(dl, dlopen, [
1402        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1403        AC_CHECK_LIB(dld, dlopen, [
1404        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1405
1406    # Some library-finding code we stole from Tcl.
1407    #--------------------------------------------------------------------
1408    #    Check for the existence of the -lsocket and -lnsl libraries.
1409    #    The order here is important, so that they end up in the right
1410    #    order in the command line generated by make.  Here are some
1411    #    special considerations:
1412    #    1. Use "connect" and "accept" to check for -lsocket, and
1413    #       "gethostbyname" to check for -lnsl.
1414    #    2. Use each function name only once:  can't redo a check because
1415    #       autoconf caches the results of the last check and won't redo it.
1416    #    3. Use -lnsl and -lsocket only if they supply procedures that
1417    #       aren't already present in the normal libraries.  This is because
1418    #       IRIX 5.2 has libraries, but they aren't needed and they're
1419    #       bogus:  they goof up name resolution if used.
1420    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1421    #       To get around this problem, check for both libraries together
1422    #       if -lsocket doesn't work by itself.
1423    #--------------------------------------------------------------------
1424
1425    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1426     [gcj_cv_lib_sockets=
1427      gcj_checkBoth=0
1428      unset ac_cv_func_connect
1429      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1430      if test "$gcj_checkSocket" = 1; then
1431          unset ac_cv_func_connect
1432          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1433                       gcj_checkBoth=1)
1434      fi
1435      if test "$gcj_checkBoth" = 1; then
1436          gcj_oldLibs=$LIBS
1437          LIBS="$LIBS -lsocket -lnsl"
1438          unset ac_cv_func_accept
1439          AC_CHECK_FUNC(accept,
1440                        [gcj_checkNsl=0
1441                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1442          unset ac_cv_func_accept
1443          LIBS=$gcj_oldLibs
1444      fi
1445      unset ac_cv_func_gethostbyname
1446      gcj_oldLibs=$LIBS
1447      LIBS="$LIBS $gcj_cv_lib_sockets"
1448      AC_CHECK_FUNC(gethostbyname, ,
1449                    [AC_CHECK_LIB(nsl, main,
1450                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1451      unset ac_cv_func_gethostbyname
1452      LIBS=$gcj_oldLIBS
1453    ])
1454    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1455
1456    if test "$with_system_zlib" = yes; then
1457       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1458    fi
1459
1460    # Test for Gtk stuff, if asked for.
1461    if test "$use_gtk_awt" = yes; then
1462       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1463       AC_SUBST(GTK_CFLAGS)
1464       AC_SUBST(GTK_LIBS)
1465
1466       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1467       AC_SUBST(GLIB_CFLAGS)
1468       AC_SUBST(GLIB_LIBS)
1469
1470       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1471       AC_SUBST(LIBART_CFLAGS)
1472       AC_SUBST(LIBART_LIBS)
1473
1474       # We require the XTest Extension to support java.awt.Robot.
1475       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1476                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1477                    [${X_LIBS}])
1478    fi
1479
1480    # On Solaris, and maybe other architectures, the Boehm collector
1481    # requires -ldl.
1482    if test "$GC" = boehm; then
1483       case "${host}" in
1484           mips-sgi-irix6*)
1485             # While IRIX 6 has libdl for the O32 and N32 ABIs, the N64 one is
1486             # missing.  It's unnecessary anyway since dlopen lives in libc.
1487             ;;
1488           *-*-darwin*)
1489             ;;
1490           *)
1491             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1492             ;;
1493       esac
1494    fi
1495 fi
1496
1497 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1498 case $build in
1499     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1500     *)         CLASSPATH_SEPARATOR=':' ;;
1501 esac
1502 AC_SUBST(CLASSPATH_SEPARATOR)
1503
1504 # We must search the source tree for java.lang, since we still don't
1505 # have libgcj.jar nor java/lang/*.class
1506 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1507 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1508
1509 # Since some classes depend on this one, we need its source available
1510 # before we can do any GCJ compilation test :-(
1511 if test ! -f gnu/classpath/Configuration.java; then
1512   test -d gnu || mkdir gnu
1513   test -d gnu/classpath || mkdir gnu/classpath
1514   # Note that it is not crucial that all the values here be correct.
1515   sed -e "s,@prefix@,$expanded_prefix," \
1516       -e "s,@VERSION@,$VERSION," \
1517       -e "s,@LIBDEBUG@,false," \
1518       -e "s,@INIT_LOAD_LIBRARY@,false," \
1519       -e "s,@@,$LIBGCJDEBUG," \
1520       -e "s,@default_toolkit@,$TOOLKIT," \
1521       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1522       -e "s,@GTK_CAIRO_ENABLED@,false," \
1523       -e "s,@ECJ_JAR@,," \
1524       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1525         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1526         > gnu/classpath/Configuration.java
1527   # We do not want to redirect the output of the grep below to /dev/null,
1528   # but we add /dev/null to the input list so that grep will print the
1529   # filename of Configuration.java in case it finds any matches.
1530   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1531     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1532   fi
1533 fi
1534
1535 LT_AC_PROG_GCJ
1536
1537 # Now remove it.
1538 rm -f gnu/classpath/Configuration.java
1539
1540 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1541
1542 AC_CHECK_SIZEOF(void *)
1543
1544 AC_C_BIGENDIAN
1545
1546 ZLIBS=
1547 SYS_ZLIBS=
1548 ZINCS=
1549
1550 if test -z "$ZLIBSPEC"; then
1551    # Use zlib from the GCC tree.
1552    ZINCS='-I$(top_srcdir)/../zlib'
1553    ZLIBS=../zlib/libzgcj_convenience.la
1554 else
1555    # System's zlib.
1556    SYS_ZLIBS="$ZLIBSPEC"
1557 fi
1558 AC_SUBST(ZLIBS)
1559 AC_SUBST(SYS_ZLIBS)
1560 AC_SUBST(ZINCS)
1561 AC_SUBST(DIVIDESPEC)
1562 AC_SUBST(CHECKREFSPEC)
1563 AC_SUBST(EXCEPTIONSPEC)
1564 AC_SUBST(BACKTRACESPEC)
1565 AC_SUBST(IEEESPEC)
1566 AC_SUBST(ATOMICSPEC)
1567
1568 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1569 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1570 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1571 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1572 AC_SUBST(LIBGCC_UNWIND_INCLUDE)
1573
1574 # Process the option "--enable-version-specific-runtime-libs"
1575 # Calculate toolexeclibdir
1576 case ${version_specific_libs} in
1577   yes)
1578     # Need the gcc compiler version to know where to install libraries
1579     # and header files if --enable-version-specific-runtime-libs option
1580     # is selected.
1581     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1582     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1583     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1584     toolexeclibdir=$toolexecmainlibdir
1585     ;;
1586   no)
1587     if test -n "$with_cross_host" &&
1588        test x"$with_cross_host" != x"no"; then
1589       # Install a library built with a cross compiler in tooldir, not libdir.
1590       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1591       toolexecmainlibdir='$(toolexecdir)/lib'
1592     else
1593       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1594       toolexecmainlibdir='$(libdir)'
1595     fi
1596     multi_os_directory=`$CC -print-multi-os-directory`
1597     case $multi_os_directory in
1598       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1599       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1600     esac
1601     ;;
1602 esac
1603 AC_SUBST(toolexecdir)
1604 AC_SUBST(toolexecmainlibdir)
1605 AC_SUBST(toolexeclibdir)
1606
1607 # Determine gcj and libgcj version number.
1608 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1609 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1610 GCJVERSION=$gcjversion
1611 AC_SUBST(GCJVERSION)
1612 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1613
1614 # Determine where the standard .db file and GNU Classpath JNI
1615 # libraries are found.
1616 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1617 multi_os_directory=`$CC -print-multi-os-directory`
1618 case $multi_os_directory in
1619   .)
1620    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1621    ;;
1622   *)
1623    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1624    ;;
1625 esac
1626 AC_SUBST(dbexecdir)
1627 AC_SUBST(gcjsubdir)
1628
1629 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1630 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1631
1632 TL_AC_GXX_INCLUDE_DIR
1633
1634 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1635 # On that system, sys/ioctl.h will not include sys/filio.h unless
1636 # BSD_COMP is defined; just including sys/filio.h is simpler.
1637 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1638 # for now.  If you change this, you also must update natFile.cc.
1639 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1640                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1641                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1642                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1643                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1644
1645 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1646 AC_CHECK_HEADERS(net/if.h, [], [], [
1647 #ifdef HAVE_SYS_SOCKET_H
1648 #include <sys/socket.h>
1649 #endif
1650 ])
1651
1652 AC_CHECK_HEADERS(inttypes.h, [
1653     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1654     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1655 ])
1656
1657 AC_CHECK_TYPE([ssize_t], [int])
1658 AC_CHECK_TYPE([magic_t], [
1659     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1660 #ifdef HAVE_MAGIC_H
1661 #include <magic.h>
1662 #endif])
1663
1664 AC_MSG_CHECKING([for in_addr_t])
1665 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1666 #if STDC_HEADERS
1667 #include <stdlib.h>
1668 #include <stddef.h>
1669 #endif
1670 #if HAVE_NETINET_IN_H
1671 #include <netinet/in.h>
1672 #endif]], [[in_addr_t foo;]])],
1673   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1674      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1675    AC_MSG_RESULT(yes)],
1676   [AC_MSG_RESULT(no)])
1677
1678 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1679 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1680   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1681      [Define if struct ip_mreq is defined in netinet/in.h.])
1682    AC_MSG_RESULT(yes)],
1683   [AC_MSG_RESULT(no)])
1684
1685 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1686 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1687   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1688      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1689    AC_MSG_RESULT(yes)],
1690   [AC_MSG_RESULT(no)])
1691
1692 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1693 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1694   [AC_DEFINE(HAVE_INET6, 1,
1695      [Define if inet6 structures are defined in netinet/in.h.])
1696    AC_MSG_RESULT(yes)],
1697   [AC_MSG_RESULT(no)])
1698
1699 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1700 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1701 #include <sys/types.h>
1702 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1703   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1704    AC_MSG_RESULT(yes)],
1705   [AC_MSG_RESULT(no)])
1706
1707 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1708 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1709   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1710    AC_MSG_RESULT(yes)],
1711   [AC_MSG_RESULT(no)
1712    AC_MSG_CHECKING([for global timezone variable])
1713    dnl FIXME: we don't want a link check here because that won't work
1714    dnl when cross-compiling.  So instead we make an assumption that
1715    dnl the header file will mention timezone if it exists.
1716    dnl Don't find the win32 function timezone
1717    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1718      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1719       AC_MSG_RESULT(yes)],
1720      [AC_MSG_RESULT(no)
1721        AC_MSG_CHECKING([for global _timezone variable])
1722        dnl FIXME: As above, don't want link check
1723        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1724          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1725             [Define if your platform has the global _timezone variable.])
1726           AC_MSG_RESULT(yes)],
1727           [AC_MSG_RESULT(no)])])])
1728
1729 AC_CHECK_PROGS(PERL, perl, false)
1730
1731 SYSDEP_SOURCES=
1732 SIGNAL_HANDLER_AUX=
1733
1734 case "${host}" in
1735  alpha*-dec-osf* | mips-sgi-irix* | *-*-solaris2*)
1736     SIGNAL_HANDLER=include/posix-signal.h
1737     ;;
1738  i?86-*-linux*)
1739     SIGNAL_HANDLER=include/i386-signal.h
1740     SIGNAL_HANDLER_AUX=include/x86_64-signal.h
1741     ;;
1742 # ia64-*)
1743 #    SYSDEP_SOURCES=sysdep/ia64.c
1744 #    test -d sysdep || mkdir sysdep
1745 #    ;;
1746  hppa*-*-linux*)
1747     SIGNAL_HANDLER=include/pa-signal.h
1748     ;;
1749  hppa*-hp-hpux*)
1750     SIGNAL_HANDLER=include/hppa-signal.h
1751     ;;
1752  ia64-*-linux*)
1753     SIGNAL_HANDLER=include/dwarf2-signal.h
1754     ;;
1755  powerpc*-*-linux*)
1756     SIGNAL_HANDLER=include/powerpc-signal.h
1757     ;;
1758  alpha*-*-linux*)
1759     SIGNAL_HANDLER=include/dwarf2-signal.h
1760     ;;
1761  s390*-*-linux*)
1762     SIGNAL_HANDLER=include/s390-signal.h
1763     ;;
1764  x86_64*-*-linux*)
1765     SIGNAL_HANDLER=include/x86_64-signal.h
1766     SIGNAL_HANDLER_AUX=include/i386-signal.h
1767     ;;
1768  sparc*-*-linux*)
1769     SIGNAL_HANDLER=include/dwarf2-signal.h
1770     ;;
1771  sh*-*-linux*)
1772     SIGNAL_HANDLER=include/sh-signal.h
1773     ;;
1774  *mingw*)
1775     SIGNAL_HANDLER=include/win32-signal.h
1776     ;;
1777  mips*-*-linux*)
1778     SIGNAL_HANDLER=include/mips-signal.h
1779     ;;
1780  m68*-*-linux*)
1781     SIGNAL_HANDLER=include/dwarf2-signal.h
1782     ;;
1783  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1784     SIGNAL_HANDLER=include/darwin-signal.h
1785     ;;
1786  powerpc*-*-aix*)
1787     SIGNAL_HANDLER=include/aix-signal.h
1788     ;;
1789  *)
1790     SIGNAL_HANDLER=include/default-signal.h
1791     ;;
1792 esac
1793
1794 # If we're using sjlj exceptions, forget what we just learned.
1795 if test "$enable_sjlj_exceptions" = yes; then
1796    SIGNAL_HANDLER=include/default-signal.h
1797    SIGNAL_HANDLER_AUX=
1798 fi
1799
1800 AC_SUBST(SYSDEP_SOURCES)
1801
1802 if test -z "$SIGNAL_HANDLER_AUX"; then
1803   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1804 fi
1805
1806 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1807                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1808
1809 if test "${multilib}" = "yes"; then
1810   multilib_arg="--enable-multilib"
1811 else
1812   multilib_arg=
1813 fi
1814
1815 # See if we support thread-local storage.
1816 GCC_CHECK_TLS
1817
1818 # For _Unwind_GetIPInfo.
1819 GCC_CHECK_UNWIND_GETIPINFO
1820
1821 # See if linker supports anonymous version scripts.
1822 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1823   [libjava_cv_anon_version_script],
1824   [AC_ARG_ENABLE(symvers,
1825      AS_HELP_STRING([--disable-symvers],
1826                     [disable symbol versioning for libjava]),
1827        [case "$enableval" in
1828          yes) libjava_cv_anon_version_script=yes ;;
1829          no)  libjava_cv_anon_version_script=no ;;
1830          *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]);;
1831         esac],
1832        [libjava_cv_anon_version_script=yes]
1833    )
1834    if test x$libjava_cv_anon_version_script = xyes; then
1835      save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1836      CFLAGS="$CFLAGS -fPIC";
1837      LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1838      echo '{ global: globalsymb*; local: *; };' > conftest.map
1839      AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1840                  [libjava_cv_anon_version_script=gnu],
1841                  [libjava_cv_anon_version_script=no])
1842      if test x$libjava_cv_anon_version_script = xno; then
1843        case "$target_os" in
1844          solaris2*)
1845            LDFLAGS="$save_LDFLAGS"
1846            LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1847            # Sun ld doesn't understand wildcards here.
1848            echo '{ global: globalsymbol; local: *; };' > conftest.map
1849            AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1850                        [libjava_cv_anon_version_script=sun], [])
1851            ;;
1852        esac
1853      fi
1854      CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1855    fi
1856   ])
1857 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1858 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1859 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1860
1861 # Check if linker supports static linking on a per library basis
1862 LD_START_STATIC_SPEC=
1863 LD_FINISH_STATIC_SPEC=
1864 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1865   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1866     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1867     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1868   fi
1869 fi
1870 AC_SUBST(LD_START_STATIC_SPEC)
1871 AC_SUBST(LD_FINISH_STATIC_SPEC)
1872
1873 here=`${PWDCMD-pwd}`
1874 AC_SUBST(here)
1875
1876 # We get this from the environment.
1877 AC_SUBST(GCJFLAGS)
1878
1879 default_python_dir="/share/gcc-`cat ${srcdir}/../gcc/BASE-VER`/python/libjava"
1880 AC_ARG_WITH([python-dir],
1881             AS_HELP_STRING([--with-python-dir],
1882                            [the location to install Python modules. This path should NOT include the prefix.]),
1883             [with_python_dir=$withval], [with_python_dir="${default_python_dir}"])
1884
1885 # Needed for installing Python modules during make install.
1886 python_mod_dir="\${prefix}${with_python_dir}"
1887
1888 # Needed for substituting into aot-compile*
1889 python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1890
1891 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1892 AC_SUBST(python_mod_dir)
1893 AC_SUBST(python_mod_dir_expanded)
1894
1895 # needed for aot-compile-rpm
1896 MAKE=`which make`
1897 AC_SUBST(MAKE)
1898
1899 AC_ARG_ENABLE([aot-compile-rpm],
1900   [AS_HELP_STRING([--enable-aot-compile-rpm],
1901                  [enable installation of aot-compile-rpm [default=no]])],
1902   [case "${enableval}" in
1903     yes) AOT_RPM_ENABLED=yes ;;
1904     no)  AOT_RPM_ENABLED=no ;;
1905     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1906   esac],
1907   [AOT_RPM_ENABLED=no]
1908 )
1909 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1910
1911 AC_ARG_ENABLE([java-home],
1912   [AS_HELP_STRING([--enable-java-home],
1913                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1914   [case "${enableval}" in
1915     yes) JAVA_HOME_ENABLED=yes ;;
1916     no)  JAVA_HOME_ENABLED=no ;;
1917     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1918   esac],
1919   [JAVA_HOME_ENABLED=no]
1920 )
1921 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1922
1923 # Only do these checks if java-home above is enabled.
1924 if test "x${JAVA_HOME_ENABLED}" = xyes
1925 then
1926
1927   AC_ARG_WITH([gcc-suffix],
1928               AS_HELP_STRING([--with-gcc-suffix],
1929                              [the GCC tool suffix (defaults to empty string)]),
1930               [gcc_suffix=$withval], [gcc_suffix=""])
1931   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1932   AC_SUBST(gcc_suffix)
1933
1934   AC_ARG_WITH([arch-directory],
1935               AS_HELP_STRING([--with-arch-directory],
1936                              [the arch directory under jre/lib (defaults to auto-detect)]),
1937               [host_cpu=$withval], [host_cpu=""])
1938
1939   AC_ARG_WITH([os-directory],
1940               AS_HELP_STRING([--with-os-directory],
1941                              [the os directory under include (defaults to auto-detect)]),
1942               [host_os=$withval], [host_os=""])
1943
1944   AC_ARG_WITH([origin-name],
1945               AS_HELP_STRING([--with-origin-name],
1946                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1947               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1948   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1949
1950   AC_ARG_WITH([arch-suffix],
1951               AS_HELP_STRING([--with-arch-suffix],
1952                              [the arch directory suffix (default is the empty string]),
1953               [arch_suffix=$withval], [arch_suffix=""])
1954   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1955
1956   AC_ARG_WITH([jvm-root-dir],
1957               AS_HELP_STRING([--with-jvm-root-dir],
1958                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1959               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1960   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1961
1962   AC_ARG_WITH([jvm-jar-dir],
1963               AS_HELP_STRING([--with-jvm-jar-dir],
1964                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1965               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1966   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1967
1968   JAVA_VERSION=1.5.0
1969   BUILD_VERSION=0
1970   AC_SUBST(JAVA_VERSION)
1971   AC_SUBST(BUILD_VERSION)
1972   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1973
1974   jre_dir=jre
1975   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1976   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1977
1978   JVM_ROOT_DIR=${jvm_root_dir}
1979   AC_SUBST(JVM_ROOT_DIR)
1980   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1981
1982   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1983   AC_SUBST(JVM_JAR_ROOT_DIR)
1984   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1985
1986   JVM_JAR_DIR=${jvm_jar_dir}
1987   AC_SUBST(JVM_JAR_DIR)
1988   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1989
1990   JRE_DIR=${jre_dir}
1991   AC_SUBST(JRE_DIR)
1992
1993   JRE_LNK=${jre_lnk}
1994   AC_SUBST(JRE_LNK)
1995
1996   SDK_LNK=${sdk_lnk}
1997   AC_SUBST(SDK_LNK)
1998
1999   SDK_BIN_DIR=${jvm_root_dir}/bin
2000   AC_SUBST(SDK_BIN_DIR)
2001   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
2002
2003   SDK_LIB_DIR=${jvm_root_dir}/lib
2004   AC_SUBST(SDK_LIB_DIR)
2005   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
2006
2007   SDK_INCLUDE_DIR=${jvm_root_dir}/include
2008   AC_SUBST(SDK_INCLUDE_DIR)
2009   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
2010
2011   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
2012   AC_SUBST(JRE_BIN_DIR)
2013   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
2014
2015   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
2016   AC_SUBST(JRE_LIB_DIR)
2017   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
2018
2019   # Find gcj prefix using gcj found in PATH.
2020   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
2021
2022   # Where do the gcj binaries live?
2023   # For jhbuild based builds, they all live in a sibling of bin called
2024   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
2025   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
2026   AC_SUBST(GCJ_BIN_DIR)
2027   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
2028
2029   AC_MSG_RESULT(host is ${host})
2030   if test "x${host_cpu}" = "x"
2031   then
2032     case ${host} in
2033       *-mingw* | *-cygwin*)
2034         host_cpu=x86;;
2035       i486-* | i586-* | i686-*)
2036         host_cpu=i386;;
2037       x86_64-*)
2038         host_cpu=amd64;;
2039       *)
2040         host_cpu=${host_cpu};;
2041     esac
2042   fi
2043   AC_MSG_RESULT(arch directory: ${host_cpu})
2044   CPU=${host_cpu}
2045   AC_SUBST(CPU)
2046
2047   if test "x${host_os}" = "x"
2048   then
2049     case ${host} in
2050       *-mingw* | *-cygwin*)
2051         host_os=win32;;
2052       *-linux*)
2053         host_os=linux;;
2054       *)
2055         host_os=${host_os};;
2056     esac
2057   fi
2058   echo os directory: ${host_os}
2059   OS=${host_os}
2060   AC_SUBST(OS)
2061
2062   # make an expanded $libdir, for substituting into
2063   # scripts (and other non-Makefile things).
2064   LIBDIR=$libdir
2065   if test "x${exec_prefix}" = "xNONE"
2066   then
2067       lib_exec_prefix=$expanded_prefix
2068   else
2069       lib_exec_prefix=$exec_prefix
2070   fi
2071   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2072   AC_SUBST(LIBDIR)
2073 fi
2074
2075 AC_CONFIG_FILES([
2076 Makefile
2077 libgcj.pc
2078 libgcj.spec
2079 libgcj-test.spec
2080 gcj/Makefile
2081 include/Makefile
2082 testsuite/Makefile
2083 contrib/aotcompile.py
2084 contrib/aot-compile
2085 contrib/aot-compile-rpm
2086 contrib/generate-cacerts.pl
2087 contrib/rebuild-gcj-db
2088 ])
2089
2090 if test ${multilib} = yes; then
2091   multilib_arg="--enable-multilib"
2092 else
2093   multilib_arg=
2094 fi
2095
2096 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2097 AC_OUTPUT