libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=3:1:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  54 WERROR="-Werror"
  55 AC_SUBST(WERROR)
  56
  57 glibgo_toolexecdir=no
  58 glibgo_toolexeclibdir=no
  59
  60 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  61 AC_ARG_ENABLE([version-specific-runtime-libs],
  62   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  63                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  64   [case "$enableval" in
  65     yes) version_specific_libs=yes ;;
  66     no)  version_specific_libs=no ;;
  67     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  68    esac],
  69   [version_specific_libs=no])
  70 AC_MSG_RESULT($version_specific_libs)
  71
  72 # Version-specific runtime libs processing.
  73 if test $version_specific_libs = yes; then
  74   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  75   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  76 fi
  77
  78 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  79 # Install a library built with a cross compiler in tooldir, not libdir.
  80 if test -n "$with_cross_host" &&
  81    test x"$with_cross_host" != x"no"; then
  82   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  83   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  84 else
  85   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${libdir}'
  87 fi
  88 multi_os_directory=`$CC -print-multi-os-directory`
  89 case $multi_os_directory in
  90   .) ;; # Avoid trailing /.
  91   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  92 esac
  93
  94 if test x"$glibgo_toolexecdir" = x"no"; then
  95   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  96   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
  97 fi
  98
  99 AC_SUBST(glibgo_toolexecdir)
 100 AC_SUBST(glibgo_toolexeclibdir)
 101 AC_SUBST(nover_glibgo_toolexeclibdir)
 102
 103 # See if the user wants to configure without libffi.  Some
 104 # architectures don't support it.  FIXME: We should set a default
 105 # based on the host.
 106 AC_ARG_WITH(libffi,
 107   AS_HELP_STRING([--without-libffi],
 108                  [don't use libffi]),
 109   [:],
 110   [with_libffi=${with_libffi_default-yes}])
 111
 112 LIBFFI=
 113 LIBFFIINCS=
 114 if test "$with_libffi" != no; then
 115    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 116    LIBFFI=../libffi/libffi_convenience.la
 117    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 118 fi
 119 AC_SUBST(LIBFFI)
 120 AC_SUBST(LIBFFIINCS)
 121
 122 # Used to tell GNU make to include a file without telling automake to
 123 # include it.
 124 go_include="-include"
 125 AC_SUBST(go_include)
 126
 127 is_darwin=no
 128 is_freebsd=no
 129 is_irix=no
 130 is_linux=no
 131 is_netbsd=no
 132 is_openbsd=no
 133 is_rtems=no
 134 is_solaris=no
 135 GOOS=unknown
 136 case ${host} in
 137   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 138   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 139   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 140   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 141   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 142   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 143   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 144   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 145 esac
 146 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 147 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 148 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 149 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 150 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 151 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 152 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 153 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 154 AC_SUBST(GOOS)
 155
 156 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 157 is_386=no
 158 is_alpha=no
 159 is_arm=no
 160 is_m68k=no
 161 mips_abi=unknown
 162 is_ppc=no
 163 is_ppc64=no
 164 is_sparc=no
 165 is_sparc64=no
 166 is_x86_64=no
 167 GOARCH=unknown
 168 case ${host} in
 169   alpha*-*-*)
 170     is_alpha=yes
 171     GOARCH=alpha
 172     ;;
 173   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 174     is_arm=yes
 175     GOARCH=arm
 176     ;;
 177 changequote(,)dnl
 178   i[34567]86-*-* | x86_64-*-*)
 179 changequote([,])dnl
 180     AC_COMPILE_IFELSE([
 181 #ifdef __x86_64__
 182 #error 64-bit
 183 #endif],
 184 [is_386=yes], [is_x86_64=yes])
 185     if test "$is_386" = "yes"; then
 186       GOARCH=386
 187     else
 188       GOARCH=amd64
 189     fi
 190     ;;
 191   m68k*-*-*)
 192     is_m68k=yes
 193     GOARCH=m68k
 194     ;;
 195   mips*-*-*)
 196     AC_COMPILE_IFELSE([
 197 #if _MIPS_SIM != _ABIO32
 198 #error not o32
 199 #endif],
 200 [mips_abi="o32"],
 201         [AC_COMPILE_IFELSE([
 202 #if _MIPS_SIM != _ABIN32
 203 #error not n32
 204 #endif],
 205 [mips_abi="n32"],
 206         [AC_COMPILE_IFELSE([
 207 #if _MIPS_SIM != _ABI64
 208 #error not n64
 209 #endif],
 210 [mips_abi="n64"],
 211         [AC_COMPILE_IFELSE([
 212 #if _MIPS_SIM != _ABIO64
 213 #error not o64
 214 #endif],
 215 [mips_abi="o64"],
 216         [AC_MSG_ERROR([unknown MIPS ABI])
 217 [mips_abi="n32"]])])])])
 218     case "$mips_abi" in
 219     "o32") GOARCH=mipso32 ;;
 220     "n32") GOARCH=mipsn32 ;;
 221     "n64") GOARCH=mipsn64 ;;
 222     "o64") GOARCH=mipso64 ;;
 223     esac
 224     ;;
 225   rs6000*-*-* | powerpc*-*-*)
 226     AC_COMPILE_IFELSE([
 227 #ifdef _ARCH_PPC64
 228 #error 64-bit
 229 #endif],
 230 [is_ppc=yes], [is_ppc64=yes])
 231     if test "$is_ppc" = "yes"; then
 232       GOARCH=ppc
 233     else
 234       GOARCH=ppc64
 235     fi
 236     ;;
 237   sparc*-*-*)
 238     AC_COMPILE_IFELSE([
 239 #if defined(__sparcv9) || defined(__arch64__)
 240 #error 64-bit
 241 #endif],
 242 [is_sparc=yes], [is_sparc64=yes])
 243     if test "$is_sparc" = "yes"; then
 244       GOARCH=sparc
 245     else
 246       GOARCH=sparc64
 247     fi
 248     ;;
 249 esac
 250 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 251 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 252 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 253 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 254 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 255 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 256 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 257 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 258 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 259 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 260 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 261 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 262 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 263 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 264 AC_SUBST(GOARCH)
 265
 266 dnl Some files are only present when needed for specific architectures.
 267 GO_LIBCALL_OS_FILE=
 268 GO_LIBCALL_OS_ARCH_FILE=
 269 GO_SYSCALL_OS_FILE=
 270 GO_SYSCALL_OS_ARCH_FILE=
 271 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 272   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 273 fi
 274 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 275   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 276 fi
 277 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 278   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 279 fi
 280 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 281   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 282 fi
 283 AC_SUBST(GO_LIBCALL_OS_FILE)
 284 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 285 AC_SUBST(GO_SYSCALL_OS_FILE)
 286 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 287
 288 dnl Special flags used to generate sysinfo.go.
 289 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 290 case "$target" in
 291     mips-sgi-irix6.5*)
 292         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 293         # msghdr in <sys/socket.h>.
 294         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 295         ;;
 296     *-*-solaris2.[[89]])
 297         # Solaris 8/9 need this so struct msghdr gets the msg_control
 298         # etc. fields in <sys/socket.h> (_XPG4_2).
 299         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 300         ;;
 301     *-*-solaris2.1[[01]])
 302         # Solaris 10+ needs this so struct msghdr gets the msg_control
 303         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 304         # above doesn't work with C99.
 305         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 306         ;;
 307 esac
 308 AC_SUBST(OSCFLAGS)
 309
 310 dnl Use -fsplit-stack when compiling C code if available.
 311 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 312 [libgo_cv_c_split_stack_supported],
 313 [CFLAGS_hold=$CFLAGS
 314 CFLAGS="$CFLAGS -fsplit-stack"
 315 AC_COMPILE_IFELSE([[int i;]],
 316 [libgo_cv_c_split_stack_supported=yes],
 317 [libgo_cv_c_split_stack_supported=no])
 318 CFLAGS=$CFLAGS_hold])
 319 if test "$libgo_cv_c_split_stack_supported" = yes; then
 320   SPLIT_STACK=-fsplit-stack
 321   AC_DEFINE(USING_SPLIT_STACK, 1,
 322                 [Define if the compiler supports -fsplit-stack])
 323 else
 324   SPLIT_STACK=
 325 fi
 326 AC_SUBST(SPLIT_STACK)
 327 AM_CONDITIONAL(USING_SPLIT_STACK,
 328         test "$libgo_cv_c_split_stack_supported" = yes)
 329
 330 dnl Check whether the linker does stack munging when calling from
 331 dnl split-stack into non-split-stack code.  We check this by looking
 332 dnl at the --help output.  FIXME: This is only half right: it's
 333 dnl possible for the linker to support this for some targets but not
 334 dnl others.
 335 AC_CACHE_CHECK([whether linker supports split stack],
 336 [libgo_cv_c_linker_supports_split_stack],
 337 libgo_cv_c_linker_supports_split_stack=no
 338 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 339   libgo_cv_c_linker_supports_split_stack=yes
 340 fi)
 341 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 342   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 343             [Define if the linker support split stack adjustments])
 344 fi
 345
 346 dnl Test for the -lm library.
 347 MATH_LIBS=
 348 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 349 AC_SUBST(MATH_LIBS)
 350
 351 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 352 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 353   [libgo_cv_lib_sockets=
 354    libgo_check_both=no
 355    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 356    if test "$libgo_check_socket" = "yes"; then
 357      unset ac_cv_func_connect
 358      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 359                   libgo_check_both=yes)
 360    fi
 361    if test "$libgo_check_both" = "yes"; then
 362      libgo_old_libs=$LIBS
 363      LIBS="$LIBS -lsocket -lnsl"
 364      unset ac_cv_func_accept
 365      AC_CHECK_FUNC(accept,
 366                    [libgo_check_nsl=no
 367                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 368      unset ac_cv_func_accept
 369      LIBS=$libgo_old_libs
 370    fi
 371    unset ac_cv_func_gethostbyname
 372    libgo_old_libs="$LIBS"
 373    AC_CHECK_FUNC(gethostbyname, ,
 374                  [AC_CHECK_LIB(nsl, main,
 375                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 376    unset ac_cv_func_gethostbyname
 377    LIBS=$libgo_old_libs
 378 ])
 379 NET_LIBS="$libgo_cv_lib_sockets"
 380 AC_SUBST(NET_LIBS)
 381
 382 dnl Test whether the compiler supports the -pthread option.
 383 AC_CACHE_CHECK([whether -pthread is supported],
 384 [libgo_cv_lib_pthread],
 385 [CFLAGS_hold=$CFLAGS
 386 CFLAGS="$CFLAGS -pthread"
 387 AC_COMPILE_IFELSE([[int i;]],
 388 [libgo_cv_lib_pthread=yes],
 389 [libgo_cv_lib_pthread=no])
 390 CFLAGS=$CFLAGS_hold])
 391 PTHREAD_CFLAGS=
 392 if test "$libgo_cv_lib_pthread" = yes; then
 393   PTHREAD_CFLAGS=-pthread
 394 fi
 395 AC_SUBST(PTHREAD_CFLAGS)
 396
 397 dnl Test for the -lpthread library.
 398 PTHREAD_LIBS=
 399 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 400 AC_SUBST(PTHREAD_LIBS)
 401
 402 dnl Test if -lrt is required for sched_yield.
 403 AC_SEARCH_LIBS([sched_yield], [rt])
 404
 405 AC_C_BIGENDIAN
 406
 407 GCC_CHECK_UNWIND_GETIPINFO
 408
 409 AC_ARG_ENABLE(sjlj-exceptions,
 410   AC_HELP_STRING([--enable-sjlj-exceptions],
 411                  [force use of builtin_setjmp for exceptions]),
 412   [case "$enableval" in
 413    yes|no|auto) ;;
 414    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 415    esac],
 416   [enable_sjlj_exceptions=auto])
 417
 418 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 419 [libgo_cv_lib_sjlj_exceptions],
 420 [AC_LANG_CONFTEST(
 421   [AC_LANG_SOURCE([
 422 void bar ();
 423 void clean (int *);
 424 void foo ()
 425 {
 426   int i __attribute__ ((cleanup (clean)));
 427   bar();
 428 }
 429 ])])
 430 CFLAGS_hold=$CFLAGS
 431 CFLAGS="--save-temps -fexceptions"
 432 libgo_cv_lib_sjlj_exceptions=unknown
 433 AS_IF([ac_fn_c_try_compile],
 434   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 435     libgo_cv_lib_sjlj_exceptions=yes
 436   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 437     libgo_cv_lib_sjlj_exceptions=no
 438   fi])
 439 CFLAGS=$CFLAGS_hold
 440 rm -f conftest*
 441 ])
 442
 443 if test "$enable_sjlj_exceptions" = "auto"; then
 444   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 445 fi
 446
 447 case $enable_sjlj_exceptions in
 448 yes)
 449   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 450         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 451   ;;
 452 no)
 453   ;;
 454 *)
 455   AC_MSG_ERROR([unable to detect exception model])
 456   ;;
 457 esac
 458
 459 AC_CHECK_HEADERS(sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 460
 461 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 462 [#ifdef HAVE_SYS_SOCKET_H
 463 #include <sys/socket.h>
 464 #endif
 465 ])
 466
 467 AC_CACHE_CHECK([whether <ustat.h> can be used],
 468 [libgo_cv_c_ustat_h],
 469 [CFLAGS_hold=$CFLAGS
 470 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 471 AC_COMPILE_IFELSE(
 472 [AC_LANG_SOURCE([
 473 #include <sys/types.h>
 474 #ifdef HAVE_LINUX_FILTER_H
 475 #include <linux/filter.h>
 476 #endif
 477 #include <ustat.h>
 478 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 479 CFLAGS=$CFLAGS_hold])
 480 if test $libgo_cv_c_ustat_h = yes; then
 481   AC_DEFINE(HAVE_USTAT_H, 1,
 482     [Define to 1 if you have the <ustat.h> header file and it works.])
 483 fi
 484
 485 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 486
 487 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 488 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 489 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 490
 491 AC_CHECK_FUNCS(epoll_create1 faccessat fallocate fchmodat fchownat futimesat inotify_add_watch inotify_init inotify_init1 inotify_rm_watch mkdirat mknodat openat renameat sync_file_range splice tee unlinkat unshare)
 492 AC_TYPE_OFF_T
 493 AC_CHECK_TYPES([loff_t])
 494
 495 LIBS_hold="$LIBS"
 496 LIBS="$LIBS -lm"
 497 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 498 LIBS="$LIBS_hold"
 499
 500 CFLAGS_hold="$CFLAGS"
 501 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 502 LIBS_hold="$LIBS"
 503 LIBS="$LIBS $PTHREAD_LIBS"
 504 AC_CHECK_FUNCS(sem_timedwait)
 505 CFLAGS="$CFLAGS_hold"
 506 LIBS="$LIBS_hold"
 507
 508 LIBS_hold="$LIBS"
 509 LIBS="$LIBS $MATH_LIBS"
 510 AC_CHECK_FUNCS(matherr)
 511 LIBS="$LIBS_hold"
 512
 513 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 514 [libgo_cv_func___sync_bool_compare_and_swap_4],
 515 [AC_LINK_IFELSE([
 516 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 517 uint32 i;
 518 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 519 ],
 520 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 521 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 522 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 523   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 524     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 525 fi
 526
 527 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 528 [libgo_cv_func___sync_bool_compare_and_swap_8],
 529 [AC_LINK_IFELSE([
 530 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 531 uint64 i;
 532 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 533 ],
 534 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 535 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 536 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 537   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 538     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 539 fi
 540
 541 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 542 [libgo_cv_func___sync_fetch_and_add_4],
 543 [AC_LINK_IFELSE([
 544 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 545 uint32 i;
 546 int main() { return __sync_fetch_and_add (&i, 1); }
 547 ],
 548 [libgo_cv_func___sync_fetch_and_add_4=yes],
 549 [libgo_cv_func___sync_fetch_and_add_4=no])])
 550 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 551   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 552     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 553 fi
 554
 555 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 556 [libgo_cv_func___sync_add_and_fetch_8],
 557 [AC_LINK_IFELSE([
 558 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 559 uint64 i;
 560 int main() { return __sync_add_and_fetch (&i, 1); }
 561 ],
 562 [libgo_cv_func___sync_add_and_fetch_8=yes],
 563 [libgo_cv_func___sync_add_and_fetch_8=no])])
 564 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 565   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 566     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 567 fi
 568
 569 dnl For x86 we want to use the -minline-all-stringops option to avoid
 570 dnl forcing a stack split when calling memcpy and friends.
 571 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 572 [libgo_cv_c_stringops],
 573 [CFLAGS_hold=$CFLAGS
 574 CFLAGS="$CFLAGS -minline-all-stringops"
 575 AC_COMPILE_IFELSE([int i;],
 576 [libgo_cv_c_stringops=yes],
 577 [libgo_cv_c_stringops=no])
 578 CFLAGS=$CFLAGS_hold])
 579 STRINGOPS_FLAG=
 580 if test "$libgo_cv_c_stringops" = yes; then
 581   STRINGOPS_FLAG=-minline-all-stringops
 582 fi
 583 AC_SUBST(STRINGOPS_FLAG)
 584
 585 dnl For x86 we want to compile the math library with -mfancy-math-387
 586 dnl -funsafe-math-optimizations so that we can use the builtin
 587 dnl instructions directly.
 588 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 589 [libgo_cv_c_fancymath],
 590 [CFLAGS_hold=$CFLAGS
 591 CFLAGS="$CFLAGS -mfancy-math-387"
 592 AC_COMPILE_IFELSE([int i;],
 593 [libgo_cv_c_fancymath=yes],
 594 [libgo_cv_c_fancymath=no])
 595 CFLAGS=$CFLAGS_hold])
 596 MATH_FLAG=
 597 if test "$libgo_cv_c_fancymath" = yes; then
 598   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 599 fi
 600 AC_SUBST(MATH_FLAG)
 601
 602 CFLAGS_hold=$CFLAGS
 603 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 604 AC_CHECK_TYPES([off64_t])
 605 CFLAGS=$CFLAGS_hold
 606
 607 dnl Work out the size of the epoll_events struct on GNU/Linux.
 608 AC_CACHE_CHECK([epoll_event size],
 609 [libgo_cv_c_epoll_event_size],
 610 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 611 [sizeof (struct epoll_event)],
 612 [#include <sys/epoll.h>],
 613 [libgo_cv_c_epoll_event_size=0])])
 614 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 615 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 616
 617 dnl Work out the offset of the fd field in the epoll_events struct on
 618 dnl GNU/Linux.
 619 AC_CACHE_CHECK([epoll_event data.fd offset],
 620 [libgo_cv_c_epoll_event_fd_offset],
 621 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 622 [offsetof (struct epoll_event, data.fd)],
 623 [#include <stddef.h>
 624 #include <sys/epoll.h>],
 625 [libgo_cv_c_epoll_event_fd_offset=0])])
 626 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 627 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 628
 629 dnl See if struct exception is defined in <math.h>.
 630 AC_CHECK_TYPE([struct exception],
 631 [libgo_has_struct_exception=yes],
 632 [libgo_has_struct_exception=no],
 633 [#include <math.h>])
 634 if test "$libgo_has_struct_exception" = "yes"; then
 635   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 636             [Define to 1 if <math.h> defines struct exception])
 637 fi
 638
 639 dnl Check if makecontext expects the uc_stack member of ucontext to point
 640 dnl to the top of the stack.
 641 case "$target" in
 642   sparc*-*-solaris2.[[89]]*)
 643     libgo_cv_lib_makecontext_stack_top=yes
 644     ;;
 645   *)
 646     libgo_cv_lib_makecontext_stack_top=no
 647     ;;
 648 esac
 649 if test "$libgo_cv_lib_makecontext_stack_top" = "yes"; then
 650   AC_DEFINE(MAKECONTEXT_STACK_TOP, 1,
 651             [Define if makecontext expects top of stack in uc_stack.])
 652 fi
 653
 654 dnl See whether setcontext changes the value of TLS variables.
 655 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 656 [libgo_cv_lib_setcontext_clobbers_tls],
 657 [CFLAGS_hold="$CFLAGS"
 658 CFLAGS="$PTHREAD_CFLAGS"
 659 LIBS_hold="$LIBS"
 660 LIBS="$LIBS $PTHREAD_LIBS"
 661 AC_CHECK_SIZEOF([void *])
 662 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 663 AC_RUN_IFELSE(
 664   [AC_LANG_SOURCE([
 665 #include <pthread.h>
 666 #include <stdlib.h>
 667 #include <ucontext.h>
 668 #include <unistd.h>
 669
 670 __thread int tls;
 671
 672 static char stack[[10 * 1024 * 1024]];
 673 static ucontext_t c;
 674
 675 /* Called via makecontext/setcontext.  */
 676
 677 static void
 678 cfn (void)
 679 {
 680   exit (tls);
 681 }
 682
 683 /* Called via pthread_create.  */
 684
 685 static void *
 686 tfn (void *dummy)
 687 {
 688   /* The thread should still see this value after calling
 689      setcontext.  */
 690   tls = 0;
 691
 692   setcontext (&c);
 693
 694   /* The call to setcontext should not return.  */
 695   abort ();
 696 }
 697
 698 int
 699 main ()
 700 {
 701   pthread_t tid;
 702
 703   /* The thread should not see this value.  */
 704   tls = 1;
 705
 706   if (getcontext (&c) < 0)
 707     abort ();
 708
 709   c.uc_stack.ss_sp = stack;
 710 #ifdef MAKECONTEXT_STACK_TOP
 711   c.uc_stack.ss_sp += sizeof stack;
 712 #endif
 713   c.uc_stack.ss_flags = 0;
 714   c.uc_stack.ss_size = sizeof stack;
 715   c.uc_link = NULL;
 716   makecontext (&c, cfn, 0);
 717
 718   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 719     abort ();
 720
 721   if (pthread_join (tid, NULL) != 0)
 722     abort ();
 723
 724   /* The thread should have called exit.  */
 725   abort ();
 726 }
 727 ])],
 728 [libgo_cv_lib_setcontext_clobbers_tls=no],
 729 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 730 [case "$target:$ptr_type_size" in
 731   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 732     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 733   *)
 734     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 735  esac
 736 ])
 737 CFLAGS="$CFLAGS_hold"
 738 LIBS="$LIBS_hold"
 739 ])
 740 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 741   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 742             [Define if setcontext clobbers TLS variables])
 743 fi
 744
 745 AC_CACHE_SAVE
 746
 747 if test ${multilib} = yes; then
 748   multilib_arg="--enable-multilib"
 749 else
 750   multilib_arg=
 751 fi
 752
 753 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 754
 755 AC_CONFIG_COMMANDS([default],
 756 [if test -n "$CONFIG_FILES"; then
 757    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 758    # that multilib installs will end up installed in the correct place.
 759    # The testsuite needs it for multilib-aware ABI baseline files.
 760    # To work around this not being passed down from config-ml.in ->
 761    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 762    # append it here.  Only modify Makefiles that have just been created.
 763    #
 764    # Also, get rid of this simulated-VPATH thing that automake does.
 765    cat > vpsed << \_EOF
 766 s!`test -f '$<' || echo '$(srcdir)/'`!!
 767 _EOF
 768    for i in $SUBDIRS; do
 769     case $CONFIG_FILES in
 770      *${i}/Makefile*)
 771        #echo "Adding MULTISUBDIR to $i/Makefile"
 772        sed -f vpsed $i/Makefile > tmp
 773        grep '^MULTISUBDIR =' Makefile >> tmp
 774        mv tmp $i/Makefile
 775        ;;
 776     esac
 777    done
 778    rm vpsed
 779  fi
 780 ],
 781 [
 782 # Variables needed in config.status (file generation) which aren't already
 783 # passed by autoconf.
 784 SUBDIRS="$SUBDIRS"
 785 ])
 786
 787 AC_OUTPUT