libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=6:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AC_SUBST(GOOS)
 176
 177 dnl Test whether we need to use DejaGNU or whether we can use the
 178 dnl simpler gotest approach.  We can only use gotest for a native
 179 dnl build.
 180 USE_DEJAGNU=no
 181 case ${host} in
 182   *-*-rtems*) USE_DEJAGNU=yes ;;
 183   ${build}) ;;
 184   *) USE_DEJAGNU=yes ;;
 185 esac
 186 AC_SUBST(USE_DEJAGNU)
 187
 188 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 189 is_386=no
 190 is_alpha=no
 191 is_arm=no
 192 is_arm64=no
 193 is_m68k=no
 194 mips_abi=unknown
 195 is_ppc=no
 196 is_ppc64=no
 197 is_s390=no
 198 is_s390x=no
 199 is_sparc=no
 200 is_sparc64=no
 201 is_x86_64=no
 202 GOARCH=unknown
 203 case ${host} in
 204   alpha*-*-*)
 205     is_alpha=yes
 206     GOARCH=alpha
 207     ;;
 208   aarch64-*-*)
 209     is_arm64=yes
 210     GOARCH=arm64
 211     ;;
 212   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 213     is_arm=yes
 214     GOARCH=arm
 215     ;;
 216 changequote(,)dnl
 217   i[34567]86-*-* | x86_64-*-*)
 218 changequote([,])dnl
 219     AC_COMPILE_IFELSE([
 220 #ifdef __x86_64__
 221 #error 64-bit
 222 #endif],
 223 [is_386=yes], [is_x86_64=yes])
 224     if test "$is_386" = "yes"; then
 225       GOARCH=386
 226     else
 227       GOARCH=amd64
 228     fi
 229     ;;
 230   m68k*-*-*)
 231     is_m68k=yes
 232     GOARCH=m68k
 233     ;;
 234   mips*-*-*)
 235     AC_COMPILE_IFELSE([
 236 #if _MIPS_SIM != _ABIO32
 237 #error not o32
 238 #endif],
 239 [mips_abi="o32"],
 240         [AC_COMPILE_IFELSE([
 241 #if _MIPS_SIM != _ABIN32
 242 #error not n32
 243 #endif],
 244 [mips_abi="n32"],
 245         [AC_COMPILE_IFELSE([
 246 #if _MIPS_SIM != _ABI64
 247 #error not n64
 248 #endif],
 249 [mips_abi="n64"],
 250         [AC_COMPILE_IFELSE([
 251 #if _MIPS_SIM != _ABIO64
 252 #error not o64
 253 #endif],
 254 [mips_abi="o64"],
 255         [AC_MSG_ERROR([unknown MIPS ABI])
 256 [mips_abi="n32"]])])])])
 257     case "$mips_abi" in
 258     "o32") GOARCH=mipso32 ;;
 259     "n32") GOARCH=mipsn32 ;;
 260     "n64") GOARCH=mipsn64 ;;
 261     "o64") GOARCH=mipso64 ;;
 262     esac
 263     ;;
 264   rs6000*-*-* | powerpc*-*-*)
 265     AC_COMPILE_IFELSE([
 266 #ifdef _ARCH_PPC64
 267 #error 64-bit
 268 #endif],
 269 [is_ppc=yes], [is_ppc64=yes])
 270     if test "$is_ppc" = "yes"; then
 271       GOARCH=ppc
 272     else
 273       GOARCH=ppc64
 274     fi
 275     ;;
 276   s390*-*-*)
 277     AC_COMPILE_IFELSE([
 278 #if defined(__s390x__)
 279 #error 64-bit
 280 #endif],
 281 [is_s390=yes], [is_s390x=yes])
 282     if test "$is_s390" = "yes"; then
 283       GOARCH=s390
 284     else
 285       GOARCH=s390x
 286     fi
 287     ;;
 288   sparc*-*-*)
 289     AC_COMPILE_IFELSE([
 290 #if defined(__sparcv9) || defined(__arch64__)
 291 #error 64-bit
 292 #endif],
 293 [is_sparc=yes], [is_sparc64=yes])
 294     if test "$is_sparc" = "yes"; then
 295       GOARCH=sparc
 296     else
 297       GOARCH=sparc64
 298     fi
 299     ;;
 300 esac
 301 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 302 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 303 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 304 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 305 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 306 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 307 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 308 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 309 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 310 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 311 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 312 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 313 AM_CONDITIONAL(LIBGO_IS_S390, test $is_s390 = yes)
 314 AM_CONDITIONAL(LIBGO_IS_S390X, test $is_s390x = yes)
 315 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 316 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 317 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 318 AC_SUBST(GOARCH)
 319
 320 dnl Some files are only present when needed for specific architectures.
 321 GO_LIBCALL_OS_FILE=
 322 GO_LIBCALL_OS_ARCH_FILE=
 323 GO_SYSCALL_OS_FILE=
 324 GO_SYSCALL_OS_ARCH_FILE=
 325 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 326   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 327 fi
 328 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 329   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 330 fi
 331 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 332   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 333 fi
 334 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 335   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 336 fi
 337 AC_SUBST(GO_LIBCALL_OS_FILE)
 338 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 339 AC_SUBST(GO_SYSCALL_OS_FILE)
 340 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 341
 342 dnl Special flags used to generate sysinfo.go.
 343 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 344 case "$target" in
 345     mips-sgi-irix6.5*)
 346         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 347         # msghdr in <sys/socket.h>.
 348         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 349         ;;
 350     *-*-solaris2.1[[01]])
 351         # Solaris 10+ needs this so struct msghdr gets the msg_control
 352         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 353         # above doesn't work with C99.
 354         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 355         ;;
 356 esac
 357 AC_SUBST(OSCFLAGS)
 358
 359 dnl Use -fsplit-stack when compiling C code if available.
 360 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 361 [libgo_cv_c_split_stack_supported],
 362 [CFLAGS_hold=$CFLAGS
 363 CFLAGS="$CFLAGS -fsplit-stack"
 364 AC_COMPILE_IFELSE([[int i;]],
 365 [libgo_cv_c_split_stack_supported=yes],
 366 [libgo_cv_c_split_stack_supported=no])
 367 CFLAGS=$CFLAGS_hold])
 368 if test "$libgo_cv_c_split_stack_supported" = yes; then
 369   SPLIT_STACK=-fsplit-stack
 370   AC_DEFINE(USING_SPLIT_STACK, 1,
 371                 [Define if the compiler supports -fsplit-stack])
 372 else
 373   SPLIT_STACK=
 374 fi
 375 AC_SUBST(SPLIT_STACK)
 376 AM_CONDITIONAL(USING_SPLIT_STACK,
 377         test "$libgo_cv_c_split_stack_supported" = yes)
 378
 379 dnl Check whether the linker does stack munging when calling from
 380 dnl split-stack into non-split-stack code.  We check this by looking
 381 dnl at the --help output.  FIXME: This is only half right: it's
 382 dnl possible for the linker to support this for some targets but not
 383 dnl others.
 384 AC_CACHE_CHECK([whether linker supports split stack],
 385 [libgo_cv_c_linker_supports_split_stack],
 386 [libgo_cv_c_linker_supports_split_stack=no
 387 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 388   libgo_cv_c_linker_supports_split_stack=yes
 389 fi])
 390 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 391   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 392             [Define if the linker support split stack adjustments])
 393 fi
 394
 395 AC_CACHE_CHECK([whether compiler is llgo],
 396 [libgo_cv_c_goc_is_llgo],
 397 [libgo_cv_c_goc_is_llgo=no
 398 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 399   libgo_cv_c_goc_is_llgo=yes
 400 fi])
 401 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 402
 403 dnl Test for the -lm library.
 404 MATH_LIBS=
 405 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 406 AC_SUBST(MATH_LIBS)
 407
 408 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 409 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 410   [libgo_cv_lib_sockets=
 411    libgo_check_both=no
 412    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 413    if test "$libgo_check_socket" = "yes"; then
 414      unset ac_cv_func_connect
 415      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 416                   libgo_check_both=yes)
 417    fi
 418    if test "$libgo_check_both" = "yes"; then
 419      libgo_old_libs=$LIBS
 420      LIBS="$LIBS -lsocket -lnsl"
 421      unset ac_cv_func_accept
 422      AC_CHECK_FUNC(accept,
 423                    [libgo_check_nsl=no
 424                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 425      unset ac_cv_func_accept
 426      LIBS=$libgo_old_libs
 427    fi
 428    unset ac_cv_func_gethostbyname
 429    libgo_old_libs="$LIBS"
 430    AC_CHECK_FUNC(gethostbyname, ,
 431                  [AC_CHECK_LIB(nsl, main,
 432                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 433    unset ac_cv_func_gethostbyname
 434    LIBS=$libgo_old_libs
 435 ])
 436 NET_LIBS="$libgo_cv_lib_sockets"
 437 AC_SUBST(NET_LIBS)
 438
 439 dnl Test whether the compiler supports the -pthread option.
 440 AC_CACHE_CHECK([whether -pthread is supported],
 441 [libgo_cv_lib_pthread],
 442 [CFLAGS_hold=$CFLAGS
 443 CFLAGS="$CFLAGS -pthread"
 444 AC_COMPILE_IFELSE([[int i;]],
 445 [libgo_cv_lib_pthread=yes],
 446 [libgo_cv_lib_pthread=no])
 447 CFLAGS=$CFLAGS_hold])
 448 PTHREAD_CFLAGS=
 449 if test "$libgo_cv_lib_pthread" = yes; then
 450   PTHREAD_CFLAGS=-pthread
 451 fi
 452 AC_SUBST(PTHREAD_CFLAGS)
 453
 454 dnl Test for the -lpthread library.
 455 PTHREAD_LIBS=
 456 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 457 AC_SUBST(PTHREAD_LIBS)
 458
 459 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 460 AC_SEARCH_LIBS([sched_yield], [rt])
 461 AC_SEARCH_LIBS([nanosleep], [rt])
 462
 463 AC_C_BIGENDIAN
 464
 465 GCC_CHECK_UNWIND_GETIPINFO
 466
 467 AC_ARG_ENABLE(sjlj-exceptions,
 468   AC_HELP_STRING([--enable-sjlj-exceptions],
 469                  [force use of builtin_setjmp for exceptions]),
 470   [case "$enableval" in
 471    yes|no|auto) ;;
 472    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 473    esac],
 474   [enable_sjlj_exceptions=auto])
 475
 476 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 477 [libgo_cv_lib_sjlj_exceptions],
 478 [AC_LANG_CONFTEST(
 479   [AC_LANG_SOURCE([
 480 void bar ();
 481 void clean (int *);
 482 void foo ()
 483 {
 484   int i __attribute__ ((cleanup (clean)));
 485   bar();
 486 }
 487 ])])
 488 CFLAGS_hold=$CFLAGS
 489 CFLAGS="--save-temps -fexceptions"
 490 libgo_cv_lib_sjlj_exceptions=unknown
 491 AS_IF([ac_fn_c_try_compile],
 492   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 493     libgo_cv_lib_sjlj_exceptions=yes
 494   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 495     libgo_cv_lib_sjlj_exceptions=no
 496   fi])
 497 CFLAGS=$CFLAGS_hold
 498 rm -f conftest*
 499 ])
 500
 501 if test "$enable_sjlj_exceptions" = "auto"; then
 502   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 503 fi
 504
 505 case $enable_sjlj_exceptions in
 506 yes)
 507   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 508         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 509   ;;
 510 no)
 511   ;;
 512 *)
 513   AC_MSG_ERROR([unable to detect exception model])
 514   ;;
 515 esac
 516
 517 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 518
 519 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 520 [#ifdef HAVE_SYS_SOCKET_H
 521 #include <sys/socket.h>
 522 #endif
 523 ])
 524
 525 AC_CACHE_CHECK([whether <ustat.h> can be used],
 526 [libgo_cv_c_ustat_h],
 527 [CFLAGS_hold=$CFLAGS
 528 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 529 AC_COMPILE_IFELSE(
 530 [AC_LANG_SOURCE([
 531 #include <sys/types.h>
 532 #ifdef HAVE_LINUX_FILTER_H
 533 #include <linux/filter.h>
 534 #endif
 535 #include <ustat.h>
 536 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 537 CFLAGS=$CFLAGS_hold])
 538 if test $libgo_cv_c_ustat_h = yes; then
 539   AC_DEFINE(HAVE_USTAT_H, 1,
 540     [Define to 1 if you have the <ustat.h> header file and it works.])
 541 fi
 542
 543 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 544
 545 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 546 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 547 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 548
 549 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 550 AC_TYPE_OFF_T
 551 AC_CHECK_TYPES([loff_t])
 552
 553 LIBS_hold="$LIBS"
 554 LIBS="$LIBS -lm"
 555 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 556 LIBS="$LIBS_hold"
 557
 558 CFLAGS_hold="$CFLAGS"
 559 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 560 LIBS_hold="$LIBS"
 561 LIBS="$LIBS $PTHREAD_LIBS"
 562 AC_CHECK_FUNCS(sem_timedwait)
 563 CFLAGS="$CFLAGS_hold"
 564 LIBS="$LIBS_hold"
 565
 566 LIBS_hold="$LIBS"
 567 LIBS="$LIBS $MATH_LIBS"
 568 AC_CHECK_FUNCS(matherr)
 569 LIBS="$LIBS_hold"
 570
 571 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 572 [libgo_cv_func___sync_bool_compare_and_swap_4],
 573 [AC_LINK_IFELSE([
 574 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 575 uint32 i;
 576 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 577 ],
 578 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 579 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 580 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 581   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 582     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 583 fi
 584
 585 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 586 [libgo_cv_func___sync_bool_compare_and_swap_8],
 587 [AC_LINK_IFELSE([
 588 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 589 uint64 i;
 590 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 591 ],
 592 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 593 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 594 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 595   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 596     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 597 fi
 598
 599 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 600 [libgo_cv_func___sync_fetch_and_add_4],
 601 [AC_LINK_IFELSE([
 602 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 603 uint32 i;
 604 int main() { return __sync_fetch_and_add (&i, 1); }
 605 ],
 606 [libgo_cv_func___sync_fetch_and_add_4=yes],
 607 [libgo_cv_func___sync_fetch_and_add_4=no])])
 608 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 609   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 610     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 611 fi
 612
 613 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 614 [libgo_cv_func___sync_add_and_fetch_8],
 615 [AC_LINK_IFELSE([
 616 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 617 uint64 i;
 618 int main() { return __sync_add_and_fetch (&i, 1); }
 619 ],
 620 [libgo_cv_func___sync_add_and_fetch_8=yes],
 621 [libgo_cv_func___sync_add_and_fetch_8=no])])
 622 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 623   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 624     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 625 fi
 626
 627 dnl For x86 we want to use the -minline-all-stringops option to avoid
 628 dnl forcing a stack split when calling memcpy and friends.
 629 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 630 [libgo_cv_c_stringops],
 631 [CFLAGS_hold=$CFLAGS
 632 CFLAGS="$CFLAGS -minline-all-stringops"
 633 AC_COMPILE_IFELSE([int i;],
 634 [libgo_cv_c_stringops=yes],
 635 [libgo_cv_c_stringops=no])
 636 CFLAGS=$CFLAGS_hold])
 637 STRINGOPS_FLAG=
 638 if test "$libgo_cv_c_stringops" = yes; then
 639   STRINGOPS_FLAG=-minline-all-stringops
 640 fi
 641 AC_SUBST(STRINGOPS_FLAG)
 642
 643 dnl For x86 we want to compile the math library with -mfancy-math-387
 644 dnl -funsafe-math-optimizations so that we can use the builtin
 645 dnl instructions directly.
 646 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 647 [libgo_cv_c_fancymath],
 648 [CFLAGS_hold=$CFLAGS
 649 CFLAGS="$CFLAGS -mfancy-math-387"
 650 AC_COMPILE_IFELSE([int i;],
 651 [libgo_cv_c_fancymath=yes],
 652 [libgo_cv_c_fancymath=no])
 653 CFLAGS=$CFLAGS_hold])
 654 MATH_FLAG=
 655 if test "$libgo_cv_c_fancymath" = yes; then
 656   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 657 else
 658   MATH_FLAG="-ffp-contract=off"
 659 fi
 660 AC_SUBST(MATH_FLAG)
 661
 662 CFLAGS_hold=$CFLAGS
 663 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 664 AC_CHECK_TYPES([off64_t])
 665 CFLAGS=$CFLAGS_hold
 666
 667 dnl Work out the size of the epoll_events struct on GNU/Linux.
 668 AC_CACHE_CHECK([epoll_event size],
 669 [libgo_cv_c_epoll_event_size],
 670 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 671 [sizeof (struct epoll_event)],
 672 [#include <sys/epoll.h>],
 673 [libgo_cv_c_epoll_event_size=0])])
 674 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 675 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 676
 677 dnl Work out the offset of the fd field in the epoll_events struct on
 678 dnl GNU/Linux.
 679 AC_CACHE_CHECK([epoll_event data.fd offset],
 680 [libgo_cv_c_epoll_event_fd_offset],
 681 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 682 [offsetof (struct epoll_event, data.fd)],
 683 [#include <stddef.h>
 684 #include <sys/epoll.h>],
 685 [libgo_cv_c_epoll_event_fd_offset=0])])
 686 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 687 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 688
 689 dnl See if struct exception is defined in <math.h>.
 690 AC_CHECK_TYPE([struct exception],
 691 [libgo_has_struct_exception=yes],
 692 [libgo_has_struct_exception=no],
 693 [#include <math.h>])
 694 if test "$libgo_has_struct_exception" = "yes"; then
 695   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 696             [Define to 1 if <math.h> defines struct exception])
 697 fi
 698
 699 dnl See whether setcontext changes the value of TLS variables.
 700 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 701 [libgo_cv_lib_setcontext_clobbers_tls],
 702 [CFLAGS_hold="$CFLAGS"
 703 CFLAGS="$PTHREAD_CFLAGS"
 704 LIBS_hold="$LIBS"
 705 LIBS="$LIBS $PTHREAD_LIBS"
 706 AC_CHECK_SIZEOF([void *])
 707 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 708 AC_RUN_IFELSE(
 709   [AC_LANG_SOURCE([
 710 #include <pthread.h>
 711 #include <stdlib.h>
 712 #include <ucontext.h>
 713 #include <unistd.h>
 714
 715 __thread int tls;
 716
 717 static char stack[[10 * 1024 * 1024]];
 718 static ucontext_t c;
 719
 720 /* Called via makecontext/setcontext.  */
 721
 722 static void
 723 cfn (void)
 724 {
 725   exit (tls);
 726 }
 727
 728 /* Called via pthread_create.  */
 729
 730 static void *
 731 tfn (void *dummy)
 732 {
 733   /* The thread should still see this value after calling
 734      setcontext.  */
 735   tls = 0;
 736
 737   setcontext (&c);
 738
 739   /* The call to setcontext should not return.  */
 740   abort ();
 741 }
 742
 743 int
 744 main ()
 745 {
 746   pthread_t tid;
 747
 748   /* The thread should not see this value.  */
 749   tls = 1;
 750
 751   if (getcontext (&c) < 0)
 752     abort ();
 753
 754   c.uc_stack.ss_sp = stack;
 755 #ifdef MAKECONTEXT_STACK_TOP
 756   c.uc_stack.ss_sp += sizeof stack;
 757 #endif
 758   c.uc_stack.ss_flags = 0;
 759   c.uc_stack.ss_size = sizeof stack;
 760   c.uc_link = NULL;
 761   makecontext (&c, cfn, 0);
 762
 763   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 764     abort ();
 765
 766   if (pthread_join (tid, NULL) != 0)
 767     abort ();
 768
 769   /* The thread should have called exit.  */
 770   abort ();
 771 }
 772 ])],
 773 [libgo_cv_lib_setcontext_clobbers_tls=no],
 774 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 775 [case "$target:$ptr_type_size" in
 776   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 777     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 778   *)
 779     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 780  esac
 781 ])
 782 CFLAGS="$CFLAGS_hold"
 783 LIBS="$LIBS_hold"
 784 ])
 785 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 786   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 787             [Define if setcontext clobbers TLS variables])
 788 fi
 789
 790 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 791 libgo_cv_ro_eh_frame, [
 792 libgo_cv_ro_eh_frame=no
 793 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 794 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 795   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 796     libgo_cv_ro_eh_frame=yes
 797   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 798        | grep -v '#write' > /dev/null; then
 799     libgo_cv_ro_eh_frame=yes
 800   fi
 801 fi
 802 rm -f conftest.*
 803 ])
 804 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 805   AC_DEFINE(EH_FRAME_FLAGS, "a",
 806             [Define to the flags needed for the .section .eh_frame directive.])
 807 else
 808   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 809             [Define to the flags needed for the .section .eh_frame directive.])
 810 fi
 811
 812 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 813 [libgo_cv_c_unused_arguments],
 814 [CFLAGS_hold=$CFLAGS
 815 CFLAGS="$CFLAGS -Qunused-arguments"
 816 AC_COMPILE_IFELSE([[int i;]],
 817 [libgo_cv_c_unused_arguments=yes],
 818 [libgo_cv_c_unused_arguments=no])
 819 CFLAGS=$CFLAGS_hold])
 820
 821 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 822 libgo_cv_as_comdat_gnu, [
 823 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 824 CFLAGS_hold=$CFLAGS
 825 if test "$libgo_cv_c_unused_arguments" = yes; then
 826   CFLAGS="$CFLAGS -Qunused-arguments"
 827 fi
 828 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 829   libgo_cv_as_comdat_gnu=yes
 830 else
 831   libgo_cv_as_comdat_gnu=no
 832 fi
 833 CFLAGS=$CFLAGS_hold
 834 ])
 835 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 836   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 837             [Define if your assembler supports GNU comdat group syntax.])
 838 fi
 839
 840 AC_CACHE_CHECK([assembler supports pc related relocs],
 841 libgo_cv_as_x86_pcrel, [
 842 libgo_cv_as_x86_pcrel=yes
 843 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 844 CFLAGS_hold=$CFLAGS
 845 if test "$libgo_cv_c_unused_arguments" = yes; then
 846   CFLAGS="$CFLAGS -Qunused-arguments"
 847 fi
 848 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 849     libgo_cv_as_x86_pcrel=no
 850 fi
 851 CFLAGS=$CFLAGS_hold
 852 ])
 853 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 854   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 855             [Define if your assembler supports PC relative relocs.])
 856 fi
 857
 858 AC_CACHE_CHECK([assembler supports unwind section type],
 859 libgo_cv_as_x86_64_unwind_section_type, [
 860 libgo_cv_as_x86_64_unwind_section_type=yes
 861 echo '.section .eh_frame,"a",@unwind' > conftest.s
 862 CFLAGS_hold=$CFLAGS
 863 if test "$libgo_cv_c_unused_arguments" = yes; then
 864   CFLAGS="$CFLAGS -Qunused-arguments"
 865 fi
 866 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 867     libgo_cv_as_x86_64_unwind_section_type=no
 868 fi
 869 CFLAGS=$CFLAGS_hold
 870 ])
 871 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 872   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 873             [Define if your assembler supports unwind section type.])
 874 fi
 875
 876 AC_CACHE_SAVE
 877
 878 if test ${multilib} = yes; then
 879   multilib_arg="--enable-multilib"
 880 else
 881   multilib_arg=
 882 fi
 883
 884 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 885
 886 AC_CONFIG_COMMANDS([default],
 887 [if test -n "$CONFIG_FILES"; then
 888    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 889    # that multilib installs will end up installed in the correct place.
 890    # The testsuite needs it for multilib-aware ABI baseline files.
 891    # To work around this not being passed down from config-ml.in ->
 892    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 893    # append it here.  Only modify Makefiles that have just been created.
 894    #
 895    # Also, get rid of this simulated-VPATH thing that automake does.
 896    cat > vpsed << \_EOF
 897 s!`test -f '$<' || echo '$(srcdir)/'`!!
 898 _EOF
 899    for i in $SUBDIRS; do
 900     case $CONFIG_FILES in
 901      *${i}/Makefile*)
 902        #echo "Adding MULTISUBDIR to $i/Makefile"
 903        sed -f vpsed $i/Makefile > tmp
 904        grep '^MULTISUBDIR =' Makefile >> tmp
 905        mv tmp $i/Makefile
 906        ;;
 907     esac
 908    done
 909    rm vpsed
 910  fi
 911 ],
 912 [
 913 # Variables needed in config.status (file generation) which aren't already
 914 # passed by autoconf.
 915 SUBDIRS="$SUBDIRS"
 916 ])
 917
 918 AC_OUTPUT