gcc/ada/s-imgbiu.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ B I U                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System.Unsigned_Types; use System.Unsigned_Types;
  36
  37 package body System.Img_BIU is
  38
  39    -----------------------------
  40    -- Set_Image_Based_Integer --
  41    -----------------------------
  42
  43    procedure Set_Image_Based_Integer
  44      (V : Integer;
  45       B : Natural;
  46       W : Integer;
  47       S : out String;
  48       P : in out Natural)
  49    is
  50       Start : Natural;
  51
  52    begin
  53       --  Positive case can just use the unsigned circuit directly
  54
  55       if V >= 0 then
  56          Set_Image_Based_Unsigned (Unsigned (V), B, W, S, P);
  57
  58       --  Negative case has to set a minus sign. Note also that we have to be
  59       --  careful not to generate overflow with the largest negative number.
  60
  61       else
  62          P := P + 1;
  63          S (P) := ' ';
  64          Start := P;
  65
  66          declare
  67             pragma Suppress (Overflow_Check);
  68             pragma Suppress (Range_Check);
  69          begin
  70             Set_Image_Based_Unsigned (Unsigned (-V), B, W - 1, S, P);
  71          end;
  72
  73          --  Set minus sign in last leading blank location. Because of the
  74          --  code above, there must be at least one such location.
  75
  76          while S (Start + 1) = ' ' loop
  77             Start := Start + 1;
  78          end loop;
  79
  80          S (Start) := '-';
  81       end if;
  82
  83    end Set_Image_Based_Integer;
  84
  85    ------------------------------
  86    -- Set_Image_Based_Unsigned --
  87    ------------------------------
  88
  89    procedure Set_Image_Based_Unsigned
  90      (V : Unsigned;
  91       B : Natural;
  92       W : Integer;
  93       S : out String;
  94       P : in out Natural)
  95    is
  96       Start : constant Natural := P;
  97       F, T  : Natural;
  98       BU    : constant Unsigned := Unsigned (B);
  99       Hex   : constant array
 100                 (Unsigned range 0 .. 15) of Character := "0123456789ABCDEF";
 101
 102       procedure Set_Digits (T : Unsigned);
 103       --  Set digits of absolute value of T
 104
 105       procedure Set_Digits (T : Unsigned) is
 106       begin
 107          if T >= BU then
 108             Set_Digits (T / BU);
 109             P := P + 1;
 110             S (P) := Hex (T mod BU);
 111          else
 112             P := P + 1;
 113             S (P) := Hex (T);
 114          end if;
 115       end Set_Digits;
 116
 117    --  Start of processing for Set_Image_Based_Unsigned
 118
 119    begin
 120
 121       if B >= 10 then
 122          P := P + 1;
 123          S (P) := '1';
 124       end if;
 125
 126       P := P + 1;
 127       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
 128
 129       P := P + 1;
 130       S (P) := '#';
 131
 132       Set_Digits (V);
 133
 134       P := P + 1;
 135       S (P) := '#';
 136
 137       --  Add leading spaces if required by width parameter
 138
 139       if P - Start < W then
 140          F := P;
 141          P := Start + W;
 142          T := P;
 143
 144          while F > Start loop
 145             S (T) := S (F);
 146             T := T - 1;
 147             F := F - 1;
 148          end loop;
 149
 150          for J in Start + 1 .. T loop
 151             S (J) := ' ';
 152          end loop;
 153       end if;
 154
 155    end Set_Image_Based_Unsigned;
 156
 157 end System.Img_BIU;