gcc/ada/7sintman.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --                             $Revision: 1.14 $
  10 --                                                                          --
  11 --             Copyright (C) 1991-2001, Florida State University            --
  12 --                                                                          --
  13 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNARL was developed by the GNARL team at Florida State University. It is --
  32 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  33 -- State University (http://www.gnat.com).                                  --
  34 --                                                                          --
  35 ------------------------------------------------------------------------------
  36
  37 --  This is the default version of this package
  38
  39 --  This is a Sun OS (FSU THREADS) version of this package
  40
  41 --  PLEASE DO NOT add any dependences on other packages. ??? why not ???
  42 --  This package is designed to work with or without tasking support.
  43
  44 --  See the other warnings in the package specification before making
  45 --  any modifications to this file.
  46
  47 --  Make a careful study of all signals available under the OS, to see which
  48 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  49 --  the lookout for special signals that may be used by the thread library.
  50
  51 --  Since this is a multi target file, the signal <-> exception mapping
  52 --  is simple minded. If you need a more precise and target specific
  53 --  signal handling, create a new s-intman.adb that will fit your needs.
  54
  55 --  This file assumes that:
  56 --
  57 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  58 --      SIGPFE  => Constraint_Error
  59 --      SIGILL  => Program_Error
  60 --      SIGSEGV => Storage_Error
  61 --      SIGBUS  => Storage_Error
  62 --
  63 --    SIGINT exists and will be kept unmasked unless the pragma
  64 --     Unreserve_All_Interrupts is specified anywhere in the application.
  65 --
  66 --    System.OS_Interface contains the following:
  67 --      SIGADAABORT: the signal that will be used to abort tasks.
  68 --      Unmasked: the OS specific set of signals that should be unmasked in
  69 --                all the threads. SIGADAABORT is unmasked by
  70 --                default
  71 --      Reserved: the OS specific set of signals that are reserved.
  72
  73 with Interfaces.C;
  74 --  used for int and other types
  75
  76 with System.OS_Interface;
  77 --  used for various Constants, Signal and types
  78
  79 package body System.Interrupt_Management is
  80
  81    use Interfaces.C;
  82    use System.OS_Interface;
  83
  84    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  85    Exception_Interrupts : constant Interrupt_List :=
  86      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  87
  88    Unreserve_All_Interrupts : Interfaces.C.int;
  89    pragma Import
  90      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  91
  92    -----------------------
  93    -- Local Subprograms --
  94    -----------------------
  95
  96    procedure Notify_Exception (signo : Signal);
  97    --  This function identifies the Ada exception to be raised using
  98    --  the information when the system received a synchronous signal.
  99    --  Since this function is machine and OS dependent, different code
 100    --  has to be provided for different target.
 101
 102    ----------------------
 103    -- Notify_Exception --
 104    ----------------------
 105
 106    Signal_Mask : aliased sigset_t;
 107    --  The set of signals handled by Notify_Exception
 108
 109    procedure Notify_Exception (signo : Signal) is
 110       Result  : Interfaces.C.int;
 111
 112    begin
 113       --  With the __builtin_longjmp, the signal mask is not restored, so we
 114       --  need to restore it explicitely.
 115
 116       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 117       pragma Assert (Result = 0);
 118
 119       --  Check that treatment of exception propagation here
 120       --  is consistent with treatment of the abort signal in
 121       --  System.Task_Primitives.Operations.
 122
 123       case signo is
 124          when SIGFPE =>
 125             raise Constraint_Error;
 126          when SIGILL =>
 127             raise Program_Error;
 128          when SIGSEGV =>
 129             raise Storage_Error;
 130          when SIGBUS =>
 131             raise Storage_Error;
 132          when others =>
 133             null;
 134       end case;
 135    end Notify_Exception;
 136
 137    ---------------------------
 138    -- Initialize_Interrupts --
 139    ---------------------------
 140
 141    --  Nothing needs to be done on this platform.
 142
 143    procedure Initialize_Interrupts is
 144    begin
 145       null;
 146    end Initialize_Interrupts;
 147
 148 -------------------------
 149 -- Package Elaboration --
 150 -------------------------
 151
 152 begin
 153    declare
 154       act     : aliased struct_sigaction;
 155       old_act : aliased struct_sigaction;
 156       Result  : Interfaces.C.int;
 157
 158    begin
 159       --  Need to call pthread_init very early because it is doing signal
 160       --  initializations.
 161
 162       pthread_init;
 163
 164       Abort_Task_Interrupt := SIGADAABORT;
 165
 166       act.sa_handler := Notify_Exception'Address;
 167
 168       act.sa_flags := 0;
 169
 170       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 171       --  handler execution we do not change the Signal_Mask to be masked for
 172       --  the Signal.
 173
 174       --  This is a temporary fix to the problem that the Signal_Mask is
 175       --  not restored after the exception (longjmp) from the handler.
 176       --  The right fix should be made in sigsetjmp so that we save
 177       --  the Signal_Set and restore it after a longjmp.
 178
 179       --  Since SA_NODEFER is obsolete, instead we reset explicitely
 180       --  the mask in the exception handler.
 181
 182       Result := sigemptyset (Signal_Mask'Access);
 183       pragma Assert (Result = 0);
 184
 185       --  ??? For the same reason explained above, we can't mask these
 186       --  signals because otherwise we won't be able to catch more than
 187       --  one signal.
 188
 189       act.sa_mask := Signal_Mask;
 190
 191       Keep_Unmasked (Abort_Task_Interrupt) := True;
 192       Keep_Unmasked (SIGXCPU) := True;
 193       Keep_Unmasked (SIGFPE) := True;
 194       Result :=
 195         sigaction
 196         (Signal (SIGFPE), act'Unchecked_Access,
 197          old_act'Unchecked_Access);
 198       pragma Assert (Result = 0);
 199
 200       --  By keeping SIGINT unmasked, allow the user to do a Ctrl-C, but at
 201       --  the same time, disable the ability of handling this signal via
 202       --  package Ada.Interrupts.
 203
 204       --  The pragma Unreserve_All_Interrupts let the user the ability to
 205       --  change this behavior.
 206
 207       if Unreserve_All_Interrupts = 0 then
 208          Keep_Unmasked (SIGINT) := True;
 209       end if;
 210
 211       for J in
 212         Exception_Interrupts'First + 1 .. Exception_Interrupts'Last
 213       loop
 214          Keep_Unmasked (Exception_Interrupts (J)) := True;
 215
 216          if Unreserve_All_Interrupts = 0 then
 217             Result :=
 218               sigaction
 219               (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 220                old_act'Unchecked_Access);
 221             pragma Assert (Result = 0);
 222          end if;
 223       end loop;
 224
 225       for J in Unmasked'Range loop
 226          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 227       end loop;
 228
 229       Reserve := Keep_Unmasked or Keep_Masked;
 230
 231       for J in Reserved'Range loop
 232          Reserve (Interrupt_ID (Reserved (J))) := True;
 233       end loop;
 234
 235       --  We do not have Signal 0 in reality. We just use this value
 236       --  to identify non-existent signals (see s-intnam.ads). Therefore,
 237       --  Signal 0 should not be used in all signal related operations hence
 238       --  mark it as reserved.
 239
 240       Reserve (0) := True;
 241    end;
 242 end System.Interrupt_Management;