gcc/ada/a-tiinau.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --              A D A . T E X T _ I O . I N T E G E R  _ A U X              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Text_IO.Generic_Aux; use Ada.Text_IO.Generic_Aux;
  35
  36 with System.Img_BIU;   use System.Img_BIU;
  37 with System.Img_Int;   use System.Img_Int;
  38 with System.Img_LLB;   use System.Img_LLB;
  39 with System.Img_LLI;   use System.Img_LLI;
  40 with System.Img_LLW;   use System.Img_LLW;
  41 with System.Img_WIU;   use System.Img_WIU;
  42 with System.Val_Int;   use System.Val_Int;
  43 with System.Val_LLI;   use System.Val_LLI;
  44
  45 package body Ada.Text_IO.Integer_Aux is
  46
  47    -----------------------
  48    -- Local Subprograms --
  49    -----------------------
  50
  51    procedure Load_Integer
  52      (File : File_Type;
  53       Buf  : out String;
  54       Ptr  : in out Natural);
  55    --  This is an auxiliary routine that is used to load a possibly signed
  56    --  integer literal value from the input file into Buf, starting at Ptr + 1.
  57    --  On return, Ptr is set to the last character stored.
  58
  59    -------------
  60    -- Get_Int --
  61    -------------
  62
  63    procedure Get_Int
  64      (File  : File_Type;
  65       Item  : out Integer;
  66       Width : Field)
  67    is
  68       Buf  : String (1 .. Field'Last);
  69       Ptr  : aliased Integer := 1;
  70       Stop : Integer := 0;
  71
  72    begin
  73       if Width /= 0 then
  74          Load_Width (File, Width, Buf, Stop);
  75          String_Skip (Buf, Ptr);
  76       else
  77          Load_Integer (File, Buf, Stop);
  78       end if;
  79
  80       Item := Scan_Integer (Buf, Ptr'Access, Stop);
  81       Check_End_Of_Field (Buf, Stop, Ptr, Width);
  82    end Get_Int;
  83
  84    -------------
  85    -- Get_LLI --
  86    -------------
  87
  88    procedure Get_LLI
  89      (File  : File_Type;
  90       Item  : out Long_Long_Integer;
  91       Width : Field)
  92    is
  93       Buf  : String (1 .. Field'Last);
  94       Ptr  : aliased Integer := 1;
  95       Stop : Integer := 0;
  96
  97    begin
  98       if Width /= 0 then
  99          Load_Width (File, Width, Buf, Stop);
 100          String_Skip (Buf, Ptr);
 101       else
 102          Load_Integer (File, Buf, Stop);
 103       end if;
 104
 105       Item := Scan_Long_Long_Integer (Buf, Ptr'Access, Stop);
 106       Check_End_Of_Field (Buf, Stop, Ptr, Width);
 107    end Get_LLI;
 108
 109    --------------
 110    -- Gets_Int --
 111    --------------
 112
 113    procedure Gets_Int
 114      (From : String;
 115       Item : out Integer;
 116       Last : out Positive)
 117    is
 118       Pos : aliased Integer;
 119
 120    begin
 121       String_Skip (From, Pos);
 122       Item := Scan_Integer (From, Pos'Access, From'Last);
 123       Last := Pos - 1;
 124
 125    exception
 126       when Constraint_Error =>
 127          raise Data_Error;
 128    end Gets_Int;
 129
 130    --------------
 131    -- Gets_LLI --
 132    --------------
 133
 134    procedure Gets_LLI
 135      (From : String;
 136       Item : out Long_Long_Integer;
 137       Last : out Positive)
 138    is
 139       Pos : aliased Integer;
 140
 141    begin
 142       String_Skip (From, Pos);
 143       Item := Scan_Long_Long_Integer (From, Pos'Access, From'Last);
 144       Last := Pos - 1;
 145
 146    exception
 147       when Constraint_Error =>
 148          raise Data_Error;
 149    end Gets_LLI;
 150
 151    ------------------
 152    -- Load_Integer --
 153    ------------------
 154
 155    procedure Load_Integer
 156      (File : File_Type;
 157       Buf  : out String;
 158       Ptr  : in out Natural)
 159    is
 160       Hash_Loc : Natural;
 161       Loaded   : Boolean;
 162
 163    begin
 164       Load_Skip (File);
 165       Load (File, Buf, Ptr, '+', '-');
 166
 167       Load_Digits (File, Buf, Ptr, Loaded);
 168
 169       if Loaded then
 170
 171          --  Deal with based literal (note : is ok replacement for #)
 172
 173          Load (File, Buf, Ptr, '#', ':', Loaded);
 174
 175          if Loaded then
 176             Hash_Loc := Ptr;
 177             Load_Extended_Digits (File, Buf, Ptr);
 178             Load (File, Buf, Ptr, Buf (Hash_Loc));
 179          end if;
 180
 181          --  Deal with exponent
 182
 183          Load (File, Buf, Ptr, 'E', 'e', Loaded);
 184
 185          if Loaded then
 186
 187             --  Note: it is strange to allow a minus sign, since the syntax
 188             --  does not, but that is what ACVC test CE3704F, case (6) wants.
 189
 190             Load (File, Buf, Ptr, '+', '-');
 191             Load_Digits (File, Buf, Ptr);
 192          end if;
 193       end if;
 194    end Load_Integer;
 195
 196    -------------
 197    -- Put_Int --
 198    -------------
 199
 200    procedure Put_Int
 201      (File  : File_Type;
 202       Item  : Integer;
 203       Width : Field;
 204       Base  : Number_Base)
 205    is
 206       Buf : String (1 .. Integer'Max (Field'Last, Width));
 207       Ptr : Natural := 0;
 208
 209    begin
 210       if Base = 10 and then Width = 0 then
 211          Set_Image_Integer (Item, Buf, Ptr);
 212       elsif Base = 10 then
 213          Set_Image_Width_Integer (Item, Width, Buf, Ptr);
 214       else
 215          Set_Image_Based_Integer (Item, Base, Width, Buf, Ptr);
 216       end if;
 217
 218       Put_Item (File, Buf (1 .. Ptr));
 219    end Put_Int;
 220
 221    -------------
 222    -- Put_LLI --
 223    -------------
 224
 225    procedure Put_LLI
 226      (File  : File_Type;
 227       Item  : Long_Long_Integer;
 228       Width : Field;
 229       Base  : Number_Base)
 230    is
 231       Buf : String (1 .. Integer'Max (Field'Last, Width));
 232       Ptr : Natural := 0;
 233
 234    begin
 235       if Base = 10 and then Width = 0 then
 236          Set_Image_Long_Long_Integer (Item, Buf, Ptr);
 237       elsif Base = 10 then
 238          Set_Image_Width_Long_Long_Integer (Item, Width, Buf, Ptr);
 239       else
 240          Set_Image_Based_Long_Long_Integer (Item, Base, Width, Buf, Ptr);
 241       end if;
 242
 243       Put_Item (File, Buf (1 .. Ptr));
 244    end Put_LLI;
 245
 246    --------------
 247    -- Puts_Int --
 248    --------------
 249
 250    procedure Puts_Int
 251      (To   : out String;
 252       Item : Integer;
 253       Base : Number_Base)
 254    is
 255       Buf : String (1 .. Integer'Max (Field'Last, To'Length));
 256       Ptr : Natural := 0;
 257
 258    begin
 259       if Base = 10 then
 260          Set_Image_Width_Integer (Item, To'Length, Buf, Ptr);
 261       else
 262          Set_Image_Based_Integer (Item, Base, To'Length, Buf, Ptr);
 263       end if;
 264
 265       if Ptr > To'Length then
 266          raise Layout_Error;
 267       else
 268          To (To'First .. To'First + Ptr - 1) := Buf (1 .. Ptr);
 269       end if;
 270    end Puts_Int;
 271
 272    --------------
 273    -- Puts_LLI --
 274    --------------
 275
 276    procedure Puts_LLI
 277      (To   : out String;
 278       Item : Long_Long_Integer;
 279       Base : Number_Base)
 280    is
 281       Buf : String (1 .. Integer'Max (Field'Last, To'Length));
 282       Ptr : Natural := 0;
 283
 284    begin
 285       if Base = 10 then
 286          Set_Image_Width_Long_Long_Integer (Item, To'Length, Buf, Ptr);
 287       else
 288          Set_Image_Based_Long_Long_Integer (Item, Base, To'Length, Buf, Ptr);
 289       end if;
 290
 291       if Ptr > To'Length then
 292          raise Layout_Error;
 293       else
 294          To (To'First .. To'First + Ptr - 1) := Buf (1 .. Ptr);
 295       end if;
 296    end Puts_LLI;
 297
 298 end Ada.Text_IO.Integer_Aux;