gcc/ada/prj-env.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              P R J . E N V                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package implements services for Project-aware tools, mostly related
  27 --  to the environment (configuration pragma files, path files, mapping files).
  28
  29 with GNAT.Dynamic_HTables;
  30 with GNAT.OS_Lib;
  31
  32 package Prj.Env is
  33
  34    procedure Initialize (In_Tree : Project_Tree_Ref);
  35    --  Initialize global components relative to environment variables
  36
  37    procedure Print_Sources (In_Tree : Project_Tree_Ref);
  38    --  Output the list of sources after Project files have been scanned
  39
  40    procedure Create_Mapping (In_Tree : Project_Tree_Ref);
  41    --  Create in memory mapping from the sources of all the projects (in body
  42    --  of package Fmap), so that Osint.Find_File will find the correct path
  43    --  corresponding to a source.
  44
  45    procedure Create_Temp_File
  46      (Shared    : Shared_Project_Tree_Data_Access;
  47       Path_FD   : out File_Descriptor;
  48       Path_Name : out Path_Name_Type;
  49       File_Use  : String);
  50    --  Create temporary file, fail with an error if it could not be created
  51
  52    procedure Create_Mapping_File
  53      (Project  : Project_Id;
  54       Language : Name_Id;
  55       In_Tree  : Project_Tree_Ref;
  56       Name     : out Path_Name_Type);
  57    --  Create a temporary mapping file for project Project. For each source or
  58    --  template of Language in the Project, put the mapping of its file name
  59    --  and path name in this file. See fmap for a description of the format
  60    --  of the mapping file.
  61    --
  62    --  Implementation note: we pass a language name, not a language_index here,
  63    --  since the latter would have to match exactly the index of that language
  64    --  for the specified project, and that is not information available in
  65    --  buildgpr.adb.
  66
  67    procedure Create_Config_Pragmas_File
  68      (For_Project : Project_Id;
  69       In_Tree     : Project_Tree_Ref);
  70    --  If we need SFN pragmas, either for non standard naming schemes or for
  71    --  individual units.
  72
  73    procedure Create_New_Path_File
  74      (Shared    : Shared_Project_Tree_Data_Access;
  75       Path_FD   : out File_Descriptor;
  76       Path_Name : out Path_Name_Type);
  77    --  Create a new temporary path file, placing file name in Path_Name
  78
  79    function Ada_Include_Path
  80      (Project   : Project_Id;
  81       In_Tree   : Project_Tree_Ref;
  82       Recursive : Boolean := False) return String;
  83    --  Get the source search path of a Project file. If Recursive it True, get
  84    --  all the source directories of the imported and modified project files
  85    --  (recursively). If Recursive is False, just get the path for the source
  86    --  directories of Project. Note: the resulting String may be empty if there
  87    --  is no source directory in the project file.
  88
  89    function Ada_Objects_Path
  90      (Project             : Project_Id;
  91       In_Tree             : Project_Tree_Ref;
  92       Including_Libraries : Boolean := True) return String_Access;
  93    --  Get the ADA_OBJECTS_PATH of a Project file. For the first call, compute
  94    --  it and cache it. When Including_Libraries is False, do not include the
  95    --  object directories of the library projects, and do not cache the result.
  96
  97    procedure Set_Ada_Paths
  98      (Project             : Project_Id;
  99       In_Tree             : Project_Tree_Ref;
 100       Including_Libraries : Boolean;
 101       Include_Path        : Boolean := True;
 102       Objects_Path        : Boolean := True);
 103    --  Set the environment variables for additional project path files, after
 104    --  creating the path files if necessary.
 105
 106    function File_Name_Of_Library_Unit_Body
 107      (Name              : String;
 108       Project           : Project_Id;
 109       In_Tree           : Project_Tree_Ref;
 110       Main_Project_Only : Boolean := True;
 111       Full_Path         : Boolean := False) return String;
 112    --  Returns the file name of a library unit, in canonical case. Name may or
 113    --  may not have an extension (corresponding to the naming scheme of the
 114    --  project). If there is no body with this name, but there is a spec, the
 115    --  name of the spec is returned.
 116    --
 117    --  If Full_Path is False (the default), the simple file name is returned.
 118    --  If Full_Path is True, the absolute path name is returned.
 119    --
 120    --  If neither a body nor a spec can be found, an empty string is returned.
 121    --  If Main_Project_Only is True, the unit must be an immediate source of
 122    --  Project. If it is False, it may be a source of one of its imported
 123    --  projects.
 124
 125    function Project_Of
 126      (Name         : String;
 127       Main_Project : Project_Id;
 128       In_Tree      : Project_Tree_Ref) return Project_Id;
 129    --  Get the project of a source. The source file name may be truncated
 130    --  (".adb" or ".ads" may be missing). If the source is in a project being
 131    --  extended, return the ultimate extending project. If it is not a source
 132    --  of any project, return No_Project.
 133
 134    procedure Get_Reference
 135      (Source_File_Name : String;
 136       In_Tree          : Project_Tree_Ref;
 137       Project          : out Project_Id;
 138       Path             : out Path_Name_Type);
 139    --  Returns the project of a source and its path in displayable form
 140
 141    generic
 142       with procedure Action (Path : String);
 143    procedure For_All_Source_Dirs
 144      (Project : Project_Id;
 145       In_Tree : Project_Tree_Ref);
 146    --  Iterate through all the source directories of a project, including those
 147    --  of imported or modified projects. Only returns those directories that
 148    --  potentially contain Ada sources (ie ignore projects that have no Ada
 149    --  sources
 150
 151    generic
 152       with procedure Action (Path : String);
 153    procedure For_All_Object_Dirs
 154      (Project : Project_Id;
 155       Tree    : Project_Tree_Ref);
 156    --  Iterate through all the object directories of a project, including those
 157    --  of imported or modified projects.
 158
 159    ------------------
 160    -- Project Path --
 161    ------------------
 162
 163    type Project_Search_Path is private;
 164    --  An abstraction of the project path. This object provides subprograms
 165    --  to search for projects on the path (and caches the results to improve
 166    --  efficiency).
 167
 168    No_Project_Search_Path : constant Project_Search_Path;
 169
 170    procedure Initialize_Default_Project_Path
 171      (Self        : in out Project_Search_Path;
 172       Target_Name : String);
 173    --  Initialize Self. It will then contain the default project path on the
 174    --  given target (including directories specified by the environment
 175    --  variables ADA_PROJECT_PATH and GPR_PROJECT_PATH). This does nothing if
 176    --  Self has already been initialized.
 177
 178    procedure Copy (From : Project_Search_Path; To : out Project_Search_Path);
 179    --  Copy From into To
 180
 181    procedure Initialize_Empty (Self : in out Project_Search_Path);
 182    --  Initialize self with an empty list of directories. If Self had already
 183    --  been set, it is reset.
 184
 185    function Is_Initialized (Self : Project_Search_Path) return Boolean;
 186    --  Whether Self has been initialized
 187
 188    procedure Free (Self : in out Project_Search_Path);
 189    --  Free the memory used by Self
 190
 191    procedure Add_Directories
 192      (Self    : in out Project_Search_Path;
 193       Path    : String;
 194       Prepend : Boolean := False);
 195    --  Add one or more directories to the path. Directories added with this
 196    --  procedure are added in order after the current directory and before the
 197    --  path given by the environment variable GPR_PROJECT_PATH. A value of "-"
 198    --  will remove the default project directory from the project path.
 199    --
 200    --  Calls to this subprogram must be performed before the first call to
 201    --  Find_Project below, or PATH will be added at the end of the search path.
 202
 203    procedure Get_Path (Self : Project_Search_Path; Path : out String_Access);
 204    --  Return the current value of the project path, either the value set
 205    --  during elaboration of the package or, if procedure Set_Project_Path has
 206    --  been called, the value set by the last call to Set_Project_Path. The
 207    --  returned value must not be modified.
 208    --  Self must have been initialized first.
 209
 210    procedure Set_Path (Self : in out Project_Search_Path; Path : String);
 211    --  Override the value of the project path. This also removes the implicit
 212    --  default search directories.
 213
 214    generic
 215       with function Check_Filename (Name : String) return Boolean;
 216    function Find_Name_In_Path
 217      (Self : Project_Search_Path;
 218       Path : String) return String_Access;
 219    --  Find a name in the project search path of Self. Check_Filename is
 220    --  the predicate to valid the search.  If Path is an absolute filename,
 221    --  simply calls the predicate with Path. Otherwise, calls the predicate
 222    --  for each component of the path. Stops as soon as the predicate
 223    --  returns True and returns the name, or returns null in case of failure.
 224
 225    procedure Find_Project
 226      (Self               : in out Project_Search_Path;
 227       Project_File_Name  : String;
 228       Directory          : String;
 229       Path               : out Namet.Path_Name_Type);
 230    --  Search for a project with the given name either in Directory (which
 231    --  often will be the directory contain the project we are currently parsing
 232    --  and which we found a reference to another project), or in the project
 233    --  path Self. Self must have been initialized first.
 234    --
 235    --  Project_File_Name can optionally contain directories, and the extension
 236    --  (.gpr) for the file name is optional.
 237    --
 238    --  Returns No_Name if no such project was found
 239
 240    function Get_Runtime_Path
 241      (Self : Project_Search_Path;
 242       Name : String) return String_Access;
 243    --  Compute the full path for the project-based runtime name.  It first
 244    --  checks that name is not a simple name (must has a path separator in it),
 245    --  and returns null in case of failure.  This check might be removed in the
 246    --  future.  The name is simply searched on the project path.
 247
 248 private
 249    package Projects_Paths is new GNAT.Dynamic_HTables.Simple_HTable
 250      (Header_Num => Header_Num,
 251       Element    => Path_Name_Type,
 252       No_Element => No_Path,
 253       Key        => Name_Id,
 254       Hash       => Hash,
 255       Equal      => "=");
 256
 257    type Project_Search_Path is record
 258       Path : GNAT.OS_Lib.String_Access;
 259       --  As a special case, if the first character is '#:" or this variable
 260       --  is unset, this means that the PATH has not been fully initialized
 261       --  yet (although subprograms above will properly take care of that).
 262
 263       Cache : Projects_Paths.Instance;
 264    end record;
 265
 266    No_Project_Search_Path : constant Project_Search_Path :=
 267                               (Path  => null,
 268                                Cache => Projects_Paths.Nil);
 269
 270 end Prj.Env;