libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 # Runs configure.host, and assorted other critical bits.  Sets
  87 # up critical shell variables.
  88 GLIBCXX_CONFIGURE
  89
  90 # Libtool setup.
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 if test "$enable_vtable_verify" = yes; then
 100   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 101   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 102 fi
 103
 104
 105 # libtool variables for C++ shared and position-independent compiles.
 106 #
 107 # Use glibcxx_lt_pic_flag to designate the automake variable
 108 # used to encapsulate the default libtool approach to creating objects
 109 # with position-independent code. Default: -prefer-pic.
 110 #
 111 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 112 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 113 #
 114 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 115 # creating position-independent objects. This varies with the target
 116 # hardware and operating system, but is often: -DPIC -fPIC.
 117 if test "$enable_shared" = yes; then
 118   glibcxx_lt_pic_flag="-prefer-pic"
 119   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 120   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 121
 122 else
 123   glibcxx_lt_pic_flag=
 124   glibcxx_compiler_pic_flag=
 125   glibcxx_compiler_shared_flag=
 126 fi
 127 AC_SUBST(glibcxx_lt_pic_flag)
 128 AC_SUBST(glibcxx_compiler_pic_flag)
 129 AC_SUBST(glibcxx_compiler_shared_flag)
 130
 131 # Override the libtool's pic_flag and pic_mode.
 132 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 133 # NB: this impacts --with-pic and --without-pic.
 134 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 135 pic_mode='default'
 136
 137 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 138 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 139
 140 # Possibly disable most of the library.
 141 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 142 ## than just ignoring the results.  Faster /and/ more correct, win win.
 143 GLIBCXX_ENABLE_HOSTED
 144
 145 # Enable descriptive messages to standard output on termination.
 146 GLIBCXX_ENABLE_VERBOSE
 147
 148 # Enable compiler support that doesn't require linking.
 149 GLIBCXX_ENABLE_PCH($is_hosted)
 150 GLIBCXX_ENABLE_THREADS
 151 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 152 GLIBCXX_ENABLE_DECIMAL_FLOAT
 153 GLIBCXX_ENABLE_INT128_FLOAT128
 154 if test "$enable_float128" = yes; then
 155   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 156 fi
 157
 158 # Checks for compiler support that doesn't require linking.
 159 GLIBCXX_CHECK_COMPILER_FEATURES
 160
 161 # Enable all the variable C++ runtime options that don't require linking.
 162 GLIBCXX_ENABLE_CSTDIO
 163 GLIBCXX_ENABLE_CLOCALE
 164 GLIBCXX_ENABLE_ALLOCATOR
 165 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 166 GLIBCXX_ENABLE_LONG_LONG([yes])
 167 GLIBCXX_ENABLE_WCHAR_T([yes])
 168 GLIBCXX_ENABLE_C99([yes])
 169 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 170 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 171 GLIBCXX_ENABLE_DEBUG([no])
 172 GLIBCXX_ENABLE_PARALLEL([yes])
 173 GLIBCXX_ENABLE_CXX_FLAGS
 174 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 175 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 176 GLIBCXX_ENABLE_PYTHON
 177 GLIBCXX_ENABLE_WERROR([no])
 178 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 179
 180 # Checks for operating systems support that doesn't require linking.
 181 GLIBCXX_CHECK_STDIO_PROTO
 182 GLIBCXX_CHECK_MATH11_PROTO
 183 GLIBCXX_CHECK_SYSTEM_ERROR
 184 GLIBCXX_CHECK_UCHAR_H
 185
 186 # For the streamoff typedef.
 187 GLIBCXX_CHECK_INT64_T
 188
 189 # For LFS support.
 190 GLIBCXX_CHECK_LFS
 191
 192 # For showmanyc_helper().
 193 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 194 GLIBCXX_CHECK_POLL
 195 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 196
 197 # For xsputn_2().
 198 AC_CHECK_HEADERS(sys/uio.h)
 199 GLIBCXX_CHECK_WRITEV
 200
 201 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 202 # so that the check is done with the C compiler (not C++).
 203 # Checking with C++ can break a canadian cross build if either
 204 # file does not exist in C but does in C++.
 205 AC_CHECK_HEADERS(fenv.h complex.h)
 206
 207 # For C99 support to TR1.
 208 GLIBCXX_CHECK_C99_TR1
 209
 210 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 211 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 212
 213 # For gettimeofday support.
 214 GLIBCXX_CHECK_GETTIMEOFDAY
 215
 216 # For clock_gettime, nanosleep and sched_yield support.
 217 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 218
 219 # Check for tmpnam which is obsolescent in POSIX.1-2008
 220 GLIBCXX_CHECK_TMPNAM
 221
 222 AC_LC_MESSAGES
 223
 224 # For hardware_concurrency
 225 AC_CHECK_HEADERS(sys/sysinfo.h)
 226 GLIBCXX_CHECK_GET_NPROCS
 227 AC_CHECK_HEADERS(unistd.h)
 228 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 229 GLIBCXX_CHECK_SC_NPROC_ONLN
 230 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 231 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 232 GLIBCXX_CHECK_SDT_H
 233
 234 # Check for available headers.
 235 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 236 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 237 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 238 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 239 wchar.h wctype.h linux/types.h])
 240
 241 AC_CHECK_HEADERS([linux/random.h], [], [],
 242 [[#ifdef HAVE_LINUX_TYPES_H
 243 # include <linux/types.h>
 244 #endif
 245 ]])
 246
 247 # Only do link tests if native. Else, hardcode.
 248 if $GLIBCXX_IS_NATIVE; then
 249
 250   # We can do more elaborate tests that assume a working linker.
 251   CANADIAN=no
 252
 253   GLIBCXX_CHECK_LINKER_FEATURES
 254   GLIBCXX_CHECK_MATH_SUPPORT
 255   GLIBCXX_CHECK_STDLIB_SUPPORT
 256
 257   # For /dev/random and /dev/urandom for std::random_device.
 258   GLIBCXX_CHECK_DEV_RANDOM
 259
 260   # For TLS support.
 261   GCC_CHECK_TLS
 262
 263   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 264   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 265   AC_CHECK_FUNCS(_wfopen)
 266
 267   # For iconv support.
 268   AM_ICONV
 269
 270 else
 271
 272   # This lets us hard-code the functionality we know we'll have in the cross
 273   # target environment.  "Let" is a sugar-coated word placed on an especially
 274   # dull and tedious hack, actually.
 275   #
 276   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 277   # that involve linking, can't be used:
 278   #    "cannot open sim-crt0.o"
 279   #    "cannot open crt0.o"
 280   # etc.  All this is because there currently exists no unified, consistent
 281   # way for top level CC information to be passed down to target directories:
 282   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 283   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 284   # crosses can be removed.
 285
 286   # If Canadian cross, then don't pick up tools from the build directory.
 287   # Used only in GLIBCXX_EXPORT_INCLUDES.
 288   if test -n "$with_cross_host" &&
 289      test x"$build_alias" != x"$with_cross_host" &&
 290      test x"$build" != x"$target";
 291   then
 292     CANADIAN=yes
 293   else
 294     CANADIAN=no
 295   fi
 296
 297   # Construct crosses by hand, eliminating bits that need ld...
 298   # GLIBCXX_CHECK_MATH_SUPPORT
 299
 300   # First, test for "known" system libraries.  We may be using newlib even
 301   # on a hosted environment.
 302   if test "x${with_newlib}" = "xyes"; then
 303     os_include_dir="os/newlib"
 304     AC_DEFINE(HAVE_HYPOT)
 305
 306     # GLIBCXX_CHECK_STDLIB_SUPPORT
 307     AC_DEFINE(HAVE_STRTOF)
 308
 309     AC_DEFINE(HAVE_ACOSF)
 310     AC_DEFINE(HAVE_ASINF)
 311     AC_DEFINE(HAVE_ATAN2F)
 312     AC_DEFINE(HAVE_ATANF)
 313     AC_DEFINE(HAVE_CEILF)
 314     AC_DEFINE(HAVE_COSF)
 315     AC_DEFINE(HAVE_COSHF)
 316     AC_DEFINE(HAVE_EXPF)
 317     AC_DEFINE(HAVE_FABSF)
 318     AC_DEFINE(HAVE_FLOORF)
 319     AC_DEFINE(HAVE_FMODF)
 320     AC_DEFINE(HAVE_FREXPF)
 321     AC_DEFINE(HAVE_LDEXPF)
 322     AC_DEFINE(HAVE_LOG10F)
 323     AC_DEFINE(HAVE_LOGF)
 324     AC_DEFINE(HAVE_MODFF)
 325     AC_DEFINE(HAVE_POWF)
 326     AC_DEFINE(HAVE_SINF)
 327     AC_DEFINE(HAVE_SINHF)
 328     AC_DEFINE(HAVE_SQRTF)
 329     AC_DEFINE(HAVE_TANF)
 330     AC_DEFINE(HAVE_TANHF)
 331
 332     AC_DEFINE(HAVE_ICONV)
 333     AC_DEFINE(HAVE_MEMALIGN)
 334   else
 335     GLIBCXX_CROSSCONFIG
 336   fi
 337
 338   # At some point, we should differentiate between architectures
 339   # like x86, which have long double versions, and alpha/powerpc/etc.,
 340   # which don't. For the time being, punt.
 341   if test x"long_double_math_on_this_cpu" = x"yes"; then
 342     AC_DEFINE(HAVE_ACOSL)
 343     AC_DEFINE(HAVE_ASINL)
 344     AC_DEFINE(HAVE_ATAN2L)
 345     AC_DEFINE(HAVE_ATANL)
 346     AC_DEFINE(HAVE_CEILL)
 347     AC_DEFINE(HAVE_COSL)
 348     AC_DEFINE(HAVE_COSHL)
 349     AC_DEFINE(HAVE_EXPL)
 350     AC_DEFINE(HAVE_FABSL)
 351     AC_DEFINE(HAVE_FLOORL)
 352     AC_DEFINE(HAVE_FMODL)
 353     AC_DEFINE(HAVE_FREXPL)
 354     AC_DEFINE(HAVE_LDEXPL)
 355     AC_DEFINE(HAVE_LOG10L)
 356     AC_DEFINE(HAVE_LOGL)
 357     AC_DEFINE(HAVE_MODFL)
 358     AC_DEFINE(HAVE_POWL)
 359     AC_DEFINE(HAVE_SINCOSL)
 360     AC_DEFINE(HAVE_SINL)
 361     AC_DEFINE(HAVE_SINHL)
 362     AC_DEFINE(HAVE_SQRTL)
 363     AC_DEFINE(HAVE_TANL)
 364     AC_DEFINE(HAVE_TANHL)
 365   fi
 366 fi
 367
 368 # Check for _Unwind_GetIPInfo.
 369 GCC_CHECK_UNWIND_GETIPINFO
 370
 371 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 372
 373 GCC_HEADER_STDINT(include/gstdint.h)
 374
 375 GLIBCXX_ENABLE_SYMVERS([yes])
 376 AC_SUBST(libtool_VERSION)
 377
 378 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 379
 380 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 381 GLIBCXX_DEFAULT_ABI
 382
 383 ac_ldbl_compat=no
 384 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 385 case "$target" in
 386   powerpc*-*-linux* | \
 387   sparc*-*-linux* | \
 388   s390*-*-linux* | \
 389   alpha*-*-linux*)
 390   AC_TRY_COMPILE(, [
 391 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 392 #error no need for long double compatibility
 393 #endif
 394   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 395   if test "$ac_ldbl_compat" = yes; then
 396     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 397               [Define if compatibility should be provided for -mlong-double-64.])
 398     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 399     case "$target" in
 400       powerpc*-*-linux*)
 401         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
 402     esac
 403   fi
 404 esac
 405 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 406 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 407
 408 # Check if assembler supports disabling hardware capability support.
 409 GCC_CHECK_ASSEMBLER_HWCAP
 410
 411 # Check if assembler supports rdrand opcode.
 412 GLIBCXX_CHECK_X86_RDRAND
 413
 414 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 415 GLIBCXX_CONFIGURE_TESTSUITE
 416
 417 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 418 GLIBCXX_CHECK_GTHREADS
 419
 420 # For Filesystem TS.
 421 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 422 GLIBCXX_ENABLE_FILESYSTEM_TS
 423 GLIBCXX_CHECK_FILESYSTEM_DEPS
 424
 425 # For Networking TS.
 426 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 427
 428 # For Transactional Memory TS
 429 GLIBCXX_CHECK_SIZE_T_MANGLING
 430
 431 # Check which release added std::exception_ptr for the target
 432 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 433
 434 # Define documentation rules conditionally.
 435
 436 # See if makeinfo has been installed and is modern enough
 437 # that we can use it.
 438 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 439                    [GNU texinfo.* \([0-9][0-9.]*\)],
 440                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 441 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 442
 443 # Check for doxygen
 444 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 445 AC_CHECK_PROG([DOT], dot, yes, no)
 446
 447 # Check for docbook
 448 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 449 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 450 GLIBCXX_CONFIGURE_DOCBOOK
 451
 452 # Check for xml/html dependencies.
 453 AM_CONDITIONAL(BUILD_XML,
 454                test $ac_cv_prog_DOXYGEN = "yes" &&
 455                test $ac_cv_prog_DOT = "yes" &&
 456                test $ac_cv_prog_XSLTPROC = "yes" &&
 457                test $ac_cv_prog_XMLLINT = "yes" &&
 458                test $glibcxx_stylesheets = "yes")
 459
 460 AM_CONDITIONAL(BUILD_HTML,
 461                test $ac_cv_prog_DOXYGEN = "yes" &&
 462                test $ac_cv_prog_DOT = "yes" &&
 463                test $ac_cv_prog_XSLTPROC = "yes" &&
 464                test $ac_cv_prog_XMLLINT = "yes" &&
 465                test $glibcxx_stylesheets = "yes")
 466
 467 # Check for man dependencies.
 468 AM_CONDITIONAL(BUILD_MAN,
 469                test $ac_cv_prog_DOXYGEN = "yes" &&
 470                test $ac_cv_prog_DOT = "yes")
 471
 472 # Check for pdf dependencies.
 473 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 474 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 475 AM_CONDITIONAL(BUILD_PDF,
 476                test $ac_cv_prog_DBLATEX = "yes" &&
 477                test $ac_cv_prog_PDFLATEX = "yes")
 478
 479 case "$build" in
 480  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 481  * ) glibcxx_include_dir_notparallel=no ;;
 482 esac
 483 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 484                test $glibcxx_include_dir_notparallel = "yes")
 485
 486 # Propagate the target-specific source directories through the build chain.
 487 ATOMICITY_SRCDIR=config/${atomicity_dir}
 488 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 489 ATOMIC_FLAGS=${atomic_flags}
 490 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 491 OS_INC_SRCDIR=config/${os_include_dir}
 492 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 493 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 494 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 495 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 496 AC_SUBST(ATOMICITY_SRCDIR)
 497 AC_SUBST(ATOMIC_WORD_SRCDIR)
 498 AC_SUBST(ATOMIC_FLAGS)
 499 AC_SUBST(CPU_DEFINES_SRCDIR)
 500 AC_SUBST(ABI_TWEAKS_SRCDIR)
 501 AC_SUBST(OS_INC_SRCDIR)
 502 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 503 AC_SUBST(CPU_OPT_EXT_RANDOM)
 504 AC_SUBST(CPU_OPT_BITS_RANDOM)
 505
 506
 507 # Add CET specific flags if Intel CET is enabled.
 508 GCC_CET_FLAGS(CET_FLAGS)
 509 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 510 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 511 AC_SUBST(EXTRA_CFLAGS)
 512 AC_SUBST(EXTRA_CXX_FLAGS)
 513
 514 # Determine cross-compile flags and AM_CONDITIONALs.
 515 #AC_SUBST(GLIBCXX_IS_NATIVE)
 516 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 517 GLIBCXX_EVALUATE_CONDITIONALS
 518
 519 AC_CACHE_SAVE
 520
 521 if test ${multilib} = yes; then
 522   multilib_arg="--enable-multilib"
 523 else
 524   multilib_arg=
 525 fi
 526
 527 # Export all the install information.
 528 GLIBCXX_EXPORT_INSTALL_INFO
 529
 530 # Export all the include and flag information to Makefiles.
 531 GLIBCXX_EXPORT_INCLUDES
 532 GLIBCXX_EXPORT_FLAGS
 533
 534 # Determine what GCC version number to use in filesystem paths.
 535 GCC_BASE_VER
 536
 537 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 538 dnl which can all be called multiple times as needed, plus one (different)
 539 dnl AC_OUTPUT macro.  This one lists the files to be created:
 540 AC_CONFIG_FILES(Makefile)
 541 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 542 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 543 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 544
 545 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 546 # that multilib installs will end up installed in the correct place.
 547 # The testsuite needs it for multilib-aware ABI baseline files.
 548 # To work around this not being passed down from config-ml.in ->
 549 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 550 # append it here.  Only modify Makefiles that have just been created.
 551 #
 552 # Also, get rid of this simulated-VPATH thing that automake does.
 553 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 554   [cat > vpsed$$ << \_EOF
 555 s!`test -f '$<' || echo '$(srcdir)/'`!!
 556 _EOF
 557    sed -f vpsed$$ $ac_file > tmp$$
 558    mv tmp$$ $ac_file
 559    rm vpsed$$
 560    echo 'MULTISUBDIR =' >> $ac_file
 561    ml_norecursion=yes
 562    . ${multi_basedir}/config-ml.in
 563    AS_UNSET([ml_norecursion])
 564 ])
 565
 566 AC_CONFIG_COMMANDS([generate-headers],
 567   [(cd include && ${MAKE-make} pch_build= )])
 568
 569 dnl And this actually makes things happen:
 570 AC_OUTPUT