gcc/ada/sem_eval.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ E V A L                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains various subprograms involved in compile time
  27 --  evaluation of expressions and checks for staticness of expressions and
  28 --  types. It also contains the circuitry for checking for violations of pure
  29 --  and preelaborated conditions (this naturally goes here, since these rules
  30 --  involve consideration of staticness).
  31
  32 --  Note: the static evaluation for attributes is found in Sem_Attr even though
  33 --  logically it belongs here. We have done this so that it is easier to add
  34 --  new attributes to GNAT.
  35
  36 with Types;  use Types;
  37 with Uintp;  use Uintp;
  38 with Urealp; use Urealp;
  39
  40 package Sem_Eval is
  41
  42    ------------------------------------
  43    -- Handling of Static Expressions --
  44    ------------------------------------
  45
  46    --  This package contains a set of routines that process individual
  47    --  subexpression nodes with the objective of folding (precomputing) the
  48    --  value of static expressions that are known at compile time and properly
  49    --  computing the setting of two flags that appear in every subexpression
  50    --  node:
  51
  52    --    Is_Static_Expression
  53
  54    --      This flag is set on any expression that is static according to the
  55    --      rules in (RM 4.9(3-32)).
  56
  57    --    Raises_Constraint_Error
  58
  59    --      This flag indicates that it is known at compile time that the
  60    --      evaluation of an expression raises constraint error. If the
  61    --      expression is static, and this flag is off, then it is also known at
  62    --      compile time that the expression does not raise constraint error
  63    --      (i.e. the flag is accurate for static expressions, and conservative
  64    --      for non-static expressions.
  65
  66    --  If a static expression does not raise constraint error, then the
  67    --  Raises_Constraint_Error flag is off, and the expression must be computed
  68    --  at compile time, which means that it has the form of either a literal,
  69    --  or a constant that is itself (recursively) either a literal or a
  70    --  constant.
  71
  72    --  The above rules must be followed exactly in order for legality checks to
  73    --  be accurate. For subexpressions that are not static according to the RM
  74    --  definition, they are sometimes folded anyway, but of course in this case
  75    --  Is_Static_Expression is not set.
  76
  77    -------------------------------
  78    -- Compile-Time Known Values --
  79    -------------------------------
  80
  81    --  For most legality checking purposes the flag Is_Static_Expression
  82    --  defined in Sinfo should be used. This package also provides a routine
  83    --  called Is_OK_Static_Expression which in addition of checking that an
  84    --  expression is static in the RM 4.9 sense, it checks that the expression
  85    --  does not raise constraint error. In fact for certain legality checks not
  86    --  only do we need to ascertain that the expression is static, but we must
  87    --  also ensure that it does not raise constraint error.
  88
  89    --  Neither of Is_Static_Expression and Is_OK_Static_Expression should be
  90    --  used for compile time evaluation purposes. In fact certain expression
  91    --  whose value may be known at compile time are not static in the RM 4.9
  92    --  sense. A typical example is:
  93
  94    --     C : constant Integer := Record_Type'Size;
  95
  96    --  The expression 'C' is not static in the technical RM sense, but for many
  97    --  simple record types, the size is in fact known at compile time. When we
  98    --  are trying to perform compile time constant folding (for instance for
  99    --  expressions like C + 1, Is_Static_Expression or Is_OK_Static_Expression
 100    --  are not the right functions to test if folding is possible. Instead, we
 101    --  use Compile_Time_Known_Value. All static expressions that do not raise
 102    --  constraint error (i.e. those for which Is_OK_Static_Expression is true)
 103    --  are known at compile time, but as shown by the above example, there may
 104    --  be cases of non-static expressions which are known at compile time.
 105
 106    -----------------
 107    -- Subprograms --
 108    -----------------
 109
 110    procedure Check_Non_Static_Context (N : Node_Id);
 111    --  Deals with the special check required for a static expression that
 112    --  appears in a non-static context, i.e. is not part of a larger static
 113    --  expression (see RM 4.9(35)), i.e. the value of the expression must be
 114    --  within the base range of the base type of its expected type. A check is
 115    --  also made for expressions that are inside the base range, but outside
 116    --  the range of the expected subtype (this is a warning message rather than
 117    --  an illegality).
 118    --
 119    --  Note: most cases of non-static context checks are handled within
 120    --  Sem_Eval itself, including all cases of expressions at the outer level
 121    --  (i.e. those that are not a subexpression). Currently the only outside
 122    --  customer for this procedure is Sem_Attr (because Eval_Attribute is
 123    --  there). There is also one special case arising from ranges (see body of
 124    --  Resolve_Range).
 125
 126    procedure Check_String_Literal_Length (N : Node_Id; Ttype : Entity_Id);
 127    --  N is either a string literal, or a constraint error node. In the latter
 128    --  case, the situation is already dealt with, and the call has no effect.
 129    --  In the former case, if the target type, Ttyp is constrained, then a
 130    --  check is made to see if the string literal is of appropriate length.
 131
 132    type Compare_Result is (LT, LE, EQ, GT, GE, NE, Unknown);
 133    subtype Compare_GE is Compare_Result range EQ .. GE;
 134    subtype Compare_LE is Compare_Result range LT .. EQ;
 135    --  Result subtypes for Compile_Time_Compare subprograms
 136
 137    function Compile_Time_Compare
 138      (L, R         : Node_Id;
 139       Assume_Valid : Boolean) return Compare_Result;
 140    pragma Inline (Compile_Time_Compare);
 141    --  Given two expression nodes, finds out whether it can be determined at
 142    --  compile time how the runtime values will compare. An Unknown result
 143    --  means that the result of a comparison cannot be determined at compile
 144    --  time, otherwise the returned result indicates the known result of the
 145    --  comparison, given as tightly as possible (i.e. EQ or LT is preferred
 146    --  returned value to LE). If Assume_Valid is true, the result reflects
 147    --  the result of assuming that entities involved in the comparison have
 148    --  valid representations. If Assume_Valid is false, then the base type of
 149    --  any involved entity is used so that no assumption of validity is made.
 150
 151    function Compile_Time_Compare
 152      (L, R         : Node_Id;
 153       Diff         : access Uint;
 154       Assume_Valid : Boolean;
 155       Rec          : Boolean := False) return Compare_Result;
 156    --  This version of Compile_Time_Compare returns extra information if the
 157    --  result is GT or LT. In these cases, if the magnitude of the difference
 158    --  can be determined at compile time, this (positive) magnitude is returned
 159    --  in Diff.all. If the magnitude of the difference cannot be determined
 160    --  then Diff.all contains No_Uint on return. Rec is a parameter that is set
 161    --  True for a recursive call from within Compile_Time_Compare to avoid some
 162    --  infinite recursion cases. It should never be set by a client.
 163
 164    procedure Flag_Non_Static_Expr (Msg : String; Expr : Node_Id);
 165    --  This procedure is called after it has been determined that Expr is not
 166    --  static when it is required to be. Msg is the text of a message that
 167    --  explains the error. This procedure checks if an error is already posted
 168    --  on Expr, if so, it does nothing unless All_Errors_Mode is set in which
 169    --  case this flag is ignored. Otherwise the given message is posted using
 170    --  Error_Msg_F, and then Why_Not_Static is called on Expr to generate
 171    --  additional messages. The string given as Msg should end with ! to make
 172    --  it an unconditional message, to ensure that if it is posted, the entire
 173    --  set of messages is all posted.
 174
 175    function Is_OK_Static_Expression (N : Node_Id) return Boolean;
 176    --  An OK static expression is one that is static in the RM definition sense
 177    --  and which does not raise constraint error. For most legality checking
 178    --  purposes you should use Is_Static_Expression. For those legality checks
 179    --  where the expression N should not raise constraint error use this
 180    --  routine. This routine is *not* to be used in contexts where the test is
 181    --  for compile time evaluation purposes. Use Compile_Time_Known_Value
 182    --  instead (see section on "Compile-Time Known Values" above).
 183
 184    function Is_Static_Range (N : Node_Id) return Boolean;
 185    --  Determine if range is static, as defined in RM 4.9(26). The only allowed
 186    --  argument is an N_Range node (but note that the semantic analysis of
 187    --  equivalent range attribute references already turned them into the
 188    --  equivalent range).
 189
 190    function Is_OK_Static_Range (N : Node_Id) return Boolean;
 191    --  Like Is_Static_Range, but also makes sure that the bounds of the range
 192    --  are compile-time evaluable (i.e. do not raise constraint error). A
 193    --  result of true means that the bounds are compile time evaluable. A
 194    --  result of false means they are not (either because the range is not
 195    --  static, or because one or the other bound raises CE).
 196
 197    function Is_Static_Subtype (Typ : Entity_Id) return Boolean;
 198    --  Determines whether a subtype fits the definition of an Ada static
 199    --  subtype as given in (RM 4.9(26)). Important note: This check does not
 200    --  include the Ada 2012 case of a non-static predicate which results in an
 201    --  otherwise static subtype being non-static. Such a subtype will return
 202    --  True for this test, so if the distinction is important, the caller must
 203    --  deal with this.
 204    --
 205    --  Implementation note: an attempt to include this Ada 2012 case failed,
 206    --  since it appears that this routine is called in some cases before the
 207    --  Static_Predicate field is set ???
 208
 209    function Is_OK_Static_Subtype (Typ : Entity_Id) return Boolean;
 210    --  Like Is_Static_Subtype but also makes sure that the bounds of the
 211    --  subtype are compile-time evaluable (i.e. do not raise constraint error).
 212    --  A result of true means that the bounds are compile time evaluable. A
 213    --  result of false means they are not (either because the range is not
 214    --  static, or because one or the other bound raises CE).
 215
 216    function Subtypes_Statically_Compatible
 217      (T1                      : Entity_Id;
 218       T2                      : Entity_Id;
 219       Formal_Derived_Matching : Boolean := False) return Boolean;
 220    --  Returns true if the subtypes are unconstrained or the constraint on
 221    --  on T1 is statically compatible with T2 (as defined by 4.9.1(4)).
 222    --  Otherwise returns false. Formal_Derived_Matching indicates whether
 223    --  the type T1 is a generic actual being checked against ancestor T2
 224    --  in a formal derived type association.
 225
 226    function Subtypes_Statically_Match
 227      (T1                      : Entity_Id;
 228       T2                      : Entity_Id;
 229       Formal_Derived_Matching : Boolean := False) return Boolean;
 230    --  Determine whether two types T1, T2, which have the same base type,
 231    --  are statically matching subtypes (RM 4.9.1(1-2)). Also includes the
 232    --  extra GNAT rule that object sizes must match (this can be false for
 233    --  types that match in the RM sense because of use of 'Object_Size),
 234    --  except when testing a generic actual T1 against an ancestor T2 in a
 235    --  formal derived type association (indicated by Formal_Derived_Matching).
 236
 237    function Compile_Time_Known_Value (Op : Node_Id) return Boolean;
 238    --  Returns true if Op is an expression not raising Constraint_Error whose
 239    --  value is known at compile time and for which a call to Expr_Value can
 240    --  be used to determine this value. This is always true if Op is a static
 241    --  expression, but can also be true for expressions which are technically
 242    --  non-static but which are in fact known at compile time. Some examples of
 243    --  such expressions are the static lower bound of a non-static range or the
 244    --  value of a constant object whose initial value is itself compile time
 245    --  known in the sense of this routine. Note that this routine is defended
 246    --  against unanalyzed expressions. Such expressions will not cause a
 247    --  blowup, they may cause pessimistic (i.e. False) results to be returned.
 248    --  In general we take a pessimistic view. False does not mean the value
 249    --  could not be known at compile time, but True means that absolutely
 250    --  definition it is known at compile time and it is safe to call
 251    --  Expr_Value on the expression Op.
 252    --
 253    --  Note that we don't define precisely the set of expressions that return
 254    --  True. Callers should not make any assumptions regarding the value that
 255    --  is returned for non-static expressions. Functional behavior should never
 256    --  be affected by whether a given non-static expression returns True or
 257    --  False when this function is called. In other words this is purely for
 258    --  efficiency optimization purposes. The code generated can often be more
 259    --  efficient with compile time known values, e.g. range analysis for the
 260    --  purpose of removing checks is more effective if we know precise bounds.
 261
 262    function CRT_Safe_Compile_Time_Known_Value (Op : Node_Id) return Boolean;
 263    --  In the case of configurable run-times, there may be an issue calling
 264    --  Compile_Time_Known_Value with non-static expressions where the legality
 265    --  of the program is not well-defined. Consider this example:
 266    --
 267    --    X := B ** C;
 268    --
 269    --  Now if C is compile time known, and has the value 4, then inline code
 270    --  can be generated at compile time, instead of calling a run-time routine.
 271    --  That's fine in the normal case, but when we have a configurable run-time
 272    --  the run-time routine may not be available. This means that the program
 273    --  will be rejected if C is not known at compile time. We don't want the
 274    --  legality of a program to depend on how clever the implementation of this
 275    --  function is. If the run-time in use lacks the exponentiation routine,
 276    --  then what we say is that exponentiation is permitted if the exponent is
 277    --  officially static and has a value in the range 0 .. 4.
 278    --
 279    --  In a case like this, we use CRT_Safe_Compile_Time_Known_Value to avoid
 280    --  this effect. This routine will return False for a non-static expression
 281    --  if we are in configurable run-time mode, even if the expression would
 282    --  normally be considered compile-time known.
 283
 284    function Compile_Time_Known_Value_Or_Aggr (Op : Node_Id) return Boolean;
 285    --  Similar to Compile_Time_Known_Value, but also returns True if the value
 286    --  is a compile-time-known aggregate, i.e. an aggregate all of whose
 287    --  constituent expressions are either compile-time-known values (based on
 288    --  calling Compile_Time_Known_Value) or compile-time-known aggregates.
 289    --  Note that the aggregate could still involve run-time checks that might
 290    --  fail (such as for subtype checks in component associations), but the
 291    --  evaluation of the expressions themselves will not raise an exception.
 292
 293    function Compile_Time_Known_Bounds (T : Entity_Id) return Boolean;
 294    --  If T is an array whose index bounds are all known at compile time, then
 295    --  True is returned. If T is not an array type, or one or more of its index
 296    --  bounds is not known at compile time, then False is returned.
 297
 298    function Expr_Value (N : Node_Id) return Uint;
 299    --  Returns the folded value of the expression N. This function is called in
 300    --  instances where it has already been determined that the expression is
 301    --  static or its value is compile time known (Compile_Time_Known_Value (N)
 302    --  returns True). This version is used for integer values, and enumeration
 303    --  or character literals. In the latter two cases, the value returned is
 304    --  the Pos value in the relevant enumeration type. It can also be used for
 305    --  fixed-point values, in which case it returns the corresponding integer
 306    --  value. It cannot be used for floating-point values.
 307
 308    function Expr_Value_E (N : Node_Id) return Entity_Id;
 309    --  Returns the folded value of the expression. This function is called in
 310    --  instances where it has already been determined that the expression is
 311    --  static or its value known at compile time. This version is used for
 312    --  enumeration types and returns the corresponding enumeration literal.
 313
 314    function Expr_Value_R (N : Node_Id) return Ureal;
 315    --  Returns the folded value of the expression. This function is called in
 316    --  instances where it has already been determined that the expression is
 317    --  static or its value known at compile time. This version is used for real
 318    --  values (including both the floating-point and fixed-point cases). In the
 319    --  case of a fixed-point type, the real value is returned (cf above version
 320    --  returning Uint).
 321
 322    function Expr_Value_S (N : Node_Id) return Node_Id;
 323    --  Returns the folded value of the expression. This function is called
 324    --  in instances where it has already been determined that the expression
 325    --  is static or its value is known at compile time. This version is used
 326    --  for string types and returns the corresponding N_String_Literal node.
 327
 328    function Expr_Rep_Value (N : Node_Id) return Uint;
 329    --  This is identical to Expr_Value, except in the case of enumeration
 330    --  literals of types for which an enumeration representation clause has
 331    --  been given, in which case it returns the representation value rather
 332    --  than the pos value. This is the value that is needed for generating code
 333    --  sequences, while the Expr_Value value is appropriate for compile time
 334    --  constraint errors or getting the logical value. Note that this function
 335    --  does NOT concern itself with biased values, if the caller needs a
 336    --  properly biased value, the subtraction of the bias must be handled
 337    --  explicitly.
 338
 339    procedure Eval_Actual                 (N : Node_Id);
 340    procedure Eval_Allocator              (N : Node_Id);
 341    procedure Eval_Arithmetic_Op          (N : Node_Id);
 342    procedure Eval_Call                   (N : Node_Id);
 343    procedure Eval_Case_Expression        (N : Node_Id);
 344    procedure Eval_Character_Literal      (N : Node_Id);
 345    procedure Eval_Concatenation          (N : Node_Id);
 346    procedure Eval_Entity_Name            (N : Node_Id);
 347    procedure Eval_If_Expression          (N : Node_Id);
 348    procedure Eval_Indexed_Component      (N : Node_Id);
 349    procedure Eval_Integer_Literal        (N : Node_Id);
 350    procedure Eval_Logical_Op             (N : Node_Id);
 351    procedure Eval_Membership_Op          (N : Node_Id);
 352    procedure Eval_Named_Integer          (N : Node_Id);
 353    procedure Eval_Named_Real             (N : Node_Id);
 354    procedure Eval_Op_Expon               (N : Node_Id);
 355    procedure Eval_Op_Not                 (N : Node_Id);
 356    procedure Eval_Real_Literal           (N : Node_Id);
 357    procedure Eval_Relational_Op          (N : Node_Id);
 358    procedure Eval_Shift                  (N : Node_Id);
 359    procedure Eval_Short_Circuit          (N : Node_Id);
 360    procedure Eval_Slice                  (N : Node_Id);
 361    procedure Eval_String_Literal         (N : Node_Id);
 362    procedure Eval_Qualified_Expression   (N : Node_Id);
 363    procedure Eval_Type_Conversion        (N : Node_Id);
 364    procedure Eval_Unary_Op               (N : Node_Id);
 365    procedure Eval_Unchecked_Conversion   (N : Node_Id);
 366
 367    function Eval_Static_Predicate_Check
 368      (N  : Node_Id;
 369      Typ : Entity_Id) return Boolean;
 370    --  Evaluate a static predicate check applied to a scalar literal
 371
 372    procedure Fold_Str (N : Node_Id; Val : String_Id; Static : Boolean);
 373    --  Rewrite N with a new N_String_Literal node as the result of the compile
 374    --  time evaluation of the node N. Val is the resulting string value from
 375    --  the folding operation. The Is_Static_Expression flag is set in the
 376    --  result node. The result is fully analyzed and resolved. Static indicates
 377    --  whether the result should be considered static or not (True = consider
 378    --  static). The point here is that normally all string literals are static,
 379    --  but if this was the result of some sequence of evaluation where values
 380    --  were known at compile time but not static, then the result is not
 381    --  static.
 382
 383    procedure Fold_Uint (N : Node_Id; Val : Uint; Static : Boolean);
 384    --  Rewrite N with a (N_Integer_Literal, N_Identifier, N_Character_Literal)
 385    --  node as the result of the compile time evaluation of the node N. Val is
 386    --  the result in the integer case and is the position of the literal in the
 387    --  literals list for the enumeration case. Is_Static_Expression is set True
 388    --  in the result node. The result is fully analyzed/resolved. Static
 389    --  indicates whether the result should be considered static or not (True =
 390    --  consider static). The point here is that normally all integer literals
 391    --  are static, but if this was the result of some sequence of evaluation
 392    --  where values were known at compile time but not static, then the result
 393    --  is not static.
 394
 395    procedure Fold_Ureal (N : Node_Id; Val : Ureal; Static : Boolean);
 396    --  Rewrite N with a new N_Real_Literal node as the result of the compile
 397    --  time evaluation of the node N. Val is the resulting real value from the
 398    --  folding operation. The Is_Static_Expression flag is set in the result
 399    --  node. The result is fully analyzed and result. Static indicates whether
 400    --  the result should be considered static or not (True = consider static).
 401    --  The point here is that normally all string literals are static, but if
 402    --  this was the result of some sequence of evaluation where values were
 403    --  known at compile time but not static, then the result is not static.
 404
 405    function Is_In_Range
 406      (N            : Node_Id;
 407       Typ          : Entity_Id;
 408       Assume_Valid : Boolean := False;
 409       Fixed_Int    : Boolean := False;
 410       Int_Real     : Boolean := False) return Boolean;
 411    --  Returns True if it can be guaranteed at compile time that expression is
 412    --  known to be in range of the subtype Typ. A result of False does not mean
 413    --  that the expression is out of range, merely that it cannot be determined
 414    --  at compile time that it is in range. If Typ is a floating point type or
 415    --  Int_Real is set, any integer value is treated as though it was a real
 416    --  value (i.e. the underlying real value is used). In this case we use the
 417    --  corresponding real value, both for the bounds of Typ, and for the value
 418    --  of the expression N. If Typ is a fixed type or a discrete type and
 419    --  Int_Real is False but flag Fixed_Int is True then any fixed-point value
 420    --  is treated as though it was discrete value (i.e. the underlying integer
 421    --  value is used). In this case we use the corresponding integer value,
 422    --  both for the bounds of Typ, and for the value of the expression N. If
 423    --  Typ is a discrete type and Fixed_Int as well as Int_Real are false,
 424    --  integer values are used throughout.
 425    --
 426    --  If Assume_Valid is set True, then N is always assumed to contain a valid
 427    --  value. If Assume_Valid is set False, then N may be invalid (unless there
 428    --  is some independent way of knowing that it is valid, i.e. either it is
 429    --  an entity with Is_Known_Valid set, or Assume_No_Invalid_Values is True.
 430
 431    function Is_Out_Of_Range
 432      (N            : Node_Id;
 433       Typ          : Entity_Id;
 434       Assume_Valid : Boolean := False;
 435       Fixed_Int    : Boolean := False;
 436       Int_Real     : Boolean := False) return Boolean;
 437    --  Returns True if it can be guaranteed at compile time that expression is
 438    --  known to be out of range of the subtype Typ. True is returned if Typ is
 439    --  a scalar type, and the value of N can be determined to be outside the
 440    --  range of Typ. A result of False does not mean that the expression is in
 441    --  range, but rather merely that it cannot be determined at compile time
 442    --  that it is out of range. The parameters Assume_Valid, Fixed_Int, and
 443    --  Int_Real are as described for Is_In_Range above.
 444
 445    function In_Subrange_Of
 446      (T1        : Entity_Id;
 447       T2        : Entity_Id;
 448       Fixed_Int : Boolean := False) return Boolean;
 449    --  Returns True if it can be guaranteed at compile time that the range of
 450    --  values for scalar type T1 are always in the range of scalar type T2. A
 451    --  result of False does not mean that T1 is not in T2's subrange, only that
 452    --  it cannot be determined at compile time. Flag Fixed_Int is used as in
 453    --  routine Is_In_Range above.
 454
 455    function Is_Null_Range (Lo : Node_Id; Hi : Node_Id) return Boolean;
 456    --  Returns True if it can guarantee that Lo .. Hi is a null range. If it
 457    --  cannot (because the value of Lo or Hi is not known at compile time) then
 458    --  it returns False.
 459
 460    function Not_Null_Range (Lo : Node_Id; Hi : Node_Id) return Boolean;
 461    --  Returns True if it can guarantee that Lo .. Hi is not a null range. If
 462    --  it cannot (because the value of Lo or Hi is not known at compile time)
 463    --  then it returns False.
 464
 465    function Predicates_Match (T1, T2 : Entity_Id) return Boolean;
 466    --  In Ada 2012, subtypes statically match if their static predicates
 467    --  match as well. This function performs the required check that
 468    --  predicates match. Separated out from Subtypes_Statically_Match so
 469    --  that it can be used in specializing error messages.
 470
 471    procedure Why_Not_Static (Expr : Node_Id);
 472    --  This procedure may be called after generating an error message that
 473    --  complains that something is non-static. If it finds good reasons,
 474    --  it generates one or more continuation error messages pointing the
 475    --  appropriate offending component of the expression. If no good reasons
 476    --  can be figured out, then no messages are generated. The expectation here
 477    --  is that the caller has already issued a message complaining that the
 478    --  expression is non-static. Note that this message should be placed using
 479    --  Error_Msg_F or Error_Msg_FE, so that it will sort before any messages
 480    --  placed by this call. Note that it is fine to call Why_Not_Static with
 481    --  something that is not an expression, and usually this has no effect, but
 482    --  in some cases (N_Parameter_Association or N_Range), it makes sense for
 483    --  the internal recursive calls.
 484
 485    procedure Initialize;
 486    --  Initializes the internal data structures. Must be called before each
 487    --  separate main program unit (e.g. in a GNSA/ASIS context).
 488
 489 private
 490    --  The Eval routines are all marked inline, since they are called once
 491
 492    pragma Inline (Eval_Actual);
 493    pragma Inline (Eval_Allocator);
 494    pragma Inline (Eval_Character_Literal);
 495    pragma Inline (Eval_If_Expression);
 496    pragma Inline (Eval_Indexed_Component);
 497    pragma Inline (Eval_Named_Integer);
 498    pragma Inline (Eval_Named_Real);
 499    pragma Inline (Eval_Real_Literal);
 500    pragma Inline (Eval_Shift);
 501    pragma Inline (Eval_Slice);
 502    pragma Inline (Eval_String_Literal);
 503    pragma Inline (Eval_Unchecked_Conversion);
 504
 505    pragma Inline (Is_OK_Static_Expression);
 506
 507 end Sem_Eval;