gomp-20050608-branch/gcc/ada/s-imgllb.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ L L B                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Unsigned_Types; use System.Unsigned_Types;
  35
  36 package body System.Img_LLB is
  37
  38    ---------------------------------------
  39    -- Set_Image_Based_Long_Long_Integer --
  40    ---------------------------------------
  41
  42    procedure Set_Image_Based_Long_Long_Integer
  43      (V : Long_Long_Integer;
  44       B : Natural;
  45       W : Integer;
  46       S : out String;
  47       P : in out Natural)
  48    is
  49       Start : Natural;
  50
  51    begin
  52       --  Positive case can just use the unsigned circuit directly
  53
  54       if V >= 0 then
  55          Set_Image_Based_Long_Long_Unsigned
  56            (Long_Long_Unsigned (V), B, W, S, P);
  57
  58       --  Negative case has to set a minus sign. Note also that we have to be
  59       --  careful not to generate overflow with the largest negative number.
  60
  61       else
  62          P := P + 1;
  63          S (P) := ' ';
  64          Start := P;
  65
  66          declare
  67             pragma Suppress (Overflow_Check);
  68             pragma Suppress (Range_Check);
  69          begin
  70             Set_Image_Based_Long_Long_Unsigned
  71               (Long_Long_Unsigned (-V), B, W - 1, S, P);
  72          end;
  73
  74          --  Set minus sign in last leading blank location. Because of the
  75          --  code above, there must be at least one such location.
  76
  77          while S (Start + 1) = ' ' loop
  78             Start := Start + 1;
  79          end loop;
  80
  81          S (Start) := '-';
  82       end if;
  83
  84    end Set_Image_Based_Long_Long_Integer;
  85
  86    ----------------------------------------
  87    -- Set_Image_Based_Long_Long_Unsigned --
  88    ----------------------------------------
  89
  90    procedure Set_Image_Based_Long_Long_Unsigned
  91      (V : Long_Long_Unsigned;
  92       B : Natural;
  93       W : Integer;
  94       S : out String;
  95       P : in out Natural)
  96    is
  97       Start : constant Natural := P;
  98       F, T  : Natural;
  99       BU    : constant Long_Long_Unsigned := Long_Long_Unsigned (B);
 100       Hex   : constant array
 101                 (Long_Long_Unsigned range 0 .. 15) of Character :=
 102                                                          "0123456789ABCDEF";
 103
 104       procedure Set_Digits (T : Long_Long_Unsigned);
 105       --  Set digits of absolute value of T
 106
 107       procedure Set_Digits (T : Long_Long_Unsigned) is
 108       begin
 109          if T >= BU then
 110             Set_Digits (T / BU);
 111             P := P + 1;
 112             S (P) := Hex (T mod BU);
 113          else
 114             P := P + 1;
 115             S (P) := Hex (T);
 116          end if;
 117       end Set_Digits;
 118
 119    --  Start of processing for Set_Image_Based_Long_Long_Unsigned
 120
 121    begin
 122
 123       if B >= 10 then
 124          P := P + 1;
 125          S (P) := '1';
 126       end if;
 127
 128       P := P + 1;
 129       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
 130
 131       P := P + 1;
 132       S (P) := '#';
 133
 134       Set_Digits (V);
 135
 136       P := P + 1;
 137       S (P) := '#';
 138
 139       --  Add leading spaces if required by width parameter
 140
 141       if P - Start < W then
 142          F := P;
 143          P := Start + W;
 144          T := P;
 145
 146          while F > Start loop
 147             S (T) := S (F);
 148             T := T - 1;
 149             F := F - 1;
 150          end loop;
 151
 152          for J in Start + 1 .. T loop
 153             S (J) := ' ';
 154          end loop;
 155       end if;
 156
 157    end Set_Image_Based_Long_Long_Unsigned;
 158
 159 end System.Img_LLB;