gcc/ada/51osinte.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --                              $Revision: 1.4 $
  10 --                                                                          --
  11 --           Copyright (C) 1999-2001 Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNARL was developed by the GNARL team at Florida State University. It is --
  32 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  33 -- State University (http://www.gnat.com).                                  --
  34 --                                                                          --
  35 ------------------------------------------------------------------------------
  36
  37 --  This is a UnixWare (Native) version of this package
  38
  39 pragma Polling (Off);
  40 --  Turn off polling, we do not want ATC polling to take place during
  41 --  tasking operations. It causes infinite loops and other problems.
  42
  43 with Interfaces.C;
  44
  45 package body System.OS_Interface is
  46
  47    use Interfaces.C;
  48
  49    -----------------
  50    -- To_Duration --
  51    -----------------
  52
  53    function To_Duration (TS : timespec) return Duration is
  54    begin
  55       return Duration (TS.tv_sec) + Duration (TS.tv_nsec) / 10#1#E9;
  56    end To_Duration;
  57
  58    function To_Duration (TV : struct_timeval) return Duration is
  59    begin
  60       return Duration (TV.tv_sec) + Duration (TV.tv_usec) / 10#1#E6;
  61    end To_Duration;
  62
  63    -----------------
  64    -- To_Timespec --
  65    -----------------
  66
  67    function To_Timespec (D : Duration) return timespec is
  68       S : time_t;
  69       F : Duration;
  70
  71    begin
  72       S := time_t (Long_Long_Integer (D));
  73       F := D - Duration (S);
  74
  75       --  If F has negative value due to a round-up, adjust for positive F
  76       --  value.
  77
  78       if F < 0.0 then
  79          S := S - 1;
  80          F := F + 1.0;
  81       end if;
  82
  83       return timespec' (tv_sec => S,
  84         tv_nsec => long (Long_Long_Integer (F * 10#1#E9)));
  85    end To_Timespec;
  86
  87    ----------------
  88    -- To_Timeval --
  89    ----------------
  90
  91    function To_Timeval (D : Duration) return struct_timeval is
  92       S : long;
  93       F : Duration;
  94
  95    begin
  96       S := long (Long_Long_Integer (D));
  97       F := D - Duration (S);
  98
  99       --  If F has negative value due to a round-up, adjust for positive F
 100       --  value.
 101
 102       if F < 0.0 then
 103          S := S - 1;
 104          F := F + 1.0;
 105       end if;
 106
 107       return struct_timeval' (tv_sec => S,
 108         tv_usec => long (Long_Long_Integer (F * 10#1#E6)));
 109    end To_Timeval;
 110
 111    -------------------
 112    -- clock_gettime --
 113    -------------------
 114
 115    function clock_gettime
 116      (clock_id : clockid_t;
 117       tp       : access timespec) return int
 118    is
 119       Result : int;
 120       tv     : aliased struct_timeval;
 121
 122       function gettimeofday
 123         (tv : access struct_timeval;
 124          tz : System.Address := System.Null_Address) return int;
 125       pragma Import (C, gettimeofday, "gettimeofday");
 126
 127    begin
 128       Result := gettimeofday (tv'Unchecked_Access);
 129       tp.all := To_Timespec (To_Duration (tv));
 130       return Result;
 131    end clock_gettime;
 132
 133    ---------------------------
 134    --  POSIX.1c  Section 3  --
 135    ---------------------------
 136
 137    function sigwait (set : access sigset_t; sig : access Signal) return int is
 138       Result : int;
 139
 140       function sigwait (set : access sigset_t) return int;
 141       pragma Import (C, sigwait, "sigwait");
 142
 143    begin
 144       Result := sigwait (set);
 145
 146       if Result < 0 then
 147          sig.all := 0;
 148          return errno;
 149       end if;
 150
 151       sig.all := Signal (Result);
 152       return 0;
 153    end sigwait;
 154
 155    function pthread_kill (thread : pthread_t; sig : Signal) return int is
 156       function pthread_kill_base
 157         (thread : access pthread_t; sig : access Signal) return int;
 158       pragma Import (C, pthread_kill_base, "pthread_kill");
 159
 160       thr   : aliased pthread_t := thread;
 161       signo : aliased Signal := sig;
 162
 163    begin
 164       return pthread_kill_base (thr'Unchecked_Access, signo'Unchecked_Access);
 165    end pthread_kill;
 166
 167    function Get_Stack_Base (thread : pthread_t) return Address is
 168    begin
 169       return Null_Address;
 170    end Get_Stack_Base;
 171
 172    procedure pthread_init is
 173    begin
 174       null;
 175    end pthread_init;
 176
 177 end System.OS_Interface;