gcc/ada/stringt.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S T R I N G T                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System; use System;
  33 with Types;  use Types;
  34
  35 package Stringt is
  36
  37 --  This package contains routines for handling the strings table which is
  38 --  used to store string constants encountered in the source, and also those
  39 --  additional string constants generated by compile time concatenation and
  40 --  other similar processing.
  41
  42 --  A string constant in this table consists of a series of Char_Code values,
  43 --  so that 16-bit character codes can be properly handled if this feature
  44 --  is implemented in the scanner.
  45
  46 --  There is no guarantee that hashing is used in the implementation, although
  47 --  it maybe. This means that the caller cannot count on having the same Id
  48 --  value for two identical strings stored separately and also cannot count on
  49 --  the two Id values being different.
  50
  51    --------------------------------------
  52    -- String Table Access Subprograms --
  53    --------------------------------------
  54
  55    procedure Initialize;
  56    --  Initializes the strings table for a new compilation. Note that
  57    --  Initialize must not be called if Tree_Read is used.
  58
  59    procedure Lock;
  60    --  Lock internal tables before calling back end
  61
  62    procedure Unlock;
  63    --  Unlock internal tables, in case back end needs to modify them
  64
  65    procedure Mark;
  66    --  Take a snapshot of the internal tables. Used in conjunction with Release
  67    --  when computing temporary string values that need not be preserved.
  68
  69    procedure Release;
  70    --  Restore the internal tables to the situation when Mark was last called.
  71    --  If Release is called with no prior call to Mark, the entire string table
  72    --  is cleared to its initial (empty) setting.
  73
  74    procedure Start_String;
  75    --  Sets up for storing a new string in the table. To store a string, a
  76    --  call is first made to Start_String, then successive calls are
  77    --  made to Store_String_Character to store the characters of the string.
  78    --  Finally, a call to End_String terminates the entry and returns it Id.
  79
  80    procedure Start_String (S : String_Id);
  81    --  Like Start_String with no parameter, except that the contents of the
  82    --  new string is initialized to be a copy of the given string. A test is
  83    --  made to see if S is the last created string, and if so it is shared,
  84    --  rather than copied, this can be particularly helpful for the case of
  85    --  a continued concatenation of string constants.
  86
  87    procedure Store_String_Char (C : Char_Code);
  88    procedure Store_String_Char (C : Character);
  89    --  Store next character of string, see description above for Start_String
  90
  91    procedure Store_String_Chars (S : String);
  92    procedure Store_String_Chars (S : String_Id);
  93    --  Store character codes of given string in sequence
  94
  95    procedure Store_String_Int (N : Int);
  96    --  Stored decimal representation of integer with possible leading minus
  97
  98    procedure Unstore_String_Char;
  99    --  Undoes effect of previous Store_String_Char call, used in some error
 100    --  situations of unterminated string constants.
 101
 102    function End_String return String_Id;
 103    --  Terminates current string and returns its Id
 104
 105    function String_Length (Id : String_Id) return Nat;
 106    --  Returns length of previously stored string
 107
 108    function Get_String_Char (Id : String_Id; Index : Int) return Char_Code;
 109    pragma Inline (Get_String_Char);
 110    --  Obtains the specified character from a stored string. The lower bound
 111    --  of stored strings is always 1, so the range is 1 .. String_Length (Id).
 112
 113    function String_Equal (L, R : String_Id) return Boolean;
 114    --  Determines if two string literals represent the same string
 115
 116    procedure String_To_Name_Buffer (S : String_Id);
 117    --  Place characters of given string in Name_Buffer, setting Name_Len.
 118    --  Error if any characters are out of Character range. Does not attempt
 119    --  to do any encoding of any characters.
 120
 121    procedure Add_String_To_Name_Buffer (S : String_Id);
 122    --  Append characters of given string to Name_Buffer, updating Name_Len.
 123    --  Error if any characters are out of Character range. Does not attempt
 124    --  to do any encoding of any characters.
 125
 126    function String_Chars_Address return System.Address;
 127    --  Return address of String_Chars table (used by Back_End call to Gigi)
 128
 129    function String_From_Name_Buffer return String_Id;
 130    --  Given a name stored in Namet.Name_Buffer (length in Namet.Name_Len),
 131    --  returns a string of the corresponding value. The value in Name_Buffer
 132    --  is unchanged, and the cases of letters are unchanged.
 133
 134    function Strings_Address return System.Address;
 135    --  Return address of Strings table (used by Back_End call to Gigi)
 136
 137    procedure Tree_Read;
 138    --  Initializes internal tables from current tree file using the relevant
 139    --  Table.Tree_Read routines. Note that Initialize should not be called if
 140    --  Tree_Read is used. Tree_Read includes all necessary initialization.
 141
 142    procedure Tree_Write;
 143    --  Writes out internal tables to current tree file using the relevant
 144    --  Table.Tree_Write routines.
 145
 146    procedure Write_Char_Code (Code : Char_Code);
 147    --  Procedure to write a character code value, used for debugging purposes
 148    --  for writing character codes. If the character code is in the range
 149    --  16#20# .. 16#7E#, then the single graphic character corresponding to
 150    --  the code is output. For any other codes in the range 16#00# .. 16#FF#,
 151    --  the code is output as ["hh"] where hh is the two digit hex value for
 152    --  the code. Codes greater than 16#FF# are output as ["hhhh"] where hhhh
 153    --  is the four digit hex representation of the code value (high order
 154    --  byte first). Hex letters are always in lower case.
 155
 156    procedure Write_String_Table_Entry (Id : String_Id);
 157    --  Writes a string value with enclosing quotes to the current file using
 158    --  routines in package Output. Does not write an end of line character.
 159    --  This procedure is used for debug output purposes, and also for output
 160    --  of strings specified by pragma Linker Option to the ali file. 7-bit
 161    --  ASCII graphics (except for double quote) are output literally.
 162    --  The double quote appears as two successive double quotes.
 163    --  All other codes, are output as described for Write_Char_Code. For
 164    --  example, the string created by folding "A" & ASCII.HT & "Hello" will
 165    --  print as "A["09"]Hello". A No_String value prints simply as "no string"
 166    --  without surrounding quote marks.
 167
 168 private
 169    pragma Inline (End_String);
 170    pragma Inline (String_Length);
 171
 172 end Stringt;