gcc/ada/sem_ch8.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 8                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2018, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Types; use Types;
  27 package Sem_Ch8 is
  28
  29    -----------------------------------
  30    -- Handling extensions of System --
  31    -----------------------------------
  32
  33    --  For targets that define a much larger System package than given in
  34    --  the RM, we use a child package containing additional declarations,
  35    --  which is loaded when needed, and whose entities are conceptually
  36    --  within System itself. The presence of this auxiliary package is
  37    --  controlled with the pragma Extend_System. The following variable
  38    --  holds the entity of the auxiliary package, to simplify the special
  39    --  visibility rules that apply to it.
  40
  41    System_Aux_Id : Entity_Id := Empty;
  42
  43    -----------------
  44    -- Subprograms --
  45    -----------------
  46
  47    procedure Analyze_Exception_Renaming         (N : Node_Id);
  48    procedure Analyze_Expanded_Name              (N : Node_Id);
  49    procedure Analyze_Generic_Function_Renaming  (N : Node_Id);
  50    procedure Analyze_Generic_Package_Renaming   (N : Node_Id);
  51    procedure Analyze_Generic_Procedure_Renaming (N : Node_Id);
  52    procedure Analyze_Object_Renaming            (N : Node_Id);
  53    procedure Analyze_Package_Renaming           (N : Node_Id);
  54    procedure Analyze_Subprogram_Renaming        (N : Node_Id);
  55
  56    procedure Analyze_Use_Package (N : Node_Id; Chain : Boolean := True);
  57    --  Analyze a use package clause and control (through the Chain parameter)
  58    --  whether to add N to the use clause chain for the name denoted within
  59    --  use clause N in case we are reanalyzing a use clause because of stack
  60    --  manipulation.
  61
  62    procedure Analyze_Use_Type (N : Node_Id; Chain : Boolean := True);
  63    --  Similar to Analyze_Use_Package except the Chain parameter applies to the
  64    --  type within N's subtype mark Current_Use_Clause.
  65
  66    procedure End_Scope;
  67    --  Called at end of scope. On exit from blocks and bodies (subprogram,
  68    --  package, task, and protected bodies), the name of the current scope
  69    --  must be removed from the scope stack, and the local entities must be
  70    --  removed from their homonym chains. On exit from record declarations,
  71    --  from package specifications, and from tasks and protected type
  72    --  specifications, more specialized procedures are invoked.
  73
  74    procedure End_Use_Clauses (Clause : Node_Id);
  75    --  Invoked on scope exit, to undo the effect of local use clauses. Clause
  76    --  is the first use-clause of a scope being exited. This can be the current
  77    --  scope, or some enclosing scopes when building a clean environment to
  78    --  compile an instance body for inlining.
  79
  80    procedure End_Use_Package (N : Node_Id);
  81    procedure End_Use_Type    (N : Node_Id);
  82    --  Subsidiaries of End_Use_Clauses. Also called directly for use clauses
  83    --  appearing in context clauses.
  84
  85    procedure Find_Direct_Name (N : Node_Id);
  86    --  Given a direct name (Identifier or Operator_Symbol), this routine scans
  87    --  the homonym chain for the name, searching for corresponding visible
  88    --  entities to find the referenced entity (or in the case of overloading,
  89    --  one candidate interpretation). On return, the Entity and Etype fields
  90    --  are set. In the non-overloaded case, these are the correct entries.
  91    --  In the overloaded case, the flag Is_Overloaded is set, Etype and Entity
  92    --  refer to an arbitrary element of the overloads set, and the appropriate
  93    --  entries have been added to the overloads table entry for the node. The
  94    --  overloading will be disambiguated during type resolution.
  95    --
  96    --  Note, when this is called during semantic analysis in the overloaded
  97    --  case, the entity set will be the most recently declared homonym. In
  98    --  particular, the caller may follow the homonym chain checking for all
  99    --  entries in the current scope, and that will give all homonyms that are
 100    --  declared before the point of call in the current scope. This is useful
 101    --  for example in the processing for pragma Inline.
 102
 103    procedure Find_Selected_Component (N : Node_Id);
 104    --  Resolve various cases of selected components, recognize expanded names
 105
 106    procedure Find_Type (N : Node_Id);
 107    --  Perform name resolution, and verify that the name found is that of a
 108    --  type. On return the Entity and Etype fields of the node N are set
 109    --  appropriately. If it is an incomplete type whose full declaration has
 110    --  been seen, they are set to the entity in the full declaration. If it
 111    --  is an incomplete type associated with an interface visible through a
 112    --  limited-with clause, whose full declaration has been seen, they are
 113    --  set to the entity in the full declaration. Similarly, if the type is
 114    --  private, it has received a full declaration, and we are in the private
 115    --  part or body of the package, then the two fields are set to the entity
 116    --  of the full declaration as well. This procedure also has special
 117    --  processing for 'Class attribute references.
 118
 119    function Has_Loop_In_Inner_Open_Scopes (S : Entity_Id) return Boolean;
 120    --  S is the entity of an open scope. This function determines if there is
 121    --  an inner scope of S which is a loop (i.e. it appears somewhere in the
 122    --  scope stack after S).
 123
 124    function In_Open_Scopes (S : Entity_Id) return Boolean;
 125    --  S is the entity of a scope. This function determines if this scope is
 126    --  currently open (i.e. it appears somewhere in the scope stack).
 127
 128    procedure Initialize;
 129    --  Initializes data structures used for visibility analysis. Must be
 130    --  called before analyzing each new main source program.
 131
 132    procedure Install_Use_Clauses
 133      (Clause             : Node_Id;
 134       Force_Installation : Boolean := False);
 135    --  Applies the use clauses appearing in a given declarative part,
 136    --  when the corresponding scope has been placed back on the scope
 137    --  stack after unstacking to compile a different context (subunit or
 138    --  parent of generic body). Force_Installation is used when called from
 139    --  Analyze_Subunit.Re_Install_Use_Clauses to insure that, after the
 140    --  analysis of the subunit, the parent's environment is again identical.
 141
 142    procedure Mark_Use_Clauses (Id : Node_Or_Entity_Id);
 143    --  Mark a given entity or node Id's relevant use clauses as effective,
 144    --  including redundant ones and ones outside of the current scope.
 145
 146    procedure Push_Scope (S : Entity_Id);
 147    --  Make new scope stack entry, pushing S, the entity for a scope onto the
 148    --  top of the scope table. The current setting of the scope suppress flags
 149    --  is saved for restoration on exit.
 150
 151    procedure Pop_Scope;
 152    --  Remove top entry from scope stack, restoring the saved setting of the
 153    --  scope suppress flags.
 154
 155    function Present_System_Aux (N : Node_Id := Empty) return Boolean;
 156    --  Return True if the auxiliary system file has been successfully loaded.
 157    --  Otherwise attempt to load it, using the name supplied by a previous
 158    --  Extend_System pragma, and report on the success of the load. If N is
 159    --  present, it is a selected component whose prefix is System, or else a
 160    --  with-clause on system. N is absent when the function is called to find
 161    --  the visibility of implicit operators.
 162
 163    function Save_Scope_Stack
 164      (Handle_Use : Boolean := True) return Elist_Id;
 165    procedure Restore_Scope_Stack
 166      (List       : Elist_Id;
 167       Handle_Use : Boolean := True);
 168    --  These two subprograms are called from Semantics, when a unit U1 is to
 169    --  be compiled in the course of the compilation of another unit U2. This
 170    --  happens whenever Rtsfind is called. U1, the unit retrieved by Rtsfind,
 171    --  must be compiled in its own context, and the current scope stack
 172    --  containing U2 and local scopes must be made unreachable. This is
 173    --  achieved using a call to Save_Scope_Stack. On return, the contents
 174    --  of the scope stack must be made accessible again with a call to
 175    --  Restore_Scope_Stack.
 176    --
 177    --  The flag Handle_Use indicates whether local use clauses must be removed
 178    --  or installed. In the case of inlining of instance bodies, the visibility
 179    --  handling is done fully in Inline_Instance_Body, and use clauses are
 180    --  handled there. Save_Scope_Stack returns the list of entities which have
 181    --  been temporarily removed from visibility; that list must be passed to
 182    --  Restore_Scope_Stack to restore their visibility.
 183
 184    procedure Set_Use (L : List_Id);
 185    --  Find use clauses that are declarative items in a package declaration
 186    --  and set the potentially use-visible flags of imported entities before
 187    --  analyzing the corresponding package body.
 188
 189    procedure Update_Use_Clause_Chain;
 190    --  Called at the end of a declarative region to detect unused use type
 191    --  clauses and maintain the Current_Use_Clause for type entities.
 192
 193    procedure ws;
 194    --  Debugging routine for use in gdb: dump all entities on scope stack
 195
 196    procedure we (S : Entity_Id);
 197    --  Debugging routine for use in gdb: dump all entities in given scope
 198
 199 end Sem_Ch8;