gcc/ada/s-rident.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . R I D E N T                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package defines the set of restriction identifiers. It is a generic
  33 --  package that is instantiated by the compiler/binder in package Rident, and
  34 --  is instantiated in package System.Restrictions for use at run-time.
  35
  36 --  The reason that we make this a generic package is so that in the case of
  37 --  the instantiation in Rident for use at compile time and bind time, we can
  38 --  generate normal image tables for the enumeration types, which are needed
  39 --  for diagnostic and informational messages. At run-time we really do not
  40 --  want to waste the space for these image tables, and they are not needed,
  41 --  so we can do the instantiation under control of Discard_Names to remove
  42 --  the tables.
  43
  44 ---------------------------------------------------
  45 -- Note On Compile/Run-Time Consistency Checking --
  46 ---------------------------------------------------
  47
  48 --  This unit is with'ed by the run-time (to make System.Restrictions which is
  49 --  used for run-time access to restriction information), by the compiler (to
  50 --  determine what restrictions are implemented and what their category is) and
  51 --  by the binder (in processing ali files, and generating the information used
  52 --  at run-time to access restriction information).
  53
  54 --  Normally the version of System.Rident referenced in all three contexts
  55 --  should be the same. However, problems could arise in certain inconsistent
  56 --  builds that used inconsistent versions of the compiler and run-time. This
  57 --  sort of thing is not strictly correct, but it does arise when short-cuts
  58 --  are taken in build procedures.
  59
  60 --  Previously, this kind of inconsistency could cause a significant problem.
  61 --  If versions of System.Rident accessed by the compiler and binder differed,
  62 --  then the binder could fail to recognize the R (restrictions line) in the
  63 --  ali file, leading to bind errors when restrictions were added or removed.
  64
  65 --  The latest implementation avoids both this problem by using a named
  66 --  scheme for recording restrictions, rather than a positional scheme which
  67 --  fails completely if restrictions are added or subtracted. Now the worst
  68 --  that happens at bind time in inconsistent builds is that unrecognized
  69 --  restrictions are ignored, and the consistency checking for restrictions
  70 --  might be incomplete, which is no big deal.
  71
  72 pragma Compiler_Unit;
  73
  74 generic
  75 package System.Rident is
  76    pragma Preelaborate;
  77
  78    --  The following enumeration type defines the set of restriction
  79    --  identifiers that are implemented in GNAT.
  80
  81    --  To add a new restriction identifier, add an entry with the name to be
  82    --  used in the pragma, and add calls to the Restrict.Check_Restriction
  83    --  routine as appropriate.
  84
  85    type Restriction_Id is
  86
  87       --  The following cases are checked for consistency in the binder. The
  88       --  binder will check that every unit either has the restriction set, or
  89       --  does not violate the restriction.
  90
  91      (Simple_Barriers,                           -- Ada 2012 (D.7 (10.9/3))
  92       No_Abort_Statements,                       -- (RM D.7(5), H.4(3))
  93       No_Access_Parameter_Allocators,            -- Ada 2012 (RM H.4 (8.3/3))
  94       No_Access_Subprograms,                     -- (RM H.4(17))
  95       No_Allocators,                             -- (RM H.4(7))
  96       No_Anonymous_Allocators,                   -- Ada 2012 (RM H.4(8/1))
  97       No_Asynchronous_Control,                   -- (RM J.13(3/2)
  98       No_Calendar,                               -- GNAT
  99       No_Coextensions,                           -- Ada 2012 (RM H.4(8.2/3))
 100       No_Default_Stream_Attributes,              -- Ada 2012 (RM 13.12.1(4/2))
 101       No_Delay,                                  -- (RM H.4(21))
 102       No_Direct_Boolean_Operators,               -- GNAT
 103       No_Dispatch,                               -- (RM H.4(19))
 104       No_Dispatching_Calls,                      -- GNAT
 105       No_Dynamic_Attachment,                     -- Ada 2012 (RM E.7(10/3))
 106       No_Dynamic_Priorities,                     -- (RM D.9(9))
 107       No_Enumeration_Maps,                       -- GNAT
 108       No_Entry_Calls_In_Elaboration_Code,        -- GNAT
 109       No_Entry_Queue,                            -- GNAT (Ravenscar)
 110       No_Exception_Handlers,                     -- GNAT
 111       No_Exception_Propagation,                  -- GNAT
 112       No_Exception_Registration,                 -- GNAT
 113       No_Exceptions,                             -- (RM H.4(12))
 114       No_Finalization,                           -- GNAT
 115       No_Fixed_Point,                            -- (RM H.4(15))
 116       No_Floating_Point,                         -- (RM H.4(14))
 117       No_IO,                                     -- (RM H.4(20))
 118       No_Implicit_Conditionals,                  -- GNAT
 119       No_Implicit_Dynamic_Code,                  -- GNAT
 120       No_Implicit_Heap_Allocations,              -- (RM D.8(8), H.4(3))
 121       No_Implicit_Loops,                         -- GNAT
 122       No_Initialize_Scalars,                     -- GNAT
 123       No_Local_Allocators,                       -- (RM H.4(8))
 124       No_Local_Timing_Events,                    -- (RM D.7(10.2/2))
 125       No_Local_Protected_Objects,                -- Ada 2012 (D.7(10/1.3))
 126       No_Nested_Finalization,                    -- (RM D.7(4))
 127       No_Protected_Type_Allocators,              -- Ada 2012 (D.7 (10.3/2))
 128       No_Protected_Types,                        -- (RM H.4(5))
 129       No_Recursion,                              -- (RM H.4(22))
 130       No_Reentrancy,                             -- (RM H.4(23))
 131       No_Relative_Delay,                         -- Ada 2012 (D.7 (10.5/3))
 132       No_Requeue_Statements,                     -- Ada 2012 (D.7 (10.6/3))
 133       No_Secondary_Stack,                        -- GNAT
 134       No_Select_Statements,                      -- Ada 2012 (D.7 (10.7/4))
 135       No_Specific_Termination_Handlers,          -- (RM D.7(10.7/2))
 136       No_Standard_Allocators_After_Elaboration,  -- Ada 2012 (RM D.7(19.1/2))
 137       No_Standard_Storage_Pools,                 -- GNAT
 138       No_Stream_Optimizations,                   -- GNAT
 139       No_Streams,                                -- GNAT
 140       No_Task_Allocators,                        -- (RM D.7(7))
 141       No_Task_Attributes_Package,                -- GNAT
 142       No_Task_Hierarchy,                         -- (RM D.7(3), H.4(3))
 143       No_Task_Termination,                       -- GNAT (Ravenscar)
 144       No_Tasking,                                -- GNAT
 145       No_Terminate_Alternatives,                 -- (RM D.7(6))
 146       No_Unchecked_Access,                       -- (RM H.4(18))
 147       No_Unchecked_Conversion,                   -- (RM J.13(4/2))
 148       No_Unchecked_Deallocation,                 -- (RM J.13(5/2))
 149       Static_Priorities,                         -- GNAT
 150       Static_Storage_Size,                       -- GNAT
 151
 152       --  The following require consistency checking with special rules. See
 153       --  individual routines in unit Bcheck for details of what is required.
 154
 155       No_Default_Initialization,                 -- GNAT
 156
 157       --  The following cases do not require consistency checking and if used
 158       --  as a configuration pragma within a specific unit, apply only to that
 159       --  unit (e.g. if used in the package spec, do not apply to the body)
 160
 161       --  Note: No_Elaboration_Code is handled specially. Like the other
 162       --  non-partition-wide restrictions, it can only be set in a unit that
 163       --  is part of the extended main source unit (body/spec/subunits). But
 164       --  it is sticky, in that if it is found anywhere within any of these
 165       --  units, it applies to all units in this extended main source.
 166
 167       Immediate_Reclamation,                     -- (RM H.4(10))
 168       No_Implementation_Aspect_Specifications,   -- Ada 2012 AI-241
 169       No_Implementation_Attributes,              -- Ada 2005 AI-257
 170       No_Implementation_Identifiers,             -- Ada 2012 AI-246
 171       No_Implementation_Pragmas,                 -- Ada 2005 AI-257
 172       No_Implementation_Restrictions,            -- GNAT
 173       No_Implementation_Units,                   -- Ada 2012 AI-242
 174       No_Implicit_Aliasing,                      -- GNAT
 175       No_Elaboration_Code,                       -- GNAT
 176       No_Obsolescent_Features,                   -- Ada 2005 AI-368
 177       No_Wide_Characters,                        -- GNAT
 178       SPARK_05,                                  -- GNAT
 179
 180       --  The following cases require a parameter value
 181
 182       No_Specification_Of_Aspect,                -- 2012 (RM 13.12.1 (6.1/3))
 183       No_Use_Of_Attribute,                       -- 2012 (RM 13.12.1 (6.2/3))
 184       No_Use_Of_Pragma,                          -- 2012 (RM 13.12.1 (6.3/3))
 185
 186       --  The following entries are fully checked at compile/bind time, which
 187       --  means that the compiler can in general tell the minimum value which
 188       --  could be used with a restrictions pragma. The binder can deduce the
 189       --  appropriate minimum value for the partition by taking the maximum
 190       --  value required by any unit.
 191
 192       Max_Protected_Entries,                     -- (RM D.7(14))
 193       Max_Select_Alternatives,                   -- (RM D.7(12))
 194       Max_Task_Entries,                          -- (RM D.7(13), H.4(3))
 195
 196       --  The following entries are also fully checked at compile/bind time,
 197       --  and the compiler can also at least in some cases tell the minimum
 198       --  value which could be used with a restriction pragma. The difference
 199       --  is that the contributions are additive, so the binder deduces this
 200       --  value by adding the unit contributions.
 201
 202       Max_Tasks,                                 -- (RM D.7(19), H.4(3))
 203
 204       --  The following entries are checked at compile time only for zero/
 205       --  nonzero entries. This means that the compiler can tell at compile
 206       --  time if a restriction value of zero is (would be) violated, but that
 207       --  the compiler cannot distinguish between different non-zero values.
 208
 209       Max_Asynchronous_Select_Nesting,           -- (RM D.7(18), H.4(3))
 210       Max_Entry_Queue_Length,                    -- Ada 2012 (RM D.7 (19.1/2))
 211
 212       --  The remaining entries are not checked at compile/bind time
 213
 214       Max_Storage_At_Blocking,                   -- (RM D.7(17))
 215
 216       Not_A_Restriction_Id);
 217
 218    --  Synonyms permitted for historical purposes of compatibility.
 219    --  Must be coordinated with Restrict.Process_Restriction_Synonym.
 220
 221    Boolean_Entry_Barriers : Restriction_Id renames Simple_Barriers;
 222    Max_Entry_Queue_Depth  : Restriction_Id renames Max_Entry_Queue_Length;
 223    No_Dynamic_Interrupts  : Restriction_Id renames No_Dynamic_Attachment;
 224    No_Requeue             : Restriction_Id renames No_Requeue_Statements;
 225    No_Task_Attributes     : Restriction_Id renames No_Task_Attributes_Package;
 226    SPARK                  : Restriction_Id renames SPARK_05;
 227
 228    subtype All_Restrictions is Restriction_Id range
 229      Simple_Barriers .. Max_Storage_At_Blocking;
 230    --  All restrictions (excluding only Not_A_Restriction_Id)
 231
 232    subtype All_Boolean_Restrictions is Restriction_Id range
 233      Simple_Barriers .. SPARK_05;
 234    --  All restrictions which do not take a parameter
 235
 236    subtype Partition_Boolean_Restrictions is All_Boolean_Restrictions range
 237      Simple_Barriers .. Static_Storage_Size;
 238    --  Boolean restrictions that are checked for partition consistency.
 239    --  Note that all parameter restrictions are checked for partition
 240    --  consistency by default, so this distinction is only needed in the
 241    --  case of Boolean restrictions.
 242
 243    subtype Cunit_Boolean_Restrictions is All_Boolean_Restrictions range
 244      Immediate_Reclamation .. SPARK_05;
 245    --  Boolean restrictions that are not checked for partition consistency
 246    --  and that thus apply only to the current unit. Note that for these
 247    --  restrictions, the compiler does not apply restrictions found in
 248    --  with'ed units, parent specs etc. to the main unit, and vice versa.
 249
 250    subtype All_Parameter_Restrictions is
 251      Restriction_Id range
 252        No_Specification_Of_Aspect .. Max_Storage_At_Blocking;
 253    --  All restrictions that take a parameter
 254
 255    subtype Checked_Parameter_Restrictions is
 256      All_Parameter_Restrictions range
 257        Max_Protected_Entries .. Max_Entry_Queue_Length;
 258    --  These are the parameter restrictions that can be at least partially
 259    --  checked at compile/binder time. Minimally, the compiler can detect
 260    --  violations of a restriction pragma with a value of zero reliably.
 261
 262    subtype Checked_Max_Parameter_Restrictions is
 263      Checked_Parameter_Restrictions range
 264        Max_Protected_Entries .. Max_Task_Entries;
 265    --  Restrictions with parameters that can be checked in some cases by
 266    --  maximizing among statically detected instances where the compiler
 267    --  can determine the count.
 268
 269    subtype Checked_Add_Parameter_Restrictions is
 270      Checked_Parameter_Restrictions range
 271        Max_Tasks .. Max_Tasks;
 272    --  Restrictions with parameters that can be checked in some cases by
 273    --  summing the statically detected instances where the compiler can
 274    --  determine the count.
 275
 276    subtype Checked_Val_Parameter_Restrictions is
 277      Checked_Parameter_Restrictions range
 278        Max_Protected_Entries .. Max_Tasks;
 279    --  Restrictions with parameter where the count is known at least in some
 280    --  cases by the compiler/binder.
 281
 282    subtype Checked_Zero_Parameter_Restrictions is
 283      Checked_Parameter_Restrictions range
 284        Max_Asynchronous_Select_Nesting .. Max_Entry_Queue_Length;
 285    --  Restrictions with parameters where the compiler can detect the use of
 286    --  the feature, and hence violations of a restriction specifying a value
 287    --  of zero, but cannot detect specific values other than zero/nonzero.
 288
 289    subtype Unchecked_Parameter_Restrictions is
 290      All_Parameter_Restrictions range
 291        Max_Storage_At_Blocking .. Max_Storage_At_Blocking;
 292    --  Restrictions with parameters where the compiler cannot ever detect
 293    --  corresponding compile time usage, so the binder and compiler never
 294    --  detect violations of any restriction.
 295
 296    -------------------------------------
 297    -- Restriction Status Declarations --
 298    -------------------------------------
 299
 300    --  The following declarations are used to record the current status or
 301    --  restrictions (for the current unit, or related units, at compile time,
 302    --  and for all units in a partition at bind time or run time).
 303
 304    type Restriction_Flags  is array (All_Restrictions)           of Boolean;
 305    type Restriction_Values is array (All_Parameter_Restrictions) of Natural;
 306    type Parameter_Flags    is array (All_Parameter_Restrictions) of Boolean;
 307
 308    type Restrictions_Info is record
 309       Set : Restriction_Flags;
 310       --  An entry is True in the Set array if a restrictions pragma has been
 311       --  encountered for the given restriction. If the value is True for a
 312       --  parameter restriction, then the corresponding entry in the Value
 313       --  array gives the minimum value encountered for any such restriction.
 314
 315       Value : Restriction_Values;
 316       --  If the entry for a parameter restriction in Set is True (i.e. a
 317       --  restrictions pragma for the restriction has been encountered), then
 318       --  the corresponding entry in the Value array is the minimum value
 319       --  specified by any such restrictions pragma. Note that a restrictions
 320       --  pragma specifying a value greater than Int'Last is simply ignored.
 321
 322       Violated : Restriction_Flags;
 323       --  An entry is True in the violations array if the compiler has detected
 324       --  a violation of the restriction. For a parameter restriction, the
 325       --  Count and Unknown arrays have additional information.
 326
 327       Count : Restriction_Values;
 328       --  If an entry for a parameter restriction is True in Violated, the
 329       --  corresponding entry in the Count array may record additional
 330       --  information. If the actual minimum count is known (by taking
 331       --  maximums, or sums, depending on the restriction), it will be
 332       --  recorded in this array. If not, then the value will remain zero.
 333       --  The value is also zero for a non-violated restriction.
 334
 335       Unknown : Parameter_Flags;
 336       --  If an entry for a parameter restriction is True in Violated, the
 337       --  corresponding entry in the Unknown array may record additional
 338       --  information. If the actual count is not known by the compiler (but
 339       --  is known to be non-zero), then the entry in Unknown will be True.
 340       --  This indicates that the value in Count is not known to be exact,
 341       --  and the actual violation count may be higher.
 342
 343       --  Note: If Violated (K) is True, then either Count (K) > 0 or
 344       --  Unknown (K) = True. It is possible for both these to be set.
 345       --  For example, if Count (K) = 3 and Unknown (K) is True, it means
 346       --  that the actual violation count is at least 3 but might be higher.
 347    end record;
 348
 349    No_Restrictions : constant Restrictions_Info :=
 350      (Set      => (others => False),
 351       Value    => (others => 0),
 352       Violated => (others => False),
 353       Count    => (others => 0),
 354       Unknown  => (others => False));
 355    --  Used to initialize Restrictions_Info variables
 356
 357    ----------------------------------
 358    -- Profile Definitions and Data --
 359    ----------------------------------
 360
 361    --  Note: to add a profile, modify the following declarations appropriately,
 362    --  add Name_xxx to Snames, and add a branch to the conditions for pragmas
 363    --  Profile and Profile_Warnings in the body of Sem_Prag.
 364
 365    type Profile_Name is
 366      (No_Profile,
 367       No_Implementation_Extensions,
 368       Ravenscar,
 369       Restricted);
 370    --  Names of recognized profiles. No_Profile is used to indicate that a
 371    --  restriction came from pragma Restrictions[_Warning], as opposed to
 372    --  pragma Profile[_Warning].
 373
 374    subtype Profile_Name_Actual is Profile_Name
 375      range No_Implementation_Extensions .. Restricted;
 376    --  Actual used profile names
 377
 378    type Profile_Data is record
 379       Set : Restriction_Flags;
 380       --  Set to True if given restriction must be set for the profile, and
 381       --  False if it need not be set (False does not mean that it must not be
 382       --  set, just that it need not be set). If the flag is True for a
 383       --  parameter restriction, then the Value array gives the maximum value
 384       --  permitted by the profile.
 385
 386       Value : Restriction_Values;
 387       --  An entry in this array is meaningful only if the corresponding flag
 388       --  in Set is True. In that case, the value in this array is the maximum
 389       --  value of the parameter permitted by the profile.
 390    end record;
 391
 392    Profile_Info : constant array (Profile_Name_Actual) of Profile_Data := (
 393
 394                      --  No_Implementation_Extensions profile
 395
 396                      No_Implementation_Extensions =>
 397
 398                        (Set   =>
 399                           (No_Implementation_Aspect_Specifications => True,
 400                            No_Implementation_Attributes            => True,
 401                            No_Implementation_Identifiers           => True,
 402                            No_Implementation_Pragmas               => True,
 403                            No_Implementation_Units                 => True,
 404                            others                                  => False),
 405
 406                         --  Value settings for Restricted profile (none
 407
 408                         Value =>
 409                           (others                          => 0)),
 410
 411                      --  Restricted Profile
 412
 413                      Restricted =>
 414
 415                         --  Restrictions for Restricted profile
 416
 417                        (Set   =>
 418                           (No_Abort_Statements             => True,
 419                            No_Asynchronous_Control         => True,
 420                            No_Dynamic_Attachment           => True,
 421                            No_Dynamic_Priorities           => True,
 422                            No_Entry_Queue                  => True,
 423                            No_Local_Protected_Objects      => True,
 424                            No_Protected_Type_Allocators    => True,
 425                            No_Requeue_Statements           => True,
 426                            No_Task_Allocators              => True,
 427                            No_Task_Attributes_Package      => True,
 428                            No_Task_Hierarchy               => True,
 429                            No_Terminate_Alternatives       => True,
 430                            Max_Asynchronous_Select_Nesting => True,
 431                            Max_Protected_Entries           => True,
 432                            Max_Select_Alternatives         => True,
 433                            Max_Task_Entries                => True,
 434                            others                          => False),
 435
 436                         --  Value settings for Restricted profile
 437
 438                         Value =>
 439                           (Max_Asynchronous_Select_Nesting => 0,
 440                            Max_Protected_Entries           => 1,
 441                            Max_Select_Alternatives         => 0,
 442                            Max_Task_Entries                => 0,
 443                            others                          => 0)),
 444
 445                      --  Ravenscar Profile
 446
 447                      --  Note: the table entries here only represent the
 448                      --  required restriction profile for Ravenscar. The
 449                      --  full Ravenscar profile also requires:
 450
 451                      --    pragma Dispatching_Policy (FIFO_Within_Priorities);
 452                      --    pragma Locking_Policy (Ceiling_Locking);
 453                      --    pragma Detect_Blocking
 454
 455                      Ravenscar  =>
 456
 457                      --  Restrictions for Ravenscar = Restricted profile ..
 458
 459                        (Set   =>
 460                           (No_Abort_Statements             => True,
 461                            No_Asynchronous_Control         => True,
 462                            No_Dynamic_Attachment           => True,
 463                            No_Dynamic_Priorities           => True,
 464                            No_Entry_Queue                  => True,
 465                            No_Local_Protected_Objects      => True,
 466                            No_Protected_Type_Allocators    => True,
 467                            No_Requeue_Statements           => True,
 468                            No_Task_Allocators              => True,
 469                            No_Task_Attributes_Package      => True,
 470                            No_Task_Hierarchy               => True,
 471                            No_Terminate_Alternatives       => True,
 472                            Max_Asynchronous_Select_Nesting => True,
 473                            Max_Protected_Entries           => True,
 474                            Max_Select_Alternatives         => True,
 475                            Max_Task_Entries                => True,
 476
 477                            --  plus these additional restrictions:
 478
 479                            No_Calendar                     => True,
 480                            No_Implicit_Heap_Allocations    => True,
 481                            No_Relative_Delay               => True,
 482                            No_Select_Statements            => True,
 483                            No_Task_Termination             => True,
 484                            Simple_Barriers                 => True,
 485                            others                          => False),
 486
 487                         --  Value settings for Ravenscar (same as Restricted)
 488
 489                         Value =>
 490                           (Max_Asynchronous_Select_Nesting => 0,
 491                            Max_Protected_Entries           => 1,
 492                            Max_Select_Alternatives         => 0,
 493                            Max_Task_Entries                => 0,
 494                            others                          => 0)));
 495
 496 end System.Rident;