gcc/ada/s-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                    S Y S T E M . E X C E P T I O N S                     --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.10 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2000 Free Software Foundation, Inc.          --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This package contains definitions used for zero cost exception handling.
  37 --  See unit Ada.Exceptions for further details. Note that the reason that
  38 --  we separate out these definitions is to avoid problems with recursion
  39 --  in rtsfind. They must be in a unit which does not require any exception
  40 --  table generation of any kind.
  41
  42 with Ada.Exceptions;
  43
  44 with System;
  45 with System.Standard_Library;
  46
  47 with Unchecked_Conversion;
  48
  49 package System.Exceptions is
  50
  51    package SSL renames System.Standard_Library;
  52    package AEX renames Ada.Exceptions;
  53
  54    --  The following section defines data structures used for zero cost
  55    --  exception handling if System.Parameters.Zero_Cost_Exceptions is
  56    --  set true (i.e. zero cost exceptions are implemented on this target).
  57
  58    --  The approach is to build tables that describe the PC ranges that
  59    --  are covered by various exception frames. When an exception occurs,
  60    --  these tables are searched to determine the address of the applicable
  61    --  handler for the current exception.
  62
  63    subtype Handler_Loc is System.Address;
  64    --  Code location representing entry address of a handler. Values of
  65    --  this type are created using the N_Handler_Loc node, and then
  66    --  passed to the Enter_Handler procedure to enter a handler.
  67
  68    subtype Code_Loc is System.Address;
  69    --  Code location used in building exception tables and for call
  70    --  addresses when propagating an exception (also traceback table)
  71    --  Values of this type are created by using Label'Address or
  72    --  extracted from machine states using Get_Code_Loc.
  73
  74    --------------------
  75    -- Handler_Record --
  76    --------------------
  77
  78    --  A Handler record is built for each choice for each exception handler
  79    --  in a frame.
  80
  81    function To_Exception_Id is
  82      new Unchecked_Conversion (SSL.Exception_Data_Ptr, AEX.Exception_Id);
  83
  84    Others_Dummy_Exception : aliased SSL.Exception_Data;
  85    Others_Id : constant AEX.Exception_Id :=
  86                  To_Exception_Id (Others_Dummy_Exception'Access);
  87    --  Dummy exception used to signal others exception
  88
  89    All_Others_Dummy_Exception : aliased SSL.Exception_Data;
  90    All_Others_Id : constant AEX.Exception_Id :=
  91                      To_Exception_Id (All_Others_Dummy_Exception'Access);
  92    --  Dummy exception used to signal all others exception (including
  93    --  exceptions not normally handled by others, e.g. Abort_Signal)
  94
  95    type Handler_Record is record
  96       Lo : Code_Loc;
  97       Hi : Code_Loc;
  98       --  Range of PC values of code covered by this handler record. The
  99       --  handler covers all code addresses that are greater than the Lo
 100       --  value, and less than or equal to the Hi value.
 101
 102       Id : AEX.Exception_Id;
 103       --  Id of exception being handled, or one of the above special values
 104
 105       Handler : Handler_Loc;
 106       --  Address of label at start of handler
 107    end record;
 108
 109    type Handler_Record_Ptr is access all Handler_Record;
 110    type Handler_Record_List is array (Natural range <>) of Handler_Record_Ptr;
 111
 112    ---------------------------
 113    -- Subprogram_Descriptor --
 114    ---------------------------
 115
 116    --  A Subprogram_Descriptor is built for each subprogram through which
 117    --  exceptions may propagate, this includes all Ada subprograms,
 118    --  and also all foreign language imported subprograms.
 119
 120    subtype Subprogram_Info_Type is System.Address;
 121    --  This type is used to represent a value that is used to unwind stack
 122    --  frames. It references target dependent data that provides sufficient
 123    --  information (e.g. about the location of the return point, use of a
 124    --  frame pointer, save-over-call registers etc) to unwind the machine
 125    --  state to the caller. For some targets, this is simply a pointer to
 126    --  the entry point of the procedure (and the routine to pop the machine
 127    --  state disassembles the code at the entry point to obtain the required
 128    --  information). On other targets, it is a pointer to data created by the
 129    --  backend or assembler to represent the required information.
 130
 131    No_Info : constant Subprogram_Info_Type := System.Null_Address;
 132    --  This is a special value used to indicate that it is not possible
 133    --  to pop past this frame. This is used at the outer level (e.g. for
 134    --  package elaboration procedures or the main procedure), and for any
 135    --  other foreign language procedure for which propagation is known
 136    --  to be impossible. An exception is considered unhandled if an
 137    --  attempt is made to pop a frame whose Subprogram_Info_Type value
 138    --  is set to No_Info.
 139
 140    type Subprogram_Descriptor (Num_Handlers : Natural) is record
 141       Code : Code_Loc;
 142       --  This is a code location used to determine which procedure we are
 143       --  in. Most usually it is simply the entry address for the procedure.
 144       --  hA given address is considered to be within the procedure referenced
 145       --  by a Subprogram_Descriptor record if this is the descriptor for
 146       --  which the Code value is as large as possible without exceeding
 147       --  the given value.
 148
 149       Subprogram_Info : Subprogram_Info_Type;
 150       --  This is a pointer to a target dependent data item that provides
 151       --  sufficient information for unwinding the stack frame of this
 152       --  procedure. A value of No_Info (zero) means that we are the
 153       --  outer level procedure.
 154
 155       Handler_Records : Handler_Record_List (1 .. Num_Handlers);
 156       --  List of pointers to Handler_Records for this procedure. The array
 157       --  is sorted inside out, i.e. entries for inner frames appear before
 158       --  entries for outer handlers. This ensures that a serial search
 159       --  finds the innermost applicable handler
 160    end record;
 161
 162    subtype Subprogram_Descriptor_0 is Subprogram_Descriptor (0);
 163    subtype Subprogram_Descriptor_1 is Subprogram_Descriptor (1);
 164    subtype Subprogram_Descriptor_2 is Subprogram_Descriptor (2);
 165    subtype Subprogram_Descriptor_3 is Subprogram_Descriptor (3);
 166    --  Predeclare commonly used subtypes for buildingt he tables
 167
 168    type Subprogram_Descriptor_Ptr is access all Subprogram_Descriptor;
 169
 170    type Subprogram_Descriptor_List
 171      is array (Natural range <>) of Subprogram_Descriptor_Ptr;
 172
 173    type Subprogram_Descriptors_Record (Count : Natural) is record
 174       SDesc : Subprogram_Descriptor_List (1 .. Count);
 175    end record;
 176
 177    type Subprogram_Descriptors_Ptr is
 178      access all Subprogram_Descriptors_Record;
 179
 180    --------------------------
 181    -- Unit Exception_Table --
 182    --------------------------
 183
 184    --  If a unit contains at least one subprogram, then a library level
 185    --  declaration of the form:
 186
 187    --    Tnn : aliased constant Subprogram_Descriptors :=
 188    --            (Count => n,
 189    --             SDesc =>
 190    --              (SD1'Unrestricted_Access,
 191    --               SD2'Unrestricted_Access,
 192    --               ...
 193    --               SDn'Unrestricted_Access));
 194    --    pragma Export (Ada, Tnn, "__gnat_unit_name__SDP");
 195
 196    --  is generated where the initializing expression is an array aggregate
 197    --  whose elements are pointers to the generated subprogram descriptors
 198    --  for the units.
 199
 200    --  Note: the ALI file contains the designation UX in each unit entry
 201    --  if a unit exception table is generated.
 202
 203    --  The binder generates a list of addresses of pointers to these tables.
 204
 205 end System.Exceptions;