libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=7:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AC_SUBST(GOOS)
 176
 177 dnl Test whether we need to use DejaGNU or whether we can use the
 178 dnl simpler gotest approach.  We can only use gotest for a native
 179 dnl build.
 180 USE_DEJAGNU=no
 181 case ${host} in
 182   *-*-rtems*) USE_DEJAGNU=yes ;;
 183   ${build}) ;;
 184   *) USE_DEJAGNU=yes ;;
 185 esac
 186 AC_SUBST(USE_DEJAGNU)
 187
 188 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 189 is_386=no
 190 is_alpha=no
 191 is_arm=no
 192 is_arm64=no
 193 is_m68k=no
 194 mips_abi=unknown
 195 is_ppc=no
 196 is_ppc64=no
 197 is_ppc64le=no
 198 is_s390=no
 199 is_s390x=no
 200 is_sparc=no
 201 is_sparc64=no
 202 is_x86_64=no
 203 GOARCH=unknown
 204 case ${host} in
 205   alpha*-*-*)
 206     is_alpha=yes
 207     GOARCH=alpha
 208     ;;
 209   aarch64-*-*)
 210     is_arm64=yes
 211     GOARCH=arm64
 212     ;;
 213   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 214     is_arm=yes
 215     GOARCH=arm
 216     ;;
 217 changequote(,)dnl
 218   i[34567]86-*-* | x86_64-*-*)
 219 changequote([,])dnl
 220     AC_COMPILE_IFELSE([
 221 #ifdef __x86_64__
 222 #error 64-bit
 223 #endif],
 224 [is_386=yes], [is_x86_64=yes])
 225     if test "$is_386" = "yes"; then
 226       GOARCH=386
 227     else
 228       GOARCH=amd64
 229     fi
 230     ;;
 231   m68k*-*-*)
 232     is_m68k=yes
 233     GOARCH=m68k
 234     ;;
 235   mips*-*-*)
 236     AC_COMPILE_IFELSE([
 237 #if _MIPS_SIM != _ABIO32
 238 #error not o32
 239 #endif],
 240 [mips_abi="o32"],
 241         [AC_COMPILE_IFELSE([
 242 #if _MIPS_SIM != _ABIN32
 243 #error not n32
 244 #endif],
 245 [mips_abi="n32"],
 246         [AC_COMPILE_IFELSE([
 247 #if _MIPS_SIM != _ABI64
 248 #error not n64
 249 #endif],
 250 [mips_abi="n64"],
 251         [AC_COMPILE_IFELSE([
 252 #if _MIPS_SIM != _ABIO64
 253 #error not o64
 254 #endif],
 255 [mips_abi="o64"],
 256         [AC_MSG_ERROR([unknown MIPS ABI])
 257 [mips_abi="n32"]])])])])
 258     case "$mips_abi" in
 259     "o32") GOARCH=mipso32 ;;
 260     "n32") GOARCH=mipsn32 ;;
 261     "n64") GOARCH=mipsn64 ;;
 262     "o64") GOARCH=mipso64 ;;
 263     esac
 264     ;;
 265   rs6000*-*-* | powerpc*-*-*)
 266     AC_COMPILE_IFELSE([
 267 #ifdef _ARCH_PPC64
 268 #error 64-bit
 269 #endif],
 270 [is_ppc=yes],
 271     [AC_COMPILE_IFELSE([
 272 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 273 #error 64be
 274 #endif],
 275 [is_ppc64le=yes],[is_ppc64=yes])])
 276     if test "$is_ppc" = "yes"; then
 277       GOARCH=ppc
 278     elif test "$is_ppc64" = "yes"; then
 279       GOARCH=ppc64
 280     else
 281       GOARCH=ppc64le
 282     fi
 283     ;;
 284   s390*-*-*)
 285     AC_COMPILE_IFELSE([
 286 #if defined(__s390x__)
 287 #error 64-bit
 288 #endif],
 289 [is_s390=yes], [is_s390x=yes])
 290     if test "$is_s390" = "yes"; then
 291       GOARCH=s390
 292     else
 293       GOARCH=s390x
 294     fi
 295     ;;
 296   sparc*-*-*)
 297     AC_COMPILE_IFELSE([
 298 #if defined(__sparcv9) || defined(__arch64__)
 299 #error 64-bit
 300 #endif],
 301 [is_sparc=yes], [is_sparc64=yes])
 302     if test "$is_sparc" = "yes"; then
 303       GOARCH=sparc
 304     else
 305       GOARCH=sparc64
 306     fi
 307     ;;
 308 esac
 309 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 310 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 311 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 312 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 313 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 314 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 315 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 316 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 317 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 318 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 319 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 320 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 321 AM_CONDITIONAL(LIBGO_IS_PPC64LE, test $is_ppc64le = yes)
 322 AM_CONDITIONAL(LIBGO_IS_S390, test $is_s390 = yes)
 323 AM_CONDITIONAL(LIBGO_IS_S390X, test $is_s390x = yes)
 324 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 325 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 326 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 327 AC_SUBST(GOARCH)
 328
 329 dnl Some files are only present when needed for specific architectures.
 330 GO_LIBCALL_OS_FILE=
 331 GO_LIBCALL_OS_ARCH_FILE=
 332 GO_SYSCALL_OS_FILE=
 333 GO_SYSCALL_OS_ARCH_FILE=
 334 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 335   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 336 fi
 337 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 338   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 339 fi
 340 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 341   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 342 fi
 343 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 344   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 345 fi
 346 AC_SUBST(GO_LIBCALL_OS_FILE)
 347 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 348 AC_SUBST(GO_SYSCALL_OS_FILE)
 349 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 350
 351 dnl Special flags used to generate sysinfo.go.
 352 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 353 case "$target" in
 354     mips-sgi-irix6.5*)
 355         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 356         # msghdr in <sys/socket.h>.
 357         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 358         ;;
 359     *-*-solaris2.1[[01]])
 360         # Solaris 10+ needs this so struct msghdr gets the msg_control
 361         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 362         # above doesn't work with C99.
 363         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 364         ;;
 365 esac
 366 AC_SUBST(OSCFLAGS)
 367
 368 dnl Use -fsplit-stack when compiling C code if available.
 369 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 370 [libgo_cv_c_split_stack_supported],
 371 [CFLAGS_hold=$CFLAGS
 372 CFLAGS="$CFLAGS -fsplit-stack"
 373 AC_COMPILE_IFELSE([[int i;]],
 374 [libgo_cv_c_split_stack_supported=yes],
 375 [libgo_cv_c_split_stack_supported=no])
 376 CFLAGS=$CFLAGS_hold])
 377
 378 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 379 dnl reject split-stack code calling non-split-stack code on targets
 380 dnl they don't support.
 381 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 382 [libgo_cv_c_linker_split_non_split],
 383 [cat > conftest1.c << EOF
 384 extern void f();
 385 int main() { f(); return 0; }
 386 EOF
 387 cat > conftest2.c << EOF
 388 void f() {}
 389 EOF
 390 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c
 391 $CC -c $CFLAGS $CPPFLAGS conftest2.c
 392 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext; then
 393   libgo_cv_c_linker_split_non_split=yes
 394 else
 395   libgo_cv_c_linker_split_non_split=no
 396 fi
 397 rm -f conftest1.* conftest2.* conftest])
 398
 399 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 400   SPLIT_STACK=-fsplit-stack
 401   AC_DEFINE(USING_SPLIT_STACK, 1,
 402                 [Define if the compiler supports -fsplit-stack])
 403 else
 404   SPLIT_STACK=
 405 fi
 406 AC_SUBST(SPLIT_STACK)
 407 AM_CONDITIONAL(USING_SPLIT_STACK,
 408         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 409
 410 dnl If the compiler supports split-stack but the linker does not, then
 411 dnl we need to explicitly disable split-stack for Go.
 412 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 413   GO_SPLIT_STACK=-fno-split-stack
 414 else
 415   GO_SPLIT_STACK=
 416 fi
 417 AC_SUBST(GO_SPLIT_STACK)
 418
 419 dnl Check whether the linker does stack munging when calling from
 420 dnl split-stack into non-split-stack code.  We check this by looking
 421 dnl at the --help output.  FIXME: This is only half right: it's
 422 dnl possible for the linker to support this for some targets but not
 423 dnl others.
 424 dnl This is slightly different from the above check, which is whether
 425 dnl the linker permits the call at all.
 426 AC_CACHE_CHECK([whether linker supports split stack],
 427 [libgo_cv_c_linker_supports_split_stack],
 428 [libgo_cv_c_linker_supports_split_stack=no
 429 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 430   libgo_cv_c_linker_supports_split_stack=yes
 431 fi])
 432 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 433   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 434             [Define if the linker support split stack adjustments])
 435 fi
 436
 437 AC_CACHE_CHECK([whether compiler is llgo],
 438 [libgo_cv_c_goc_is_llgo],
 439 [libgo_cv_c_goc_is_llgo=no
 440 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 441   libgo_cv_c_goc_is_llgo=yes
 442 fi])
 443 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 444
 445 dnl Test for the -lm library.
 446 MATH_LIBS=
 447 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 448 AC_SUBST(MATH_LIBS)
 449
 450 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 451 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 452   [libgo_cv_lib_sockets=
 453    libgo_check_both=no
 454    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 455    if test "$libgo_check_socket" = "yes"; then
 456      unset ac_cv_func_connect
 457      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 458                   libgo_check_both=yes)
 459    fi
 460    if test "$libgo_check_both" = "yes"; then
 461      libgo_old_libs=$LIBS
 462      LIBS="$LIBS -lsocket -lnsl"
 463      unset ac_cv_func_accept
 464      AC_CHECK_FUNC(accept,
 465                    [libgo_check_nsl=no
 466                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 467      unset ac_cv_func_accept
 468      LIBS=$libgo_old_libs
 469    fi
 470    unset ac_cv_func_gethostbyname
 471    libgo_old_libs="$LIBS"
 472    AC_CHECK_FUNC(gethostbyname, ,
 473                  [AC_CHECK_LIB(nsl, main,
 474                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 475    unset ac_cv_func_gethostbyname
 476    LIBS=$libgo_old_libs
 477 ])
 478 NET_LIBS="$libgo_cv_lib_sockets"
 479 AC_SUBST(NET_LIBS)
 480
 481 dnl Test whether the compiler supports the -pthread option.
 482 AC_CACHE_CHECK([whether -pthread is supported],
 483 [libgo_cv_lib_pthread],
 484 [CFLAGS_hold=$CFLAGS
 485 CFLAGS="$CFLAGS -pthread"
 486 AC_COMPILE_IFELSE([[int i;]],
 487 [libgo_cv_lib_pthread=yes],
 488 [libgo_cv_lib_pthread=no])
 489 CFLAGS=$CFLAGS_hold])
 490 PTHREAD_CFLAGS=
 491 if test "$libgo_cv_lib_pthread" = yes; then
 492   PTHREAD_CFLAGS=-pthread
 493 fi
 494 AC_SUBST(PTHREAD_CFLAGS)
 495
 496 dnl Test for the -lpthread library.
 497 PTHREAD_LIBS=
 498 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 499 AC_SUBST(PTHREAD_LIBS)
 500
 501 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 502 AC_SEARCH_LIBS([sched_yield], [rt])
 503 AC_SEARCH_LIBS([nanosleep], [rt])
 504
 505 AC_C_BIGENDIAN
 506
 507 GCC_CHECK_UNWIND_GETIPINFO
 508
 509 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 510
 511 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 512 [#ifdef HAVE_SYS_SOCKET_H
 513 #include <sys/socket.h>
 514 #endif
 515 ])
 516
 517 AC_CACHE_CHECK([whether <ustat.h> can be used],
 518 [libgo_cv_c_ustat_h],
 519 [CFLAGS_hold=$CFLAGS
 520 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 521 AC_COMPILE_IFELSE(
 522 [AC_LANG_SOURCE([
 523 #include <sys/types.h>
 524 #ifdef HAVE_LINUX_FILTER_H
 525 #include <linux/filter.h>
 526 #endif
 527 #include <ustat.h>
 528 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 529 CFLAGS=$CFLAGS_hold])
 530 if test $libgo_cv_c_ustat_h = yes; then
 531   AC_DEFINE(HAVE_USTAT_H, 1,
 532     [Define to 1 if you have the <ustat.h> header file and it works.])
 533 fi
 534
 535 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 536
 537 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 538 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 539 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 540
 541 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 542 AC_TYPE_OFF_T
 543 AC_CHECK_TYPES([loff_t])
 544
 545 LIBS_hold="$LIBS"
 546 LIBS="$LIBS -lm"
 547 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 548 LIBS="$LIBS_hold"
 549
 550 CFLAGS_hold="$CFLAGS"
 551 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 552 LIBS_hold="$LIBS"
 553 LIBS="$LIBS $PTHREAD_LIBS"
 554 AC_CHECK_FUNCS(sem_timedwait)
 555 CFLAGS="$CFLAGS_hold"
 556 LIBS="$LIBS_hold"
 557
 558 LIBS_hold="$LIBS"
 559 LIBS="$LIBS $MATH_LIBS"
 560 AC_CHECK_FUNCS(matherr)
 561 LIBS="$LIBS_hold"
 562
 563 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 564 [libgo_cv_func___sync_bool_compare_and_swap_4],
 565 [AC_LINK_IFELSE([
 566 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 567 uint32 i;
 568 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 569 ],
 570 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 571 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 572 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 573   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 574     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 575 fi
 576
 577 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 578 [libgo_cv_func___sync_bool_compare_and_swap_8],
 579 [AC_LINK_IFELSE([
 580 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 581 uint64 i;
 582 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 583 ],
 584 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 585 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 586 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 587   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 588     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 589 fi
 590
 591 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 592 [libgo_cv_func___sync_fetch_and_add_4],
 593 [AC_LINK_IFELSE([
 594 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 595 uint32 i;
 596 int main() { return __sync_fetch_and_add (&i, 1); }
 597 ],
 598 [libgo_cv_func___sync_fetch_and_add_4=yes],
 599 [libgo_cv_func___sync_fetch_and_add_4=no])])
 600 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 601   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 602     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 603 fi
 604
 605 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 606 [libgo_cv_func___sync_add_and_fetch_8],
 607 [AC_LINK_IFELSE([
 608 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 609 uint64 i;
 610 int main() { return __sync_add_and_fetch (&i, 1); }
 611 ],
 612 [libgo_cv_func___sync_add_and_fetch_8=yes],
 613 [libgo_cv_func___sync_add_and_fetch_8=no])])
 614 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 615   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 616     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 617 fi
 618
 619 dnl For x86 we want to use the -minline-all-stringops option to avoid
 620 dnl forcing a stack split when calling memcpy and friends.
 621 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 622 [libgo_cv_c_stringops],
 623 [CFLAGS_hold=$CFLAGS
 624 CFLAGS="$CFLAGS -minline-all-stringops"
 625 AC_COMPILE_IFELSE([int i;],
 626 [libgo_cv_c_stringops=yes],
 627 [libgo_cv_c_stringops=no])
 628 CFLAGS=$CFLAGS_hold])
 629 STRINGOPS_FLAG=
 630 if test "$libgo_cv_c_stringops" = yes; then
 631   STRINGOPS_FLAG=-minline-all-stringops
 632 fi
 633 AC_SUBST(STRINGOPS_FLAG)
 634
 635 dnl For x86 we want to compile the math library with -mfancy-math-387
 636 dnl -funsafe-math-optimizations so that we can use the builtin
 637 dnl instructions directly.
 638 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 639 [libgo_cv_c_fancymath],
 640 [CFLAGS_hold=$CFLAGS
 641 CFLAGS="$CFLAGS -mfancy-math-387"
 642 AC_COMPILE_IFELSE([int i;],
 643 [libgo_cv_c_fancymath=yes],
 644 [libgo_cv_c_fancymath=no])
 645 CFLAGS=$CFLAGS_hold])
 646 MATH_FLAG=
 647 if test "$libgo_cv_c_fancymath" = yes; then
 648   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 649 else
 650   MATH_FLAG="-ffp-contract=off"
 651 fi
 652 AC_SUBST(MATH_FLAG)
 653
 654 CFLAGS_hold=$CFLAGS
 655 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 656 AC_CHECK_TYPES([off64_t])
 657 CFLAGS=$CFLAGS_hold
 658
 659 dnl Work out the size of the epoll_events struct on GNU/Linux.
 660 AC_CACHE_CHECK([epoll_event size],
 661 [libgo_cv_c_epoll_event_size],
 662 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 663 [sizeof (struct epoll_event)],
 664 [#include <sys/epoll.h>],
 665 [libgo_cv_c_epoll_event_size=0])])
 666 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 667 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 668
 669 dnl Work out the offset of the fd field in the epoll_events struct on
 670 dnl GNU/Linux.
 671 AC_CACHE_CHECK([epoll_event data.fd offset],
 672 [libgo_cv_c_epoll_event_fd_offset],
 673 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 674 [offsetof (struct epoll_event, data.fd)],
 675 [#include <stddef.h>
 676 #include <sys/epoll.h>],
 677 [libgo_cv_c_epoll_event_fd_offset=0])])
 678 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 679 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 680
 681 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 682 dnl in Solaris 12 for XPG7 compatibility.
 683 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 684                 [have_stat_timespec=yes], [have_stat_timespec=no])
 685 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 686
 687 dnl See if struct exception is defined in <math.h>.
 688 AC_CHECK_TYPE([struct exception],
 689 [libgo_has_struct_exception=yes],
 690 [libgo_has_struct_exception=no],
 691 [#include <math.h>])
 692 if test "$libgo_has_struct_exception" = "yes"; then
 693   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 694             [Define to 1 if <math.h> defines struct exception])
 695 fi
 696
 697 dnl See whether setcontext changes the value of TLS variables.
 698 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 699 [libgo_cv_lib_setcontext_clobbers_tls],
 700 [CFLAGS_hold="$CFLAGS"
 701 CFLAGS="$PTHREAD_CFLAGS"
 702 LIBS_hold="$LIBS"
 703 LIBS="$LIBS $PTHREAD_LIBS"
 704 AC_CHECK_SIZEOF([void *])
 705 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 706 AC_RUN_IFELSE(
 707   [AC_LANG_SOURCE([
 708 #include <pthread.h>
 709 #include <stdlib.h>
 710 #include <ucontext.h>
 711 #include <unistd.h>
 712
 713 __thread int tls;
 714
 715 static char stack[[10 * 1024 * 1024]];
 716 static ucontext_t c;
 717
 718 /* Called via makecontext/setcontext.  */
 719
 720 static void
 721 cfn (void)
 722 {
 723   exit (tls);
 724 }
 725
 726 /* Called via pthread_create.  */
 727
 728 static void *
 729 tfn (void *dummy)
 730 {
 731   /* The thread should still see this value after calling
 732      setcontext.  */
 733   tls = 0;
 734
 735   setcontext (&c);
 736
 737   /* The call to setcontext should not return.  */
 738   abort ();
 739 }
 740
 741 int
 742 main ()
 743 {
 744   pthread_t tid;
 745
 746   /* The thread should not see this value.  */
 747   tls = 1;
 748
 749   if (getcontext (&c) < 0)
 750     abort ();
 751
 752   c.uc_stack.ss_sp = stack;
 753 #ifdef MAKECONTEXT_STACK_TOP
 754   c.uc_stack.ss_sp += sizeof stack;
 755 #endif
 756   c.uc_stack.ss_flags = 0;
 757   c.uc_stack.ss_size = sizeof stack;
 758   c.uc_link = NULL;
 759   makecontext (&c, cfn, 0);
 760
 761   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 762     abort ();
 763
 764   if (pthread_join (tid, NULL) != 0)
 765     abort ();
 766
 767   /* The thread should have called exit.  */
 768   abort ();
 769 }
 770 ])],
 771 [libgo_cv_lib_setcontext_clobbers_tls=no],
 772 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 773 [case "$target:$ptr_type_size" in
 774   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 775     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 776   *)
 777     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 778  esac
 779 ])
 780 CFLAGS="$CFLAGS_hold"
 781 LIBS="$LIBS_hold"
 782 ])
 783 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 784   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 785             [Define if setcontext clobbers TLS variables])
 786 fi
 787
 788 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 789 libgo_cv_ro_eh_frame, [
 790 libgo_cv_ro_eh_frame=no
 791 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 792 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 793   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 794     libgo_cv_ro_eh_frame=yes
 795   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 796        | grep -v '#write' > /dev/null; then
 797     libgo_cv_ro_eh_frame=yes
 798   fi
 799 fi
 800 rm -f conftest.*
 801 ])
 802 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 803   AC_DEFINE(EH_FRAME_FLAGS, "a",
 804             [Define to the flags needed for the .section .eh_frame directive.])
 805 else
 806   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 807             [Define to the flags needed for the .section .eh_frame directive.])
 808 fi
 809
 810 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 811 [libgo_cv_c_unused_arguments],
 812 [CFLAGS_hold=$CFLAGS
 813 CFLAGS="$CFLAGS -Qunused-arguments"
 814 AC_COMPILE_IFELSE([[int i;]],
 815 [libgo_cv_c_unused_arguments=yes],
 816 [libgo_cv_c_unused_arguments=no])
 817 CFLAGS=$CFLAGS_hold])
 818
 819 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 820 libgo_cv_as_comdat_gnu, [
 821 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 822 CFLAGS_hold=$CFLAGS
 823 if test "$libgo_cv_c_unused_arguments" = yes; then
 824   CFLAGS="$CFLAGS -Qunused-arguments"
 825 fi
 826 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 827   libgo_cv_as_comdat_gnu=yes
 828 else
 829   libgo_cv_as_comdat_gnu=no
 830 fi
 831 CFLAGS=$CFLAGS_hold
 832 ])
 833 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 834   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 835             [Define if your assembler supports GNU comdat group syntax.])
 836 fi
 837
 838 AC_CACHE_CHECK([assembler supports pc related relocs],
 839 libgo_cv_as_x86_pcrel, [
 840 libgo_cv_as_x86_pcrel=yes
 841 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 842 CFLAGS_hold=$CFLAGS
 843 if test "$libgo_cv_c_unused_arguments" = yes; then
 844   CFLAGS="$CFLAGS -Qunused-arguments"
 845 fi
 846 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 847     libgo_cv_as_x86_pcrel=no
 848 fi
 849 CFLAGS=$CFLAGS_hold
 850 ])
 851 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 852   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 853             [Define if your assembler supports PC relative relocs.])
 854 fi
 855
 856 AC_CACHE_CHECK([assembler supports unwind section type],
 857 libgo_cv_as_x86_64_unwind_section_type, [
 858 libgo_cv_as_x86_64_unwind_section_type=yes
 859 echo '.section .eh_frame,"a",@unwind' > conftest.s
 860 CFLAGS_hold=$CFLAGS
 861 if test "$libgo_cv_c_unused_arguments" = yes; then
 862   CFLAGS="$CFLAGS -Qunused-arguments"
 863 fi
 864 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 865     libgo_cv_as_x86_64_unwind_section_type=no
 866 fi
 867 CFLAGS=$CFLAGS_hold
 868 ])
 869 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 870   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 871             [Define if your assembler supports unwind section type.])
 872 fi
 873
 874 AC_CACHE_SAVE
 875
 876 if test ${multilib} = yes; then
 877   multilib_arg="--enable-multilib"
 878 else
 879   multilib_arg=
 880 fi
 881
 882 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 883
 884 AC_CONFIG_COMMANDS([default],
 885 [if test -n "$CONFIG_FILES"; then
 886    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 887    # that multilib installs will end up installed in the correct place.
 888    # The testsuite needs it for multilib-aware ABI baseline files.
 889    # To work around this not being passed down from config-ml.in ->
 890    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 891    # append it here.  Only modify Makefiles that have just been created.
 892    #
 893    # Also, get rid of this simulated-VPATH thing that automake does.
 894    cat > vpsed << \_EOF
 895 s!`test -f '$<' || echo '$(srcdir)/'`!!
 896 _EOF
 897    for i in $SUBDIRS; do
 898     case $CONFIG_FILES in
 899      *${i}/Makefile*)
 900        #echo "Adding MULTISUBDIR to $i/Makefile"
 901        sed -f vpsed $i/Makefile > tmp
 902        grep '^MULTISUBDIR =' Makefile >> tmp
 903        mv tmp $i/Makefile
 904        ;;
 905     esac
 906    done
 907    rm vpsed
 908  fi
 909 ],
 910 [
 911 # Variables needed in config.status (file generation) which aren't already
 912 # passed by autoconf.
 913 SUBDIRS="$SUBDIRS"
 914 ])
 915
 916 AC_OUTPUT