gomp-20050608-branch/gcc/ada/a-except-2005.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  This version is used for all Ada 2005 builds. It differs from a-except.ads
  39 --  only with respect to the addition of Wide_[Wide]Exception_Name functions.
  40 --  The additional entities are marked with pragma Ada_05, so this extended
  41 --  unit is also perfectly suitable for use in Ada 95 or Ada 83 mode.
  42
  43 --  The reason for this splitting off of a separate version is that bootstrap
  44 --  compilers often will be used that do not support Ada 2005 features, and
  45 --  Ada.Exceptions is part of the compiler sources.
  46
  47 --  The base version of this unit Ada.Exceptions omits the Wide version of
  48 --  Exception_Name and is used to build the compiler and other basic tools.
  49
  50 pragma Polling (Off);
  51 --  We must turn polling off for this unit, because otherwise we get
  52 --  elaboration circularities with ourself.
  53
  54 with System;
  55 with System.Parameters;
  56 with System.Standard_Library;
  57 with System.Traceback_Entries;
  58
  59 package Ada.Exceptions is
  60    pragma Warnings (Off);
  61    pragma Preelaborate_05;
  62    pragma Warnings (On);
  63    --  In accordance with Ada 2005 AI-362. The warnings pragmas are so that we
  64    --  can compile this using older compiler versions, which will ignore the
  65    --  pragma, which is fine for the bootstrap.
  66
  67    type Exception_Id is private;
  68    Null_Id : constant Exception_Id;
  69
  70    type Exception_Occurrence is limited private;
  71    type Exception_Occurrence_Access is access all Exception_Occurrence;
  72
  73    Null_Occurrence : constant Exception_Occurrence;
  74
  75    function Exception_Name (Id : Exception_Id) return String;
  76
  77    function Exception_Name (X : Exception_Occurrence) return String;
  78
  79    function Wide_Exception_Name
  80      (Id : Exception_Id) return Wide_String;
  81    pragma Ada_05 (Wide_Exception_Name);
  82
  83    function Wide_Exception_Name
  84      (X : Exception_Occurrence) return Wide_String;
  85    pragma Ada_05 (Wide_Exception_Name);
  86
  87    function Wide_Wide_Exception_Name
  88      (Id : Exception_Id) return Wide_Wide_String;
  89    pragma Ada_05 (Wide_Wide_Exception_Name);
  90
  91    function Wide_Wide_Exception_Name
  92      (X : Exception_Occurrence) return Wide_Wide_String;
  93    pragma Ada_05 (Wide_Wide_Exception_Name);
  94
  95    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  96    --  Note: it would be really nice to give a pragma No_Return for this
  97    --  procedure, but it would be wrong, since Raise_Exception does return
  98    --  if given the null exception. However we do special case the name in
  99    --  the test in the compiler for issuing a warning for a missing return
 100    --  after this call. Program_Error seems reasonable enough in such a case.
 101    --  See also the routine Raise_Exception_Always in the private part.
 102
 103    function Exception_Message (X : Exception_Occurrence) return String;
 104
 105    procedure Reraise_Occurrence (X : Exception_Occurrence);
 106    --  Note: it would be really nice to give a pragma No_Return for this
 107    --  procedure, but it would be wrong, since Reraise_Occurrence does return
 108    --  if the argument is the null exception occurrence. See also procedure
 109    --  Reraise_Occurrence_Always in the private part of this package.
 110
 111    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
 112
 113    function Exception_Information (X : Exception_Occurrence) return String;
 114    --  The format of the exception information is as follows:
 115    --
 116    --    exception name (as in Exception_Name)
 117    --    message (or a null line if no message)
 118    --    PID=nnnn
 119    --    0xyyyyyyyy 0xyyyyyyyy ...
 120    --
 121    --  The lines are separated by a ASCII.LF character
 122    --  The nnnn is the partition Id given as decimal digits.
 123    --  The 0x... line represents traceback program counter locations,
 124    --  in order with the first one being the exception location.
 125
 126    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 127    --  not the function from Rtsfind, so it is important that the procedure
 128    --  come first, since Rtsfind finds the first matching entity.
 129
 130    procedure Save_Occurrence
 131      (Target : out Exception_Occurrence;
 132       Source : Exception_Occurrence);
 133
 134    function Save_Occurrence
 135      (Source : Exception_Occurrence)
 136       return   Exception_Occurrence_Access;
 137
 138 private
 139    package SSL renames System.Standard_Library;
 140    package SP renames System.Parameters;
 141
 142    subtype EOA is Exception_Occurrence_Access;
 143
 144    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 145
 146    ------------------
 147    -- Exception_Id --
 148    ------------------
 149
 150    subtype Code_Loc is System.Address;
 151    --  Code location used in building exception tables and for call addresses
 152    --  when propagating an exception. Values of this type are created by using
 153    --  Label'Address or extracted from machine states using Get_Code_Loc.
 154
 155    Null_Loc : constant Code_Loc := System.Null_Address;
 156    --  Null code location, used to flag outer level frame
 157
 158    type Exception_Id is new SSL.Exception_Data_Ptr;
 159
 160    function EId_To_String (X : Exception_Id) return String;
 161    function String_To_EId (S : String) return Exception_Id;
 162    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 163    --  Functions for implementing Exception_Id stream attributes
 164
 165    Null_Id : constant Exception_Id := null;
 166
 167    -------------------------
 168    -- Private Subprograms --
 169    -------------------------
 170
 171    function Current_Target_Exception return Exception_Occurrence;
 172    pragma Export
 173      (Ada, Current_Target_Exception,
 174       "__gnat_current_target_exception");
 175    --  This routine should return the current raised exception on targets
 176    --  which have built-in exception handling such as the Java Virtual
 177    --  Machine. For other targets this routine is simply ignored. Currently,
 178    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 179    --  allows this routine to be accessed elsewhere in the run-time, even
 180    --  though it is in the private part of this package (it is not allowed
 181    --  to be in the visible part, since this is set by the reference manual).
 182
 183    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 184    --  Like Exception_Name, but returns the simple non-qualified name of the
 185    --  exception. This is used to implement the Exception_Name function in
 186    --  Current_Exceptions (the DEC compatible unit). It is called from the
 187    --  compiler generated code (using Rtsfind, which does not respect the
 188    --  private barrier, so we can place this function in the private part
 189    --  where the compiler can find it, but the spec is unchanged.)
 190
 191    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 192    pragma No_Return (Raise_Exception_Always);
 193    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 194    --  This differs from Raise_Exception only in that the caller has determined
 195    --  that for sure the parameter E is not null, and that therefore the call
 196    --  to this procedure cannot return. The expander converts Raise_Exception
 197    --  calls to Raise_Exception_Always if it can determine this is the case.
 198    --  The Export allows this routine to be accessed from Pure units.
 199
 200    procedure Raise_From_Signal_Handler
 201      (E : Exception_Id;
 202       M : System.Address);
 203    pragma Export
 204      (Ada, Raise_From_Signal_Handler,
 205            "ada__exceptions__raise_from_signal_handler");
 206    pragma No_Return (Raise_From_Signal_Handler);
 207    --  This routine is used to raise an exception from a signal handler. The
 208    --  signal handler has already stored the machine state (i.e. the state that
 209    --  corresponds to the location at which the signal was raised). E is the
 210    --  Exception_Id specifying what exception is being raised, and M is a
 211    --  pointer to a null-terminated string which is the message to be raised.
 212    --  Note that this routine never returns, so it is permissible to simply
 213    --  jump to this routine, rather than call it. This may be appropriate for
 214    --  systems where the right way to get out of signal handler is to alter the
 215    --  PC value in the machine state or in some other way ask the operating
 216    --  system to return here rather than to the original location.
 217
 218    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 219    pragma No_Return (Reraise_Occurrence_Always);
 220    --  This differs from Raise_Occurrence only in that the caller guarantees
 221    --  that for sure the parameter X is not the null occurrence, and that
 222    --  therefore this procedure cannot return. The expander uses this routine
 223    --  in the translation of a raise statement with no parameter (reraise).
 224
 225    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 226    pragma No_Return (Reraise_Occurrence_No_Defer);
 227    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 228    --  before the call and the parameter X is known not to be the null
 229    --  occurrence. This is used in generated code when it is known that
 230    --  abort is already deferred.
 231
 232    -----------------------
 233    -- Polling Interface --
 234    -----------------------
 235
 236    --  The GNAT compiler has an option to generate polling calls to the Poll
 237    --  routine in this package. Specifying the -gnatP option for a compilation
 238    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 239    --  entry and on every iteration of a loop, thus avoiding the possibility of
 240    --  a case of unbounded time between calls.
 241
 242    --  This polling interface may be used for instrumentation or debugging
 243    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 244
 245    --  In the GNAT technology itself, this interface is used to implement
 246    --  immediate aynschronous transfer of control and immediate abort on
 247    --  targets which do not provide for one thread interrupting another.
 248
 249    --  Note: this used to be in a separate unit called System.Poll, but that
 250    --  caused horrible circular elaboration problems between System.Poll and
 251    --  Ada.Exceptions. One way of solving such circularities is unification!
 252
 253    procedure Poll;
 254    --  Check for asynchronous abort. Note that we do not inline the body.
 255    --  This makes the interface more useful for debugging purposes.
 256
 257    --------------------------
 258    -- Exception_Occurrence --
 259    --------------------------
 260
 261    package TBE renames System.Traceback_Entries;
 262
 263    Max_Tracebacks : constant := 50;
 264    --  Maximum number of trace backs stored in exception occurrence
 265
 266    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 267    --  Traceback array stored in exception occurrence
 268
 269    type Exception_Occurrence is record
 270       Id : Exception_Id;
 271       --  Exception_Identity for this exception occurrence
 272       --  WARNING System.System.Finalization_Implementation.Finalize_List
 273       --  relies on the fact that this field is always first in the exception
 274       --  occurrence
 275
 276       Msg_Length : Natural := 0;
 277       --  Length of message (zero = no message)
 278
 279       Msg : String (1 .. Exception_Msg_Max_Length);
 280       --  Characters of message
 281
 282       Cleanup_Flag : Boolean := False;
 283       --  The cleanup flag is normally False, it is set True for an exception
 284       --  occurrence passed to a cleanup routine, and will still be set True
 285       --  when the cleanup routine does a Reraise_Occurrence call using this
 286       --  exception occurrence. This is used to avoid recording a bogus trace
 287       --  back entry from this reraise call.
 288
 289       Exception_Raised : Boolean := False;
 290       --  Set to true to indicate that this exception occurrence has actually
 291       --  been raised. When an exception occurrence is first created, this is
 292       --  set to False, then when it is processed by Raise_Current_Exception,
 293       --  it is set to True. If Raise_Current_Exception is used to raise an
 294       --  exception for which this flag is already True, then it knows that
 295       --  it is dealing with the reraise case (which is useful to distinguish
 296       --  for exception tracing purposes).
 297
 298       Pid : Natural := 0;
 299       --  Partition_Id for partition raising exception
 300
 301       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 302       --  Number of traceback entries stored
 303
 304       Tracebacks : Tracebacks_Array;
 305       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 306
 307       Private_Data : System.Address := System.Null_Address;
 308       --  Field used by low level exception mechanism to store specific data.
 309       --  Currently used by the GCC exception mechanism to store a pointer to
 310       --  a GNAT_GCC_Exception.
 311    end record;
 312
 313    function "=" (Left, Right : Exception_Occurrence) return Boolean
 314      is abstract;
 315    --  Don't allow comparison on exception occurrences, we should not need
 316    --  this, and it would not work right, because of the Msg and Tracebacks
 317    --  fields which have unused entries not copied by Save_Occurrence.
 318
 319    function EO_To_String (X : Exception_Occurrence) return String;
 320    function String_To_EO (S : String) return Exception_Occurrence;
 321    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 322    --  Functions for implementing Exception_Occurrence stream attributes
 323
 324    Null_Occurrence : constant Exception_Occurrence := (
 325      Id               => null,
 326      Msg_Length       => 0,
 327      Msg              => (others => ' '),
 328      Cleanup_Flag     => False,
 329      Exception_Raised => False,
 330      Pid              => 0,
 331      Num_Tracebacks   => 0,
 332      Tracebacks       => (others => TBE.Null_TB_Entry),
 333      Private_Data     => System.Null_Address);
 334
 335 end Ada.Exceptions;