libquadmath/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
   9 #
  10 # You will slowly go insane if you do not grok the following fact:  when
  11 # building this library, the top-level /target/ becomes the library's /host/.
  12 #
  13 # configure then causes --target to default to --host, exactly like any
  14 # other package using autoconf.  Therefore, 'target' and 'host' will
  15 # always be the same.  This makes sense both for native and cross compilers
  16 # just think about it for a little while.  :-)
  17 #
  18 # Also, if this library is being configured as part of a cross compiler, the
  19 # top-level configure script will pass the "real" host as $with_cross_host.
  20 #
  21 # Do not delete or change the following two lines.  For why, see
  22 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  23 AC_CANONICAL_SYSTEM
  24 ACX_NONCANONICAL_TARGET
  25
  26 target_alias=${target_alias-$host_alias}
  27 AC_SUBST(target_alias)
  28
  29 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
  30
  31 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  32 AC_ARG_ENABLE(version-specific-runtime-libs,
  33 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  34  [specify that runtime libraries should be installed in a compiler-specific directory]),
  35 [case "$enableval" in
  36  yes) version_specific_libs=yes ;;
  37  no)  version_specific_libs=no ;;
  38  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  39  esac],
  40 [version_specific_libs=no])
  41 AC_MSG_RESULT($version_specific_libs)
  42
  43 GCC_NO_EXECUTABLES
  44
  45 AC_USE_SYSTEM_EXTENSIONS
  46
  47 # See if makeinfo has been installed and is modern enough
  48 # that we can use it.
  49 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  50                    [GNU texinfo.* \([0-9][0-9.]*\)],
  51                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  52 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  53
  54 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
  55
  56 # Configure libtool
  57 AM_PROG_LIBTOOL
  58 ACX_LT_HOST_FLAGS
  59 AC_SUBST(enable_shared)
  60 AC_SUBST(enable_static)
  61
  62 AM_MAINTAINER_MODE
  63 AM_ENABLE_MULTILIB(, ..)
  64
  65 AC_LANG_C
  66 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  67 # We must force CC to /not/ be precious variables; otherwise
  68 # the wrong, non-multilib-adjusted value will be used in multilibs.
  69 # As a side effect, we have to subst CFLAGS ourselves.
  70
  71 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  72 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  73 AC_PROG_CC
  74 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  75
  76 AC_SUBST(CFLAGS)
  77
  78 AM_PROG_CC_C_O
  79
  80 if test "x$GCC" != "xyes"; then
  81   AC_MSG_ERROR([libquadmath must be built with GCC])
  82 fi
  83 AC_PROG_CPP
  84
  85 # Calculate toolexeclibdir
  86 # Also toolexecdir, though it's only used in toolexeclibdir
  87 case ${version_specific_libs} in
  88   yes)
  89     # Need the gcc compiler version to know where to install libraries
  90     # and header files if --enable-version-specific-runtime-libs option
  91     # is selected.
  92     toolexecdir='$(libdir)/gcc/$(target_alias)'
  93     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  94     ;;
  95   no)
  96     if test -n "$with_cross_host" &&
  97        test x"$with_cross_host" != x"no"; then
  98       # Install a library built with a cross compiler in tooldir, not libdir.
  99       toolexecdir='$(exec_prefix)/$(target_alias)'
 100       toolexeclibdir='$(toolexecdir)/lib'
 101     else
 102       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 103       toolexeclibdir='$(libdir)'
 104     fi
 105     multi_os_directory=`$CC -print-multi-os-directory`
 106     case $multi_os_directory in
 107       .) ;; # Avoid trailing /.
 108       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 109     esac
 110     ;;
 111 esac
 112 AC_SUBST(toolexecdir)
 113 AC_SUBST(toolexeclibdir)
 114
 115 AC_CHECK_HEADERS(fenv.h langinfo.h locale.h wchar.h wctype.h limits.h ctype.h printf.h errno.h)
 116 LIBQUAD_CHECK_MATH_H_SIGNGAM
 117
 118 # If available, sqrtl and cbrtl speed up the calculation -
 119 # but they are not required
 120 if test x$gcc_no_link != xyes; then
 121   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
 122   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
 123   AC_CHECK_LIB([m],[feholdexcept],[AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])])
 124   AC_CHECK_LIB([m],[fesetround],[AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])])
 125   AC_CHECK_LIB([m],[feupdateenv],[AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])])
 126   AC_CHECK_LIB([m],[fesetenv],[AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])])
 127   AC_CHECK_LIB([m],[fetestexcept],[AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])])
 128   AC_CHECK_FUNCS(strtoull)
 129 else
 130   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
 131     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])
 132   fi
 133   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
 134     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])
 135   fi
 136   if test "x$ac_cv_lib_m_feholdexcept" = x""yes; then
 137     AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])
 138   fi
 139   if test "x$ac_cv_lib_m_fesetround" = x""yes; then
 140     AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])
 141   fi
 142   if test "x$ac_cv_lib_m_feupdateenv" = x""yes; then
 143     AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])
 144   fi
 145   if test "x$ac_cv_lib_m_fesetenv" = x""yes; then
 146     AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])
 147   fi
 148   if test "x$ac_cv_lib_m_fetestexcept" = x""yes; then
 149     AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])
 150   fi
 151 fi
 152
 153 # Check for hidden visibility (copied from libssp).
 154 saved_CFLAGS="$CFLAGS"
 155 CFLAGS="$CFLAGS -Werror"
 156 AC_MSG_CHECKING([whether hidden visibility is supported])
 157 AC_TRY_COMPILE([
 158 void __attribute__((visibility ("hidden"))) bar (void) {}],,
 159 [quadmath_hidden=yes],[quadmath_hidden=no])
 160 AC_MSG_RESULT($quadmath_hidden)
 161 if test x$quadmath_hidden = xyes; then
 162   AC_DEFINE([HAVE_HIDDEN_VISIBILITY],[1],[__attribute__((visibility ("hidden"))) supported])
 163 fi
 164 CFLAGS="$saved_CFLAGS"
 165
 166 # Check for symbol versioning (copied from libssp).
 167 AC_MSG_CHECKING([whether symbol versioning is supported])
 168 AC_ARG_ENABLE(symvers,
 169 AS_HELP_STRING([--disable-symvers],
 170   [disable symbol versioning for libquadmath]),
 171 quadmath_use_symver=$enableval,
 172 quadmath_use_symver=yes)
 173 if test "x$quadmath_use_symver" != xno; then
 174   if test x$gcc_no_link = xyes; then
 175     # If we cannot link, we cannot build shared libraries, so do not use
 176     # symbol versioning.
 177     quadmath_use_symver=no
 178   else
 179     save_LDFLAGS="$LDFLAGS"
 180     LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 181     cat > conftest.map <<EOF
 182 FOO_1.0 {
 183   global: *foo*; bar; local: *;
 184 };
 185 EOF
 186     AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
 187     if test x$quadmath_use_symver = xno; then
 188       case "$target_os" in
 189         solaris2*)
 190           LDFLAGS="$save_LDFLAGS"
 191           LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 192           # Sun ld cannot handle wildcards and treats all entries as undefined.
 193           cat > conftest.map <<EOF
 194 FOO_1.0 {
 195   global: foo; local: *;
 196 };
 197 EOF
 198           AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
 199           ;;
 200       esac
 201     fi
 202     LDFLAGS="$save_LDFLAGS"
 203   fi
 204 fi
 205 AC_MSG_RESULT($quadmath_use_symver)
 206 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
 207 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
 208 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
 209
 210 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
 211   [GCC_TRY_COMPILE_OR_LINK([
 212     typedef _Complex float __attribute__((mode(TC))) __complex128;
 213
 214     __float128 foo (__float128 x)
 215     {
 216
 217      __complex128 z1, z2;
 218
 219      z1 = x;
 220      z2 = x / 7.Q;
 221      z2 /= z1;
 222
 223      return (__float128) z2;
 224     }
 225
 226     __float128 bar (__float128 x)
 227     {
 228       return x * __builtin_huge_valq ();
 229     }
 230   ],[
 231     foo (1.2Q);
 232     bar (1.2Q);
 233   ],[
 234     libquad_cv_have_float128=yes
 235   ],[
 236     libquad_cv_have_float128=no
 237 ])])
 238 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
 239
 240 # Check for printf hook support.
 241 AC_MSG_CHECKING([whether printf hooks are supported])
 242 AC_TRY_COMPILE([
 243 #include <printf.h>
 244 #include <stdarg.h>
 245 #include <stdlib.h>
 246 extern void flt128_va (void *, va_list *);
 247 extern int flt128_ais (const struct printf_info *, size_t, int *, int *);
 248 extern int flt128_printf_fp (FILE *, const struct printf_info *, const void *const *);
 249 ],[
 250 int pa_flt128 = register_printf_type (flt128_va);
 251 int mod_Q = register_printf_modifier (L"Q");
 252 int res = register_printf_specifier ('f', flt128_printf_fp, flt128_ais);
 253 struct printf_info info = { .user = -1 };
 254 ],
 255 [quadmath_printf_hooks=yes],[quadmath_printf_hooks=no])
 256 AC_MSG_RESULT($quadmath_printf_hooks)
 257 if test x$quadmath_printf_hooks = xyes; then
 258   AC_DEFINE([HAVE_PRINTF_HOOKS],[1],[GNU C Library stype printf hooks supported])
 259 fi
 260
 261 # Check for whether locale support for quadmath_snprintf or Q printf hooks
 262 # should be provided.
 263 AC_MSG_CHECKING([whether nl_langinfo should be used])
 264 AC_TRY_COMPILE([#include <langinfo.h>],[
 265 const char *s;
 266 s = nl_langinfo (DECIMAL_POINT);
 267 s = nl_langinfo (MON_DECIMAL_POINT);
 268 s = nl_langinfo (GROUPING);
 269 s = nl_langinfo (MON_GROUPING);
 270 s = nl_langinfo (THOUSANDS_SEP);
 271 s = nl_langinfo (MON_THOUSANDS_SEP);
 272 (void) s;
 273 ],
 274 [quadmath_use_nl_langinfo=yes],[quadmath_use_nl_langinfo=no])
 275 AC_MSG_RESULT($quadmath_use_nl_langinfo)
 276 if test x$quadmath_use_nl_langinfo = xyes; then
 277   AC_DEFINE([USE_NL_LANGINFO],[1],[whether nl_langinfo should be used])
 278 fi
 279
 280 AC_MSG_CHECKING([whether nl_langinfo should be used for wide char locale info])
 281 AC_TRY_COMPILE([#include <langinfo.h>],[
 282 const char *s;
 283 s = nl_langinfo (_NL_NUMERIC_DECIMAL_POINT_WC);
 284 s = nl_langinfo (_NL_MONETARY_DECIMAL_POINT_WC);
 285 s = nl_langinfo (_NL_NUMERIC_THOUSANDS_SEP_WC);
 286 s = nl_langinfo (_NL_MONETARY_THOUSANDS_SEP_WC);
 287 (void) s;
 288 ],
 289 [quadmath_use_nl_langinfo_wc=yes],[quadmath_use_nl_langinfo_wc=no])
 290 AC_MSG_RESULT($quadmath_use_nl_langinfo_wc)
 291 if test x$quadmath_use_nl_langinfo_wc = xyes; then
 292   AC_DEFINE([USE_NL_LANGINFO_WC],[1],[whether nl_langinfo should be used for wide char locale info])
 293 fi
 294
 295 AC_MSG_CHECKING([whether localeconv should be used])
 296 AC_TRY_COMPILE([#include <locale.h>],[
 297 const struct lconv *l = localeconv ();
 298 const char *s;
 299 s = l->decimal_point;
 300 s = l->mon_decimal_point;
 301 s = l->grouping;
 302 s = l->mon_grouping;
 303 s = l->thousands_sep;
 304 s = l->mon_thousands_sep;
 305 (void) s;
 306 ],
 307 [quadmath_use_localeconv=yes],[quadmath_use_localeconv=no])
 308 AC_MSG_RESULT($quadmath_use_localeconv)
 309 if test x$quadmath_use_localeconv = xyes; then
 310   AC_DEFINE([USE_LOCALECONV],[1],[whether localeconv should be used])
 311 fi
 312
 313 # Check for whether i18n number rewriting support for quadmath_snprintf
 314 # or Q printf hooks should be provided.
 315 AC_MSG_CHECKING([whether i18n number rewriting support for quadmath_snprintf should be added])
 316 AC_TRY_COMPILE([#include <langinfo.h>
 317 #include <limits.h>
 318 #include <string.h>
 319 #include <wchar.h>
 320 #include <wctype.h>],[
 321 const char *s;
 322 char decimal[MB_LEN_MAX];
 323 wctrans_t map = wctrans ("to_outpunct");
 324 wint_t wdecimal = towctrans (L'.', map);
 325 mbstate_t state;
 326 memset (&state, '\0', sizeof (state));
 327 wcrtomb (decimal, wdecimal, &state);
 328 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
 329 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
 330 s = nl_langinfo (_NL_CTYPE_MB_CUR_MAX);
 331 (void) s;
 332 ],
 333 [quadmath_use_i18n_number_h=yes],[quadmath_use_i18n_number_h=no])
 334 AC_MSG_RESULT($quadmath_use_i18n_number_h)
 335 if test x$quadmath_use_i18n_number_h = xyes; then
 336   AC_DEFINE([USE_I18N_NUMBER_H],[1],[whether i18n number rewriting can be supported])
 337 fi
 338
 339 AC_CACHE_SAVE
 340
 341 if test ${multilib} = yes; then
 342   multilib_arg="--enable-multilib"
 343 else
 344   multilib_arg=
 345 fi
 346
 347
 348 # We would like our source tree to be readonly. However when releases or
 349 # pre-releases are generated, the flex/bison generated files as well as the
 350 # various formats of manuals need to be included along with the rest of the
 351 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 352 # just that.
 353 AC_MSG_CHECKING(generated-files-in-srcdir)
 354 AC_ARG_ENABLE(generated-files-in-srcdir,
 355 AS_HELP_STRING([--enable-generated-files-in-srcdir],
 356  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
 357 [case "$enableval" in
 358  yes) enable_generated_files_in_srcdir=yes ;;
 359  no)  enable_generated_files_in_srcdir=no ;;
 360  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 361  esac],
 362 [enable_generated_files_in_srcdir=no])
 363 AC_MSG_RESULT($enable_generated_files_in_srcdir)
 364 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
 365
 366
 367 AC_CONFIG_FILES(Makefile)
 368 AC_OUTPUT