gcc/ada/a-cfhase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --    A D A . C O N T A I N E R S . F O R M A L _ H A S H E D _ S E T S     --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Hashed_Sets in the
  33 --  Ada 2012 RM. The modifications are to facilitate formal proofs by making it
  34 --  easier to express properties.
  35
  36 --  The modifications are:
  37
  38 --    A parameter for the container is added to every function reading the
  39 --    content of a container: Element, Next, Query_Element, Has_Element, Key,
  40 --    Iterate, Equivalent_Elements. This change is motivated by the need to
  41 --    have cursors which are valid on different containers (typically a
  42 --    container C and its previous version C'Old) for expressing properties,
  43 --    which is not possible if cursors encapsulate an access to the underlying
  44 --    container.
  45
  46 --    There are three new functions:
  47
  48 --      function Strict_Equal (Left, Right : Set) return Boolean;
  49 --      function Left  (Container : Set; Position : Cursor) return Set;
  50 --      function Right (Container : Set; Position : Cursor) return Set;
  51
  52 --    See detailed specifications for these subprograms
  53
  54 private with Ada.Containers.Hash_Tables;
  55
  56 generic
  57    type Element_Type is private;
  58
  59    with function Hash (Element : Element_Type) return Hash_Type;
  60
  61    with function Equivalent_Elements (Left, Right : Element_Type)
  62                                       return Boolean;
  63
  64    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  65
  66 package Ada.Containers.Formal_Hashed_Sets is
  67    pragma Pure;
  68
  69    type Set (Capacity : Count_Type; Modulus : Hash_Type) is private;
  70    pragma Preelaborable_Initialization (Set);
  71
  72    type Cursor is private;
  73    pragma Preelaborable_Initialization (Cursor);
  74
  75    Empty_Set : constant Set;
  76
  77    No_Element : constant Cursor;
  78
  79    function "=" (Left, Right : Set) return Boolean;
  80
  81    function Equivalent_Sets (Left, Right : Set) return Boolean;
  82
  83    function To_Set (New_Item : Element_Type) return Set;
  84
  85    function Capacity (Container : Set) return Count_Type;
  86
  87    procedure Reserve_Capacity
  88      (Container : in out Set;
  89       Capacity  : Count_Type)
  90    with
  91      Pre => Capacity <= Container.Capacity;
  92
  93    function Length (Container : Set) return Count_Type;
  94
  95    function Is_Empty (Container : Set) return Boolean;
  96
  97    procedure Clear (Container : in out Set);
  98
  99    procedure Assign (Target : in out Set; Source : Set) with
 100      Pre => Target.Capacity >= Length (Source);
 101
 102    function Copy
 103      (Source   : Set;
 104       Capacity : Count_Type := 0) return Set
 105    with
 106      Pre => Capacity >= Source.Capacity;
 107
 108    function Element
 109      (Container : Set;
 110       Position  : Cursor) return Element_Type
 111    with
 112      Pre => Has_Element (Container, Position);
 113
 114    procedure Replace_Element
 115      (Container : in out Set;
 116       Position  : Cursor;
 117       New_Item  : Element_Type)
 118    with
 119      Pre => Has_Element (Container, Position);
 120
 121    procedure Move (Target : in out Set; Source : in out Set) with
 122      Pre => Target.Capacity >= Length (Source);
 123
 124    procedure Insert
 125      (Container : in out Set;
 126       New_Item  : Element_Type;
 127       Position  : out Cursor;
 128       Inserted  : out Boolean)
 129    with
 130      Pre => Length (Container) < Container.Capacity;
 131
 132    procedure Insert  (Container : in out Set; New_Item : Element_Type) with
 133      Pre => Length (Container) < Container.Capacity
 134               and then (not Contains (Container, New_Item));
 135
 136    procedure Include (Container : in out Set; New_Item : Element_Type) with
 137      Pre => Length (Container) < Container.Capacity;
 138
 139    procedure Replace (Container : in out Set; New_Item : Element_Type) with
 140      Pre => Contains (Container, New_Item);
 141
 142    procedure Exclude (Container : in out Set; Item     : Element_Type);
 143
 144    procedure Delete  (Container : in out Set; Item     : Element_Type) with
 145      Pre => Contains (Container, Item);
 146
 147    procedure Delete (Container : in out Set; Position  : in out Cursor) with
 148      Pre => Has_Element (Container, Position);
 149
 150    procedure Union (Target : in out Set; Source : Set) with
 151      Pre => Length (Target) + Length (Source) -
 152               Length (Intersection (Target, Source)) <= Target.Capacity;
 153
 154    function Union (Left, Right : Set) return Set;
 155
 156    function "or" (Left, Right : Set) return Set renames Union;
 157
 158    procedure Intersection (Target : in out Set; Source : Set);
 159
 160    function Intersection (Left, Right : Set) return Set;
 161
 162    function "and" (Left, Right : Set) return Set renames Intersection;
 163
 164    procedure Difference (Target : in out Set; Source : Set);
 165
 166    function Difference (Left, Right : Set) return Set;
 167
 168    function "-" (Left, Right : Set) return Set renames Difference;
 169
 170    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 171
 172    function Symmetric_Difference (Left, Right : Set) return Set;
 173
 174    function "xor" (Left, Right : Set) return Set
 175      renames Symmetric_Difference;
 176
 177    function Overlap (Left, Right : Set) return Boolean;
 178
 179    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 180
 181    function First (Container : Set) return Cursor;
 182
 183    function Next (Container : Set; Position : Cursor) return Cursor with
 184      Pre => Has_Element (Container, Position) or else Position = No_Element;
 185
 186    procedure Next (Container : Set; Position : in out Cursor) with
 187      Pre => Has_Element (Container, Position) or else Position = No_Element;
 188
 189    function Find
 190      (Container : Set;
 191       Item      : Element_Type) return Cursor;
 192
 193    function Contains (Container : Set; Item : Element_Type) return Boolean;
 194
 195    function Has_Element (Container : Set; Position : Cursor) return Boolean;
 196
 197    function Equivalent_Elements (Left  : Set; CLeft : Cursor;
 198                                  Right : Set; CRight : Cursor) return Boolean;
 199
 200    function Equivalent_Elements
 201      (Left  : Set; CLeft : Cursor;
 202       Right : Element_Type) return Boolean;
 203
 204    function Equivalent_Elements
 205      (Left  : Element_Type;
 206       Right : Set; CRight : Cursor) return Boolean;
 207
 208    function Default_Modulus (Capacity : Count_Type) return Hash_Type;
 209
 210    generic
 211       type Key_Type (<>) is private;
 212
 213       with function Key (Element : Element_Type) return Key_Type;
 214
 215       with function Hash (Key : Key_Type) return Hash_Type;
 216
 217       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 218
 219    package Generic_Keys is
 220
 221       function Key (Container : Set; Position : Cursor) return Key_Type;
 222
 223       function Element (Container : Set; Key : Key_Type) return Element_Type;
 224
 225       procedure Replace
 226         (Container : in out Set;
 227          Key       : Key_Type;
 228          New_Item  : Element_Type);
 229
 230       procedure Exclude (Container : in out Set; Key : Key_Type);
 231
 232       procedure Delete (Container : in out Set; Key : Key_Type);
 233
 234       function Find (Container : Set; Key : Key_Type) return Cursor;
 235
 236       function Contains (Container : Set; Key : Key_Type) return Boolean;
 237
 238    end Generic_Keys;
 239
 240    function Strict_Equal (Left, Right : Set) return Boolean;
 241    --  Strict_Equal returns True if the containers are physically equal, i.e.
 242    --  they are structurally equal (function "=" returns True) and that they
 243    --  have the same set of cursors.
 244
 245    function Left  (Container : Set; Position : Cursor) return Set with
 246      Pre => Has_Element (Container, Position) or else Position = No_Element;
 247    function Right (Container : Set; Position : Cursor) return Set with
 248      Pre => Has_Element (Container, Position) or else Position = No_Element;
 249    --  Left returns a container containing all elements preceding Position
 250    --  (excluded) in Container. Right returns a container containing all
 251    --  elements following Position (included) in Container. These two new
 252    --  functions can be used to express invariant properties in loops which
 253    --  iterate over containers. Left returns the part of the container already
 254    --  scanned and Right the part not scanned yet.
 255
 256 private
 257
 258    pragma Inline (Next);
 259
 260    type Node_Type is
 261       record
 262          Element     : Element_Type;
 263          Next        : Count_Type;
 264          Has_Element : Boolean := False;
 265       end record;
 266
 267    package HT_Types is new
 268      Ada.Containers.Hash_Tables.Generic_Bounded_Hash_Table_Types (Node_Type);
 269
 270    type Set (Capacity : Count_Type; Modulus : Hash_Type) is
 271       new HT_Types.Hash_Table_Type (Capacity, Modulus) with null record;
 272
 273    use HT_Types;
 274
 275    type Cursor is record
 276       Node : Count_Type;
 277    end record;
 278
 279    No_Element : constant Cursor := (Node => 0);
 280
 281    Empty_Set : constant Set := (Capacity => 0, Modulus => 0, others => <>);
 282
 283 end Ada.Containers.Formal_Hashed_Sets;