gomp-20050608-branch/libffi/src/powerpc/linux64.S

   1 /* -----------------------------------------------------------------------
   2    sysv.h - Copyright (c) 2003 Jakub Jelinek <jakub@redhat.com>
   3
   4    PowerPC64 Assembly glue.
   5
   6    Permission is hereby granted, free of charge, to any person obtaining
   7    a copy of this software and associated documentation files (the
   8    ``Software''), to deal in the Software without restriction, including
   9    without limitation the rights to use, copy, modify, merge, publish,
  10    distribute, sublicense, and/or sell copies of the Software, and to
  11    permit persons to whom the Software is furnished to do so, subject to
  12    the following conditions:
  13
  14    The above copyright notice and this permission notice shall be included
  15    in all copies or substantial portions of the Software.
  16
  17    THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND, EXPRESS
  18    OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19    MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  20    IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY CLAIM, DAMAGES OR
  21    OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
  22    ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  23    OTHER DEALINGS IN THE SOFTWARE.
  24    ----------------------------------------------------------------------- */
  25
  26 #define LIBFFI_ASM
  27 #include <fficonfig.h>
  28 #include <ffi.h>
  29
  30 #ifdef __powerpc64__
  31         .hidden ffi_call_LINUX64, .ffi_call_LINUX64
  32         .globl  ffi_call_LINUX64, .ffi_call_LINUX64
  33         .section        ".opd","aw"
  34         .align  3
  35 ffi_call_LINUX64:
  36         .quad   .ffi_call_LINUX64,.TOC.@tocbase,0
  37         .size   ffi_call_LINUX64,24
  38         .type   .ffi_call_LINUX64,@function
  39         .text
  40 .ffi_call_LINUX64:
  41 .LFB1:
  42         mflr    %r0
  43         std     %r28, -32(%r1)
  44         std     %r29, -24(%r1)
  45         std     %r30, -16(%r1)
  46         std     %r31, -8(%r1)
  47         std     %r0, 16(%r1)
  48
  49         mr      %r28, %r1       /* our AP.  */
  50         stdux   %r1, %r1, %r4
  51 .LCFI0:
  52         mr      %r31, %r5       /* flags, */
  53         mr      %r30, %r6       /* rvalue, */
  54         mr      %r29, %r7       /* function address.  */
  55         std     %r2, 40(%r1)
  56
  57         /* Call ffi_prep_args64.  */
  58         mr      %r4, %r1
  59         bl      .ffi_prep_args64
  60
  61         ld      %r0, 0(%r29)
  62         ld      %r2, 8(%r29)
  63         ld      %r11, 16(%r29)
  64
  65         /* Now do the call.  */
  66         /* Set up cr1 with bits 4-7 of the flags.  */
  67         mtcrf   0x40, %r31
  68
  69         /* Get the address to call into CTR.  */
  70         mtctr   %r0
  71         /* Load all those argument registers.  */
  72         ld      %r3, -32-(8*8)(%r28)
  73         ld      %r4, -32-(7*8)(%r28)
  74         ld      %r5, -32-(6*8)(%r28)
  75         ld      %r6, -32-(5*8)(%r28)
  76         bf-     5, 1f
  77         ld      %r7, -32-(4*8)(%r28)
  78         ld      %r8, -32-(3*8)(%r28)
  79         ld      %r9, -32-(2*8)(%r28)
  80         ld      %r10, -32-(1*8)(%r28)
  81 1:
  82
  83         /* Load all the FP registers.  */
  84         bf-     6, 2f
  85         lfd     %f1, -32-(21*8)(%r28)
  86         lfd     %f2, -32-(20*8)(%r28)
  87         lfd     %f3, -32-(19*8)(%r28)
  88         lfd     %f4, -32-(18*8)(%r28)
  89         lfd     %f5, -32-(17*8)(%r28)
  90         lfd     %f6, -32-(16*8)(%r28)
  91         lfd     %f7, -32-(15*8)(%r28)
  92         lfd     %f8, -32-(14*8)(%r28)
  93         lfd     %f9, -32-(13*8)(%r28)
  94         lfd     %f10, -32-(12*8)(%r28)
  95         lfd     %f11, -32-(11*8)(%r28)
  96         lfd     %f12, -32-(10*8)(%r28)
  97         lfd     %f13, -32-(9*8)(%r28)
  98 2:
  99
 100         /* Make the call.  */
 101         bctrl
 102
 103         /* Now, deal with the return value.  */
 104         mtcrf   0x01, %r31
 105         bt-     30, .Ldone_return_value
 106         bt-     29, .Lfp_return_value
 107         std     %r3, 0(%r30)
 108         /* Fall through...  */
 109
 110 .Ldone_return_value:
 111         /* Restore the registers we used and return.  */
 112         ld      %r2, 40(%r1)
 113         mr      %r1, %r28
 114         ld      %r0, 16(%r28)
 115         ld      %r28, -32(%r1)
 116         mtlr    %r0
 117         ld      %r29, -24(%r1)
 118         ld      %r30, -16(%r1)
 119         ld      %r31, -8(%r1)
 120         blr
 121
 122 .Lfp_return_value:
 123         bt      27, .Lfd_return_value
 124         bf      28, .Lfloat_return_value
 125         stfd    %f1, 0(%r30)
 126         b       .Ldone_return_value
 127 .Lfd_return_value:
 128         stfd    %f1, 0(%r30)
 129         stfd    %f2, 8(%r30)
 130         b       .Ldone_return_value
 131 .Lfloat_return_value:
 132         stfs    %f1, 0(%r30)
 133         b       .Ldone_return_value
 134 .LFE1:
 135         .long   0
 136         .byte   0,12,0,1,128,4,0,0
 137         .size   .ffi_call_LINUX64,.-.ffi_call_LINUX64
 138
 139         .section        .eh_frame,EH_FRAME_FLAGS,@progbits
 140 .Lframe1:
 141         .4byte  .LECIE1-.LSCIE1  # Length of Common Information Entry
 142 .LSCIE1:
 143         .4byte  0x0      # CIE Identifier Tag
 144         .byte   0x1      # CIE Version
 145         .ascii "zR\0"    # CIE Augmentation
 146         .uleb128 0x1     # CIE Code Alignment Factor
 147         .sleb128 -8      # CIE Data Alignment Factor
 148         .byte   0x41     # CIE RA Column
 149         .uleb128 0x1     # Augmentation size
 150         .byte   0x14     # FDE Encoding (pcrel udata8)
 151         .byte   0xc      # DW_CFA_def_cfa
 152         .uleb128 0x1
 153         .uleb128 0x0
 154         .align 3
 155 .LECIE1:
 156 .LSFDE1:
 157         .4byte  .LEFDE1-.LASFDE1         # FDE Length
 158 .LASFDE1:
 159         .4byte  .LASFDE1-.Lframe1        # FDE CIE offset
 160         .8byte  .LFB1-.  # FDE initial location
 161         .8byte  .LFE1-.LFB1      # FDE address range
 162         .uleb128 0x0     # Augmentation size
 163         .byte   0x2      # DW_CFA_advance_loc1
 164         .byte   .LCFI0-.LFB1
 165         .byte   0xd      # DW_CFA_def_cfa_register
 166         .uleb128 0x1c
 167         .byte   0x11     # DW_CFA_offset_extended_sf
 168         .uleb128 0x41
 169         .sleb128 -2
 170         .byte   0x9f     # DW_CFA_offset, column 0x1f
 171         .uleb128 0x1
 172         .byte   0x9e     # DW_CFA_offset, column 0x1e
 173         .uleb128 0x2
 174         .byte   0x9d     # DW_CFA_offset, column 0x1d
 175         .uleb128 0x3
 176         .byte   0x9c     # DW_CFA_offset, column 0x1c
 177         .uleb128 0x4
 178         .align 3
 179 .LEFDE1:
 180 #endif