libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 AC_PROG_LN_S
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR
   9                            configuring in a subdirectory])
  10 AC_ARG_WITH(cross-host,
  11 [  --with-cross-host=HOST  configuring with a cross compiler])
  12
  13 LIBGCJ_CONFIGURE(.)
  14
  15 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  16
  17 # Only use libltdl for native builds.
  18 if test -z "${with_cross_host}"; then
  19    AC_LIBLTDL_CONVENIENCE
  20    AC_LIBTOOL_DLOPEN
  21    DIRLTDL=libltdl
  22    AC_DEFINE(USE_LTDL)
  23    # Sigh.  Libtool's macro doesn't do the right thing.
  24    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  25    # FIXME: this is a hack.
  26    sub_auxdir="`cd $ac_aux_dir && pwd`"
  27    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -z "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66
  67 dnl Should we use hashtable-based synchronization?
  68 dnl Currently works only for Linux X86/ia64
  69 dnl Typically faster and more space-efficient
  70 AC_ARG_ENABLE(hash-synchronization,
  71 [  --enable-hash-synchronization
  72                           Use global hash table for monitor locks])
  73
  74 if test -z "$enable_hash_synchronization"; then
  75    enable_hash_synchronization=$enable_hash_synchronization_default
  76 fi
  77
  78
  79 dnl See if the user has requested runtime debugging.
  80 LIBGCJDEBUG="false"
  81 AC_SUBST(LIBGCJDEBUG)
  82 AC_ARG_ENABLE(libgcj-debug,
  83 [  --enable-libgcj-debug   enable runtime debugging code],
  84   if test "$enable_libgcj_debug" = yes; then
  85     AC_DEFINE(DEBUG)
  86     LIBGCJDEBUG="true"
  87   fi)
  88
  89 dnl See if the user has the interpreter included.
  90 AC_ARG_ENABLE(interpreter,
  91 [  --enable-interpreter    enable interpreter],
  92   if test "$enable_interpreter" = yes; then
  93     # This can also be set in configure.host.
  94     libgcj_interpreter=yes
  95   elif test "$enable_interpreter" = no; then
  96     libgcj_interpreter=no
  97   fi)
  98
  99 if test "$libgcj_interpreter" = yes; then
 100    AC_DEFINE(INTERPRETER)
 101 fi
 102
 103 AC_MSG_CHECKING([for exception model to use])
 104 AC_LANG_SAVE
 105 AC_LANG_CPLUSPLUS
 106 AC_ARG_ENABLE(sjlj-exceptions,
 107 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 108 [:],
 109 [dnl Botheration.  Now we've got to detect the exception model.
 110 dnl Link tests against libgcc.a are problematic since -- at least
 111 dnl as of this writing -- we've not been given proper -L bits for
 112 dnl single-tree newlib and libgloss.
 113 dnl
 114 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 115 dnl conftest files before we got a change to grep them first.
 116 cat > conftest.$ac_ext << EOF
 117 [#]line __oline__ "configure"
 118 struct S { ~S(); };
 119 void bar();
 120 void foo()
 121 {
 122   S s;
 123   bar();
 124 }
 125 EOF
 126 old_CXXFLAGS="$CXXFLAGS"
 127 CXXFLAGS=-S
 128 if AC_TRY_EVAL(ac_compile); then
 129   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 130     enable_sjlj_exceptions=yes
 131   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 132     enable_sjlj_exceptions=no
 133   fi
 134 fi
 135 CXXFLAGS="$old_CXXFLAGS"
 136 rm -f conftest*])
 137 if test x$enable_sjlj_exceptions = xyes; then
 138   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 139         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 140   ac_exception_model_name=sjlj
 141 elif test x$enable_sjlj_exceptions = xno; then
 142   ac_exception_model_name="call frame"
 143 else
 144   AC_MSG_ERROR([unable to detect exception model])
 145 fi
 146 AC_LANG_RESTORE
 147 AC_MSG_RESULT($ac_exception_model_name)
 148
 149 dnl See if the user wants to disable java.net.  This is the mildly
 150 dnl ugly way that we admit that target-side configuration sucks.
 151 AC_ARG_ENABLE(java-net,
 152 [  --disable-java-net      disable java.net])
 153
 154 dnl Whether java.net is built by default can depend on the target.
 155 if test -z "$enable_java_net"; then
 156    enable_java_net=${enable_java_net_default-yes}
 157 fi
 158 if test "$enable_java_net" = no; then
 159    AC_DEFINE(DISABLE_JAVA_NET)
 160 fi
 161
 162 dnl See if the user wants to configure without libffi.  Some
 163 dnl architectures don't support it, and default values are set in
 164 dnl configure.host.
 165 AC_ARG_WITH(libffi,
 166 [  --without-libffi        don't use libffi],,with_libffi=${with_libffi_default-yes})
 167
 168 LIBFFI=
 169 LIBFFIINCS=
 170 if test "$with_libffi" != no; then
 171    AC_DEFINE(USE_LIBFFI)
 172    LIBFFI=../libffi/libfficonvenience.la
 173    LIBFFIINCS="-I$(top_srcdir)/../libffi/include -I$(MULTIBUILDTOP)../libffi/include"
 174 fi
 175 AC_SUBST(LIBFFI)
 176 AC_SUBST(LIBFFIINCS)
 177
 178 dnl See if the user wants to disable JVMPI support.
 179 AC_ARG_ENABLE(jvmpi,
 180 [  --disable-jvmpi         disable JVMPI support])
 181
 182 if test "$enable_jvmpi" != no; then
 183     AC_DEFINE(ENABLE_JVMPI)
 184 fi
 185
 186 dnl If the target is an eCos system, use the appropriate eCos
 187 dnl I/O routines.
 188 dnl FIXME: this should not be a local option but a global target
 189 dnl system; at present there is no eCos target.
 190 TARGET_ECOS="no"
 191 AC_ARG_WITH(ecos,
 192 [  --with-ecos             enable runtime eCos target support],
 193 TARGET_ECOS="$with_ecos"
 194 )
 195
 196 case "$TARGET_ECOS" in
 197    no)
 198       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 199       PROCESS=${PROCESS-Posix}
 200       ;;
 201    *)
 202       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 203       PROCESS=Ecos
 204       AC_DEFINE(ECOS)
 205       ;;
 206 esac
 207
 208 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 209 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 210 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 211 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 212
 213
 214 dnl These may not be defined in a non-ANS conformant embedded system.
 215 dnl FIXME: Should these case a runtime exception in that case?
 216 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 217 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 218
 219 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 220 dnl to create the link will fail.
 221 test -d java || mkdir java
 222 test -d java/io || mkdir java/io
 223 test -d gnu || mkdir gnu
 224 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 225
 226 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 227 test -d java/lang || mkdir java/lang
 228 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 229 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 230
 231 SYSTEMSPEC=
 232 AC_SUBST(SYSTEMSPEC)
 233
 234 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 235 AC_SUBST(LIBGCJTESTSPEC)
 236
 237 AC_ARG_WITH(system-zlib,
 238 [  --with-system-zlib      use installed libz])
 239 ZLIBSPEC=
 240 AC_SUBST(ZLIBSPEC)
 241 ZLIBTESTSPEC=
 242 AC_SUBST(ZLIBTESTSPEC)
 243
 244 dnl FIXME: this should be _libs on some hosts.
 245 libsubdir=.libs
 246
 247 dnl Allow the GC to be disabled.  Can be useful when debugging.
 248 AC_MSG_CHECKING([for garbage collector to use])
 249 AC_ARG_ENABLE(java-gc,
 250 changequote(<<,>>)dnl
 251 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 252 changequote([,])
 253   GC=$enableval,
 254   GC=boehm)
 255 GCLIBS=
 256 GCINCS=
 257 GCDEPS=
 258 GCOBJS=
 259 GCSPEC=
 260 JC1GCSPEC=
 261 GCTESTSPEC=
 262 case "$GC" in
 263  boehm)
 264     AC_MSG_RESULT(boehm)
 265     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 266     # We include the path to the boehm-gc build directory.
 267     # See Makefile.am to understand why.
 268     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 269     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 270     GCSPEC='-lgcjgc'
 271     JC1GCSPEC='-fuse-boehm-gc'
 272     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 273     dnl We also want to pick up some cpp flags required when including
 274     dnl boehm-config.h.  Yuck.
 275     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 276     GCOBJS=boehm.lo
 277     GCHDR=boehm-gc.h
 278     dnl The POSIX thread support needs to know this.
 279     AC_DEFINE(HAVE_BOEHM_GC)
 280     ;;
 281  no)
 282     AC_MSG_RESULT(none)
 283     GCOBJS=nogc.lo
 284     GCHDR=no-gc.h
 285     ;;
 286  *)
 287     AC_MSG_ERROR(unrecognized collector \"$GC\")
 288     ;;
 289 esac
 290 AC_SUBST(GCLIBS)
 291 AC_SUBST(GCINCS)
 292 AC_SUBST(GCDEPS)
 293 AC_SUBST(GCOBJS)
 294 AC_SUBST(GCSPEC)
 295 AC_SUBST(JC1GCSPEC)
 296 AC_SUBST(GCTESTSPEC)
 297 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 298
 299
 300 AC_MSG_CHECKING([for thread model used by GCC])
 301 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 302 AC_MSG_RESULT([$THREADS])
 303
 304 case "$THREADS" in
 305  no | none | single)
 306     THREADS=none
 307     ;;
 308  posix | pthreads)
 309     THREADS=posix
 310     case "$host" in
 311      *-*-linux*)
 312         AC_DEFINE(LINUX_THREADS)
 313         ;;
 314     esac
 315     ;;
 316  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 317     AC_MSG_ERROR(thread package $THREADS not yet supported)
 318     ;;
 319  *)
 320     AC_MSG_ERROR($THREADS is an unknown thread package)
 321     ;;
 322 esac
 323
 324 THREADLIBS=
 325 THREADINCS=
 326 THREADDEPS=
 327 THREADOBJS=
 328 THREADH=
 329 THREADSPEC=
 330 case "$THREADS" in
 331  posix)
 332     THREADLIBS=-lpthread
 333     THREADSPEC=-lpthread
 334     THREADOBJS=posix-threads.lo
 335     THREADH=posix-threads.h
 336     # MIT pthreads doesn't seem to have the mutexattr functions.
 337     # But for now we don't check for it.  We just assume you aren't
 338     # using MIT pthreads.
 339     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 340
 341     # If we're using the Boehm GC, then we happen to know that it
 342     # defines _REENTRANT, so we don't bother.  Eww.
 343     if test "$GC" != boehm; then
 344        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 345     fi
 346     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 347     ;;
 348
 349  none)
 350     THREADOBJS=no-threads.lo
 351     THREADH=no-threads.h
 352     ;;
 353 esac
 354 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 355 AC_SUBST(THREADLIBS)
 356 AC_SUBST(THREADINCS)
 357 AC_SUBST(THREADDEPS)
 358 AC_SUBST(THREADOBJS)
 359 AC_SUBST(THREADSPEC)
 360
 361 HASH_SYNC_SPEC=
 362 # Hash synchronization is only useful with posix threads right now.
 363 if test "$enable_hash_synchronization" = yes && test "$THREADS" = "posix"; then
 364    HASH_SYNC_SPEC=-fhash-synchronization
 365    AC_DEFINE(JV_HASH_SYNCHRONIZATION)
 366 fi
 367 AC_SUBST(HASH_SYNC_SPEC)
 368
 369
 370 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 371
 372 CANADIAN=no
 373 NULL_TARGET=no
 374 NATIVE=yes
 375
 376 # We're in the tree with gcc, and need to include some of its headers.
 377 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 378
 379 if test -n "${with_cross_host}"; then
 380    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 381    # may not work correctly, because the compiler may not be able to
 382    # link executables.
 383
 384    # We assume newlib.  This lets us hard-code the functions we know
 385    # we'll have.
 386    AC_DEFINE(HAVE_MEMMOVE)
 387    AC_DEFINE(HAVE_MEMCPY)
 388    AC_DEFINE(HAVE_STRERROR)
 389    AC_DEFINE(HAVE_GMTIME_R)
 390    AC_DEFINE(HAVE_LOCALTIME_R)
 391    dnl This is only for POSIX threads.
 392    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 393    dnl We also assume we are using gcc, which provides alloca.
 394    AC_DEFINE(HAVE_ALLOCA)
 395
 396    dnl Assume we do not have getuid and friends.
 397    AC_DEFINE(NO_GETUID)
 398
 399    ZLIBSPEC=-lzgcj
 400    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 401
 402    # If Canadian cross, then don't pick up tools from the build
 403    # directory.
 404    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 405       CANADIAN=yes
 406       GCC_UNWIND_INCLUDE=
 407       GCJ="${target_alias}-gcj"
 408    fi
 409    NATIVE=no
 410 else
 411    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 412    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 413    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 414    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 415    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 416    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 417    AC_CHECK_FUNCS(backtrace fork execvp pipe sigaction)
 418    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 419    AC_CHECK_LIB(dl, dladdr, [
 420      AC_DEFINE(HAVE_DLADDR)])
 421    AC_CHECK_FILES(/proc/self/exe, [
 422      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 423
 424    AC_CHECK_FUNCS(gethostbyname_r, [
 425      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 426      # There are two different kinds of gethostbyname_r.
 427      # We look for the one that returns `int'.
 428      # Hopefully this check is robust enough.
 429      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 430        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 431
 432      case " $GCINCS " in
 433      *" -D_REENTRANT "*) ;;
 434      *)
 435         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 436         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 437         [libjava_cv_gethostbyname_r_needs_reentrant],
 438         [ AC_LANG_SAVE
 439           AC_LANG_CPLUSPLUS
 440           AC_TRY_COMPILE([#include <netdb.h>],
 441             [gethostbyname_r("", 0, 0);],
 442             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 443                 CPPFLAGS_SAVE="$CPPFLAGS"
 444                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 445                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 446                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 447                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 448                 CPPFLAGS="$CPPFLAGS_SAVE"
 449           ])
 450           AC_LANG_RESTORE
 451         ])
 452         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 453           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 454         fi
 455      ;;
 456      esac
 457
 458      AC_CACHE_CHECK([for struct hostent_data],
 459         [libjava_cv_struct_hostent_data], [dnl
 460         AC_TRY_COMPILE([
 461 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 462 # define _REENTRANT 1
 463 #endif
 464 #include <netdb.h>], [struct hostent_data data;],
 465           [libjava_cv_struct_hostent_data=yes],
 466           [libjava_cv_struct_hostent_data=no])])
 467      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 468        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 469          [Define if struct hostent_data is defined in netdb.h])
 470      fi
 471    ])
 472
 473    AC_CHECK_FUNCS(gethostbyaddr_r, [
 474      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 475      # There are two different kinds of gethostbyaddr_r.
 476      # We look for the one that returns `int'.
 477      # Hopefully this check is robust enough.
 478      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 479        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 480
 481    AC_CHECK_FUNCS(gethostname, [
 482      AC_DEFINE(HAVE_GETHOSTNAME)
 483      AC_EGREP_HEADER(gethostname, unistd.h, [
 484        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 485
 486    # Look for these functions in the thread library, but only bother
 487    # if using POSIX threads.
 488    if test "$THREADS" = posix; then
 489       save_LIBS="$LIBS"
 490       LIBS="$LIBS $THREADLIBS"
 491       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 492       # E.g., Solaris.
 493       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 494
 495       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 496       # Solaris 7 the name librt is preferred.
 497       AC_CHECK_FUNCS(sched_yield, , [
 498         AC_CHECK_LIB(rt, sched_yield, [
 499           AC_DEFINE(HAVE_SCHED_YIELD)
 500           THREADLIBS="$THREADLIBS -lrt"
 501           THREADSPEC="$THREADSPEC -lrt"], [
 502           AC_CHECK_LIB(posix4, sched_yield, [
 503             AC_DEFINE(HAVE_SCHED_YIELD)
 504             THREADLIBS="$THREADLIBS -lposix4"
 505             THREADSPEC="$THREADSPEC -lposix4"])])])
 506       LIBS="$save_LIBS"
 507
 508       # We can save a little space at runtime if the mutex has m_count
 509       # or __m_count.  This is a nice hack for Linux.
 510       AC_TRY_COMPILE([#include <pthread.h>], [
 511           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 512         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 513         AC_TRY_COMPILE([#include <pthread.h>], [
 514             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 515           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 516    fi
 517
 518    # We require a way to get the time.
 519    time_found=no
 520    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 521    if test "$time_found" = no; then
 522       AC_MSG_ERROR([no function found to get the time])
 523    fi
 524
 525    AC_CHECK_FUNCS(memmove)
 526
 527    # We require memcpy.
 528    memcpy_found=no
 529    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 530    if test "$memcpy_found" = no; then
 531       AC_MSG_ERROR([memcpy is required])
 532    fi
 533
 534    # Some library-finding code we stole from Tcl.
 535    #--------------------------------------------------------------------
 536    #    Check for the existence of the -lsocket and -lnsl libraries.
 537    #    The order here is important, so that they end up in the right
 538    #    order in the command line generated by make.  Here are some
 539    #    special considerations:
 540    #    1. Use "connect" and "accept" to check for -lsocket, and
 541    #       "gethostbyname" to check for -lnsl.
 542    #    2. Use each function name only once:  can't redo a check because
 543    #       autoconf caches the results of the last check and won't redo it.
 544    #    3. Use -lnsl and -lsocket only if they supply procedures that
 545    #       aren't already present in the normal libraries.  This is because
 546    #       IRIX 5.2 has libraries, but they aren't needed and they're
 547    #       bogus:  they goof up name resolution if used.
 548    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 549    #       To get around this problem, check for both libraries together
 550    #       if -lsocket doesn't work by itself.
 551    #--------------------------------------------------------------------
 552
 553    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 554     [gcj_cv_lib_sockets=
 555      gcj_checkBoth=0
 556      unset ac_cv_func_connect
 557      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 558      if test "$gcj_checkSocket" = 1; then
 559          unset ac_cv_func_connect
 560          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 561                       gcj_checkBoth=1)
 562      fi
 563      if test "$gcj_checkBoth" = 1; then
 564          gcj_oldLibs=$LIBS
 565          LIBS="$LIBS -lsocket -lnsl"
 566          unset ac_cv_func_accept
 567          AC_CHECK_FUNC(accept,
 568                        [gcj_checkNsl=0
 569                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 570          unset ac_cv_func_accept
 571          LIBS=$gcj_oldLibs
 572      fi
 573      unset ac_cv_func_gethostbyname
 574      gcj_oldLibs=$LIBS
 575      LIBS="$LIBS $gcj_cv_lib_sockets"
 576      AC_CHECK_FUNC(gethostbyname, ,
 577                    [AC_CHECK_LIB(nsl, main,
 578                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 579      unset ac_cv_func_gethostbyname
 580      LIBS=$gcj_oldLIBS
 581    ])
 582    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 583
 584    if test "$with_system_zlib" = yes; then
 585       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 586    else
 587       ZLIBSPEC=-lzgcj
 588       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 589    fi
 590
 591    # On Solaris, and maybe other architectures, the Boehm collector
 592    # requires -ldl.
 593    if test "$GC" = boehm; then
 594       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 595    fi
 596
 597    if test -z "${with_multisubdir}"; then
 598       builddotdot=.
 599    else
 600 changequote(<<,>>)
 601       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 602 changequote([,])
 603    fi
 604    if test -x "${builddotdot}/../../gcc/gcj"; then
 605       dir="`cd ${builddotdot}/../../gcc && pwd`"
 606       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 607    else
 608       CANADIAN=yes
 609       NULL_TARGET=yes
 610       GCJ="gcj -B`pwd`/"
 611    fi
 612 fi
 613
 614 # Create it, so that compile/link tests don't fail
 615 test -f libgcj.spec || touch libgcj.spec
 616
 617 # We must search the source tree for java.lang, since we still don't
 618 # have libgcj.jar nor java/lang/*.class
 619 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 620 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 621
 622 # Since some classes depend on this one, we need its source available
 623 # before we can do any GCJ compilation test :-(
 624 if test ! -f gnu/classpath/Configuration.java; then
 625   test -d gnu || mkdir gnu
 626   test -d gnu/classpath || mkdir gnu/classpath
 627   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 628         < $srcdir/gnu/classpath/Configuration.java.in \
 629         > gnu/classpath/Configuration.java
 630   # We do not want to redirect the output of the grep below to /dev/null,
 631   # but we add /dev/null to the input list so that grep will print the
 632   # filename of Configuration.java in case it finds any matches.
 633   if grep @ gnu/classpath/Configuration.java /dev/null; then
 634     AC_MSG_ERROR([configure.in is missing the substitutions above])
 635   fi
 636 fi
 637
 638 LT_AC_PROG_GCJ
 639
 640 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 641
 642 dnl FIXME: cross compilation
 643 AC_CHECK_SIZEOF(void *)
 644
 645 ZLIBS=
 646 ZDEPS=
 647 ZINCS=
 648 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 649    # We include the path to the zlib build directory.
 650    # See Makefile.am to understand why.
 651    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 652    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 653    ZINCS='-I$(top_srcdir)/../zlib'
 654 else
 655    ZLIBS="$ZLIBSPEC"
 656 fi
 657 AC_SUBST(ZLIBS)
 658 AC_SUBST(ZDEPS)
 659 AC_SUBST(ZINCS)
 660 AC_SUBST(DIVIDESPEC)
 661 AC_SUBST(EXCEPTIONSPEC)
 662
 663 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 664 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 665 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 666 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 667 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 668 AC_SUBST(GCC_UNWIND_INCLUDE)
 669
 670 # Determine gcj version number.
 671 changequote(<<,>>)
 672 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 673 changequote([,])
 674 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 675 AC_SUBST(GCJVERSION)
 676
 677 AC_SUBST(AM_RUNTESTFLAGS)
 678
 679 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 680 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 681 save_CFLAGS="$CFLAGS"
 682 CFLAGS="-x c++ -O2 -ffloat-store"
 683 AC_TRY_COMPILE([#include <math.h>], ,
 684   [AC_MSG_RESULT(no)],
 685   [AC_DEFINE(__NO_MATH_INLINES)
 686    AC_MSG_RESULT(yes)])
 687 CFLAGS="$save_CFLAGS"
 688
 689 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 690 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 691 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 692 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 693 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 694 dnl for now.  If you change this, you also must update natFile.cc.
 695 AC_CHECK_HEADERS(dirent.h)
 696
 697 AC_CHECK_TYPE([ssize_t], [int])
 698
 699 AC_MSG_CHECKING([for in_addr_t])
 700 AC_TRY_COMPILE([#include <sys/types.h>
 701 #if STDC_HEADERS
 702 #include <stdlib.h>
 703 #include <stddef.h>
 704 #endif
 705 #if HAVE_NETINET_IN_H
 706 #include <netinet/in.h>
 707 #endif], [in_addr_t foo;],
 708   [AC_DEFINE([HAVE_IN_ADDR_T])
 709    AC_MSG_RESULT(yes)],
 710   [AC_MSG_RESULT(no)])
 711
 712 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 713 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 714   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 715    AC_MSG_RESULT(yes)],
 716   [AC_MSG_RESULT(no)])
 717
 718 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 719 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 720   [AC_DEFINE(HAVE_INET6)
 721    AC_MSG_RESULT(yes)],
 722   [AC_MSG_RESULT(no)])
 723
 724 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 725 AC_TRY_COMPILE([#include <sys/types.h>
 726 #include <sys/socket.h>], [socklen_t x = 5;],
 727   [AC_DEFINE(HAVE_SOCKLEN_T)
 728    AC_MSG_RESULT(yes)],
 729   [AC_MSG_RESULT(no)])
 730
 731 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 732 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 733   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 734    AC_MSG_RESULT(yes)],
 735   [AC_MSG_RESULT(no)
 736    AC_MSG_CHECKING([for global timezone variable])
 737    dnl FIXME: we don't want a link check here because that won't work
 738    dnl when cross-compiling.  So instead we make an assumption that
 739    dnl the header file will mention timezone if it exists.
 740    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 741      [AC_DEFINE(HAVE_TIMEZONE)
 742       AC_MSG_RESULT(yes)],
 743      [AC_MSG_RESULT(no)])])
 744
 745 AC_FUNC_ALLOCA
 746
 747 AC_CHECK_PROGS(PERL, perl, false)
 748
 749 SYSDEP_SOURCES=
 750
 751 case "${host}" in
 752  i?86-*-linux*)
 753     SIGNAL_HANDLER=include/i386-signal.h
 754     ;;
 755  sparc-sun-solaris*)
 756     SIGNAL_HANDLER=include/sparc-signal.h
 757     ;;
 758 # ia64-*)
 759 #    SYSDEP_SOURCES=sysdep/ia64.c
 760 #    test -d sysdep || mkdir sysdep
 761 #    ;;
 762  powerpc-*-linux*)
 763     SIGNAL_HANDLER=include/dwarf2-signal.h
 764     ;;
 765  alpha*-*-linux*)
 766     SIGNAL_HANDLER=include/dwarf2-signal.h
 767     ;;
 768  *)
 769     SIGNAL_HANDLER=include/default-signal.h
 770     ;;
 771 esac
 772
 773 # If we're using sjlj exceptions, forget what we just learned.
 774 if test "$enable_sjlj_exceptions" = yes; then
 775    SIGNAL_HANDLER=include/default-signal.h
 776 fi
 777
 778 AC_SUBST(SYSDEP_SOURCES)
 779
 780 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 781
 782 if test "${multilib}" = "yes"; then
 783   multilib_arg="--enable-multilib"
 784 else
 785   multilib_arg=
 786 fi
 787
 788 AC_PATH_XTRA
 789
 790 dnl Determine which AWT peer libraries to build
 791 AC_ARG_ENABLE(java-awt,
 792 [  --enable-java-awt       list of AWT peer implementations to be built])
 793
 794 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 795 use_xlib_awt=""
 796 use_gtk_awt=""
 797
 798 for peer in $peerlibs ; do
 799   case $peer in
 800     xlib)
 801       if [test "$no_x" = yes]; then
 802         echo "*** xlib peers requested but no X library available" 1>&2
 803         exit 1
 804       else
 805         use_xlib_awt="yes"
 806       fi
 807       ;;
 808     gtk)
 809       # Nothing, yet...
 810       ;;
 811     *)
 812       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 813       exit 1
 814   esac
 815 done
 816
 817 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 818 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 819
 820
 821 here=`pwd`
 822 AC_SUBST(here)
 823
 824 # We get this from the environment.
 825 AC_SUBST(GCJFLAGS)
 826
 827 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 828 [# Only add multilib support code if we just rebuilt top-level Makefile.
 829 case " $CONFIG_FILES " in
 830  *" Makefile "*)
 831    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 832    ;;
 833 esac
 834
 835 # Make subdirectories and `.d' files.  Look in both srcdir and
 836 # builddir for the .java files.
 837 h=`pwd`
 838 : > deps.mk
 839 ( (cd $srcdir && find . -name '*.java' -print) ;
 840   find . -name '*.java' -print) | \
 841    fgrep -v testsuite | \
 842    sed -e 's/\.java/.d/' | \
 843    while read f; do
 844       echo "include $f" >> deps.mk
 845       test -f $f || {
 846 changequote(<<,>>)
 847          d=`echo $f | sed -e 's,/[^/]*$,,'`
 848 changequote([,])
 849          $libgcj_basedir/../mkinstalldirs $d
 850          echo > $f
 851       }
 852    done
 853 ],
 854 srcdir=${srcdir}
 855 host=${host}
 856 target=${target}
 857 with_multisubdir=${with_multisubdir}
 858 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 859 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 860 libgcj_basedir=${libgcj_basedir}
 861 CC="${CC}"
 862 CXX="${CXX}"
 863 )