intl/configure.ac

   1 AC_INIT
   2 AC_USE_SYSTEM_EXTENSIONS
   3 AC_CONFIG_SRCDIR(gettext.c)
   4 AC_CONFIG_HEADER(config.h)
   5 AC_CONFIG_MACRO_DIR(../config)
   6 AM_GNU_GETTEXT_VERSION(0.12.1)
   7 AM_GNU_GETTEXT([], [need-ngettext])
   8
   9 # This replaces the extensive use of DEFS in the original Makefile.in.
  10 AC_DEFINE(IN_LIBINTL, 1, [Define because this is libintl.])
  11 AC_DEFINE(IN_LIBRARY, 1, [Define because this is a library.])
  12 AC_DEFINE(DEPENDS_ON_LIBICONV, 1, [Define because we depend on libiconv.])
  13 AC_DEFINE(ENABLE_RELOCATABLE, 1, [Define to enable relocation.])
  14 AC_DEFINE(NO_XMALLOC, 1, [Define if there is no xmalloc.])
  15 AC_DEFINE(set_relocation_prefix, libintl_set_relocation_prefix,
  16 [Define this entry point correctly.])
  17 AC_DEFINE(relocate, libintl_relocate,
  18 [Define this entry point correctly.])
  19
  20 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  21 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  22 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  23 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  24
  25 AC_ARG_ENABLE(maintainer-mode,
  26 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  27 enable_maintainer_mode=no)
  28 if test "x$enable_maintainer_mode" = xno; then
  29   MAINT='#'
  30 else
  31   MAINT=
  32 fi
  33 AC_SUBST(MAINT)
  34
  35 dnl Variables for tags utilities; based on automake 1.16.4+'s init.m4
  36 if test -z "$CTAGS"; then
  37   CTAGS=ctags
  38 fi
  39 AC_SUBST([CTAGS])
  40 if test -z "$ETAGS"; then
  41   ETAGS=etags
  42 fi
  43 AC_SUBST([ETAGS])
  44 if test -z "$MKID"; then
  45   MKID=mkid
  46 fi
  47 AC_SUBST([MKID])
  48
  49 # Additional info for config.intl.
  50 AC_SUBST(LIBINTL_DEP)
  51 AC_SUBST(INCINTL)
  52
  53 LIBINTL_DEP=
  54 INCINTL=
  55 case $USE_INCLUDED_LIBINTL in
  56   yes)
  57     LIBINTL=`echo $LIBINTL | sed 's,${top_builddir},&/..,' `
  58     LTLIBINTL=`echo $LTLIBINTL | sed 's,${top_builddir},&/..,' `
  59     LIBINTL_DEP='${top_builddir}/../intl/libintl.a'
  60     INCINTL='-I${top_builddir}/../intl'
  61     ;;
  62 esac
  63
  64 BISON3_YES='#'
  65 BISON3_NO=
  66 if test "$INTLBISON" != :; then
  67   ac_bison3=no
  68   AC_MSG_CHECKING([bison 3 or later])
  69 changequote(<<,>>)dnl
  70   ac_prog_version=`$INTLBISON --version 2>&1 | sed -n 's/^.*GNU Bison.* \([0-9]*\.[0-9.]*\).*$/\1/p'`
  71   case $ac_prog_version in
  72     [3-9].*)
  73 changequote([,])dnl
  74       ac_prog_version="$ac_prog_version, bison3"; ac_bison3=yes;;
  75     *) ac_prog_version="$ac_prog_version, old";;
  76   esac
  77   AC_MSG_RESULT([$ac_prog_version])
  78   if test $ac_bison3 = yes; then
  79     BISON3_YES=
  80     BISON3_NO='#'
  81   fi
  82 fi
  83 AC_SUBST(BISON3_YES)
  84 AC_SUBST(BISON3_NO)
  85
  86 # Enable --enable-host-shared.
  87 AC_ARG_ENABLE(host-shared,
  88 [AS_HELP_STRING([--enable-host-shared],
  89        [build host code as shared libraries])])
  90 AC_SUBST(enable_host_shared)
  91
  92 # Enable --enable-host-pie.
  93 AC_ARG_ENABLE(host-pie,
  94 [AS_HELP_STRING([--enable-host-pie],
  95        [build host code as PIE])])
  96 AC_SUBST(enable_host_pie)
  97
  98 if test x$enable_host_shared = xyes; then
  99   PICFLAG=-fPIC
 100 elif test x$enable_host_pie = xyes; then
 101   PICFLAG=-fPIE
 102 else
 103   PICFLAG=
 104 fi
 105 AC_SUBST(PICFLAG)
 106
 107 AC_CONFIG_FILES(Makefile config.intl)
 108 AC_OUTPUT