gcc/ada/5posprim.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --                  S Y S T E M . O S _ P R I M I T I V E S                 --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1998-2001 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This version uses gettimeofday and select
  36 --  Currently OpenNT, Dec Unix, Solaris and SCO UnixWare use this file.
  37
  38 package body System.OS_Primitives is
  39
  40    --  ??? These definitions are duplicated from System.OS_Interface
  41    --  because we don't want to depend on any package. Consider removing
  42    --  these declarations in System.OS_Interface and move these ones in
  43    --  the spec.
  44
  45    type struct_timezone is record
  46       tz_minuteswest  : Integer;
  47       tz_dsttime   : Integer;
  48    end record;
  49    pragma Convention (C, struct_timezone);
  50    type struct_timezone_ptr is access all struct_timezone;
  51
  52    type struct_timeval is record
  53       tv_sec       : Integer;
  54       tv_usec      : Integer;
  55    end record;
  56    pragma Convention (C, struct_timeval);
  57
  58    function gettimeofday
  59      (tv : access struct_timeval;
  60       tz : struct_timezone_ptr) return Integer;
  61    pragma Import (C, gettimeofday, "gettimeofday");
  62
  63    type fd_set is null record;
  64    type fd_set_ptr is access all fd_set;
  65
  66    function C_select
  67      (n         : Integer    := 0;
  68       readfds,
  69       writefds,
  70       exceptfds : fd_set_ptr := null;
  71       timeout   : access struct_timeval) return Integer;
  72    pragma Import (C, C_select, "select");
  73
  74    -----------
  75    -- Clock --
  76    -----------
  77
  78    function Clock return Duration is
  79       TV     : aliased struct_timeval;
  80       Result : Integer;
  81
  82    begin
  83       Result := gettimeofday (TV'Access, null);
  84       return Duration (TV.tv_sec) + Duration (TV.tv_usec) / 10#1#E6;
  85    end Clock;
  86
  87    ---------------------
  88    -- Monotonic_Clock --
  89    ---------------------
  90
  91    function Monotonic_Clock return Duration renames Clock;
  92
  93    -----------------
  94    -- Timed_Delay --
  95    -----------------
  96
  97    procedure Timed_Delay
  98      (Time : Duration;
  99       Mode : Integer)
 100    is
 101       Result     : Integer;
 102       Rel_Time   : Duration;
 103       Abs_Time   : Duration;
 104       Check_Time : Duration := Clock;
 105       timeval    : aliased struct_timeval;
 106
 107    begin
 108       if Mode = Relative then
 109          Rel_Time := Time;
 110          Abs_Time := Time + Check_Time;
 111       else
 112          Rel_Time := Time - Check_Time;
 113          Abs_Time := Time;
 114       end if;
 115
 116       if Rel_Time > 0.0 then
 117          loop
 118             timeval.tv_sec := Integer (Rel_Time);
 119
 120             if Duration (timeval.tv_sec) > Rel_Time then
 121                timeval.tv_sec := timeval.tv_sec - 1;
 122             end if;
 123
 124             timeval.tv_usec :=
 125               Integer ((Rel_Time - Duration (timeval.tv_sec)) * 10#1#E6);
 126
 127             Result := C_select (timeout => timeval'Unchecked_Access);
 128             Check_Time := Clock;
 129
 130             exit when Abs_Time <= Check_Time;
 131
 132             Rel_Time := Abs_Time - Check_Time;
 133          end loop;
 134       end if;
 135    end Timed_Delay;
 136
 137 end System.OS_Primitives;