gcc/ada/a-wtmoio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . W I D E _ T E X T _ I O . M O D U L A R _ I O          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --   Copyright (C) 1992,1993,1994,1995,1996 Free Software Foundation, Inc.  --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with Ada.Wide_Text_IO.Modular_Aux;
  36
  37 with System.Unsigned_Types; use System.Unsigned_Types;
  38 with System.WCh_Con;        use System.WCh_Con;
  39 with System.WCh_WtS;        use System.WCh_WtS;
  40
  41 package body Ada.Wide_Text_IO.Modular_IO is
  42
  43    subtype TFT is Ada.Wide_Text_IO.File_Type;
  44    --  File type required for calls to routines in Aux
  45
  46    package Aux renames Ada.Wide_Text_IO.Modular_Aux;
  47
  48    ---------
  49    -- Get --
  50    ---------
  51
  52    procedure Get
  53      (File  : in File_Type;
  54       Item  : out Num;
  55       Width : in Field := 0)
  56    is
  57    begin
  58       if Num'Size > Unsigned'Size then
  59          Aux.Get_LLU (TFT (File), Long_Long_Unsigned (Item), Width);
  60       else
  61          Aux.Get_Uns (TFT (File), Unsigned (Item), Width);
  62       end if;
  63
  64    exception
  65       when Constraint_Error => raise Data_Error;
  66    end Get;
  67
  68    procedure Get
  69      (Item  : out Num;
  70       Width : in Field := 0)
  71    is
  72    begin
  73       Get (Current_Input, Item, Width);
  74    end Get;
  75
  76    procedure Get
  77      (From : in Wide_String;
  78       Item : out Num;
  79       Last : out Positive)
  80    is
  81       S : constant String := Wide_String_To_String (From, WCEM_Upper);
  82       --  String on which we do the actual conversion. Note that the method
  83       --  used for wide character encoding is irrelevant, since if there is
  84       --  a character outside the Standard.Character range then the call to
  85       --  Aux.Gets will raise Data_Error in any case.
  86
  87    begin
  88       if Num'Size > Unsigned'Size then
  89          Aux.Gets_LLU (S, Long_Long_Unsigned (Item), Last);
  90       else
  91          Aux.Gets_Uns (S, Unsigned (Item), Last);
  92       end if;
  93
  94    exception
  95       when Constraint_Error => raise Data_Error;
  96    end Get;
  97
  98    ---------
  99    -- Put --
 100    ---------
 101
 102    procedure Put
 103      (File  : in File_Type;
 104       Item  : in Num;
 105       Width : in Field := Default_Width;
 106       Base  : in Number_Base := Default_Base)
 107    is
 108    begin
 109       if Num'Size > Unsigned'Size then
 110          Aux.Put_LLU (TFT (File), Long_Long_Unsigned (Item), Width, Base);
 111       else
 112          Aux.Put_Uns (TFT (File), Unsigned (Item), Width, Base);
 113       end if;
 114    end Put;
 115
 116    procedure Put
 117      (Item  : in Num;
 118       Width : in Field := Default_Width;
 119       Base  : in Number_Base := Default_Base)
 120    is
 121    begin
 122       Put (Current_Output, Item, Width, Base);
 123    end Put;
 124
 125    procedure Put
 126      (To   : out Wide_String;
 127       Item : in Num;
 128       Base : in Number_Base := Default_Base)
 129    is
 130       S : String (To'First .. To'Last);
 131
 132    begin
 133       if Num'Size > Unsigned'Size then
 134          Aux.Puts_LLU (S, Long_Long_Unsigned (Item), Base);
 135       else
 136          Aux.Puts_Uns (S, Unsigned (Item), Base);
 137       end if;
 138
 139       for J in S'Range loop
 140          To (J) := Wide_Character'Val (Character'Pos (S (J)));
 141       end loop;
 142    end Put;
 143
 144 end Ada.Wide_Text_IO.Modular_IO;