gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for SPARK cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    -----------------------------
 155    -- SPARK Xrefs Information --
 156    -----------------------------
 157
 158    package body SPARK_Specific is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Actual_Typ     : Character := Typ;
 377       Call           : Node_Id;
 378       Def            : Source_Ptr;
 379       Ent            : Entity_Id;
 380       Ent_Scope      : Entity_Id;
 381       Formal         : Entity_Id;
 382       Kind           : Entity_Kind;
 383       Nod            : Node_Id;
 384       Ref            : Source_Ptr;
 385       Ref_Scope      : Entity_Id;
 386
 387       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 388       --  Get the enclosing entity through renamings, which may come from
 389       --  source or from the translation of generic instantiations.
 390
 391       function Is_On_LHS (Node : Node_Id) return Boolean;
 392       --  Used to check if a node is on the left hand side of an assignment.
 393       --  The following cases are handled:
 394       --
 395       --   Variable    Node is a direct descendant of left hand side of an
 396       --               assignment statement.
 397       --
 398       --   Prefix      Of an indexed or selected component that is present in
 399       --               a subtree rooted by an assignment statement. There is
 400       --               no restriction of nesting of components, thus cases
 401       --               such as A.B (C).D are handled properly. However a prefix
 402       --               of a dereference (either implicit or explicit) is never
 403       --               considered as on a LHS.
 404       --
 405       --   Out param   Same as above cases, but OUT parameter
 406
 407       function OK_To_Set_Referenced return Boolean;
 408       --  Returns True if the Referenced flag can be set. There are a few
 409       --  exceptions where we do not want to set this flag, see body for
 410       --  details of these exceptional cases.
 411
 412       ---------------------------
 413       -- Get_Through_Renamings --
 414       ---------------------------
 415
 416       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 417          Result : Entity_Id := E;
 418       begin
 419          while Present (Result)
 420            and then Is_Object (Result)
 421            and then Present (Renamed_Object (Result))
 422          loop
 423             Result := Get_Enclosing_Object (Renamed_Object (Result));
 424          end loop;
 425          return Result;
 426       end Get_Through_Renamings;
 427
 428       ---------------
 429       -- Is_On_LHS --
 430       ---------------
 431
 432       --  ??? There are several routines here and there that perform a similar
 433       --      (but subtly different) computation, which should be factored:
 434
 435       --      Sem_Util.May_Be_Lvalue
 436       --      Sem_Util.Known_To_Be_Assigned
 437       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 438       --      Exp_Smem.Is_Out_Actual
 439
 440       function Is_On_LHS (Node : Node_Id) return Boolean is
 441          N : Node_Id;
 442          P : Node_Id;
 443          K : Node_Kind;
 444
 445       begin
 446          --  Only identifiers are considered, is this necessary???
 447
 448          if Nkind (Node) /= N_Identifier then
 449             return False;
 450          end if;
 451
 452          --  Immediate return if appeared as OUT parameter
 453
 454          if Kind = E_Out_Parameter then
 455             return True;
 456          end if;
 457
 458          --  Search for assignment statement subtree root
 459
 460          N := Node;
 461          loop
 462             P := Parent (N);
 463             K := Nkind (P);
 464
 465             if K = N_Assignment_Statement then
 466                return Name (P) = N;
 467
 468             --  Check whether the parent is a component and the current node is
 469             --  its prefix, but return False if the current node has an access
 470             --  type, as in that case the selected or indexed component is an
 471             --  implicit dereference, and the LHS is the designated object, not
 472             --  the access object.
 473
 474             --  ??? case of a slice assignment?
 475
 476             --  ??? Note that in some cases this is called too early
 477             --  (see comments in Sem_Ch8.Find_Direct_Name), at a point where
 478             --  the tree is not fully typed yet. In that case we may lack
 479             --  an Etype for N, and we must disable the check for an implicit
 480             --  dereference. If the dereference is on an LHS, this causes a
 481             --  false positive.
 482
 483             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 484               and then Prefix (P) = N
 485               and then not (Present (Etype (N))
 486                               and then
 487                             Is_Access_Type (Etype (N)))
 488             then
 489                N := P;
 490
 491             --  All other cases, definitely not on left side
 492
 493             else
 494                return False;
 495             end if;
 496          end loop;
 497       end Is_On_LHS;
 498
 499       ---------------------------
 500       -- OK_To_Set_Referenced --
 501       ---------------------------
 502
 503       function OK_To_Set_Referenced return Boolean is
 504          P : Node_Id;
 505
 506       begin
 507          --  A reference from a pragma Unreferenced or pragma Unmodified or
 508          --  pragma Warnings does not cause the Referenced flag to be set.
 509          --  This avoids silly warnings about things being referenced and
 510          --  not assigned when the only reference is from the pragma.
 511
 512          if Nkind (N) = N_Identifier then
 513             P := Parent (N);
 514
 515             if Nkind (P) = N_Pragma_Argument_Association then
 516                P := Parent (P);
 517
 518                if Nkind (P) = N_Pragma then
 519                   if Nam_In (Pragma_Name (P), Name_Warnings,
 520                                               Name_Unmodified,
 521                                               Name_Unreferenced)
 522                   then
 523                      return False;
 524                   end if;
 525                end if;
 526
 527             --  A reference to a formal in a named parameter association does
 528             --  not make the formal referenced. Formals that are unused in the
 529             --  subprogram body are properly flagged as such, even if calls
 530             --  elsewhere use named notation.
 531
 532             elsif Nkind (P) = N_Parameter_Association
 533               and then N = Selector_Name (P)
 534             then
 535                return False;
 536             end if;
 537          end if;
 538
 539          return True;
 540       end OK_To_Set_Referenced;
 541
 542    --  Start of processing for Generate_Reference
 543
 544    begin
 545       pragma Assert (Nkind (E) in N_Entity);
 546       Find_Actual (N, Formal, Call);
 547
 548       if Present (Formal) then
 549          Kind := Ekind (Formal);
 550       else
 551          Kind := E_Void;
 552       end if;
 553
 554       --  Check for obsolescent reference to package ASCII. GNAT treats this
 555       --  element of annex J specially since in practice, programs make a lot
 556       --  of use of this feature, so we don't include it in the set of features
 557       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 558       --  are required to note it as a violation of the RM defined restriction.
 559
 560       if E = Standard_ASCII then
 561          Check_Restriction (No_Obsolescent_Features, N);
 562       end if;
 563
 564       --  Check for reference to entity marked with Is_Obsolescent
 565
 566       --  Note that we always allow obsolescent references in the compiler
 567       --  itself and the run time, since we assume that we know what we are
 568       --  doing in such cases. For example the calls in Ada.Characters.Handling
 569       --  to its own obsolescent subprograms are just fine.
 570
 571       --  In any case we only generate warnings if we are in the extended main
 572       --  source unit, and the entity itself is not in the extended main source
 573       --  unit, since we assume the source unit itself knows what is going on
 574       --  (and for sure we do not want silly warnings, e.g. on the end line of
 575       --  an obsolescent procedure body).
 576
 577       if Is_Obsolescent (E)
 578         and then not GNAT_Mode
 579         and then not In_Extended_Main_Source_Unit (E)
 580         and then In_Extended_Main_Source_Unit (N)
 581       then
 582          Check_Restriction (No_Obsolescent_Features, N);
 583
 584          if Warn_On_Obsolescent_Feature then
 585             Output_Obsolescent_Entity_Warnings (N, E);
 586          end if;
 587       end if;
 588
 589       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 590       --  detect real explicit references (modifications and references).
 591
 592       if Comes_From_Source (N)
 593         and then Is_Ada_2005_Only (E)
 594         and then Ada_Version < Ada_2005
 595         and then Warn_On_Ada_2005_Compatibility
 596         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 597       then
 598          Error_Msg_NE ("& is only defined in Ada 2005?y?", N, E);
 599       end if;
 600
 601       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 602       --  detect real explicit references (modifications and references).
 603
 604       if Comes_From_Source (N)
 605         and then Is_Ada_2012_Only (E)
 606         and then Ada_Version < Ada_2012
 607         and then Warn_On_Ada_2012_Compatibility
 608         and then (Typ = 'm' or else Typ = 'r')
 609       then
 610          Error_Msg_NE ("& is only defined in Ada 2012?y?", N, E);
 611       end if;
 612
 613       --  Never collect references if not in main source unit. However, we omit
 614       --  this test if Typ is 'e' or 'k', since these entries are structural,
 615       --  and it is useful to have them in units that reference packages as
 616       --  well as units that define packages. We also omit the test for the
 617       --  case of 'p' since we want to include inherited primitive operations
 618       --  from other packages.
 619
 620       --  We also omit this test is this is a body reference for a subprogram
 621       --  instantiation. In this case the reference is to the generic body,
 622       --  which clearly need not be in the main unit containing the instance.
 623       --  For the same reason we accept an implicit reference generated for
 624       --  a default in an instance.
 625
 626       if not In_Extended_Main_Source_Unit (N) then
 627          if Typ = 'e'
 628            or else Typ = 'I'
 629            or else Typ = 'p'
 630            or else Typ = 'i'
 631            or else Typ = 'k'
 632            or else (Typ = 'b' and then Is_Generic_Instance (E))
 633
 634             --  Allow the generation of references to reads, writes and calls
 635             --  in SPARK mode when the related context comes from an instance.
 636
 637            or else
 638              (SPARK_Mode
 639                 and then In_Extended_Main_Code_Unit (N)
 640                 and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 641          then
 642             null;
 643          else
 644             return;
 645          end if;
 646       end if;
 647
 648       --  For reference type p, the entity must be in main source unit
 649
 650       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 651          return;
 652       end if;
 653
 654       --  Unless the reference is forced, we ignore references where the
 655       --  reference itself does not come from source.
 656
 657       if not Force and then not Comes_From_Source (N) then
 658          return;
 659       end if;
 660
 661       --  Deal with setting entity as referenced, unless suppressed. Note that
 662       --  we still do Set_Referenced on entities that do not come from source.
 663       --  This situation arises when we have a source reference to a derived
 664       --  operation, where the derived operation itself does not come from
 665       --  source, but we still want to mark it as referenced, since we really
 666       --  are referencing an entity in the corresponding package (this avoids
 667       --  wrong complaints that the package contains no referenced entities).
 668
 669       if Set_Ref then
 670
 671          --  Assignable object appearing on left side of assignment or as
 672          --  an out parameter.
 673
 674          if Is_Assignable (E)
 675            and then Is_On_LHS (N)
 676            and then Ekind (E) /= E_In_Out_Parameter
 677          then
 678             --  For objects that are renamings, just set as simply referenced
 679             --  we do not try to do assignment type tracking in this case.
 680
 681             if Present (Renamed_Object (E)) then
 682                Set_Referenced (E);
 683
 684             --  Out parameter case
 685
 686             elsif Kind = E_Out_Parameter then
 687
 688                --  If warning mode for all out parameters is set, or this is
 689                --  the only warning parameter, then we want to mark this for
 690                --  later warning logic by setting Referenced_As_Out_Parameter
 691
 692                if Warn_On_Modified_As_Out_Parameter (Formal) then
 693                   Set_Referenced_As_Out_Parameter (E, True);
 694                   Set_Referenced_As_LHS (E, False);
 695
 696                --  For OUT parameter not covered by the above cases, we simply
 697                --  regard it as a normal reference (in this case we do not
 698                --  want any of the warning machinery for out parameters).
 699
 700                else
 701                   Set_Referenced (E);
 702                end if;
 703
 704             --  For the left hand of an assignment case, we do nothing here.
 705             --  The processing for Analyze_Assignment_Statement will set the
 706             --  Referenced_As_LHS flag.
 707
 708             else
 709                null;
 710             end if;
 711
 712          --  Check for a reference in a pragma that should not count as a
 713          --  making the variable referenced for warning purposes.
 714
 715          elsif Is_Non_Significant_Pragma_Reference (N) then
 716             null;
 717
 718          --  A reference in an attribute definition clause does not count as a
 719          --  reference except for the case of Address. The reason that 'Address
 720          --  is an exception is that it creates an alias through which the
 721          --  variable may be referenced.
 722
 723          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 724            and then Chars (Parent (N)) /= Name_Address
 725            and then N = Name (Parent (N))
 726          then
 727             null;
 728
 729          --  Constant completion does not count as a reference
 730
 731          elsif Typ = 'c'
 732            and then Ekind (E) = E_Constant
 733          then
 734             null;
 735
 736          --  Record representation clause does not count as a reference
 737
 738          elsif Nkind (N) = N_Identifier
 739            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 740          then
 741             null;
 742
 743          --  Discriminants do not need to produce a reference to record type
 744
 745          elsif Typ = 'd'
 746            and then Nkind (Parent (N)) = N_Discriminant_Specification
 747          then
 748             null;
 749
 750          --  All other cases
 751
 752          else
 753             --  Special processing for IN OUT parameters, where we have an
 754             --  implicit assignment to a simple variable.
 755
 756             if Kind = E_In_Out_Parameter
 757               and then Is_Assignable (E)
 758             then
 759                --  For sure this counts as a normal read reference
 760
 761                Set_Referenced (E);
 762                Set_Last_Assignment (E, Empty);
 763
 764                --  We count it as being referenced as an out parameter if the
 765                --  option is set to warn on all out parameters, except that we
 766                --  have a special exclusion for an intrinsic subprogram, which
 767                --  is most likely an instantiation of Unchecked_Deallocation
 768                --  which we do not want to consider as an assignment since it
 769                --  generates false positives. We also exclude the case of an
 770                --  IN OUT parameter if the name of the procedure is Free,
 771                --  since we suspect similar semantics.
 772
 773                if Warn_On_All_Unread_Out_Parameters
 774                  and then Is_Entity_Name (Name (Call))
 775                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 776                  and then Chars (Name (Call)) /= Name_Free
 777                then
 778                   Set_Referenced_As_Out_Parameter (E, True);
 779                   Set_Referenced_As_LHS (E, False);
 780                end if;
 781
 782             --  Don't count a recursive reference within a subprogram as a
 783             --  reference (that allows detection of a recursive subprogram
 784             --  whose only references are recursive calls as unreferenced).
 785
 786             elsif Is_Subprogram (E)
 787               and then E = Nearest_Dynamic_Scope (Current_Scope)
 788             then
 789                null;
 790
 791             --  Any other occurrence counts as referencing the entity
 792
 793             elsif OK_To_Set_Referenced then
 794                Set_Referenced (E);
 795
 796                --  If variable, this is an OK reference after an assignment
 797                --  so we can clear the Last_Assignment indication.
 798
 799                if Is_Assignable (E) then
 800                   Set_Last_Assignment (E, Empty);
 801                end if;
 802             end if;
 803          end if;
 804
 805          --  Check for pragma Unreferenced given and reference is within
 806          --  this source unit (occasion for possible warning to be issued).
 807
 808          if Has_Unreferenced (E)
 809            and then In_Same_Extended_Unit (E, N)
 810          then
 811             --  A reference as a named parameter in a call does not count
 812             --  as a violation of pragma Unreferenced for this purpose...
 813
 814             if Nkind (N) = N_Identifier
 815               and then Nkind (Parent (N)) = N_Parameter_Association
 816               and then Selector_Name (Parent (N)) = N
 817             then
 818                null;
 819
 820             --  ... Neither does a reference to a variable on the left side
 821             --  of an assignment.
 822
 823             elsif Is_On_LHS (N) then
 824                null;
 825
 826             --  For entry formals, we want to place the warning message on the
 827             --  corresponding entity in the accept statement. The current scope
 828             --  is the body of the accept, so we find the formal whose name
 829             --  matches that of the entry formal (there is no link between the
 830             --  two entities, and the one in the accept statement is only used
 831             --  for conformance checking).
 832
 833             elsif Ekind (Scope (E)) = E_Entry then
 834                declare
 835                   BE : Entity_Id;
 836
 837                begin
 838                   BE := First_Entity (Current_Scope);
 839                   while Present (BE) loop
 840                      if Chars (BE) = Chars (E) then
 841                         Error_Msg_NE -- CODEFIX
 842                           ("??pragma Unreferenced given for&!", N, BE);
 843                         exit;
 844                      end if;
 845
 846                      Next_Entity (BE);
 847                   end loop;
 848                end;
 849
 850             --  Here we issue the warning, since this is a real reference
 851
 852             else
 853                Error_Msg_NE -- CODEFIX
 854                  ("?pragma Unreferenced given for&!", N, E);
 855             end if;
 856          end if;
 857
 858          --  If this is a subprogram instance, mark as well the internal
 859          --  subprogram in the wrapper package, which may be a visible
 860          --  compilation unit.
 861
 862          if Is_Overloadable (E)
 863            and then Is_Generic_Instance (E)
 864            and then Present (Alias (E))
 865          then
 866             Set_Referenced (Alias (E));
 867          end if;
 868       end if;
 869
 870       --  Generate reference if all conditions are met:
 871
 872       if
 873          --  Cross referencing must be active
 874
 875          Opt.Xref_Active
 876
 877          --  The entity must be one for which we collect references
 878
 879          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 880
 881          --  Both Sloc values must be set to something sensible
 882
 883          and then Sloc (E) > No_Location
 884          and then Sloc (N) > No_Location
 885
 886          --  Ignore references from within an instance. The only exceptions to
 887          --  this are default subprograms, for which we generate an implicit
 888          --  reference and compilations in SPARK mode.
 889
 890          and then
 891            (Instantiation_Location (Sloc (N)) = No_Location
 892              or else Typ = 'i'
 893              or else SPARK_Mode)
 894
 895         --  Ignore dummy references
 896
 897         and then Typ /= ' '
 898       then
 899          if Nkind_In (N, N_Identifier,
 900                          N_Defining_Identifier,
 901                          N_Defining_Operator_Symbol,
 902                          N_Operator_Symbol,
 903                          N_Defining_Character_Literal)
 904            or else Nkind (N) in N_Op
 905            or else (Nkind (N) = N_Character_Literal
 906                      and then Sloc (Entity (N)) /= Standard_Location)
 907          then
 908             Nod := N;
 909
 910          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 911             Nod := Selector_Name (N);
 912
 913          else
 914             return;
 915          end if;
 916
 917          --  Normal case of source entity comes from source
 918
 919          if Comes_From_Source (E) then
 920             Ent := E;
 921
 922          --  Entity does not come from source, but is a derived subprogram and
 923          --  the derived subprogram comes from source (after one or more
 924          --  derivations) in which case the reference is to parent subprogram.
 925
 926          elsif Is_Overloadable (E)
 927            and then Present (Alias (E))
 928          then
 929             Ent := Alias (E);
 930             while not Comes_From_Source (Ent) loop
 931                if No (Alias (Ent)) then
 932                   return;
 933                end if;
 934
 935                Ent := Alias (Ent);
 936             end loop;
 937
 938          --  The internally created defining entity for a child subprogram
 939          --  that has no previous spec has valid references.
 940
 941          elsif Is_Overloadable (E)
 942            and then Is_Child_Unit (E)
 943          then
 944             Ent := E;
 945
 946          --  Ditto for the formals of such a subprogram
 947
 948          elsif Is_Overloadable (Scope (E))
 949            and then Is_Child_Unit (Scope (E))
 950          then
 951             Ent := E;
 952
 953          --  Record components of discriminated subtypes or derived types must
 954          --  be treated as references to the original component.
 955
 956          elsif Ekind (E) = E_Component
 957            and then Comes_From_Source (Original_Record_Component (E))
 958          then
 959             Ent := Original_Record_Component (E);
 960
 961          --  If this is an expanded reference to a discriminant, recover the
 962          --  original discriminant, which gets the reference.
 963
 964          elsif Ekind (E) = E_In_Parameter
 965            and then  Present (Discriminal_Link (E))
 966          then
 967             Ent := Discriminal_Link (E);
 968             Set_Referenced (Ent);
 969
 970          --  Ignore reference to any other entity that is not from source
 971
 972          else
 973             return;
 974          end if;
 975
 976          --  In SPARK mode, consider the underlying entity renamed instead of
 977          --  the renaming, which is needed to compute a valid set of effects
 978          --  (reads, writes) for the enclosing subprogram.
 979
 980          if SPARK_Mode then
 981             Ent := Get_Through_Renamings (Ent);
 982
 983             --  If no enclosing object, then it could be a reference to any
 984             --  location not tracked individually, like heap-allocated data.
 985             --  Conservatively approximate this possibility by generating a
 986             --  dereference, and return.
 987
 988             if No (Ent) then
 989                if Actual_Typ = 'w' then
 990                   SPARK_Specific.Generate_Dereference (Nod, 'r');
 991                   SPARK_Specific.Generate_Dereference (Nod, 'w');
 992                else
 993                   SPARK_Specific.Generate_Dereference (Nod, 'r');
 994                end if;
 995
 996                return;
 997             end if;
 998          end if;
 999
1000          --  Record reference to entity
1001
1002          if Actual_Typ = 'p'
1003            and then Is_Subprogram (Nod)
1004            and then Present (Overridden_Operation (Nod))
1005          then
1006             Actual_Typ := 'P';
1007          end if;
1008
1009          if SPARK_Mode then
1010             Ref := Sloc (Nod);
1011             Def := Sloc (Ent);
1012
1013             Ref_Scope := SPARK_Specific.Enclosing_Subprogram_Or_Package (Nod);
1014             Ent_Scope := SPARK_Specific.Enclosing_Subprogram_Or_Package (Ent);
1015
1016             --  Since we are reaching through renamings in SPARK mode, we may
1017             --  end up with standard constants. Ignore those.
1018
1019             if Sloc (Ent_Scope) <= Standard_Location
1020               or else Def <= Standard_Location
1021             then
1022                return;
1023             end if;
1024
1025             Add_Entry
1026               ((Ent      => Ent,
1027                 Loc       => Ref,
1028                 Typ       => Actual_Typ,
1029                 Eun       => Get_Code_Unit (Def),
1030                 Lun       => Get_Code_Unit (Ref),
1031                 Ref_Scope => Ref_Scope,
1032                 Ent_Scope => Ent_Scope),
1033                Ent_Scope_File => Get_Code_Unit (Ent));
1034
1035          else
1036             Ref := Original_Location (Sloc (Nod));
1037             Def := Original_Location (Sloc (Ent));
1038
1039             --  If this is an operator symbol, skip the initial quote for
1040             --  navigation purposes. This is not done for the end label,
1041             --  where we want the actual position after the closing quote.
1042
1043             if Typ = 't' then
1044                null;
1045
1046             elsif Nkind (N) = N_Defining_Operator_Symbol
1047               or else Nkind (Nod) = N_Operator_Symbol
1048             then
1049                Ref := Ref + 1;
1050             end if;
1051
1052             Add_Entry
1053               ((Ent      => Ent,
1054                 Loc       => Ref,
1055                 Typ       => Actual_Typ,
1056                 Eun       => Get_Source_Unit (Def),
1057                 Lun       => Get_Source_Unit (Ref),
1058                 Ref_Scope => Empty,
1059                 Ent_Scope => Empty),
1060                Ent_Scope_File => No_Unit);
1061          end if;
1062       end if;
1063    end Generate_Reference;
1064
1065    -----------------------------------
1066    -- Generate_Reference_To_Formals --
1067    -----------------------------------
1068
1069    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1070       Formal : Entity_Id;
1071
1072    begin
1073       if Is_Generic_Subprogram (E) then
1074          Formal := First_Entity (E);
1075
1076          while Present (Formal)
1077            and then not Is_Formal (Formal)
1078          loop
1079             Next_Entity (Formal);
1080          end loop;
1081
1082       elsif Ekind (E) in Access_Subprogram_Kind then
1083          Formal := First_Formal (Designated_Type (E));
1084
1085       else
1086          Formal := First_Formal (E);
1087       end if;
1088
1089       while Present (Formal) loop
1090          if Ekind (Formal) = E_In_Parameter then
1091
1092             if Nkind (Parameter_Type (Parent (Formal)))
1093               = N_Access_Definition
1094             then
1095                Generate_Reference (E, Formal, '^', False);
1096             else
1097                Generate_Reference (E, Formal, '>', False);
1098             end if;
1099
1100          elsif Ekind (Formal) = E_In_Out_Parameter then
1101             Generate_Reference (E, Formal, '=', False);
1102
1103          else
1104             Generate_Reference (E, Formal, '<', False);
1105          end if;
1106
1107          Next_Formal (Formal);
1108       end loop;
1109    end Generate_Reference_To_Formals;
1110
1111    -------------------------------------------
1112    -- Generate_Reference_To_Generic_Formals --
1113    -------------------------------------------
1114
1115    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1116       Formal : Entity_Id;
1117
1118    begin
1119       Formal := First_Entity (E);
1120       while Present (Formal) loop
1121          if Comes_From_Source (Formal) then
1122             Generate_Reference (E, Formal, 'z', False);
1123          end if;
1124
1125          Next_Entity (Formal);
1126       end loop;
1127    end Generate_Reference_To_Generic_Formals;
1128
1129    -------------
1130    -- Get_Key --
1131    -------------
1132
1133    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1134    begin
1135       return E;
1136    end Get_Key;
1137
1138    ----------
1139    -- Hash --
1140    ----------
1141
1142    function Hash (F : Xref_Entry_Number) return Header_Num is
1143       --  It is unlikely to have two references to the same entity at the same
1144       --  source location, so the hash function depends only on the Ent and Loc
1145       --  fields.
1146
1147       XE : Xref_Entry renames Xrefs.Table (F);
1148       type M is mod 2**32;
1149
1150       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1151       --  It would be more natural to write:
1152       --
1153       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1154       --
1155       --  But we can't use M'Mod, because it prevents bootstrapping with older
1156       --  compilers. Loc can be negative, so we do "abs" before converting.
1157       --  One day this can be cleaned up ???
1158
1159    begin
1160       return Header_Num (H mod Num_Buckets);
1161    end Hash;
1162
1163    -----------------
1164    -- HT_Set_Next --
1165    -----------------
1166
1167    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1168    begin
1169       Xrefs.Table (E).HTable_Next := Next;
1170    end HT_Set_Next;
1171
1172    -------------
1173    -- HT_Next --
1174    -------------
1175
1176    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1177    begin
1178       return Xrefs.Table (E).HTable_Next;
1179    end HT_Next;
1180
1181    ----------------
1182    -- Initialize --
1183    ----------------
1184
1185    procedure Initialize is
1186    begin
1187       Xrefs.Init;
1188    end Initialize;
1189
1190    --------
1191    -- Lt --
1192    --------
1193
1194    function Lt (T1, T2 : Xref_Entry) return Boolean is
1195    begin
1196       --  First test: if entity is in different unit, sort by unit
1197
1198       if T1.Key.Eun /= T2.Key.Eun then
1199          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1200
1201       --  Second test: within same unit, sort by entity Sloc
1202
1203       elsif T1.Def /= T2.Def then
1204          return T1.Def < T2.Def;
1205
1206       --  Third test: sort definitions ahead of references
1207
1208       elsif T1.Key.Loc = No_Location then
1209          return True;
1210
1211       elsif T2.Key.Loc = No_Location then
1212          return False;
1213
1214       --  Fourth test: for same entity, sort by reference location unit
1215
1216       elsif T1.Key.Lun /= T2.Key.Lun then
1217          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1218
1219       --  Fifth test: order of location within referencing unit
1220
1221       elsif T1.Key.Loc /= T2.Key.Loc then
1222          return T1.Key.Loc < T2.Key.Loc;
1223
1224       --  Finally, for two locations at the same address, we prefer
1225       --  the one that does NOT have the type 'r' so that a modification
1226       --  or extension takes preference, when there are more than one
1227       --  reference at the same location. As a result, in the case of
1228       --  entities that are in-out actuals, the read reference follows
1229       --  the modify reference.
1230
1231       else
1232          return T2.Key.Typ = 'r';
1233       end if;
1234    end Lt;
1235
1236    -----------------------
1237    -- Output_References --
1238    -----------------------
1239
1240    procedure Output_References is
1241
1242       procedure Get_Type_Reference
1243         (Ent   : Entity_Id;
1244          Tref  : out Entity_Id;
1245          Left  : out Character;
1246          Right : out Character);
1247       --  Given an Entity_Id Ent, determines whether a type reference is
1248       --  required. If so, Tref is set to the entity for the type reference
1249       --  and Left and Right are set to the left/right brackets to be output
1250       --  for the reference. If no type reference is required, then Tref is
1251       --  set to Empty, and Left/Right are set to space.
1252
1253       procedure Output_Import_Export_Info (Ent : Entity_Id);
1254       --  Output language and external name information for an interfaced
1255       --  entity, using the format <language, external_name>.
1256
1257       ------------------------
1258       -- Get_Type_Reference --
1259       ------------------------
1260
1261       procedure Get_Type_Reference
1262         (Ent   : Entity_Id;
1263          Tref  : out Entity_Id;
1264          Left  : out Character;
1265          Right : out Character)
1266       is
1267          Sav : Entity_Id;
1268
1269       begin
1270          --  See if we have a type reference
1271
1272          Tref := Ent;
1273          Left := '{';
1274          Right := '}';
1275
1276          loop
1277             Sav := Tref;
1278
1279             --  Processing for types
1280
1281             if Is_Type (Tref) then
1282
1283                --  Case of base type
1284
1285                if Base_Type (Tref) = Tref then
1286
1287                   --  If derived, then get first subtype
1288
1289                   if Tref /= Etype (Tref) then
1290                      Tref := First_Subtype (Etype (Tref));
1291
1292                      --  Set brackets for derived type, but don't override
1293                      --  pointer case since the fact that something is a
1294                      --  pointer is more important.
1295
1296                      if Left /= '(' then
1297                         Left := '<';
1298                         Right := '>';
1299                      end if;
1300
1301                   --  If non-derived ptr, get directly designated type.
1302                   --  If the type has a full view, all references are on the
1303                   --  partial view, that is seen first.
1304
1305                   elsif Is_Access_Type (Tref) then
1306                      Tref := Directly_Designated_Type (Tref);
1307                      Left := '(';
1308                      Right := ')';
1309
1310                   elsif Is_Private_Type (Tref)
1311                     and then Present (Full_View (Tref))
1312                   then
1313                      if Is_Access_Type (Full_View (Tref)) then
1314                         Tref := Directly_Designated_Type (Full_View (Tref));
1315                         Left := '(';
1316                         Right := ')';
1317
1318                      --  If the full view is an array type, we also retrieve
1319                      --  the corresponding component type, because the ali
1320                      --  entry already indicates that this is an array.
1321
1322                      elsif Is_Array_Type (Full_View (Tref)) then
1323                         Tref := Component_Type (Full_View (Tref));
1324                         Left := '(';
1325                         Right := ')';
1326                      end if;
1327
1328                   --  If non-derived array, get component type. Skip component
1329                   --  type for case of String or Wide_String, saves worthwhile
1330                   --  space.
1331
1332                   elsif Is_Array_Type (Tref)
1333                     and then Tref /= Standard_String
1334                     and then Tref /= Standard_Wide_String
1335                   then
1336                      Tref := Component_Type (Tref);
1337                      Left := '(';
1338                      Right := ')';
1339
1340                   --  For other non-derived base types, nothing
1341
1342                   else
1343                      exit;
1344                   end if;
1345
1346                --  For a subtype, go to ancestor subtype
1347
1348                else
1349                   Tref := Ancestor_Subtype (Tref);
1350
1351                   --  If no ancestor subtype, go to base type
1352
1353                   if No (Tref) then
1354                      Tref := Base_Type (Sav);
1355                   end if;
1356                end if;
1357
1358             --  For objects, functions, enum literals, just get type from
1359             --  Etype field.
1360
1361             elsif Is_Object (Tref)
1362               or else Ekind (Tref) = E_Enumeration_Literal
1363               or else Ekind (Tref) = E_Function
1364               or else Ekind (Tref) = E_Operator
1365             then
1366                Tref := Etype (Tref);
1367
1368                --  Another special case: an object of a classwide type
1369                --  initialized with a tag-indeterminate call gets a subtype
1370                --  of the classwide type during expansion. See if the original
1371                --  type in the declaration is named, and return it instead
1372                --  of going to the root type.
1373
1374                if Ekind (Tref) = E_Class_Wide_Subtype
1375                  and then Nkind (Parent (Ent)) = N_Object_Declaration
1376                  and then
1377                    Nkind (Original_Node (Object_Definition (Parent (Ent))))
1378                      = N_Identifier
1379                then
1380                   Tref :=
1381                     Entity
1382                       (Original_Node ((Object_Definition (Parent (Ent)))));
1383                end if;
1384
1385             --  For anything else, exit
1386
1387             else
1388                exit;
1389             end if;
1390
1391             --  Exit if no type reference, or we are stuck in some loop trying
1392             --  to find the type reference, or if the type is standard void
1393             --  type (the latter is an implementation artifact that should not
1394             --  show up in the generated cross-references).
1395
1396             exit when No (Tref)
1397               or else Tref = Sav
1398               or else Tref = Standard_Void_Type;
1399
1400             --  If we have a usable type reference, return, otherwise keep
1401             --  looking for something useful (we are looking for something
1402             --  that either comes from source or standard)
1403
1404             if Sloc (Tref) = Standard_Location
1405               or else Comes_From_Source (Tref)
1406             then
1407                --  If the reference is a subtype created for a generic actual,
1408                --  go actual directly, the inner subtype is not user visible.
1409
1410                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1411                  and then not Comes_From_Source (Parent (Tref))
1412                  and then
1413                   (Is_Wrapper_Package (Scope (Tref))
1414                      or else Is_Generic_Instance (Scope (Tref)))
1415                then
1416                   Tref := First_Subtype (Base_Type (Tref));
1417                end if;
1418
1419                return;
1420             end if;
1421          end loop;
1422
1423          --  If we fall through the loop, no type reference
1424
1425          Tref := Empty;
1426          Left := ' ';
1427          Right := ' ';
1428       end Get_Type_Reference;
1429
1430       -------------------------------
1431       -- Output_Import_Export_Info --
1432       -------------------------------
1433
1434       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1435          Language_Name : Name_Id;
1436          Conv          : constant Convention_Id := Convention (Ent);
1437
1438       begin
1439          --  Generate language name from convention
1440
1441          if Conv  = Convention_C then
1442             Language_Name := Name_C;
1443
1444          elsif Conv = Convention_CPP then
1445             Language_Name := Name_CPP;
1446
1447          elsif Conv = Convention_Ada then
1448             Language_Name := Name_Ada;
1449
1450          else
1451             --  For the moment we ignore all other cases ???
1452
1453             return;
1454          end if;
1455
1456          Write_Info_Char ('<');
1457          Get_Unqualified_Name_String (Language_Name);
1458
1459          for J in 1 .. Name_Len loop
1460             Write_Info_Char (Name_Buffer (J));
1461          end loop;
1462
1463          if Present (Interface_Name (Ent)) then
1464             Write_Info_Char (',');
1465             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1466
1467             for J in 1 .. Name_Len loop
1468                Write_Info_Char (Name_Buffer (J));
1469             end loop;
1470          end if;
1471
1472          Write_Info_Char ('>');
1473       end Output_Import_Export_Info;
1474
1475    --  Start of processing for Output_References
1476
1477    begin
1478       --  First we add references to the primitive operations of tagged types
1479       --  declared in the main unit.
1480
1481       Handle_Prim_Ops : declare
1482          Ent  : Entity_Id;
1483
1484       begin
1485          for J in 1 .. Xrefs.Last loop
1486             Ent := Xrefs.Table (J).Key.Ent;
1487
1488             if Is_Type (Ent)
1489               and then Is_Tagged_Type (Ent)
1490               and then Is_Base_Type (Ent)
1491               and then In_Extended_Main_Source_Unit (Ent)
1492             then
1493                Generate_Prim_Op_References (Ent);
1494             end if;
1495          end loop;
1496       end Handle_Prim_Ops;
1497
1498       --  Before we go ahead and output the references we have a problem
1499       --  that needs dealing with. So far we have captured things that are
1500       --  definitely referenced by the main unit, or defined in the main
1501       --  unit. That's because we don't want to clutter up the ali file
1502       --  for this unit with definition lines for entities in other units
1503       --  that are not referenced.
1504
1505       --  But there is a glitch. We may reference an entity in another unit,
1506       --  and it may have a type reference to an entity that is not directly
1507       --  referenced in the main unit, which may mean that there is no xref
1508       --  entry for this entity yet in the list of references.
1509
1510       --  If we don't do something about this, we will end with an orphan type
1511       --  reference, i.e. it will point to an entity that does not appear
1512       --  within the generated references in the ali file. That is not good for
1513       --  tools using the xref information.
1514
1515       --  To fix this, we go through the references adding definition entries
1516       --  for any unreferenced entities that can be referenced in a type
1517       --  reference. There is a recursion problem here, and that is dealt with
1518       --  by making sure that this traversal also traverses any entries that
1519       --  get added by the traversal.
1520
1521       Handle_Orphan_Type_References : declare
1522          J    : Nat;
1523          Tref : Entity_Id;
1524          Ent  : Entity_Id;
1525
1526          L, R : Character;
1527          pragma Warnings (Off, L);
1528          pragma Warnings (Off, R);
1529
1530          procedure New_Entry (E : Entity_Id);
1531          --  Make an additional entry into the Xref table for a type entity
1532          --  that is related to the current entity (parent, type ancestor,
1533          --  progenitor, etc.).
1534
1535          ----------------
1536          -- New_Entry --
1537          ----------------
1538
1539          procedure New_Entry (E : Entity_Id) is
1540          begin
1541             pragma Assert (Present (E));
1542
1543             if not Has_Xref_Entry (Implementation_Base_Type (E))
1544               and then Sloc (E) > No_Location
1545             then
1546                Add_Entry
1547                  ((Ent => E,
1548                    Loc => No_Location,
1549                    Typ => Character'First,
1550                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1551                    Lun => No_Unit,
1552                    Ref_Scope => Empty,
1553                    Ent_Scope => Empty),
1554                   Ent_Scope_File => No_Unit);
1555             end if;
1556          end New_Entry;
1557
1558       --  Start of processing for Handle_Orphan_Type_References
1559
1560       begin
1561          --  Note that this is not a for loop for a very good reason. The
1562          --  processing of items in the table can add new items to the table,
1563          --  and they must be processed as well.
1564
1565          J := 1;
1566          while J <= Xrefs.Last loop
1567             Ent := Xrefs.Table (J).Key.Ent;
1568             Get_Type_Reference (Ent, Tref, L, R);
1569
1570             if Present (Tref)
1571               and then not Has_Xref_Entry (Tref)
1572               and then Sloc (Tref) > No_Location
1573             then
1574                New_Entry (Tref);
1575
1576                if Is_Record_Type (Ent)
1577                  and then Present (Interfaces (Ent))
1578                then
1579                   --  Add an entry for each one of the given interfaces
1580                   --  implemented by type Ent.
1581
1582                   declare
1583                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1584                   begin
1585                      while Present (Elmt) loop
1586                         New_Entry (Node (Elmt));
1587                         Next_Elmt (Elmt);
1588                      end loop;
1589                   end;
1590                end if;
1591             end if;
1592
1593             --  Collect inherited primitive operations that may be declared in
1594             --  another unit and have no visible reference in the current one.
1595
1596             if Is_Type (Ent)
1597               and then Is_Tagged_Type (Ent)
1598               and then Is_Derived_Type (Ent)
1599               and then Is_Base_Type (Ent)
1600               and then In_Extended_Main_Source_Unit (Ent)
1601             then
1602                declare
1603                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1604                   Op      : Elmt_Id;
1605                   Prim    : Entity_Id;
1606
1607                   function Parent_Op (E : Entity_Id) return Entity_Id;
1608                   --  Find original operation, which may be inherited through
1609                   --  several derivations.
1610
1611                   function Parent_Op (E : Entity_Id) return Entity_Id is
1612                      Orig_Op : constant Entity_Id := Alias (E);
1613
1614                   begin
1615                      if No (Orig_Op) then
1616                         return Empty;
1617
1618                      elsif not Comes_From_Source (E)
1619                        and then not Has_Xref_Entry (Orig_Op)
1620                        and then Comes_From_Source (Orig_Op)
1621                      then
1622                         return Orig_Op;
1623                      else
1624                         return Parent_Op (Orig_Op);
1625                      end if;
1626                   end Parent_Op;
1627
1628                begin
1629                   Op := First_Elmt (Op_List);
1630                   while Present (Op) loop
1631                      Prim := Parent_Op (Node (Op));
1632
1633                      if Present (Prim) then
1634                         Add_Entry
1635                           ((Ent => Prim,
1636                             Loc => No_Location,
1637                             Typ => Character'First,
1638                             Eun => Get_Source_Unit (Sloc (Prim)),
1639                             Lun => No_Unit,
1640                             Ref_Scope => Empty,
1641                             Ent_Scope => Empty),
1642                            Ent_Scope_File => No_Unit);
1643                      end if;
1644
1645                      Next_Elmt (Op);
1646                   end loop;
1647                end;
1648             end if;
1649
1650             J := J + 1;
1651          end loop;
1652       end Handle_Orphan_Type_References;
1653
1654       --  Now we have all the references, including those for any embedded
1655       --  type references, so we can sort them, and output them.
1656
1657       Output_Refs : declare
1658
1659          Nrefs : constant Nat := Xrefs.Last;
1660          --  Number of references in table
1661
1662          Rnums : array (0 .. Nrefs) of Nat;
1663          --  This array contains numbers of references in the Xrefs table.
1664          --  This list is sorted in output order. The extra 0'th entry is
1665          --  convenient for the call to sort. When we sort the table, we
1666          --  move the entries in Rnums around, but we do not move the
1667          --  original table entries.
1668
1669          Curxu : Unit_Number_Type;
1670          --  Current xref unit
1671
1672          Curru : Unit_Number_Type;
1673          --  Current reference unit for one entity
1674
1675          Curent : Entity_Id;
1676          --  Current entity
1677
1678          Curnam : String (1 .. Name_Buffer'Length);
1679          Curlen : Natural;
1680          --  Simple name and length of current entity
1681
1682          Curdef : Source_Ptr;
1683          --  Original source location for current entity
1684
1685          Crloc : Source_Ptr;
1686          --  Current reference location
1687
1688          Ctyp : Character;
1689          --  Entity type character
1690
1691          Prevt : Character;
1692          --  reference kind of previous reference
1693
1694          Tref : Entity_Id;
1695          --  Type reference
1696
1697          Rref : Node_Id;
1698          --  Renaming reference
1699
1700          Trunit : Unit_Number_Type;
1701          --  Unit number for type reference
1702
1703          function Lt (Op1, Op2 : Natural) return Boolean;
1704          --  Comparison function for Sort call
1705
1706          function Name_Change (X : Entity_Id) return Boolean;
1707          --  Determines if entity X has a different simple name from Curent
1708
1709          procedure Move (From : Natural; To : Natural);
1710          --  Move procedure for Sort call
1711
1712          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1713
1714          --------
1715          -- Lt --
1716          --------
1717
1718          function Lt (Op1, Op2 : Natural) return Boolean is
1719             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1720             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1721
1722          begin
1723             return Lt (T1, T2);
1724          end Lt;
1725
1726          ----------
1727          -- Move --
1728          ----------
1729
1730          procedure Move (From : Natural; To : Natural) is
1731          begin
1732             Rnums (Nat (To)) := Rnums (Nat (From));
1733          end Move;
1734
1735          -----------------
1736          -- Name_Change --
1737          -----------------
1738
1739          --  Why a string comparison here??? Why not compare Name_Id values???
1740
1741          function Name_Change (X : Entity_Id) return Boolean is
1742          begin
1743             Get_Unqualified_Name_String (Chars (X));
1744
1745             if Name_Len /= Curlen then
1746                return True;
1747             else
1748                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1749             end if;
1750          end Name_Change;
1751
1752       --  Start of processing for Output_Refs
1753
1754       begin
1755          --  Capture the definition Sloc values. We delay doing this till now,
1756          --  since at the time the reference or definition is made, private
1757          --  types may be swapped, and the Sloc value may be incorrect. We
1758          --  also set up the pointer vector for the sort.
1759
1760          --  For user-defined operators we need to skip the initial quote and
1761          --  point to the first character of the name, for navigation purposes.
1762
1763          for J in 1 .. Nrefs loop
1764             declare
1765                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1766                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1767
1768             begin
1769                Rnums (J) := J;
1770
1771                if Nkind (E) = N_Defining_Operator_Symbol then
1772                   Xrefs.Table (J).Def := Loc + 1;
1773                else
1774                   Xrefs.Table (J).Def := Loc;
1775                end if;
1776             end;
1777          end loop;
1778
1779          --  Sort the references
1780
1781          Sorting.Sort (Integer (Nrefs));
1782
1783          --  Initialize loop through references
1784
1785          Curxu  := No_Unit;
1786          Curent := Empty;
1787          Curdef := No_Location;
1788          Curru  := No_Unit;
1789          Crloc  := No_Location;
1790          Prevt  := 'm';
1791
1792          --  Loop to output references
1793
1794          for Refno in 1 .. Nrefs loop
1795             Output_One_Ref : declare
1796                Ent : Entity_Id;
1797
1798                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1799                --  The current entry to be accessed
1800
1801                Left  : Character;
1802                Right : Character;
1803                --  Used for {} or <> or () for type reference
1804
1805                procedure Check_Type_Reference
1806                  (Ent            : Entity_Id;
1807                   List_Interface : Boolean);
1808                --  Find whether there is a meaningful type reference for
1809                --  Ent, and display it accordingly. If List_Interface is
1810                --  true, then Ent is a progenitor interface of the current
1811                --  type entity being listed. In that case list it as is,
1812                --  without looking for a type reference for it.
1813
1814                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1815                --  Recursive procedure to output instantiation references for
1816                --  the given source ptr in [file|line[...]] form. No output
1817                --  if the given location is not a generic template reference.
1818
1819                procedure Output_Overridden_Op (Old_E : Entity_Id);
1820                --  For a subprogram that is overriding, display information
1821                --  about the inherited operation that it overrides.
1822
1823                --------------------------
1824                -- Check_Type_Reference --
1825                --------------------------
1826
1827                procedure Check_Type_Reference
1828                  (Ent            : Entity_Id;
1829                   List_Interface : Boolean)
1830                is
1831                begin
1832                   if List_Interface then
1833
1834                      --  This is a progenitor interface of the type for which
1835                      --  xref information is being generated.
1836
1837                      Tref  := Ent;
1838                      Left  := '<';
1839                      Right := '>';
1840
1841                   else
1842                      Get_Type_Reference (Ent, Tref, Left, Right);
1843                   end if;
1844
1845                   if Present (Tref) then
1846
1847                      --  Case of standard entity, output name
1848
1849                      if Sloc (Tref) = Standard_Location then
1850                         Write_Info_Char (Left);
1851                         Write_Info_Name (Chars (Tref));
1852                         Write_Info_Char (Right);
1853
1854                      --  Case of source entity, output location
1855
1856                      else
1857                         Write_Info_Char (Left);
1858                         Trunit := Get_Source_Unit (Sloc (Tref));
1859
1860                         if Trunit /= Curxu then
1861                            Write_Info_Nat (Dependency_Num (Trunit));
1862                            Write_Info_Char ('|');
1863                         end if;
1864
1865                         Write_Info_Nat
1866                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1867
1868                         declare
1869                            Ent  : Entity_Id;
1870                            Ctyp : Character;
1871
1872                         begin
1873                            Ent := Tref;
1874                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1875
1876                            if Ctyp = '+'
1877                              and then Present (Full_View (Ent))
1878                            then
1879                               Ent := Underlying_Type (Ent);
1880
1881                               if Present (Ent) then
1882                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1883                               end if;
1884                            end if;
1885
1886                            Write_Info_Char (Ctyp);
1887                         end;
1888
1889                         Write_Info_Nat
1890                           (Int (Get_Column_Number (Sloc (Tref))));
1891
1892                         --  If the type comes from an instantiation, add the
1893                         --  corresponding info.
1894
1895                         Output_Instantiation_Refs (Sloc (Tref));
1896                         Write_Info_Char (Right);
1897                      end if;
1898                   end if;
1899                end Check_Type_Reference;
1900
1901                -------------------------------
1902                -- Output_Instantiation_Refs --
1903                -------------------------------
1904
1905                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1906                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1907                   Lun  : Unit_Number_Type;
1908                   Cu   : constant Unit_Number_Type := Curru;
1909
1910                begin
1911                   --  Nothing to do if this is not an instantiation
1912
1913                   if Iloc = No_Location then
1914                      return;
1915                   end if;
1916
1917                   --  Output instantiation reference
1918
1919                   Write_Info_Char ('[');
1920                   Lun := Get_Source_Unit (Iloc);
1921
1922                   if Lun /= Curru then
1923                      Curru := Lun;
1924                      Write_Info_Nat (Dependency_Num (Curru));
1925                      Write_Info_Char ('|');
1926                   end if;
1927
1928                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1929
1930                   --  Recursive call to get nested instantiations
1931
1932                   Output_Instantiation_Refs (Iloc);
1933
1934                   --  Output final ] after call to get proper nesting
1935
1936                   Write_Info_Char (']');
1937                   Curru := Cu;
1938                   return;
1939                end Output_Instantiation_Refs;
1940
1941                --------------------------
1942                -- Output_Overridden_Op --
1943                --------------------------
1944
1945                procedure Output_Overridden_Op (Old_E : Entity_Id) is
1946                   Op : Entity_Id;
1947
1948                begin
1949                   --  The overridden operation has an implicit declaration
1950                   --  at the point of derivation. What we want to display
1951                   --  is the original operation, which has the actual body
1952                   --  (or abstract declaration) that is being overridden.
1953                   --  The overridden operation is not always set, e.g. when
1954                   --  it is a predefined operator.
1955
1956                   if No (Old_E) then
1957                      return;
1958
1959                   --  Follow alias chain if one is present
1960
1961                   elsif Present (Alias (Old_E)) then
1962
1963                      --  The subprogram may have been implicitly inherited
1964                      --  through several levels of derivation, so find the
1965                      --  ultimate (source) ancestor.
1966
1967                      Op := Ultimate_Alias (Old_E);
1968
1969                   --  Normal case of no alias present. We omit generated
1970                   --  primitives like tagged equality, that have no source
1971                   --  representation.
1972
1973                   else
1974                      Op := Old_E;
1975                   end if;
1976
1977                   if Present (Op)
1978                     and then Sloc (Op) /= Standard_Location
1979                     and then Comes_From_Source (Op)
1980                   then
1981                      declare
1982                         Loc      : constant Source_Ptr := Sloc (Op);
1983                         Par_Unit : constant Unit_Number_Type :=
1984                                      Get_Source_Unit (Loc);
1985
1986                      begin
1987                         Write_Info_Char ('<');
1988
1989                         if Par_Unit /= Curxu then
1990                            Write_Info_Nat (Dependency_Num (Par_Unit));
1991                            Write_Info_Char ('|');
1992                         end if;
1993
1994                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
1995                         Write_Info_Char ('p');
1996                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
1997                         Write_Info_Char ('>');
1998                      end;
1999                   end if;
2000                end Output_Overridden_Op;
2001
2002             --  Start of processing for Output_One_Ref
2003
2004             begin
2005                Ent := XE.Key.Ent;
2006                Ctyp := Xref_Entity_Letters (Ekind (Ent));
2007
2008                --  Skip reference if it is the only reference to an entity,
2009                --  and it is an END line reference, and the entity is not in
2010                --  the current extended source. This prevents junk entries
2011                --  consisting only of packages with END lines, where no
2012                --  entity from the package is actually referenced.
2013
2014                if XE.Key.Typ = 'e'
2015                  and then Ent /= Curent
2016                  and then (Refno = Nrefs
2017                             or else
2018                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
2019                  and then not In_Extended_Main_Source_Unit (Ent)
2020                then
2021                   goto Continue;
2022                end if;
2023
2024                --  For private type, get full view type
2025
2026                if Ctyp = '+'
2027                  and then Present (Full_View (XE.Key.Ent))
2028                then
2029                   Ent := Underlying_Type (Ent);
2030
2031                   if Present (Ent) then
2032                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2033                   end if;
2034                end if;
2035
2036                --  Special exception for Boolean
2037
2038                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2039                   Ctyp := 'B';
2040                end if;
2041
2042                --  For variable reference, get corresponding type
2043
2044                if Ctyp = '*' then
2045                   Ent := Etype (XE.Key.Ent);
2046                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2047
2048                   --  If variable is private type, get full view type
2049
2050                   if Ctyp = '+'
2051                     and then Present (Full_View (Etype (XE.Key.Ent)))
2052                   then
2053                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2054
2055                      if Present (Ent) then
2056                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2057                      end if;
2058
2059                   elsif Is_Generic_Type (Ent) then
2060
2061                      --  If the type of the entity is a generic private type,
2062                      --  there is no usable full view, so retain the indication
2063                      --  that this is an object.
2064
2065                      Ctyp := '*';
2066                   end if;
2067
2068                   --  Special handling for access parameters and objects and
2069                   --  components of an anonymous access type.
2070
2071                   if Ekind_In (Etype (XE.Key.Ent),
2072                                E_Anonymous_Access_Type,
2073                                E_Anonymous_Access_Subprogram_Type,
2074                                E_Anonymous_Access_Protected_Subprogram_Type)
2075                   then
2076                      if Is_Formal (XE.Key.Ent)
2077                        or else
2078                          Ekind_In
2079                            (XE.Key.Ent, E_Variable, E_Constant, E_Component)
2080                      then
2081                         Ctyp := 'p';
2082                      end if;
2083
2084                      --  Special handling for Boolean
2085
2086                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2087                      Ctyp := 'b';
2088                   end if;
2089                end if;
2090
2091                --  Special handling for abstract types and operations
2092
2093                if Is_Overloadable (XE.Key.Ent)
2094                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2095                then
2096                   if Ctyp = 'U' then
2097                      Ctyp := 'x';            --  Abstract procedure
2098
2099                   elsif Ctyp = 'V' then
2100                      Ctyp := 'y';            --  Abstract function
2101                   end if;
2102
2103                elsif Is_Type (XE.Key.Ent)
2104                  and then Is_Abstract_Type (XE.Key.Ent)
2105                then
2106                   if Is_Interface (XE.Key.Ent) then
2107                      Ctyp := 'h';
2108
2109                   elsif Ctyp = 'R' then
2110                      Ctyp := 'H';            --  Abstract type
2111                   end if;
2112                end if;
2113
2114                --  Only output reference if interesting type of entity
2115
2116                if Ctyp = ' '
2117
2118                --  Suppress references to object definitions, used for local
2119                --  references.
2120
2121                  or else XE.Key.Typ = 'D'
2122                  or else XE.Key.Typ = 'I'
2123
2124                --  Suppress self references, except for bodies that act as
2125                --  specs.
2126
2127                  or else (XE.Key.Loc = XE.Def
2128                            and then
2129                              (XE.Key.Typ /= 'b'
2130                                or else not Is_Subprogram (XE.Key.Ent)))
2131
2132                --  Also suppress definitions of body formals (we only
2133                --  treat these as references, and the references were
2134                --  separately recorded).
2135
2136                  or else (Is_Formal (XE.Key.Ent)
2137                            and then Present (Spec_Entity (XE.Key.Ent)))
2138                then
2139                   null;
2140
2141                else
2142                   --  Start new Xref section if new xref unit
2143
2144                   if XE.Key.Eun /= Curxu then
2145                      if Write_Info_Col > 1 then
2146                         Write_Info_EOL;
2147                      end if;
2148
2149                      Curxu := XE.Key.Eun;
2150
2151                      Write_Info_Initiate ('X');
2152                      Write_Info_Char (' ');
2153                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2154                      Write_Info_Char (' ');
2155                      Write_Info_Name
2156                        (Reference_Name (Source_Index (XE.Key.Eun)));
2157                   end if;
2158
2159                   --  Start new Entity line if new entity. Note that we
2160                   --  consider two entities the same if they have the same
2161                   --  name and source location. This causes entities in
2162                   --  instantiations to be treated as though they referred
2163                   --  to the template.
2164
2165                   if No (Curent)
2166                     or else
2167                       (XE.Key.Ent /= Curent
2168                          and then
2169                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2170                   then
2171                      Curent := XE.Key.Ent;
2172                      Curdef := XE.Def;
2173
2174                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2175                      Curlen := Name_Len;
2176                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2177
2178                      if Write_Info_Col > 1 then
2179                         Write_Info_EOL;
2180                      end if;
2181
2182                      --  Write column number information
2183
2184                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2185                      Write_Info_Char (Ctyp);
2186                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2187
2188                      --  Write level information
2189
2190                      Write_Level_Info : declare
2191                         function Is_Visible_Generic_Entity
2192                           (E : Entity_Id) return Boolean;
2193                         --  Check whether E is declared in the visible part
2194                         --  of a generic package. For source navigation
2195                         --  purposes, treat this as a visible entity.
2196
2197                         function Is_Private_Record_Component
2198                           (E : Entity_Id) return Boolean;
2199                         --  Check whether E is a non-inherited component of a
2200                         --  private extension. Even if the enclosing record is
2201                         --  public, we want to treat the component as private
2202                         --  for navigation purposes.
2203
2204                         ---------------------------------
2205                         -- Is_Private_Record_Component --
2206                         ---------------------------------
2207
2208                         function Is_Private_Record_Component
2209                           (E : Entity_Id) return Boolean
2210                         is
2211                            S : constant Entity_Id := Scope (E);
2212                         begin
2213                            return
2214                              Ekind (E) = E_Component
2215                                and then Nkind (Declaration_Node (S)) =
2216                                  N_Private_Extension_Declaration
2217                                and then Original_Record_Component (E) = E;
2218                         end Is_Private_Record_Component;
2219
2220                         -------------------------------
2221                         -- Is_Visible_Generic_Entity --
2222                         -------------------------------
2223
2224                         function Is_Visible_Generic_Entity
2225                           (E : Entity_Id) return Boolean
2226                         is
2227                            Par : Node_Id;
2228
2229                         begin
2230                            --  The Present check here is an error defense
2231
2232                            if Present (Scope (E))
2233                              and then Ekind (Scope (E)) /= E_Generic_Package
2234                            then
2235                               return False;
2236                            end if;
2237
2238                            Par := Parent (E);
2239                            while Present (Par) loop
2240                               if
2241                                 Nkind (Par) = N_Generic_Package_Declaration
2242                               then
2243                                  --  Entity is a generic formal
2244
2245                                  return False;
2246
2247                               elsif
2248                                 Nkind (Parent (Par)) = N_Package_Specification
2249                               then
2250                                  return
2251                                    Is_List_Member (Par)
2252                                      and then List_Containing (Par) =
2253                                        Visible_Declarations (Parent (Par));
2254                               else
2255                                  Par := Parent (Par);
2256                               end if;
2257                            end loop;
2258
2259                            return False;
2260                         end Is_Visible_Generic_Entity;
2261
2262                      --  Start of processing for Write_Level_Info
2263
2264                      begin
2265                         if Is_Hidden (Curent)
2266                           or else Is_Private_Record_Component (Curent)
2267                         then
2268                            Write_Info_Char (' ');
2269
2270                         elsif
2271                            Is_Public (Curent)
2272                              or else Is_Visible_Generic_Entity (Curent)
2273                         then
2274                            Write_Info_Char ('*');
2275
2276                         else
2277                            Write_Info_Char (' ');
2278                         end if;
2279                      end Write_Level_Info;
2280
2281                      --  Output entity name. We use the occurrence from the
2282                      --  actual source program at the definition point.
2283
2284                      declare
2285                         Ent_Name : constant String :=
2286                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2287                      begin
2288                         for C in Ent_Name'Range loop
2289                            Write_Info_Char (Ent_Name (C));
2290                         end loop;
2291                      end;
2292
2293                      --  See if we have a renaming reference
2294
2295                      if Is_Object (XE.Key.Ent)
2296                        and then Present (Renamed_Object (XE.Key.Ent))
2297                      then
2298                         Rref := Renamed_Object (XE.Key.Ent);
2299
2300                      elsif Is_Overloadable (XE.Key.Ent)
2301                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2302                                            = N_Subprogram_Renaming_Declaration
2303                      then
2304                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2305
2306                      elsif Ekind (XE.Key.Ent) = E_Package
2307                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2308                                          N_Package_Renaming_Declaration
2309                      then
2310                         Rref := Name (Declaration_Node (XE.Key.Ent));
2311
2312                      else
2313                         Rref := Empty;
2314                      end if;
2315
2316                      if Present (Rref) then
2317                         if Nkind (Rref) = N_Expanded_Name then
2318                            Rref := Selector_Name (Rref);
2319                         end if;
2320
2321                         if Nkind (Rref) = N_Identifier
2322                           or else Nkind (Rref) = N_Operator_Symbol
2323                         then
2324                            null;
2325
2326                         --  For renamed array components, use the array name
2327                         --  for the renamed entity, which reflect the fact that
2328                         --  in general the whole array is aliased.
2329
2330                         elsif Nkind (Rref) = N_Indexed_Component then
2331                            if Nkind (Prefix (Rref)) = N_Identifier then
2332                               Rref := Prefix (Rref);
2333                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2334                               Rref := Selector_Name (Prefix (Rref));
2335                            else
2336                               Rref := Empty;
2337                            end if;
2338
2339                         else
2340                            Rref := Empty;
2341                         end if;
2342                      end if;
2343
2344                      --  Write out renaming reference if we have one
2345
2346                      if Present (Rref) then
2347                         Write_Info_Char ('=');
2348                         Write_Info_Nat
2349                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2350                         Write_Info_Char (':');
2351                         Write_Info_Nat
2352                           (Int (Get_Column_Number (Sloc (Rref))));
2353                      end if;
2354
2355                      --  Indicate that the entity is in the unit of the current
2356                      --  xref section.
2357
2358                      Curru := Curxu;
2359
2360                      --  Write out information about generic parent, if entity
2361                      --  is an instance.
2362
2363                      if  Is_Generic_Instance (XE.Key.Ent) then
2364                         declare
2365                            Gen_Par : constant Entity_Id :=
2366                                        Generic_Parent
2367                                          (Specification
2368                                             (Unit_Declaration_Node
2369                                                (XE.Key.Ent)));
2370                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2371                            Gen_U   : constant Unit_Number_Type :=
2372                                        Get_Source_Unit (Loc);
2373
2374                         begin
2375                            Write_Info_Char ('[');
2376
2377                            if Curru /= Gen_U then
2378                               Write_Info_Nat (Dependency_Num (Gen_U));
2379                               Write_Info_Char ('|');
2380                            end if;
2381
2382                            Write_Info_Nat
2383                              (Int (Get_Logical_Line_Number (Loc)));
2384                            Write_Info_Char (']');
2385                         end;
2386                      end if;
2387
2388                      --  See if we have a type reference and if so output
2389
2390                      Check_Type_Reference (XE.Key.Ent, False);
2391
2392                      --  Additional information for types with progenitors
2393
2394                      if Is_Record_Type (XE.Key.Ent)
2395                        and then Present (Interfaces (XE.Key.Ent))
2396                      then
2397                         declare
2398                            Elmt : Elmt_Id :=
2399                                     First_Elmt (Interfaces (XE.Key.Ent));
2400                         begin
2401                            while Present (Elmt) loop
2402                               Check_Type_Reference (Node (Elmt), True);
2403                               Next_Elmt (Elmt);
2404                            end loop;
2405                         end;
2406
2407                      --  For array types, list index types as well. (This is
2408                      --  not C, indexes have distinct types).
2409
2410                      elsif Is_Array_Type (XE.Key.Ent) then
2411                         declare
2412                            Indx : Node_Id;
2413                         begin
2414                            Indx := First_Index (XE.Key.Ent);
2415                            while Present (Indx) loop
2416                               Check_Type_Reference
2417                                 (First_Subtype (Etype (Indx)), True);
2418                               Next_Index (Indx);
2419                            end loop;
2420                         end;
2421                      end if;
2422
2423                      --  If the entity is an overriding operation, write info
2424                      --  on operation that was overridden.
2425
2426                      if Is_Subprogram (XE.Key.Ent)
2427                        and then Present (Overridden_Operation (XE.Key.Ent))
2428                      then
2429                         Output_Overridden_Op
2430                           (Overridden_Operation (XE.Key.Ent));
2431                      end if;
2432
2433                      --  End of processing for entity output
2434
2435                      Crloc := No_Location;
2436                   end if;
2437
2438                   --  Output the reference if it is not as the same location
2439                   --  as the previous one, or it is a read-reference that
2440                   --  indicates that the entity is an in-out actual in a call.
2441
2442                   if XE.Key.Loc /= No_Location
2443                     and then
2444                       (XE.Key.Loc /= Crloc
2445                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2446                   then
2447                      Crloc := XE.Key.Loc;
2448                      Prevt := XE.Key.Typ;
2449
2450                      --  Start continuation if line full, else blank
2451
2452                      if Write_Info_Col > 72 then
2453                         Write_Info_EOL;
2454                         Write_Info_Initiate ('.');
2455                      end if;
2456
2457                      Write_Info_Char (' ');
2458
2459                      --  Output file number if changed
2460
2461                      if XE.Key.Lun /= Curru then
2462                         Curru := XE.Key.Lun;
2463                         Write_Info_Nat (Dependency_Num (Curru));
2464                         Write_Info_Char ('|');
2465                      end if;
2466
2467                      Write_Info_Nat
2468                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2469                      Write_Info_Char (XE.Key.Typ);
2470
2471                      if Is_Overloadable (XE.Key.Ent) then
2472                         if (Is_Imported (XE.Key.Ent) and then XE.Key.Typ = 'b')
2473                              or else
2474                            (Is_Exported (XE.Key.Ent) and then XE.Key.Typ = 'i')
2475                         then
2476                            Output_Import_Export_Info (XE.Key.Ent);
2477                         end if;
2478                      end if;
2479
2480                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2481
2482                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2483                   end if;
2484                end if;
2485             end Output_One_Ref;
2486
2487          <<Continue>>
2488             null;
2489          end loop;
2490
2491          Write_Info_EOL;
2492       end Output_Refs;
2493    end Output_References;
2494
2495 --  Start of elaboration for Lib.Xref
2496
2497 begin
2498    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2499    --  because it's not an access type.
2500
2501    Xref_Set.Reset;
2502 end Lib.Xref;