?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Implement -mmemcpy-strategy= and -mmemset-strategy= options
[official-gcc.git] / gcc / ada / par-ch6.adb
blob7531f405fe108da51cef99b036024ee974712d10
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- P A R . C H 6 --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2013, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 pragma Style_Checks (All_Checks);
27 -- Turn off subprogram body ordering check. Subprograms are in order
28 -- by RM section rather than alphabetical
29
30 with Sinfo.CN; use Sinfo.CN;
31
32 separate (Par)
33 package body Ch6 is
34
35 -- Local subprograms, used only in this chapter
36
37 function P_Defining_Designator return Node_Id;
38 function P_Defining_Operator_Symbol return Node_Id;
39 function P_Return_Object_Declaration return Node_Id;
40
41 procedure P_Return_Subtype_Indication (Decl_Node : Node_Id);
42 -- Decl_Node is a N_Object_Declaration. Set the Null_Exclusion_Present and
43 -- Object_Definition fields of Decl_Node.
44
45 procedure Check_Junk_Semicolon_Before_Return;
46 -- Check for common error of junk semicolon before RETURN keyword of
47 -- function specification. If present, skip over it with appropriate error
48 -- message, leaving Scan_Ptr pointing to the RETURN after. This routine
49 -- also deals with a possibly misspelled version of Return.
50
51 procedure No_Constraint_Maybe_Expr_Func;
52 -- Called after scanning return subtype to check for missing constraint,
53 -- taking into account the possibility of an occurrence of an expression
54 -- function where the IS has been forgotten.
55
56 ----------------------------------------
57 -- Check_Junk_Semicolon_Before_Return --
58 ----------------------------------------
59
60 procedure Check_Junk_Semicolon_Before_Return is
61 Scan_State : Saved_Scan_State;
62
63 begin
64 if Token = Tok_Semicolon then
65 Save_Scan_State (Scan_State);
66 Scan; -- past the semicolon
67
68 if Token = Tok_Return then
69 Restore_Scan_State (Scan_State);
70 Error_Msg_SC -- CODEFIX
71 ("|extra "";"" ignored");
72 Scan; -- rescan past junk semicolon
73 else
74 Restore_Scan_State (Scan_State);
75 end if;
76
77 elsif Bad_Spelling_Of (Tok_Return) then
78 null;
79 end if;
80 end Check_Junk_Semicolon_Before_Return;
81
82 -----------------------------------
83 -- No_Constraint_Maybe_Expr_Func --
84 -----------------------------------
85
86 procedure No_Constraint_Maybe_Expr_Func is
87 begin
88 -- If we have a left paren at the start of the line, then assume this is
89 -- the case of an expression function with missing IS. We do not have to
90 -- diagnose the missing IS, that is done elsewhere. We do this game in
91 -- Ada 2012 mode where expression functions are legal.
92
93 if Token = Tok_Left_Paren
94 and Ada_Version >= Ada_2012
95 and Token_Is_At_Start_Of_Line
96 then
97 -- One exception if we have "(token .." then this is a constraint
98
99 declare
100 Scan_State : Saved_Scan_State;
101
102 begin
103 Save_Scan_State (Scan_State);
104 Scan; -- past left paren
105 Scan; -- past following token
106
107 -- If we have "(token .." then restore scan state and treat as
108 -- unexpected constraint.
109
110 if Token = Tok_Dot_Dot then
111 Restore_Scan_State (Scan_State);
112 No_Constraint;
113
114 -- Otherwise we treat this as an expression function
115
116 else
117 Restore_Scan_State (Scan_State);
118 end if;
119 end;
120
121 -- Otherwise use standard routine to check for no constraint present
122
123 else
124 No_Constraint;
125 end if;
126 end No_Constraint_Maybe_Expr_Func;
127
128 -----------------------------------------------------
129 -- 6.1 Subprogram (Also 6.3, 8.5.4, 10.1.3, 12.3) --
130 -----------------------------------------------------
131
132 -- This routine scans out a subprogram declaration, subprogram body,
133 -- subprogram renaming declaration or subprogram generic instantiation.
134 -- It also handles the new Ada 2012 expression function form
135
136 -- SUBPROGRAM_DECLARATION ::=
137 -- SUBPROGRAM_SPECIFICATION
138 -- [ASPECT_SPECIFICATIONS];
139
140 -- ABSTRACT_SUBPROGRAM_DECLARATION ::=
141 -- SUBPROGRAM_SPECIFICATION is abstract
142 -- [ASPECT_SPECIFICATIONS];
143
144 -- SUBPROGRAM_SPECIFICATION ::=
145 -- procedure DEFINING_PROGRAM_UNIT_NAME PARAMETER_PROFILE
146 -- | function DEFINING_DESIGNATOR PARAMETER_AND_RESULT_PROFILE
147
148 -- PARAMETER_PROFILE ::= [FORMAL_PART]
149
150 -- PARAMETER_AND_RESULT_PROFILE ::= [FORMAL_PART] return SUBTYPE_MARK
151
152 -- SUBPROGRAM_BODY ::=
153 -- SUBPROGRAM_SPECIFICATION [ASPECT_SPECIFICATIONS] is
154 -- DECLARATIVE_PART
155 -- begin
156 -- HANDLED_SEQUENCE_OF_STATEMENTS
157 -- end [DESIGNATOR];
158
159 -- SUBPROGRAM_RENAMING_DECLARATION ::=
160 -- SUBPROGRAM_SPECIFICATION renames callable_entity_NAME
161 -- [ASPECT_SPECIFICATIONS];
162
163 -- SUBPROGRAM_BODY_STUB ::=
164 -- SUBPROGRAM_SPECIFICATION is separate;
165
166 -- GENERIC_INSTANTIATION ::=
167 -- procedure DEFINING_PROGRAM_UNIT_NAME is
168 -- new generic_procedure_NAME [GENERIC_ACTUAL_PART];
169 -- | function DEFINING_DESIGNATOR is
170 -- new generic_function_NAME [GENERIC_ACTUAL_PART];
171
172 -- NULL_PROCEDURE_DECLARATION ::=
173 -- SUBPROGRAM_SPECIFICATION is null;
174
175 -- Null procedures are an Ada 2005 feature. A null procedure declaration
176 -- is classified as a basic declarative item, but it is parsed here, with
177 -- other subprogram constructs.
178
179 -- EXPRESSION_FUNCTION ::=
180 -- FUNCTION SPECIFICATION IS (EXPRESSION)
181 -- [ASPECT_SPECIFICATIONS];
182
183 -- The value in Pf_Flags indicates which of these possible declarations
184 -- is acceptable to the caller:
185
186 -- Pf_Flags.Decl Set if declaration OK
187 -- Pf_Flags.Gins Set if generic instantiation OK
188 -- Pf_Flags.Pbod Set if proper body OK
189 -- Pf_Flags.Rnam Set if renaming declaration OK
190 -- Pf_Flags.Stub Set if body stub OK
191 -- Pf_Flags.Pexp Set if expression function OK
192
193 -- If an inappropriate form is encountered, it is scanned out but an
194 -- error message indicating that it is appearing in an inappropriate
195 -- context is issued. The only possible values for Pf_Flags are those
196 -- defined as constants in the Par package.
197
198 -- The caller has checked that the initial token is FUNCTION, PROCEDURE,
199 -- NOT or OVERRIDING.
200
201 -- Error recovery: cannot raise Error_Resync
202
203 function P_Subprogram (Pf_Flags : Pf_Rec) return Node_Id is
204 Specification_Node : Node_Id;
205 Name_Node : Node_Id;
206 Aspects : List_Id;
207 Fpart_List : List_Id;
208 Fpart_Sloc : Source_Ptr;
209 Result_Not_Null : Boolean := False;
210 Result_Node : Node_Id;
211 Inst_Node : Node_Id;
212 Body_Node : Node_Id;
213 Decl_Node : Node_Id;
214 Rename_Node : Node_Id;
215 Absdec_Node : Node_Id;
216 Stub_Node : Node_Id;
217 Fproc_Sloc : Source_Ptr;
218 Func : Boolean;
219 Scan_State : Saved_Scan_State;
220
221 -- Flags for optional overriding indication. Two flags are needed,
222 -- to distinguish positive and negative overriding indicators from
223 -- the absence of any indicator.
224
225 Is_Overriding : Boolean := False;
226 Not_Overriding : Boolean := False;
227
228 begin
229 -- Set up scope stack entry. Note that the Labl field will be set later
230
231 SIS_Entry_Active := False;
232 SIS_Missing_Semicolon_Message := No_Error_Msg;
233 Push_Scope_Stack;
234 Scope.Table (Scope.Last).Sloc := Token_Ptr;
235 Scope.Table (Scope.Last).Etyp := E_Name;
236 Scope.Table (Scope.Last).Ecol := Start_Column;
237 Scope.Table (Scope.Last).Lreq := False;
238
239 Aspects := Empty_List;
240
241 -- Ada 2005: Scan leading NOT OVERRIDING indicator
242
243 if Token = Tok_Not then
244 Scan; -- past NOT
245
246 if Token = Tok_Overriding then
247 Scan; -- past OVERRIDING
248 Not_Overriding := True;
249
250 -- Overriding keyword used in non Ada 2005 mode
251
252 elsif Token = Tok_Identifier
253 and then Token_Name = Name_Overriding
254 then
255 Error_Msg_SC ("overriding indicator is an Ada 2005 extension");
256 Error_Msg_SC ("\unit must be compiled with -gnat05 switch");
257 Scan; -- past Overriding
258 Not_Overriding := True;
259
260 else
261 Error_Msg_SC -- CODEFIX
262 ("OVERRIDING expected!");
263 end if;
264
265 -- Ada 2005: scan leading OVERRIDING indicator
266
267 -- Note: in the case of OVERRIDING keyword used in Ada 95 mode, the
268 -- declaration circuit already gave an error message and changed the
269 -- token to Tok_Overriding.
270
271 elsif Token = Tok_Overriding then
272 Scan; -- past OVERRIDING
273 Is_Overriding := True;
274 end if;
275
276 if Is_Overriding or else Not_Overriding then
277
278 -- Note that if we are not in Ada_2005 mode, error messages have
279 -- already been given, so no need to give another message here.
280
281 -- An overriding indicator is allowed for subprogram declarations,
282 -- bodies (including subunits), renamings, stubs, and instantiations.
283 -- The test against Pf_Decl_Pbod is added to account for the case of
284 -- subprograms declared in a protected type, where only subprogram
285 -- declarations and bodies can occur. The Pf_Pbod case is for
286 -- subunits.
287
288 if Pf_Flags /= Pf_Decl_Gins_Pbod_Rnam_Stub_Pexp
289 and then
290 Pf_Flags /= Pf_Decl_Pbod_Pexp
291 and then
292 Pf_Flags /= Pf_Pbod_Pexp
293 then
294 Error_Msg_SC ("overriding indicator not allowed here!");
295
296 elsif Token /= Tok_Function and then Token /= Tok_Procedure then
297 Error_Msg_SC -- CODEFIX
298 ("FUNCTION or PROCEDURE expected!");
299 end if;
300 end if;
301
302 Func := (Token = Tok_Function);
303 Fproc_Sloc := Token_Ptr;
304 Scan; -- past FUNCTION or PROCEDURE
305 Ignore (Tok_Type);
306 Ignore (Tok_Body);
307
308 if Func then
309 Name_Node := P_Defining_Designator;
310
311 if Nkind (Name_Node) = N_Defining_Operator_Symbol
312 and then Scope.Last = 1
313 then
314 Error_Msg_SP ("operator symbol not allowed at library level");
315 Name_Node := New_Entity (N_Defining_Identifier, Sloc (Name_Node));
316
317 -- Set name from file name, we need some junk name, and that's
318 -- as good as anything. This is only approximate, since we do
319 -- not do anything with non-standard name translations.
320
321 Get_Name_String (File_Name (Current_Source_File));
322
323 for J in 1 .. Name_Len loop
324 if Name_Buffer (J) = '.' then
325 Name_Len := J - 1;
326 exit;
327 end if;
328 end loop;
329
330 Set_Chars (Name_Node, Name_Find);
331 Set_Error_Posted (Name_Node);
332 end if;
333
334 else
335 Name_Node := P_Defining_Program_Unit_Name;
336 end if;
337
338 Scope.Table (Scope.Last).Labl := Name_Node;
339 Ignore (Tok_Colon);
340
341 -- Deal with generic instantiation, the one case in which we do not
342 -- have a subprogram specification as part of whatever we are parsing
343
344 if Token = Tok_Is then
345 Save_Scan_State (Scan_State); -- at the IS
346 T_Is; -- checks for redundant IS
347
348 if Token = Tok_New then
349 if not Pf_Flags.Gins then
350 Error_Msg_SC ("generic instantiation not allowed here!");
351 end if;
352
353 Scan; -- past NEW
354
355 if Func then
356 Inst_Node := New_Node (N_Function_Instantiation, Fproc_Sloc);
357 Set_Name (Inst_Node, P_Function_Name);
358 else
359 Inst_Node := New_Node (N_Procedure_Instantiation, Fproc_Sloc);
360 Set_Name (Inst_Node, P_Qualified_Simple_Name);
361 end if;
362
363 Set_Defining_Unit_Name (Inst_Node, Name_Node);
364 Set_Generic_Associations (Inst_Node, P_Generic_Actual_Part_Opt);
365 P_Aspect_Specifications (Inst_Node);
366 Pop_Scope_Stack; -- Don't need scope stack entry in this case
367
368 if Is_Overriding then
369 Set_Must_Override (Inst_Node);
370
371 elsif Not_Overriding then
372 Set_Must_Not_Override (Inst_Node);
373 end if;
374
375 return Inst_Node;
376
377 else
378 Restore_Scan_State (Scan_State); -- to the IS
379 end if;
380 end if;
381
382 -- If not a generic instantiation, then we definitely have a subprogram
383 -- specification (all possibilities at this stage include one here)
384
385 Fpart_Sloc := Token_Ptr;
386
387 Check_Misspelling_Of (Tok_Return);
388
389 -- Scan formal part. First a special error check. If we have an
390 -- identifier here, then we have a definite error. If this identifier
391 -- is on the same line as the designator, then we assume it is the
392 -- first formal after a missing left parenthesis
393
394 if Token = Tok_Identifier
395 and then not Token_Is_At_Start_Of_Line
396 then
397 T_Left_Paren; -- to generate message
398 Fpart_List := P_Formal_Part;
399
400 -- Otherwise scan out an optional formal part in the usual manner
401
402 else
403 Fpart_List := P_Parameter_Profile;
404 end if;
405
406 -- We treat what we have as a function specification if FUNCTION was
407 -- used, or if a RETURN is present. This gives better error recovery
408 -- since later RETURN statements will be valid in either case.
409
410 Check_Junk_Semicolon_Before_Return;
411 Result_Node := Error;
412
413 if Token = Tok_Return then
414 if not Func then
415 Error_Msg -- CODEFIX
416 ("PROCEDURE should be FUNCTION", Fproc_Sloc);
417 Func := True;
418 end if;
419
420 Scan; -- past RETURN
421
422 Result_Not_Null := P_Null_Exclusion; -- Ada 2005 (AI-231)
423
424 -- Ada 2005 (AI-318-02)
425
426 if Token = Tok_Access then
427 if Ada_Version < Ada_2005 then
428 Error_Msg_SC
429 ("anonymous access result type is an Ada 2005 extension");
430 Error_Msg_SC ("\unit must be compiled with -gnat05 switch");
431 end if;
432
433 Result_Node := P_Access_Definition (Result_Not_Null);
434
435 else
436 Result_Node := P_Subtype_Mark;
437 No_Constraint_Maybe_Expr_Func;
438 end if;
439
440 else
441 -- Skip extra parenthesis at end of formal part
442
443 Ignore (Tok_Right_Paren);
444
445 -- For function, scan result subtype
446
447 if Func then
448 TF_Return;
449
450 if Prev_Token = Tok_Return then
451 Result_Node := P_Subtype_Mark;
452 end if;
453 end if;
454 end if;
455
456 if Func then
457 Specification_Node :=
458 New_Node (N_Function_Specification, Fproc_Sloc);
459
460 Set_Null_Exclusion_Present (Specification_Node, Result_Not_Null);
461 Set_Result_Definition (Specification_Node, Result_Node);
462
463 else
464 Specification_Node :=
465 New_Node (N_Procedure_Specification, Fproc_Sloc);
466 end if;
467
468 Set_Defining_Unit_Name (Specification_Node, Name_Node);
469 Set_Parameter_Specifications (Specification_Node, Fpart_List);
470
471 if Is_Overriding then
472 Set_Must_Override (Specification_Node);
473
474 elsif Not_Overriding then
475 Set_Must_Not_Override (Specification_Node);
476 end if;
477
478 -- Error check: barriers not allowed on protected functions/procedures
479
480 if Token = Tok_When then
481 if Func then
482 Error_Msg_SC ("barrier not allowed on function, only on entry");
483 else
484 Error_Msg_SC ("barrier not allowed on procedure, only on entry");
485 end if;
486
487 Scan; -- past WHEN
488 Discard_Junk_Node (P_Expression);
489 end if;
490
491 -- Deal with semicolon followed by IS. We want to treat this as IS
492
493 if Token = Tok_Semicolon then
494 Save_Scan_State (Scan_State);
495 Scan; -- past semicolon
496
497 if Token = Tok_Is then
498 Error_Msg_SP -- CODEFIX
499 ("extra "";"" ignored");
500 else
501 Restore_Scan_State (Scan_State);
502 end if;
503 end if;
504
505 -- Subprogram declaration ended by aspect specifications
506
507 if Aspect_Specifications_Present then
508 goto Subprogram_Declaration;
509
510 -- Deal with case of semicolon ending a subprogram declaration
511
512 elsif Token = Tok_Semicolon then
513 if not Pf_Flags.Decl then
514 T_Is;
515 end if;
516
517 Save_Scan_State (Scan_State);
518 Scan; -- past semicolon
519
520 -- If semicolon is immediately followed by IS, then ignore the
521 -- semicolon, and go process the body.
522
523 if Token = Tok_Is then
524 Error_Msg_SP -- CODEFIX
525 ("|extra "";"" ignored");
526 T_Is; -- scan past IS
527 goto Subprogram_Body;
528
529 -- If BEGIN follows in an appropriate column, we immediately
530 -- commence the error action of assuming that the previous
531 -- subprogram declaration should have been a subprogram body,
532 -- i.e. that the terminating semicolon should have been IS.
533
534 elsif Token = Tok_Begin
535 and then Start_Column >= Scope.Table (Scope.Last).Ecol
536 then
537 Error_Msg_SP -- CODEFIX
538 ("|"";"" should be IS!");
539 goto Subprogram_Body;
540
541 else
542 Restore_Scan_State (Scan_State);
543 goto Subprogram_Declaration;
544 end if;
545
546 -- Case of not followed by semicolon
547
548 else
549 -- Subprogram renaming declaration case
550
551 Check_Misspelling_Of (Tok_Renames);
552
553 if Token = Tok_Renames then
554 if not Pf_Flags.Rnam then
555 Error_Msg_SC ("renaming declaration not allowed here!");
556 end if;
557
558 Rename_Node :=
559 New_Node (N_Subprogram_Renaming_Declaration, Token_Ptr);
560 Scan; -- past RENAMES
561 Set_Name (Rename_Node, P_Name);
562 Set_Specification (Rename_Node, Specification_Node);
563 P_Aspect_Specifications (Rename_Node);
564 TF_Semicolon;
565 Pop_Scope_Stack;
566 return Rename_Node;
567
568 -- Case of IS following subprogram specification
569
570 elsif Token = Tok_Is then
571 T_Is; -- ignore redundant Is's
572
573 if Token_Name = Name_Abstract then
574 Check_95_Keyword (Tok_Abstract, Tok_Semicolon);
575 end if;
576
577 -- Deal nicely with (now obsolete) use of <> in place of abstract
578
579 if Token = Tok_Box then
580 Error_Msg_SC -- CODEFIX
581 ("ABSTRACT expected");
582 Token := Tok_Abstract;
583 end if;
584
585 -- Abstract subprogram declaration case
586
587 if Token = Tok_Abstract then
588 Absdec_Node :=
589 New_Node (N_Abstract_Subprogram_Declaration, Token_Ptr);
590 Set_Specification (Absdec_Node, Specification_Node);
591 Pop_Scope_Stack; -- discard unneeded entry
592 Scan; -- past ABSTRACT
593 P_Aspect_Specifications (Absdec_Node);
594 return Absdec_Node;
595
596 -- Ada 2005 (AI-248): Parse a null procedure declaration
597
598 elsif Token = Tok_Null then
599 if Ada_Version < Ada_2005 then
600 Error_Msg_SP ("null procedures are an Ada 2005 extension");
601 Error_Msg_SP ("\unit must be compiled with -gnat05 switch");
602 end if;
603
604 Scan; -- past NULL
605
606 if Func then
607 Error_Msg_SP ("only procedures can be null");
608 else
609 Set_Null_Present (Specification_Node);
610 end if;
611
612 goto Subprogram_Declaration;
613
614 -- Check for IS NEW with Formal_Part present and handle nicely
615
616 elsif Token = Tok_New then
617 Error_Msg
618 ("formal part not allowed in instantiation", Fpart_Sloc);
619 Scan; -- past NEW
620
621 if Func then
622 Inst_Node := New_Node (N_Function_Instantiation, Fproc_Sloc);
623 else
624 Inst_Node :=
625 New_Node (N_Procedure_Instantiation, Fproc_Sloc);
626 end if;
627
628 Set_Defining_Unit_Name (Inst_Node, Name_Node);
629 Set_Name (Inst_Node, P_Name);
630 Set_Generic_Associations (Inst_Node, P_Generic_Actual_Part_Opt);
631 TF_Semicolon;
632 Pop_Scope_Stack; -- Don't need scope stack entry in this case
633 return Inst_Node;
634
635 else
636 goto Subprogram_Body;
637 end if;
638
639 -- Aspect specifications present
640
641 elsif Aspect_Specifications_Present then
642 goto Subprogram_Declaration;
643
644 -- Here we have a missing IS or missing semicolon
645
646 else
647 -- If the next token is a left paren at the start of a line, then
648 -- this is almost certainly the start of the expression for an
649 -- expression function, so in this case guess a missing IS.
650
651 if Token = Tok_Left_Paren and then Token_Is_At_Start_Of_Line then
652 Error_Msg_AP -- CODEFIX
653 ("missing IS");
654
655 -- In all other cases, we guess a missing semicolon, since we are
656 -- good at fixing up a semicolon which should really be an IS.
657
658 else
659 Error_Msg_AP -- CODEFIX
660 ("|missing "";""");
661 SIS_Missing_Semicolon_Message := Get_Msg_Id;
662 goto Subprogram_Declaration;
663 end if;
664 end if;
665 end if;
666
667 -- Processing for stub or subprogram body or expression function
668
669 <<Subprogram_Body>>
670
671 -- Subprogram body stub case
672
673 if Separate_Present then
674 if not Pf_Flags.Stub then
675 Error_Msg_SC ("body stub not allowed here!");
676 end if;
677
678 if Nkind (Name_Node) = N_Defining_Operator_Symbol then
679 Error_Msg
680 ("operator symbol cannot be used as subunit name",
681 Sloc (Name_Node));
682 end if;
683
684 Stub_Node :=
685 New_Node (N_Subprogram_Body_Stub, Sloc (Specification_Node));
686 Set_Specification (Stub_Node, Specification_Node);
687
688 -- The specification has been parsed as part of a subprogram
689 -- declaration, and aspects have already been collected.
690
691 if Is_Non_Empty_List (Aspects) then
692 Set_Parent (Aspects, Stub_Node);
693 Set_Aspect_Specifications (Stub_Node, Aspects);
694 end if;
695
696 Scan; -- past SEPARATE
697 Pop_Scope_Stack;
698 TF_Semicolon;
699 return Stub_Node;
700
701 -- Subprogram body or expression function case
702
703 else
704 Scan_Body_Or_Expression_Function : declare
705
706 Body_Is_Hidden_In_SPARK : Boolean;
707 Hidden_Region_Start : Source_Ptr;
708
709 function Likely_Expression_Function return Boolean;
710 -- Returns True if we have a probable case of an expression
711 -- function omitting the parentheses, if so, returns True
712 -- and emits an appropriate error message, else returns False.
713
714 --------------------------------
715 -- Likely_Expression_Function --
716 --------------------------------
717
718 function Likely_Expression_Function return Boolean is
719 begin
720 -- If currently pointing to BEGIN or a declaration keyword
721 -- or a pragma, then we definitely have a subprogram body.
722 -- This is a common case, so worth testing first.
723
724 if Token = Tok_Begin
725 or else Token in Token_Class_Declk
726 or else Token = Tok_Pragma
727 then
728 return False;
729
730 -- Test for tokens which could only start an expression and
731 -- thus signal the case of a expression function.
732
733 elsif Token in Token_Class_Literal
734 or else Token in Token_Class_Unary_Addop
735 or else Token = Tok_Left_Paren
736 or else Token = Tok_Abs
737 or else Token = Tok_Null
738 or else Token = Tok_New
739 or else Token = Tok_Not
740 then
741 null;
742
743 -- Anything other than an identifier must be a body
744
745 elsif Token /= Tok_Identifier then
746 return False;
747
748 -- Here for an identifier
749
750 else
751 -- If the identifier is the first token on its line, then
752 -- let's assume that we have a missing begin and this is
753 -- intended as a subprogram body. However, if the context
754 -- is a function and the unit is a package declaration, a
755 -- body would be illegal, so try for an unparenthesized
756 -- expression function.
757
758 if Token_Is_At_Start_Of_Line then
759 declare
760 -- The enclosing scope entry is a subprogram spec
761
762 Spec_Node : constant Node_Id :=
763 Parent
764 (Scope.Table (Scope.Last).Labl);
765 Lib_Node : Node_Id := Spec_Node;
766
767 begin
768 -- Check whether there is an enclosing scope that
769 -- is a package declaration.
770
771 if Scope.Last > 1 then
772 Lib_Node :=
773 Parent (Scope.Table (Scope.Last - 1).Labl);
774 end if;
775
776 if Ada_Version >= Ada_2012
777 and then
778 Nkind (Lib_Node) = N_Package_Specification
779 and then
780 Nkind (Spec_Node) = N_Function_Specification
781 then
782 null;
783 else
784 return False;
785 end if;
786 end;
787
788 -- Otherwise we have to scan ahead. If the identifier is
789 -- followed by a colon or a comma, it is a declaration
790 -- and hence we have a subprogram body. Otherwise assume
791 -- a expression function.
792
793 else
794 declare
795 Scan_State : Saved_Scan_State;
796 Tok : Token_Type;
797
798 begin
799 Save_Scan_State (Scan_State);
800 Scan; -- past identifier
801 Tok := Token;
802 Restore_Scan_State (Scan_State);
803
804 if Tok = Tok_Colon or else Tok = Tok_Comma then
805 return False;
806 end if;
807 end;
808 end if;
809 end if;
810
811 -- Fall through if we have a likely expression function
812
813 Error_Msg_SC
814 ("expression function must be enclosed in parentheses");
815 return True;
816 end Likely_Expression_Function;
817
818 -- Start of processing for Scan_Body_Or_Expression_Function
819
820 begin
821 -- Expression_Function case
822
823 if Token = Tok_Left_Paren
824 or else Likely_Expression_Function
825 then
826 -- Check expression function allowed here
827
828 if not Pf_Flags.Pexp then
829 Error_Msg_SC ("expression function not allowed here!");
830 end if;
831
832 -- Check we are in Ada 2012 mode
833
834 if Ada_Version < Ada_2012 then
835 Error_Msg_SC
836 ("expression function is an Ada 2012 feature!");
837 Error_Msg_SC
838 ("\unit must be compiled with -gnat2012 switch!");
839 end if;
840
841 -- Catch an illegal placement of the aspect specification
842 -- list:
843
844 -- function_specification
845 -- [aspect_specification] is (expression);
846
847 -- This case is correctly processed by the parser because
848 -- the expression function first appears as a subprogram
849 -- declaration to the parser.
850
851 if Is_Non_Empty_List (Aspects) then
852 Error_Msg
853 ("aspect specifications must come after parenthesized "
854 & "expression", Sloc (First (Aspects)));
855 end if;
856
857 -- Parse out expression and build expression function
858
859 Body_Node :=
860 New_Node
861 (N_Expression_Function, Sloc (Specification_Node));
862 Set_Specification (Body_Node, Specification_Node);
863 Set_Expression (Body_Node, P_Expression);
864
865 -- Expression functions can carry pre/postconditions
866
867 P_Aspect_Specifications (Body_Node);
868 Pop_Scope_Stack;
869
870 -- Subprogram body case
871
872 else
873 -- Check body allowed here
874
875 if not Pf_Flags.Pbod then
876 Error_Msg_SP ("subprogram body not allowed here!");
877 end if;
878
879 -- Here is the test for a suspicious IS (i.e. one that
880 -- looks like it might more properly be a semicolon).
881 -- See separate section describing use of IS instead
882 -- of semicolon in package Parse.
883
884 if (Token in Token_Class_Declk
885 or else
886 Token = Tok_Identifier)
887 and then Start_Column <= Scope.Table (Scope.Last).Ecol
888 and then Scope.Last /= 1
889 then
890 Scope.Table (Scope.Last).Etyp := E_Suspicious_Is;
891 Scope.Table (Scope.Last).S_Is := Prev_Token_Ptr;
892 end if;
893
894 -- Build and return subprogram body, parsing declarations
895 -- and statement sequence that belong to the body.
896
897 Body_Node :=
898 New_Node (N_Subprogram_Body, Sloc (Specification_Node));
899 Set_Specification (Body_Node, Specification_Node);
900
901 -- If aspects are present, the specification is parsed as
902 -- a subprogram declaration, and we jump here after seeing
903 -- the keyword IS. Attach asspects previously collected to
904 -- the body.
905
906 if Is_Non_Empty_List (Aspects) then
907 Set_Parent (Aspects, Body_Node);
908 Set_Aspect_Specifications (Body_Node, Aspects);
909 end if;
910
911 -- In SPARK, a HIDE directive can be placed at the beginning
912 -- of a subprogram implementation, thus hiding the
913 -- subprogram body from SPARK tool-set. No violation of the
914 -- SPARK restriction should be issued on nodes in a hidden
915 -- part, which is obtained by marking such hidden parts.
916
917 if Token = Tok_SPARK_Hide then
918 Body_Is_Hidden_In_SPARK := True;
919 Hidden_Region_Start := Token_Ptr;
920 Scan; -- past HIDE directive
921 else
922 Body_Is_Hidden_In_SPARK := False;
923 end if;
924
925 Parse_Decls_Begin_End (Body_Node);
926
927 if Body_Is_Hidden_In_SPARK then
928 Set_Hidden_Part_In_SPARK (Hidden_Region_Start, Token_Ptr);
929 end if;
930 end if;
931
932 return Body_Node;
933 end Scan_Body_Or_Expression_Function;
934 end if;
935
936 -- Processing for subprogram declaration
937
938 <<Subprogram_Declaration>>
939 Decl_Node :=
940 New_Node (N_Subprogram_Declaration, Sloc (Specification_Node));
941 Set_Specification (Decl_Node, Specification_Node);
942 Aspects := Get_Aspect_Specifications (Semicolon => False);
943
944 -- Aspects may be present on a subprogram body. The source parsed
945 -- so far is that of its specification, go parse the body and attach
946 -- the collected aspects, if any, to the body.
947
948 if Token = Tok_Is then
949 Scan;
950 goto Subprogram_Body;
951
952 else
953 if Is_Non_Empty_List (Aspects) then
954 Set_Parent (Aspects, Decl_Node);
955 Set_Aspect_Specifications (Decl_Node, Aspects);
956 end if;
957
958 TF_Semicolon;
959 end if;
960
961 -- If this is a context in which a subprogram body is permitted,
962 -- set active SIS entry in case (see section titled "Handling
963 -- Semicolon Used in Place of IS" in body of Parser package)
964 -- Note that SIS_Missing_Semicolon_Message is already set properly.
965
966 if Pf_Flags.Pbod then
967 SIS_Labl := Scope.Table (Scope.Last).Labl;
968 SIS_Sloc := Scope.Table (Scope.Last).Sloc;
969 SIS_Ecol := Scope.Table (Scope.Last).Ecol;
970 SIS_Declaration_Node := Decl_Node;
971 SIS_Semicolon_Sloc := Prev_Token_Ptr;
972 SIS_Entry_Active := True;
973 end if;
974
975 Pop_Scope_Stack;
976 return Decl_Node;
977 end P_Subprogram;
978
979 ---------------------------------
980 -- 6.1 Subprogram Declaration --
981 ---------------------------------
982
983 -- Parsed by P_Subprogram (6.1)
984
985 ------------------------------------------
986 -- 6.1 Abstract Subprogram Declaration --
987 ------------------------------------------
988
989 -- Parsed by P_Subprogram (6.1)
990
991 -----------------------------------
992 -- 6.1 Subprogram Specification --
993 -----------------------------------
994
995 -- SUBPROGRAM_SPECIFICATION ::=
996 -- procedure DEFINING_PROGRAM_UNIT_NAME PARAMETER_PROFILE
997 -- | function DEFINING_DESIGNATOR PARAMETER_AND_RESULT_PROFILE
998
999 -- PARAMETER_PROFILE ::= [FORMAL_PART]
1000
1001 -- PARAMETER_AND_RESULT_PROFILE ::= [FORMAL_PART] return SUBTYPE_MARK
1002
1003 -- Subprogram specifications that appear in subprogram declarations
1004 -- are parsed by P_Subprogram (6.1). This routine is used in other
1005 -- contexts where subprogram specifications occur.
1006
1007 -- Note: this routine does not affect the scope stack in any way
1008
1009 -- Error recovery: can raise Error_Resync
1010
1011 function P_Subprogram_Specification return Node_Id is
1012 Specification_Node : Node_Id;
1013 Result_Not_Null : Boolean;
1014 Result_Node : Node_Id;
1015
1016 begin
1017 if Token = Tok_Function then
1018 Specification_Node := New_Node (N_Function_Specification, Token_Ptr);
1019 Scan; -- past FUNCTION
1020 Ignore (Tok_Body);
1021 Set_Defining_Unit_Name (Specification_Node, P_Defining_Designator);
1022 Set_Parameter_Specifications
1023 (Specification_Node, P_Parameter_Profile);
1024 Check_Junk_Semicolon_Before_Return;
1025 TF_Return;
1026
1027 Result_Not_Null := P_Null_Exclusion; -- Ada 2005 (AI-231)
1028
1029 -- Ada 2005 (AI-318-02)
1030
1031 if Token = Tok_Access then
1032 if Ada_Version < Ada_2005 then
1033 Error_Msg_SC
1034 ("anonymous access result type is an Ada 2005 extension");
1035 Error_Msg_SC ("\unit must be compiled with -gnat05 switch");
1036 end if;
1037
1038 Result_Node := P_Access_Definition (Result_Not_Null);
1039
1040 else
1041 Result_Node := P_Subtype_Mark;
1042 No_Constraint_Maybe_Expr_Func;
1043 end if;
1044
1045 Set_Null_Exclusion_Present (Specification_Node, Result_Not_Null);
1046 Set_Result_Definition (Specification_Node, Result_Node);
1047 return Specification_Node;
1048
1049 elsif Token = Tok_Procedure then
1050 Specification_Node := New_Node (N_Procedure_Specification, Token_Ptr);
1051 Scan; -- past PROCEDURE
1052 Ignore (Tok_Body);
1053 Set_Defining_Unit_Name
1054 (Specification_Node, P_Defining_Program_Unit_Name);
1055 Set_Parameter_Specifications
1056 (Specification_Node, P_Parameter_Profile);
1057 return Specification_Node;
1058
1059 else
1060 Error_Msg_SC ("subprogram specification expected");
1061 raise Error_Resync;
1062 end if;
1063 end P_Subprogram_Specification;
1064
1065 ---------------------
1066 -- 6.1 Designator --
1067 ---------------------
1068
1069 -- DESIGNATOR ::=
1070 -- [PARENT_UNIT_NAME .] IDENTIFIER | OPERATOR_SYMBOL
1071
1072 -- The caller has checked that the initial token is an identifier,
1073 -- operator symbol, or string literal. Note that we don't bother to
1074 -- do much error diagnosis in this routine, since it is only used for
1075 -- the label on END lines, and the routines in package Par.Endh will
1076 -- check that the label is appropriate.
1077
1078 -- Error recovery: cannot raise Error_Resync
1079
1080 function P_Designator return Node_Id is
1081 Ident_Node : Node_Id;
1082 Name_Node : Node_Id;
1083 Prefix_Node : Node_Id;
1084
1085 function Real_Dot return Boolean;
1086 -- Tests if a current token is an interesting period, i.e. is followed
1087 -- by an identifier or operator symbol or string literal. If not, it is
1088 -- probably just incorrect punctuation to be caught by our caller. Note
1089 -- that the case of an operator symbol or string literal is also an
1090 -- error, but that is an error that we catch here. If the result is
1091 -- True, a real dot has been scanned and we are positioned past it,
1092 -- if the result is False, the scan position is unchanged.
1093
1094 --------------
1095 -- Real_Dot --
1096 --------------
1097
1098 function Real_Dot return Boolean is
1099 Scan_State : Saved_Scan_State;
1100
1101 begin
1102 if Token /= Tok_Dot then
1103 return False;
1104
1105 else
1106 Save_Scan_State (Scan_State);
1107 Scan; -- past dot
1108
1109 if Token = Tok_Identifier
1110 or else Token = Tok_Operator_Symbol
1111 or else Token = Tok_String_Literal
1112 then
1113 return True;
1114
1115 else
1116 Restore_Scan_State (Scan_State);
1117 return False;
1118 end if;
1119 end if;
1120 end Real_Dot;
1121
1122 -- Start of processing for P_Designator
1123
1124 begin
1125 Ident_Node := Token_Node;
1126 Scan; -- past initial token
1127
1128 if Prev_Token = Tok_Operator_Symbol
1129 or else Prev_Token = Tok_String_Literal
1130 or else not Real_Dot
1131 then
1132 return Ident_Node;
1133
1134 -- Child name case
1135
1136 else
1137 Prefix_Node := Ident_Node;
1138
1139 -- Loop through child names, on entry to this loop, Prefix contains
1140 -- the name scanned so far, and Ident_Node is the last identifier.
1141
1142 loop
1143 Name_Node := New_Node (N_Selected_Component, Prev_Token_Ptr);
1144 Set_Prefix (Name_Node, Prefix_Node);
1145 Ident_Node := P_Identifier;
1146 Set_Selector_Name (Name_Node, Ident_Node);
1147 Prefix_Node := Name_Node;
1148 exit when not Real_Dot;
1149 end loop;
1150
1151 -- On exit from the loop, Ident_Node is the last identifier scanned,
1152 -- i.e. the defining identifier, and Prefix_Node is a node for the
1153 -- entire name, structured (incorrectly!) as a selected component.
1154
1155 Name_Node := Prefix (Prefix_Node);
1156 Change_Node (Prefix_Node, N_Designator);
1157 Set_Name (Prefix_Node, Name_Node);
1158 Set_Identifier (Prefix_Node, Ident_Node);
1159 return Prefix_Node;
1160 end if;
1161
1162 exception
1163 when Error_Resync =>
1164 while Token = Tok_Dot or else Token = Tok_Identifier loop
1165 Scan;
1166 end loop;
1167
1168 return Error;
1169 end P_Designator;
1170
1171 ------------------------------
1172 -- 6.1 Defining Designator --
1173 ------------------------------
1174
1175 -- DEFINING_DESIGNATOR ::=
1176 -- DEFINING_PROGRAM_UNIT_NAME | DEFINING_OPERATOR_SYMBOL
1177
1178 -- Error recovery: cannot raise Error_Resync
1179
1180 function P_Defining_Designator return Node_Id is
1181 begin
1182 if Token = Tok_Operator_Symbol then
1183 return P_Defining_Operator_Symbol;
1184
1185 elsif Token = Tok_String_Literal then
1186 Error_Msg_SC ("invalid operator name");
1187 Scan; -- past junk string
1188 return Error;
1189
1190 else
1191 return P_Defining_Program_Unit_Name;
1192 end if;
1193 end P_Defining_Designator;
1194
1195 -------------------------------------
1196 -- 6.1 Defining Program Unit Name --
1197 -------------------------------------
1198
1199 -- DEFINING_PROGRAM_UNIT_NAME ::=
1200 -- [PARENT_UNIT_NAME .] DEFINING_IDENTIFIER
1201
1202 -- Note: PARENT_UNIT_NAME may be present only in 95 mode at the outer level
1203
1204 -- Error recovery: cannot raise Error_Resync
1205
1206 function P_Defining_Program_Unit_Name return Node_Id is
1207 Ident_Node : Node_Id;
1208 Name_Node : Node_Id;
1209 Prefix_Node : Node_Id;
1210
1211 begin
1212 -- Set identifier casing if not already set and scan initial identifier
1213
1214 if Token = Tok_Identifier
1215 and then Identifier_Casing (Current_Source_File) = Unknown
1216 then
1217 Set_Identifier_Casing (Current_Source_File, Determine_Token_Casing);
1218 end if;
1219
1220 Ident_Node := P_Identifier (C_Dot);
1221 Merge_Identifier (Ident_Node, Tok_Return);
1222
1223 -- Normal case (not child library unit name)
1224
1225 if Token /= Tok_Dot then
1226 Change_Identifier_To_Defining_Identifier (Ident_Node);
1227 Warn_If_Standard_Redefinition (Ident_Node);
1228 return Ident_Node;
1229
1230 -- Child library unit name case
1231
1232 else
1233 if Scope.Last > 1 then
1234 Error_Msg_SP ("child unit allowed only at library level");
1235 raise Error_Resync;
1236
1237 elsif Ada_Version = Ada_83 then
1238 Error_Msg_SP ("(Ada 83) child unit not allowed!");
1239
1240 end if;
1241
1242 Prefix_Node := Ident_Node;
1243
1244 -- Loop through child names, on entry to this loop, Prefix contains
1245 -- the name scanned so far, and Ident_Node is the last identifier.
1246
1247 loop
1248 exit when Token /= Tok_Dot;
1249 Name_Node := New_Node (N_Selected_Component, Token_Ptr);
1250 Scan; -- past period
1251 Set_Prefix (Name_Node, Prefix_Node);
1252 Ident_Node := P_Identifier (C_Dot);
1253 Set_Selector_Name (Name_Node, Ident_Node);
1254 Prefix_Node := Name_Node;
1255 end loop;
1256
1257 -- On exit from the loop, Ident_Node is the last identifier scanned,
1258 -- i.e. the defining identifier, and Prefix_Node is a node for the
1259 -- entire name, structured (incorrectly!) as a selected component.
1260
1261 Name_Node := Prefix (Prefix_Node);
1262 Change_Node (Prefix_Node, N_Defining_Program_Unit_Name);
1263 Set_Name (Prefix_Node, Name_Node);
1264 Change_Identifier_To_Defining_Identifier (Ident_Node);
1265 Warn_If_Standard_Redefinition (Ident_Node);
1266 Set_Defining_Identifier (Prefix_Node, Ident_Node);
1267
1268 -- All set with unit name parsed
1269
1270 return Prefix_Node;
1271 end if;
1272
1273 exception
1274 when Error_Resync =>
1275 while Token = Tok_Dot or else Token = Tok_Identifier loop
1276 Scan;
1277 end loop;
1278
1279 return Error;
1280 end P_Defining_Program_Unit_Name;
1281
1282 --------------------------
1283 -- 6.1 Operator Symbol --
1284 --------------------------
1285
1286 -- OPERATOR_SYMBOL ::= STRING_LITERAL
1287
1288 -- Operator symbol is returned by the scanner as Tok_Operator_Symbol
1289
1290 -----------------------------------
1291 -- 6.1 Defining Operator Symbol --
1292 -----------------------------------
1293
1294 -- DEFINING_OPERATOR_SYMBOL ::= OPERATOR_SYMBOL
1295
1296 -- The caller has checked that the initial symbol is an operator symbol
1297
1298 function P_Defining_Operator_Symbol return Node_Id is
1299 Op_Node : Node_Id;
1300
1301 begin
1302 Op_Node := Token_Node;
1303 Change_Operator_Symbol_To_Defining_Operator_Symbol (Op_Node);
1304 Scan; -- past operator symbol
1305 return Op_Node;
1306 end P_Defining_Operator_Symbol;
1307
1308 ----------------------------
1309 -- 6.1 Parameter_Profile --
1310 ----------------------------
1311
1312 -- PARAMETER_PROFILE ::= [FORMAL_PART]
1313
1314 -- Empty is returned if no formal part is present
1315
1316 -- Error recovery: cannot raise Error_Resync
1317
1318 function P_Parameter_Profile return List_Id is
1319 begin
1320 if Token = Tok_Left_Paren then
1321 Scan; -- part left paren
1322 return P_Formal_Part;
1323 else
1324 return No_List;
1325 end if;
1326 end P_Parameter_Profile;
1327
1328 ---------------------------------------
1329 -- 6.1 Parameter And Result Profile --
1330 ---------------------------------------
1331
1332 -- Parsed by its parent construct, which uses P_Parameter_Profile to
1333 -- parse the parameters, and P_Subtype_Mark to parse the return type.
1334
1335 ----------------------
1336 -- 6.1 Formal part --
1337 ----------------------
1338
1339 -- FORMAL_PART ::= (PARAMETER_SPECIFICATION {; PARAMETER_SPECIFICATION})
1340
1341 -- PARAMETER_SPECIFICATION ::=
1342 -- DEFINING_IDENTIFIER_LIST : [ALIASED] MODE [NULL_EXCLUSION]
1343 -- SUBTYPE_MARK [:= DEFAULT_EXPRESSION]
1344 -- | DEFINING_IDENTIFIER_LIST : ACCESS_DEFINITION
1345 -- [:= DEFAULT_EXPRESSION]
1346
1347 -- This scans the construct Formal_Part. The caller has already checked
1348 -- that the initial token is a left parenthesis, and skipped past it, so
1349 -- that on entry Token is the first token following the left parenthesis.
1350
1351 -- Note: The ALIASED keyword is allowed only in Ada 2012 mode (AI 142)
1352
1353 -- Error recovery: cannot raise Error_Resync
1354
1355 function P_Formal_Part return List_Id is
1356 Specification_List : List_Id;
1357 Specification_Node : Node_Id;
1358 Scan_State : Saved_Scan_State;
1359 Num_Idents : Nat;
1360 Ident : Nat;
1361 Ident_Sloc : Source_Ptr;
1362 Not_Null_Present : Boolean := False;
1363 Not_Null_Sloc : Source_Ptr;
1364
1365 Idents : array (Int range 1 .. 4096) of Entity_Id;
1366 -- This array holds the list of defining identifiers. The upper bound
1367 -- of 4096 is intended to be essentially infinite, and we do not even
1368 -- bother to check for it being exceeded.
1369
1370 begin
1371 Specification_List := New_List;
1372 Specification_Loop : loop
1373 begin
1374 if Token = Tok_Pragma then
1375 Error_Msg_SC ("pragma not allowed in formal part");
1376 Discard_Junk_Node (P_Pragma (Skipping => True));
1377 end if;
1378
1379 Ignore (Tok_Left_Paren);
1380 Ident_Sloc := Token_Ptr;
1381 Idents (1) := P_Defining_Identifier (C_Comma_Colon);
1382 Num_Idents := 1;
1383
1384 Ident_Loop : loop
1385 exit Ident_Loop when Token = Tok_Colon;
1386
1387 -- The only valid tokens are colon and comma, so if we have
1388 -- neither do a bit of investigation to see which is the
1389 -- better choice for insertion.
1390
1391 if Token /= Tok_Comma then
1392
1393 -- Assume colon if ALIASED, IN or OUT keyword found
1394
1395 exit Ident_Loop when Token = Tok_Aliased or else
1396 Token = Tok_In or else
1397 Token = Tok_Out;
1398
1399 -- Otherwise scan ahead
1400
1401 Save_Scan_State (Scan_State);
1402 Look_Ahead : loop
1403
1404 -- If we run into a semicolon, then assume that a
1405 -- colon was missing, e.g. Parms (X Y; ...). Also
1406 -- assume missing colon on EOF (a real disaster!)
1407 -- and on a right paren, e.g. Parms (X Y), and also
1408 -- on an assignment symbol, e.g. Parms (X Y := ..)
1409
1410 if Token = Tok_Semicolon
1411 or else Token = Tok_Right_Paren
1412 or else Token = Tok_EOF
1413 or else Token = Tok_Colon_Equal
1414 then
1415 Restore_Scan_State (Scan_State);
1416 exit Ident_Loop;
1417
1418 -- If we run into a colon, assume that we had a missing
1419 -- comma, e.g. Parms (A B : ...). Also assume a missing
1420 -- comma if we hit another comma, e.g. Parms (A B, C ..)
1421
1422 elsif Token = Tok_Colon
1423 or else Token = Tok_Comma
1424 then
1425 Restore_Scan_State (Scan_State);
1426 exit Look_Ahead;
1427 end if;
1428
1429 Scan;
1430 end loop Look_Ahead;
1431 end if;
1432
1433 -- Here if a comma is present, or to be assumed
1434
1435 T_Comma;
1436 Num_Idents := Num_Idents + 1;
1437 Idents (Num_Idents) := P_Defining_Identifier (C_Comma_Colon);
1438 end loop Ident_Loop;
1439
1440 -- Fall through the loop on encountering a colon, or deciding
1441 -- that there is a missing colon.
1442
1443 T_Colon;
1444
1445 -- If there are multiple identifiers, we repeatedly scan the
1446 -- type and initialization expression information by resetting
1447 -- the scan pointer (so that we get completely separate trees
1448 -- for each occurrence).
1449
1450 if Num_Idents > 1 then
1451 Save_Scan_State (Scan_State);
1452 end if;
1453
1454 -- Loop through defining identifiers in list
1455
1456 Ident := 1;
1457
1458 Ident_List_Loop : loop
1459 Specification_Node :=
1460 New_Node (N_Parameter_Specification, Ident_Sloc);
1461 Set_Defining_Identifier (Specification_Node, Idents (Ident));
1462
1463 -- Scan possible ALIASED for Ada 2012 (AI-142)
1464
1465 if Token = Tok_Aliased then
1466 if Ada_Version < Ada_2012 then
1467 Error_Msg_SC ("ALIASED parameter is an Ada 2012 feature");
1468 else
1469 Set_Aliased_Present (Specification_Node);
1470 end if;
1471
1472 Scan; -- past ALIASED
1473 end if;
1474
1475 -- Scan possible NOT NULL for Ada 2005 (AI-231, AI-447)
1476
1477 Not_Null_Sloc := Token_Ptr;
1478 Not_Null_Present :=
1479 P_Null_Exclusion (Allow_Anonymous_In_95 => True);
1480
1481 -- Case of ACCESS keyword present
1482
1483 if Token = Tok_Access then
1484 Set_Null_Exclusion_Present
1485 (Specification_Node, Not_Null_Present);
1486
1487 if Ada_Version = Ada_83 then
1488 Error_Msg_SC ("(Ada 83) access parameters not allowed");
1489 end if;
1490
1491 Set_Parameter_Type
1492 (Specification_Node,
1493 P_Access_Definition (Not_Null_Present));
1494
1495 -- Case of IN or OUT present
1496
1497 else
1498 if Token = Tok_In or else Token = Tok_Out then
1499 if Not_Null_Present then
1500 Error_Msg
1501 ("`NOT NULL` can only be used with `ACCESS`",
1502 Not_Null_Sloc);
1503
1504 if Token = Tok_In then
1505 Error_Msg
1506 ("\`IN` not allowed together with `ACCESS`",
1507 Not_Null_Sloc);
1508 else
1509 Error_Msg
1510 ("\`OUT` not allowed together with `ACCESS`",
1511 Not_Null_Sloc);
1512 end if;
1513 end if;
1514
1515 P_Mode (Specification_Node);
1516 Not_Null_Present := P_Null_Exclusion; -- Ada 2005 (AI-231)
1517 end if;
1518
1519 Set_Null_Exclusion_Present
1520 (Specification_Node, Not_Null_Present);
1521
1522 if Token = Tok_Procedure
1523 or else
1524 Token = Tok_Function
1525 then
1526 Error_Msg_SC ("formal subprogram parameter not allowed");
1527 Scan;
1528
1529 if Token = Tok_Left_Paren then
1530 Discard_Junk_List (P_Formal_Part);
1531 end if;
1532
1533 if Token = Tok_Return then
1534 Scan;
1535 Discard_Junk_Node (P_Subtype_Mark);
1536 end if;
1537
1538 Set_Parameter_Type (Specification_Node, Error);
1539
1540 else
1541 Set_Parameter_Type (Specification_Node, P_Subtype_Mark);
1542 No_Constraint;
1543 end if;
1544 end if;
1545
1546 Set_Expression (Specification_Node, Init_Expr_Opt (True));
1547
1548 if Ident > 1 then
1549 Set_Prev_Ids (Specification_Node, True);
1550 end if;
1551
1552 if Ident < Num_Idents then
1553 Set_More_Ids (Specification_Node, True);
1554 end if;
1555
1556 Append (Specification_Node, Specification_List);
1557 exit Ident_List_Loop when Ident = Num_Idents;
1558 Ident := Ident + 1;
1559 Restore_Scan_State (Scan_State);
1560 end loop Ident_List_Loop;
1561
1562 exception
1563 when Error_Resync =>
1564 Resync_Semicolon_List;
1565 end;
1566
1567 if Token = Tok_Semicolon then
1568 Save_Scan_State (Scan_State);
1569 Scan; -- past semicolon
1570
1571 -- If we have RETURN or IS after the semicolon, then assume
1572 -- that semicolon should have been a right parenthesis and exit
1573
1574 if Token = Tok_Is or else Token = Tok_Return then
1575 Error_Msg_SP -- CODEFIX
1576 ("|"";"" should be "")""");
1577 exit Specification_Loop;
1578 end if;
1579
1580 -- If we have a declaration keyword after the semicolon, then
1581 -- assume we had a missing right parenthesis and terminate list
1582
1583 if Token in Token_Class_Declk then
1584 Error_Msg_AP -- CODEFIX
1585 ("missing "")""");
1586 Restore_Scan_State (Scan_State);
1587 exit Specification_Loop;
1588 end if;
1589
1590 elsif Token = Tok_Right_Paren then
1591 Scan; -- past right paren
1592 exit Specification_Loop;
1593
1594 -- Special check for common error of using comma instead of semicolon
1595
1596 elsif Token = Tok_Comma then
1597 T_Semicolon;
1598 Scan; -- past comma
1599
1600 -- Special check for omitted separator
1601
1602 elsif Token = Tok_Identifier then
1603 T_Semicolon;
1604
1605 -- If nothing sensible, skip to next semicolon or right paren
1606
1607 else
1608 T_Semicolon;
1609 Resync_Semicolon_List;
1610
1611 if Token = Tok_Semicolon then
1612 Scan; -- past semicolon
1613 else
1614 T_Right_Paren;
1615 exit Specification_Loop;
1616 end if;
1617 end if;
1618 end loop Specification_Loop;
1619
1620 return Specification_List;
1621 end P_Formal_Part;
1622
1623 ----------------------------------
1624 -- 6.1 Parameter Specification --
1625 ----------------------------------
1626
1627 -- Parsed by P_Formal_Part (6.1)
1628
1629 ---------------
1630 -- 6.1 Mode --
1631 ---------------
1632
1633 -- MODE ::= [in] | in out | out
1634
1635 -- There is no explicit node in the tree for the Mode. Instead the
1636 -- In_Present and Out_Present flags are set in the parent node to
1637 -- record the presence of keywords specifying the mode.
1638
1639 -- Error_Recovery: cannot raise Error_Resync
1640
1641 procedure P_Mode (Node : Node_Id) is
1642 begin
1643 if Token = Tok_In then
1644 Scan; -- past IN
1645 Set_In_Present (Node, True);
1646
1647 if Style.Mode_In_Check and then Token /= Tok_Out then
1648 Error_Msg_SP -- CODEFIX
1649 ("(style) IN should be omitted");
1650 end if;
1651
1652 -- Since Ada 2005, formal objects can have an anonymous access type,
1653 -- and of course carry a mode indicator.
1654
1655 if Token = Tok_Access
1656 and then Nkind (Node) /= N_Formal_Object_Declaration
1657 then
1658 Error_Msg_SP ("IN not allowed together with ACCESS");
1659 Scan; -- past ACCESS
1660 end if;
1661 end if;
1662
1663 if Token = Tok_Out then
1664 Scan; -- past OUT
1665 Set_Out_Present (Node, True);
1666 end if;
1667
1668 if Token = Tok_In then
1669 Error_Msg_SC ("IN must precede OUT in parameter mode");
1670 Scan; -- past IN
1671 Set_In_Present (Node, True);
1672 end if;
1673 end P_Mode;
1674
1675 --------------------------
1676 -- 6.3 Subprogram Body --
1677 --------------------------
1678
1679 -- Parsed by P_Subprogram (6.1)
1680
1681 -----------------------------------
1682 -- 6.4 Procedure Call Statement --
1683 -----------------------------------
1684
1685 -- Parsed by P_Sequence_Of_Statements (5.1)
1686
1687 ------------------------
1688 -- 6.4 Function Call --
1689 ------------------------
1690
1691 -- Parsed by P_Name (4.1)
1692
1693 --------------------------------
1694 -- 6.4 Actual Parameter Part --
1695 --------------------------------
1696
1697 -- Parsed by P_Name (4.1)
1698
1699 --------------------------------
1700 -- 6.4 Parameter Association --
1701 --------------------------------
1702
1703 -- Parsed by P_Name (4.1)
1704
1705 ------------------------------------
1706 -- 6.4 Explicit Actual Parameter --
1707 ------------------------------------
1708
1709 -- Parsed by P_Name (4.1)
1710
1711 ---------------------------
1712 -- 6.5 Return Statement --
1713 ---------------------------
1714
1715 -- SIMPLE_RETURN_STATEMENT ::= return [EXPRESSION];
1716 --
1717 -- EXTENDED_RETURN_STATEMENT ::=
1718 -- return DEFINING_IDENTIFIER : [aliased] RETURN_SUBTYPE_INDICATION
1719 -- [:= EXPRESSION] [do
1720 -- HANDLED_SEQUENCE_OF_STATEMENTS
1721 -- end return];
1722 --
1723 -- RETURN_SUBTYPE_INDICATION ::= SUBTYPE_INDICATION | ACCESS_DEFINITION
1724
1725 -- RETURN_STATEMENT ::= return [EXPRESSION];
1726
1727 -- Error recovery: can raise Error_Resync
1728
1729 procedure P_Return_Subtype_Indication (Decl_Node : Node_Id) is
1730
1731 -- Note: We don't need to check Ada_Version here, because this is
1732 -- only called in >= Ada 2005 cases anyway.
1733
1734 Not_Null_Present : constant Boolean := P_Null_Exclusion;
1735
1736 begin
1737 Set_Null_Exclusion_Present (Decl_Node, Not_Null_Present);
1738
1739 if Token = Tok_Access then
1740 Set_Object_Definition
1741 (Decl_Node, P_Access_Definition (Not_Null_Present));
1742 else
1743 Set_Object_Definition
1744 (Decl_Node, P_Subtype_Indication (Not_Null_Present));
1745 end if;
1746 end P_Return_Subtype_Indication;
1747
1748 -- Error recovery: can raise Error_Resync
1749
1750 function P_Return_Object_Declaration return Node_Id is
1751 Return_Obj : Node_Id;
1752 Decl_Node : Node_Id;
1753
1754 begin
1755 Return_Obj := Token_Node;
1756 Change_Identifier_To_Defining_Identifier (Return_Obj);
1757 Warn_If_Standard_Redefinition (Return_Obj);
1758 Decl_Node := New_Node (N_Object_Declaration, Token_Ptr);
1759 Set_Defining_Identifier (Decl_Node, Return_Obj);
1760
1761 Scan; -- past identifier
1762 Scan; -- past :
1763
1764 -- First an error check, if we have two identifiers in a row, a likely
1765 -- possibility is that the first of the identifiers is an incorrectly
1766 -- spelled keyword. See similar check in P_Identifier_Declarations.
1767
1768 if Token = Tok_Identifier then
1769 declare
1770 SS : Saved_Scan_State;
1771 I2 : Boolean;
1772
1773 begin
1774 Save_Scan_State (SS);
1775 Scan; -- past initial identifier
1776 I2 := (Token = Tok_Identifier);
1777 Restore_Scan_State (SS);
1778
1779 if I2
1780 and then
1781 (Bad_Spelling_Of (Tok_Access) or else
1782 Bad_Spelling_Of (Tok_Aliased) or else
1783 Bad_Spelling_Of (Tok_Constant))
1784 then
1785 null;
1786 end if;
1787 end;
1788 end if;
1789
1790 -- We allow "constant" here (as in "return Result : constant
1791 -- T..."). This is not in the latest RM, but the ARG is considering an
1792 -- AI on the subject (see AI05-0015-1), which we expect to be approved.
1793
1794 if Token = Tok_Constant then
1795 Scan; -- past CONSTANT
1796 Set_Constant_Present (Decl_Node);
1797
1798 if Token = Tok_Aliased then
1799 Error_Msg_SC -- CODEFIX
1800 ("ALIASED should be before CONSTANT");
1801 Scan; -- past ALIASED
1802 Set_Aliased_Present (Decl_Node);
1803 end if;
1804
1805 elsif Token = Tok_Aliased then
1806 Scan; -- past ALIASED
1807 Set_Aliased_Present (Decl_Node);
1808
1809 -- The restrictions on the use of aliased in an extended return
1810 -- are semantic, not syntactic.
1811
1812 if Token = Tok_Constant then
1813 Scan; -- past CONSTANT
1814 Set_Constant_Present (Decl_Node);
1815 end if;
1816 end if;
1817
1818 P_Return_Subtype_Indication (Decl_Node);
1819
1820 if Token = Tok_Colon_Equal then
1821 Scan; -- past :=
1822 Set_Expression (Decl_Node, P_Expression_No_Right_Paren);
1823 end if;
1824
1825 return Decl_Node;
1826 end P_Return_Object_Declaration;
1827
1828 -- Error recovery: can raise Error_Resync
1829
1830 function P_Return_Statement return Node_Id is
1831 -- The caller has checked that the initial token is RETURN
1832
1833 function Is_Simple return Boolean;
1834 -- Scan state is just after RETURN (and is left that way).
1835 -- Determine whether this is a simple or extended return statement
1836 -- by looking ahead for "identifier :", which implies extended.
1837
1838 ---------------
1839 -- Is_Simple --
1840 ---------------
1841
1842 function Is_Simple return Boolean is
1843 Scan_State : Saved_Scan_State;
1844 Result : Boolean := True;
1845
1846 begin
1847 if Token = Tok_Identifier then
1848 Save_Scan_State (Scan_State); -- at identifier
1849 Scan; -- past identifier
1850
1851 if Token = Tok_Colon then
1852 Result := False; -- It's an extended_return_statement.
1853 end if;
1854
1855 Restore_Scan_State (Scan_State); -- to identifier
1856 end if;
1857
1858 return Result;
1859 end Is_Simple;
1860
1861 Return_Sloc : constant Source_Ptr := Token_Ptr;
1862 Return_Node : Node_Id;
1863
1864 -- Start of processing for P_Return_Statement
1865
1866 begin
1867 Scan; -- past RETURN
1868
1869 -- Simple_return_statement, no expression, return an
1870 -- N_Simple_Return_Statement node with the expression field left Empty.
1871
1872 if Token = Tok_Semicolon then
1873 Scan; -- past ;
1874 Return_Node := New_Node (N_Simple_Return_Statement, Return_Sloc);
1875
1876 -- Non-trivial case
1877
1878 else
1879 -- Simple_return_statement with expression
1880
1881 -- We avoid trying to scan an expression if we are at an
1882 -- expression terminator since in that case the best error
1883 -- message is probably that we have a missing semicolon.
1884
1885 if Is_Simple then
1886 Return_Node := New_Node (N_Simple_Return_Statement, Return_Sloc);
1887
1888 if Token not in Token_Class_Eterm then
1889 Set_Expression (Return_Node, P_Expression_No_Right_Paren);
1890 end if;
1891
1892 -- Extended_return_statement (Ada 2005 only -- AI-318):
1893
1894 else
1895 if Ada_Version < Ada_2005 then
1896 Error_Msg_SP
1897 (" extended_return_statement is an Ada 2005 extension");
1898 Error_Msg_SP ("\unit must be compiled with -gnat05 switch");
1899 end if;
1900
1901 Return_Node := New_Node (N_Extended_Return_Statement, Return_Sloc);
1902 Set_Return_Object_Declarations
1903 (Return_Node, New_List (P_Return_Object_Declaration));
1904
1905 if Token = Tok_Do then
1906 Push_Scope_Stack;
1907 Scope.Table (Scope.Last).Etyp := E_Return;
1908 Scope.Table (Scope.Last).Ecol := Start_Column;
1909 Scope.Table (Scope.Last).Sloc := Return_Sloc;
1910
1911 Scan; -- past DO
1912 Set_Handled_Statement_Sequence
1913 (Return_Node, P_Handled_Sequence_Of_Statements);
1914 End_Statements;
1915
1916 -- Do we need to handle Error_Resync here???
1917 end if;
1918 end if;
1919
1920 TF_Semicolon;
1921 end if;
1922
1923 return Return_Node;
1924 end P_Return_Statement;
1925
1926 end Ch6;
Mirror of the offical gcc git repository hosted at gcc.gnu.org