gcc/ada/lib-load.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . L O A D                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.8 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- GNAT was originally developed  by the GNAT team at  New York University. --
  25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  26 --                                                                          --
  27 ------------------------------------------------------------------------------
  28
  29 --  This child package contains the function used to load a separately
  30 --  compiled unit, as well as the routine used to initialize the unit
  31 --  table and load the main source file.
  32
  33 package Lib.Load is
  34
  35    -------------------------------
  36    -- Handling of Renamed Units --
  37    -------------------------------
  38
  39    --  A compilation unit can be a renaming of another compilation unit.
  40    --  Such renamed units are not allowed as parent units, that is you
  41    --  cannot declare a unit:
  42
  43    --     with x;
  44    --     package x.y is end;
  45
  46    --  where x is a renaming of some other package. However you can refer
  47    --  to a renamed unit in a with clause:
  48
  49    --     package p is end;
  50
  51    --     package p.q is end;
  52
  53    --     with p;
  54    --     package pr renames p;
  55
  56    --     with pr.q ....
  57
  58    --  This means that in the context of a with clause, the normal fixed
  59    --  correspondence between unit and file names is broken. In the above
  60    --  example, there is no file named pr-q.ads, since the actual child
  61    --  unit is p.q, and it will be found in file p-q.ads.
  62
  63    --  In order to deal with this case, we have to first load pr.ads, and
  64    --  then discover that it is a renaming of p, so that we know that pr.q
  65    --  really refers to p.q. Furthermore this can happen at any level:
  66
  67    --     with p.q;
  68    --     package p.r renames p.q;
  69
  70    --     with p.q;
  71    --     package p.q.s is end;
  72
  73    --     with p.r.s ...
  74
  75    --  Now we have a case where the parent p.r is a child unit and is
  76    --  a renaming. This shows that renaming can occur at any level.
  77
  78    --  Finally, consider:
  79
  80    --     with pr.q.s ...
  81
  82    --  Here the parent pr.q is not itself a renaming, but it really refers
  83    --  to the unit p.q, and again we cannot know this without loading the
  84    --  parent. The bottom line here is that while the file name of a unit
  85    --  always corresponds to the unit name, the unit name as given to the
  86    --  Load_Unit function may not be the real unit.
  87
  88    -----------------
  89    -- Subprograms --
  90    -----------------
  91
  92    procedure Initialize;
  93    --  Called at the start of compiling a new main source unit to initialize
  94    --  the library processing for the new main source. Establishes and
  95    --  initializes the units table entry for the new main unit (leaving
  96    --  the Unit_File_Name entry of Main_Unit set to No_File if there are no
  97    --  more files. Otherwise the main source file has been opened and read
  98    --  and then closed on return.
  99
 100    procedure Initialize_Version (U : Unit_Number_Type);
 101    --  This is called once the source file corresponding to unit U has been
 102    --  fully scanned. At that point the checksum is computed, and can be used
 103    --  to initialize the version number.
 104
 105    function Load_Unit
 106      (Load_Name  : Unit_Name_Type;
 107       Required   : Boolean;
 108       Error_Node : Node_Id;
 109       Subunit    : Boolean;
 110       Corr_Body  : Unit_Number_Type := No_Unit;
 111       Renamings  : Boolean          := False)
 112       return       Unit_Number_Type;
 113    --  This function loads and parses the unit specified by Load_Name (or
 114    --  returns the unit number for the previously constructed units table
 115    --  entry if this is not the first call for this unit). Required indicates
 116    --  the behavior on a file not found condition, as further described below,
 117    --  and Error_Node is the node in the calling program to which error
 118    --  messages are to be attached.
 119    --
 120    --  If the corresponding file is found, the value returned by Load is the
 121    --  unit number that indexes the corresponding entry in the units table. If
 122    --  a serious enough parser error occurs to prevent subsequent semantic
 123    --  analysis, then the Fatal_Error flag of the returned entry is set and
 124    --  in addition, the fatal error flag of the calling unit is also set.
 125    --
 126    --  If the corresponding file is not found, then the behavior depends on
 127    --  the setting of Required. If Required is False, then No_Unit is returned
 128    --  and no error messages are issued. If Required is True, then an error
 129    --  message is posted, and No_Unit is returned.
 130    --
 131    --  A special case arises in the call from Rtsfind, where Error_Node is set
 132    --  to Empty. In this case Required is False, and the caller in any case
 133    --  treats any error as fatal.
 134    --
 135    --  The Subunit parameter is True to load a subunit, and False to load
 136    --  any other kind of unit (including all specs, package bodies, and
 137    --  subprogram bodies).
 138    --
 139    --  The Corr_Body argument is normally defaulted. It is set only in the
 140    --  case of loading the corresponding spec when the main unit is a body.
 141    --  In this case, Corr_Body is the unit number of this corresponding
 142    --  body. This is used to set the Serial_Ref_Unit field of the unit
 143    --  table entry. It is also used to deal with the special processing
 144    --  required by RM 10.1.4(4). See description in lib.ads.
 145    --
 146    --  Renamings activates the handling of renamed units as separately
 147    --  described in the documentation of this unit. If this parameter is
 148    --  set to True, then Load_Name may not be the real unit name and it
 149    --  is necessary to load parents to find the real name.
 150
 151    function Create_Dummy_Package_Unit
 152      (With_Node : Node_Id;
 153       Spec_Name : Unit_Name_Type)
 154       return      Unit_Number_Type;
 155    --  With_Node is the Node_Id of a with statement for which the file could
 156    --  not be found, and Spec_Name is the corresponding unit name. This call
 157    --  creates a dummy package unit so that compilation can continue without
 158    --  blowing up when the missing unit is referenced.
 159
 160    procedure Make_Instance_Unit (N : Node_Id);
 161    --  When a compilation unit is an instantiation, it contains both the
 162    --  declaration and the body of the instance, each of which can have its
 163    --  own elaboration routine. The file itself corresponds to the declaration.
 164    --  We create an additional entry for the body, so that the binder can
 165    --  generate the proper elaboration calls to both. The argument N is the
 166    --  compilation unit node created for the body.
 167
 168    procedure Version_Update (U : Node_Id; From : Node_Id);
 169    --  This routine is called when unit U is found to be semantically
 170    --  dependent on unit From. It updates the version of U to register
 171    --  dependence on the version of From. The arguments are compilation
 172    --  unit nodes for the relevant library nodes.
 173
 174 end Lib.Load;