libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5 AC_CONFIG_MACRO_DIRS([../config])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 if test -z "$ETAGS"; then
  66   ETAGS=etags
  67 fi
  68 AC_SUBST([ETAGS])
  69
  70 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  71 # rely on it - libiberty is built before texinfo.
  72 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  73 if test "x$MAKEINFO" = "x"; then
  74     MAKEINFO="@echo makeinfo missing; true"
  75     BUILD_INFO=
  76 else
  77     BUILD_INFO=info
  78     case "$MAKEINFO" in
  79       */missing\ makeinfo*)
  80         BUILD_INFO=
  81         AC_MSG_WARN([
  82 *** Makeinfo is missing. Info documentation will not be built.])
  83         ;;
  84       *)
  85         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  86           x*\ [[1-3]].* )
  87             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  88             BUILD_INFO=
  89             AC_MSG_WARN([
  90 *** Makeinfo is too old. Info documentation will not be built.])
  91           ;;
  92         esac
  93         ;;
  94     esac
  95 fi
  96 AC_SUBST(MAKEINFO)
  97 AC_SUBST(BUILD_INFO)
  98
  99 AC_CHECK_PROG(PERL, perl, perl, )
 100 if test x"$PERL" = x""; then
 101   HAVE_PERL='#'
 102 else
 103   HAVE_PERL=''
 104 fi
 105 AC_SUBST(HAVE_PERL)
 106
 107 AC_CANONICAL_HOST
 108
 109 dnl When we start using automake:
 110 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 111
 112 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 113 dnl to call AC_CHECK_PROG.
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 118 # Add --enable-multilib to configure.
 119 # Default to --enable-multilib
 120 AC_ARG_ENABLE(multilib,
 121 [  --enable-multilib       build many library versions (default)],
 122 [case "$enableval" in
 123   yes) multilib=yes ;;
 124   no)  multilib=no ;;
 125   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 126  esac],
 127               [multilib=yes])
 128
 129 # Even if the default multilib is not a cross compilation,
 130 # it may be that some of the other multilibs are.
 131 if test $cross_compiling = no && test $multilib = yes \
 132    && test "x${with_multisubdir}" != x ; then
 133    cross_compiling=maybe
 134 fi
 135
 136 # We may wish to install the target headers somewhere.
 137 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 138 dnl install-libiberty is disabled by default
 139
 140 AC_ARG_ENABLE(install-libiberty,
 141 [  --enable-install-libiberty       Install headers and library for end users],
 142 enable_install_libiberty=$enableval,
 143 enable_install_libiberty=no)dnl
 144
 145 # Option parsed, now set things appropriately.
 146 case x"$enable_install_libiberty" in
 147   xyes|x)
 148     target_header_dir=libiberty
 149     ;;
 150   xno)
 151     target_header_dir=
 152     ;;
 153   *)
 154     # This could be sanity-checked in various ways...
 155     target_header_dir="${enable_install_libiberty}"
 156     ;;
 157 esac
 158 AC_MSG_RESULT($enable_install_libiberty)
 159 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 160
 161 GCC_NO_EXECUTABLES
 162 AC_PROG_CC
 163 AC_GNU_SOURCE
 164 AC_SYS_LARGEFILE
 165 AC_PROG_CPP_WERROR
 166
 167 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 168                           -Wstrict-prototypes \
 169                           -Wshadow=local], [ac_libiberty_warn_cflags])
 170 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 171
 172 AC_PROG_CC_C_O
 173 # autoconf is lame and doesn't give us any substitution variable for this.
 174 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 175   NO_MINUS_C_MINUS_O=yes
 176 else
 177   OUTPUT_OPTION='-o $@'
 178 fi
 179 AC_SUBST(NO_MINUS_C_MINUS_O)
 180 AC_SUBST(OUTPUT_OPTION)
 181
 182 AC_C_CONST
 183 AC_C_INLINE
 184 AC_C_BIGENDIAN
 185
 186 dnl When we start using libtool:
 187 dnl Default to a non shared library.  This may be overridden by the
 188 dnl configure option --enable-shared.
 189 dnl AM_DISABLE_SHARED
 190
 191 dnl When we start using libtool:
 192 dnl AM_PROG_LIBTOOL
 193
 194 dnl When we start using automake:
 195 dnl AM_CONFIG_HEADER(config.h:config.in)
 196 AC_CONFIG_HEADER(config.h:config.in)
 197
 198 dnl When we start using automake:
 199 dnl AM_MAINTAINER_MODE
 200 dnl AC_EXEEXT
 201
 202 dnl When we start using automake:
 203 dnl AM_PROG_INSTALL
 204 AC_PROG_INSTALL
 205
 206 # Don't build the shared library for build.
 207 if [[ -n "${with_build_subdir}" ]]; then
 208   enable_shared=no
 209 fi
 210
 211 frag=
 212 case "${host}" in
 213   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 214                         frag=mh-aix ;;
 215   *-*-cxux7*)           frag=mh-cxux7 ;;
 216   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 217   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 218   i370-*-opened*)       frag=mh-openedition ;;
 219   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 220 esac
 221
 222 if [[ -n "${frag}" ]]; then
 223   frag=${libiberty_topdir}/libiberty/config/$frag
 224 fi
 225
 226 GCC_PICFLAG
 227
 228 # If they didn't specify --enable-shared, don't generate shared libs.
 229 case "${enable_shared}" in
 230   yes) shared=yes ;;
 231   no) shared=no ;;
 232   "") shared=no ;;
 233   *) shared=yes ;;
 234 esac
 235
 236 # ...unless --enable-host-shared was passed from top-level config:
 237 if [[ "${enable_host_shared}" = "yes" ]]; then
 238   shared=yes
 239 fi
 240
 241 if [[ "${shared}" != "yes" ]]; then
 242   PICFLAG=
 243 fi
 244 AC_SUBST(PICFLAG)
 245
 246 NOASANFLAG=
 247 case " ${CFLAGS} " in
 248   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 249   *\ -fsanitize=hwaddress\ *) NOASANFLAG=-fno-sanitize=hwaddress ;;
 250 esac
 251 AC_SUBST(NOASANFLAG)
 252
 253 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 254 AC_SUBST(CET_HOST_FLAGS)
 255
 256 echo "# Warning: this fragment is automatically generated" > temp-frag
 257
 258 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 259   echo "Appending ${frag} to xhost-mkfrag"
 260   echo "# Following fragment copied from ${frag}" >> temp-frag
 261   cat ${frag} >> temp-frag
 262 fi
 263
 264 # record if we want to build shared libs.
 265 if [[ "${shared}" = "yes" ]]; then
 266   echo enable_shared = yes >> temp-frag
 267 else
 268   echo enable_shared = no >> temp-frag
 269 fi
 270
 271 frag=xhost-mkfrag
 272 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 273
 274 host_makefile_frag=${frag}
 275 AC_SUBST_FILE(host_makefile_frag)
 276
 277 # It's OK to check for header files.  Although the compiler may not be
 278 # able to link anything, it had better be able to at least compile
 279 # something.
 280 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 281 AC_HEADER_SYS_WAIT
 282 AC_HEADER_TIME
 283
 284 libiberty_AC_DECLARE_ERRNO
 285
 286 # Determine sizes of some types.
 287 AC_CHECK_SIZEOF([int])
 288 AC_CHECK_SIZEOF([long])
 289 AC_CHECK_SIZEOF([size_t])
 290
 291 # Check for presense of long long
 292 AC_CHECK_TYPE([long long],
 293   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 294   [])
 295
 296 # Look for a 64-bit type.
 297 AC_MSG_CHECKING([for a 64-bit type])
 298 AC_CACHE_VAL(liberty_cv_uint64,
 299 [AC_TRY_COMPILE(
 300 [#ifdef HAVE_STDINT_H
 301 #include <stdint.h>
 302 #endif],
 303 [extern uint64_t foo;],
 304 liberty_cv_uint64=uint64_t,
 305 [AC_TRY_COMPILE(
 306 [#ifdef HAVE_LIMITS_H
 307 #include <limits.h>
 308 #endif
 309 #ifndef CHAR_BIT
 310 #define CHAR_BIT 8
 311 #endif],
 312 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 313 liberty_cv_uint64="unsigned long",
 314 [AC_TRY_COMPILE(
 315 [#ifdef HAVE_LIMITS_H
 316 #include <limits.h>
 317 #endif
 318 #ifndef CHAR_BIT
 319 #define CHAR_BIT 8
 320 #endif],
 321 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 322 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 323 AC_MSG_RESULT($liberty_cv_uint64)
 324 if test "$liberty_cv_uint64" != none; then
 325   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 326                      [Define to an unsigned 64-bit type available in the compiler.])
 327 fi
 328
 329 AC_TYPE_INTPTR_T
 330 AC_TYPE_UINTPTR_T
 331 AC_TYPE_SSIZE_T
 332
 333 # Given the above check, we always have uintptr_t or a fallback
 334 # definition.  So define HAVE_UINTPTR_T in case any imported code
 335 # relies on it.
 336 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 337
 338 AC_TYPE_PID_T
 339
 340 # This is the list of functions which libiberty will provide if they
 341 # are not available on the host.
 342
 343 funcs="asprintf"
 344 funcs="$funcs atexit"
 345 funcs="$funcs basename"
 346 funcs="$funcs bcmp"
 347 funcs="$funcs bcopy"
 348 funcs="$funcs bsearch"
 349 funcs="$funcs bzero"
 350 funcs="$funcs calloc"
 351 funcs="$funcs clock"
 352 funcs="$funcs ffs"
 353 funcs="$funcs getcwd"
 354 funcs="$funcs getpagesize"
 355 funcs="$funcs gettimeofday"
 356 funcs="$funcs index"
 357 funcs="$funcs insque"
 358 funcs="$funcs memchr"
 359 funcs="$funcs memcmp"
 360 funcs="$funcs memcpy"
 361 funcs="$funcs memmem"
 362 funcs="$funcs memmove"
 363 funcs="$funcs mempcpy"
 364 funcs="$funcs memset"
 365 funcs="$funcs mkstemps"
 366 funcs="$funcs putenv"
 367 funcs="$funcs random"
 368 funcs="$funcs rename"
 369 funcs="$funcs rindex"
 370 funcs="$funcs setenv"
 371 funcs="$funcs snprintf"
 372 funcs="$funcs sigsetmask"
 373 funcs="$funcs stpcpy"
 374 funcs="$funcs stpncpy"
 375 funcs="$funcs strcasecmp"
 376 funcs="$funcs strchr"
 377 funcs="$funcs strdup"
 378 funcs="$funcs strncasecmp"
 379 funcs="$funcs strndup"
 380 funcs="$funcs strnlen"
 381 funcs="$funcs strrchr"
 382 funcs="$funcs strstr"
 383 funcs="$funcs strtod"
 384 funcs="$funcs strtol"
 385 funcs="$funcs strtoul"
 386 funcs="$funcs strtoll"
 387 funcs="$funcs strtoull"
 388 funcs="$funcs strverscmp"
 389 funcs="$funcs tmpnam"
 390 funcs="$funcs vasprintf"
 391 funcs="$funcs vfprintf"
 392 funcs="$funcs vprintf"
 393 funcs="$funcs vsnprintf"
 394 funcs="$funcs vsprintf"
 395 funcs="$funcs waitpid"
 396 funcs="$funcs setproctitle"
 397
 398 # Also in the old function.def file: alloca, vfork, getopt.
 399
 400 vars="sys_errlist sys_nerr sys_siglist"
 401
 402 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 403  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 404  realpath setrlimit spawnve spawnvpe strerror strsignal sysconf sysctl \
 405  sysmp table times wait3 wait4"
 406
 407 # Darwin has sbrk, but it is deprecated and that produces build-time warnings
 408 # so do not check for it.
 409 case "${host}" in
 410   *-*-darwin*) ;;
 411   *) checkfuncs="$checkfuncs sbrk"
 412 esac
 413
 414 # These are neither executed nor required, but they help keep
 415 # autoheader happy without adding a bunch of text to acconfig.h.
 416 if test "x" = "y"; then
 417   AC_CHECK_FUNCS(asprintf atexit \
 418     basename bcmp bcopy bsearch bzero \
 419     calloc canonicalize_file_name clock \
 420     dup3 \
 421     ffs __fsetlocking \
 422     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 423     index insque \
 424     memchr memcmp memcpy memmem memmove memset mkstemps \
 425     on_exit \
 426     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 427     random realpath rename rindex \
 428     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 429      stpcpy stpncpy strcasecmp strchr strdup \
 430      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 431      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 432     table times tmpnam \
 433     vasprintf vfprintf vprintf vsprintf \
 434     wait3 wait4 waitpid)
 435   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 436   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 437   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 438   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 439 fi
 440
 441 # For each of these functions, if the host does not provide the
 442 # function we want to put FN.o in LIBOBJS, and if the host does
 443 # provide the function, we want to define HAVE_FN in config.h.
 444
 445 setobjs=
 446 CHECK=
 447 if test -n "${with_target_subdir}"; then
 448
 449   # We are being configured as a target library.  AC_REPLACE_FUNCS
 450   # may not work correctly, because the compiler may not be able to
 451   # link executables.  Note that we may still be being configured
 452   # native.
 453
 454   # If we are being configured for newlib, we know which functions
 455   # newlib provide and which ones we will be expected to provide.
 456
 457   if test "x${with_newlib}" = "xyes"; then
 458     AC_LIBOBJ([asprintf])
 459     AC_LIBOBJ([basename])
 460     AC_LIBOBJ([insque])
 461     AC_LIBOBJ([random])
 462     AC_LIBOBJ([strdup])
 463     AC_LIBOBJ([vasprintf])
 464
 465     for f in $funcs; do
 466       case "$f" in
 467         asprintf | basename | insque | random | strdup | vasprintf)
 468           ;;
 469         *)
 470           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 471           AC_DEFINE_UNQUOTED($n)
 472           ;;
 473       esac
 474     done
 475
 476     # newlib doesnt provide any of the variables in $vars, so we
 477     # dont have to check them here.
 478
 479     # Of the functions in $checkfuncs, newlib only has strerror.
 480     AC_DEFINE(HAVE_STRERROR)
 481
 482     setobjs=yes
 483
 484   fi
 485
 486   # If we are being configured for Mingw, we know which functions
 487   # Mingw provides and which ones we will be expected to provide.
 488
 489   case "${host}" in
 490   *-*-mingw*)
 491     AC_LIBOBJ([asprintf])
 492     AC_LIBOBJ([basename])
 493     AC_LIBOBJ([bcmp])
 494     AC_LIBOBJ([bcopy])
 495     AC_LIBOBJ([bzero])
 496     AC_LIBOBJ([clock])
 497     AC_LIBOBJ([ffs])
 498     AC_LIBOBJ([getpagesize])
 499     AC_LIBOBJ([index])
 500     AC_LIBOBJ([insque])
 501     AC_LIBOBJ([mempcpy])
 502     AC_LIBOBJ([mkstemps])
 503     AC_LIBOBJ([random])
 504     AC_LIBOBJ([rindex])
 505     AC_LIBOBJ([sigsetmask])
 506     AC_LIBOBJ([stpcpy])
 507     AC_LIBOBJ([stpncpy])
 508     AC_LIBOBJ([strndup])
 509     AC_LIBOBJ([strnlen])
 510     AC_LIBOBJ([strverscmp])
 511     AC_LIBOBJ([vasprintf])
 512     AC_LIBOBJ([waitpid])
 513
 514     for f in $funcs; do
 515       case "$f" in
 516         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 517           ;;
 518         *)
 519           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 520           AC_DEFINE_UNQUOTED($n)
 521           ;;
 522       esac
 523     done
 524
 525     # Mingw doesnt provide any of the variables in $vars, so we
 526     # dont have to check them here.
 527
 528     # Of the functions in $checkfuncs, Mingw only has strerror.
 529     AC_DEFINE(HAVE_STRERROR)
 530
 531     setobjs=yes
 532     ;;
 533
 534   *-*-msdosdjgpp)
 535     AC_LIBOBJ([vasprintf])
 536     AC_LIBOBJ([vsnprintf])
 537     AC_LIBOBJ([snprintf])
 538     AC_LIBOBJ([asprintf])
 539
 540     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 541              getcwd getpagesize getrusage gettimeofday \
 542              index insque memchr memcmp memcpy memmove memset psignal \
 543              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 544              strchr strdup strerror strncasecmp strrchr strstr strtod \
 545              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 546              vsprintf waitpid
 547     do
 548       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 549       AC_DEFINE_UNQUOTED($n)
 550     done
 551
 552
 553     setobjs=yes
 554     ;;
 555
 556   esac
 557
 558 else
 559
 560    # Not a target library, so we set things up to run the test suite.
 561    CHECK=really-check
 562
 563 fi
 564
 565 AC_SUBST(CHECK)
 566 AC_SUBST(target_header_dir)
 567
 568 case "${host}" in
 569   *-*-cygwin* | *-*-mingw*)
 570     AC_DEFINE(HAVE_SYS_ERRLIST)
 571     AC_DEFINE(HAVE_SYS_NERR)
 572     ;;
 573 esac
 574
 575 if test -z "${setobjs}"; then
 576   case "${host}" in
 577
 578   *-*-vxworks*)
 579     # Handle VxWorks configuration specially, since on VxWorks the
 580     # libraries are actually on the target board, not in the file
 581     # system.
 582     AC_LIBOBJ([basename])
 583     AC_LIBOBJ([getpagesize])
 584     AC_LIBOBJ([insque])
 585     AC_LIBOBJ([random])
 586     AC_LIBOBJ([strcasecmp])
 587     AC_LIBOBJ([strncasecmp])
 588     AC_LIBOBJ([strdup])
 589     AC_LIBOBJ([vfork])
 590     AC_LIBOBJ([waitpid])
 591     AC_LIBOBJ([vasprintf])
 592     for f in $funcs; do
 593       case "$f" in
 594         basename | getpagesize | insque | random | strcasecmp)
 595           ;;
 596         strncasecmp | strdup | vfork | waitpid | vasprintf)
 597           ;;
 598         *)
 599           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 600           AC_DEFINE_UNQUOTED($n)
 601           ;;
 602       esac
 603     done
 604
 605     # VxWorks doesn't provide any of the variables in $vars, so we
 606     # don't have to check them here.
 607
 608     # Of the functions in $checkfuncs, VxWorks only has strerror.
 609     AC_DEFINE(HAVE_STRERROR)
 610
 611     setobjs=yes
 612     ;;
 613
 614   esac
 615 fi
 616
 617 if test -z "${setobjs}"; then
 618
 619   case "${host}" in
 620
 621   *-*-android*)
 622     # On android, getpagesize is defined in unistd.h as a static inline
 623     # function, which AC_CHECK_FUNCS does not handle properly.
 624     ac_cv_func_getpagesize=yes
 625     ;;
 626
 627   hppa*-*-hpux*)
 628     # Replace system snprintf and vsnprintf with libiberty implementations.
 629     AC_LIBOBJ([snprintf])
 630     AC_LIBOBJ([vsnprintf])
 631     ;;
 632
 633   *-*-mingw32*)
 634     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 635     # macros, so the test below won't find them.
 636     libiberty_cv_var_sys_nerr=yes
 637     libiberty_cv_var_sys_errlist=yes
 638     ;;
 639
 640   *-*-msdosdjgpp*)
 641     # vfork and fork are stubs.
 642     ac_cv_func_vfork_works=no
 643     ;;
 644
 645   *-*-uwin*)
 646     # Under some versions of uwin, vfork is notoriously buggy and the test
 647     # can hang configure; on other versions, vfork exists just as a stub.
 648     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 649     ac_cv_func_vfork_works=no
 650     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 651     # macros (actually, these are imported from a DLL, but the end effect
 652     # is the same), so the test below won't find them.
 653     libiberty_cv_var_sys_nerr=yes
 654     libiberty_cv_var_sys_errlist=yes
 655     ;;
 656
 657   *-*-*vms*)
 658     # Under VMS, vfork works very different than on Unix. The standard test
 659     # won't work, and it isn't easily adaptable. It makes more sense to
 660     # just force it.
 661     ac_cv_func_vfork_works=yes
 662     ;;
 663
 664   esac
 665
 666   # We haven't set the list of objects yet.  Use the standard autoconf
 667   # tests.  This will only work if the compiler works.
 668   AC_ISC_POSIX
 669   AC_REPLACE_FUNCS($funcs)
 670   libiberty_AC_FUNC_C_ALLOCA
 671   AC_FUNC_FORK
 672   if test $ac_cv_func_vfork_works = no; then
 673     AC_LIBOBJ([vfork])
 674   fi
 675   # We only need _doprnt if we might use it to implement v*printf.
 676   if test $ac_cv_func_vprintf != yes \
 677      || test $ac_cv_func_vfprintf != yes \
 678      || test $ac_cv_func_vsprintf != yes; then
 679     AC_REPLACE_FUNCS(_doprnt)
 680   else
 681     AC_CHECK_FUNCS(_doprnt)
 682   fi
 683
 684   for v in $vars; do
 685     AC_MSG_CHECKING([for $v])
 686     AC_CACHE_VAL(libiberty_cv_var_$v,
 687       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern int $v [];]],[[if ($v [0]) return 1;]])],
 688                       [eval "libiberty_cv_var_$v=yes"],
 689                       [eval "libiberty_cv_var_$v=no"])])
 690     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 691       AC_MSG_RESULT(yes)
 692       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 693       AC_DEFINE_UNQUOTED($n)
 694     else
 695       AC_MSG_RESULT(no)
 696     fi
 697   done
 698
 699   # special check for _system_configuration because AIX <4.3.2 do not
 700   # contain the `physmem' member.
 701   AC_MSG_CHECKING([for external symbol _system_configuration])
 702   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 703                         [[double x = _system_configuration.physmem;]])],
 704     [AC_MSG_RESULT([yes])
 705     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 706               [Define if you have the _system_configuration variable.])],
 707     [AC_MSG_RESULT([no])])
 708
 709   AC_CHECK_FUNCS($checkfuncs)
 710   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 711   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc])
 712   case "${host}" in
 713       *-*-darwin*) ;; # Darwin's sbrk implementation is deprecated.
 714       *) AC_CHECK_DECLS([sbrk]);;
 715   esac
 716   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 717   AC_CHECK_DECLS([strverscmp])
 718   AC_CHECK_DECLS([strnlen])
 719   libiberty_NEED_DECLARATION(canonicalize_file_name)
 720 fi
 721
 722 # Figure out which version of pexecute to use.
 723 case "${host}" in
 724      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 725      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 726      *-*-msdos*)                pexecute=pex-msdos  ;;
 727      *)                         pexecute=pex-unix   ;;
 728 esac
 729 AC_SUBST(pexecute)
 730
 731 libiberty_AC_FUNC_STRNCMP
 732
 733 # Install a library built with a cross compiler in $(tooldir) rather
 734 # than $(libdir).
 735 if test -z "${with_cross_host}"; then
 736   INSTALL_DEST=libdir
 737 else
 738   INSTALL_DEST=tooldir
 739 fi
 740 AC_SUBST(INSTALL_DEST)
 741
 742 m4_pattern_allow(LIBOBJS)
 743 L=""
 744 for l in x $LIBOBJS; do
 745   case $l in
 746     x) ;;
 747     *) L="$L ./$l" ;;
 748   esac
 749 done
 750 LIBOBJS="$L"
 751
 752 dnl Required by html and install-html
 753 AC_SUBST(datarootdir)
 754 AC_SUBST(docdir)
 755 AC_SUBST(htmldir)
 756
 757 # We need multilib support, but only if configuring for the target.
 758 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 759 AC_CONFIG_COMMANDS([default],
 760   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 761 if test -n "$CONFIG_FILES"; then
 762   if test -n "${with_target_subdir}"; then
 763     # FIXME: We shouldn't need to set ac_file
 764     ac_file=Makefile
 765     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 766     . ${libiberty_topdir}/config-ml.in
 767   fi
 768 fi]],
 769 [[srcdir=${srcdir}
 770 host=${host}
 771 target=${target}
 772 with_target_subdir=${with_target_subdir}
 773 with_multisubdir=${with_multisubdir}
 774 ac_configure_args="--enable-multilib ${ac_configure_args}"
 775 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 776 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 777 libiberty_topdir=${libiberty_topdir}
 778 ]])
 779 AC_OUTPUT